gentoo resync : 08.07.2021

1 files changed, 43 insertions, 0 deletions

diff --git a/net-analyzer/wapiti/wapiti-3.0.5.ebuild b/net-analyzer/wapiti/wapiti-3.0.5.ebuild
new file mode 100644
index 000000000000..4363743763ef
--- /dev/null
+++ b/net-analyzer/wapiti/wapiti-3.0.5.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( python3_{7..9} )
+PYTHON_REQ_USE='xml'
+
+inherit distutils-r1
+
+MY_P=${PN}3-${PV}
+DESCRIPTION="Web-application vulnerability scanner"
+HOMEPAGE="http://wapiti.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="kerberos ntlm"
+
+RDEPEND="dev-python/beautifulsoup:4[${PYTHON_USEDEP}]
+	dev-python/lxml[${PYTHON_USEDEP}]
+	dev-python/mako[${PYTHON_USEDEP}]
+	>=dev-python/requests-1.2.3[${PYTHON_USEDEP}]
+	dev-python/tld[${PYTHON_USEDEP}]
+	dev-python/yaswfp[${PYTHON_USEDEP}]
+	kerberos? ( dev-python/requests-kerberos[${PYTHON_USEDEP}] )
+	ntlm? ( dev-python/requests-ntlm[${PYTHON_USEDEP}] )"
+
+distutils_enable_tests --install pytest
+BDEPEND+=" test? ( dev-python/responses[${PYTHON_USEDEP}] )"
+# Many tests require execution of local test php server
+RESTRICT="test"
+
+S=${WORKDIR}/${MY_P}
+
+python_prepare_all() {
+	sed -e 's/"pytest-runner"//' \
+		-e "/find_packages/s/()/(exclude=['tests*'])/" \
+		-i setup.py || die
+	distutils-r1_python_prepare_all
+}