reinit the tree, so we can have metadata

4 files changed, 159 insertions, 0 deletions

diff --git a/net-analyzer/ettercap/Manifest b/net-analyzer/ettercap/Manifest
new file mode 100644
index 000000000000..4fa872acef7f
--- /dev/null
+++ b/net-analyzer/ettercap/Manifest
@@ -0,0 +1,6 @@
+DIST ettercap-0.8.2.tar.gz 8082561 SHA256 f38514f35bea58bfe6ef1902bfd4761de0379942a9aa3e175fc9348f4eef2c81 SHA512 18137b1cc518c9db3c9650157a5cbf09dbb665b79876a24875d6c5125e8923ebde543464adb61cf1d1244101242f4d66b80d94ef3b36aa265cefca7646aa6415 WHIRLPOOL 3acc250a8c8929cf3f5533edf0e4657b8670525542f1f727c0ecd2af560db9de9004c16e880f05577fffa5cedd5535b448d4e675e3adbd4ae11675ee8f229bfd
+EBUILD ettercap-0.8.2.ebuild 1635 SHA256 309b330402a61105b667d3c25e5191c6ed191640a96a6fbceaad33515cbe4d9a SHA512 898efe8f5940791be61dda3406628bb9d4b857148fe3cc7d8a879fd0eeb2d1407887bff50f3fa7722fec0f2c34f5d3cb938dbd88f60c71fd7fc0d115e1bf5632 WHIRLPOOL d53134759daebcb17095faa4fa2ab23e2602c7424779823d32d703412406859505f954fba60b7a9e0dae389de21c11ab8e44175e593ce96606fef0a3aee94a54
+EBUILD ettercap-9999.ebuild 1944 SHA256 f3ecb944900ba35d84ee88f3bc6d9bde3f344d3c31d356f000c5a3b03977be87 SHA512 1651bd8444ab6decf9f0284f99b6924e318e80a04edf8acc6061e3698d10a35e6eb91d24b0cb906e3b9dd07471654e6887a57a24c206b748dd0e84d1520d5e0f WHIRLPOOL 9e3ba242c075e365ac180aa2400208056e7e6f2171c1a1913ad02bc8d08b6f43157db09c35788a3a4e5a457b8ac2da3ef1fcfef3aba5578d843ae649b3d5e94d
+MISC ChangeLog 2622 SHA256 c47011a5aa62600858d363d96e9e215cd94417988b6950b147414f767c19f8bd SHA512 d2e4a950ed58c817e3f37e6b82bdf03cc94d88a61d0bc9c8db3d9d64f11b54456571e4071549ab1e337b7b0e20097143a9b890185f5dec019642ac7776101fec WHIRLPOOL 5187f295c1a5371512c7f76ac7880a244589483a3b7b5ee28fe9e76dbfd542b4670d5a88d4fabf0a2fdf3eace5f11445a0cb6186696985ba1b72a9584020a56a
+MISC ChangeLog-2015 22295 SHA256 ac8da1367d3f7b72f8a2621f2880416422009247cd51675a7a2a05d99b324e1f SHA512 9edad2e9cdf22c2dc7a289b4518db2e7a3219e9584404f922e6c7a31cbf4dbb1a6091de2b4599faf1aebbf5f3844b3a01cedb018a3142f6cc285efc5082a4518 WHIRLPOOL ce858740ffe5c912721948cb682d31e2b1fdfe85845dfb752d68d35dce864ff6884da5d458cf62ea93a25ce2843458e0295af3ae5cd0adaa4d8457838be25f46
+MISC metadata.xml 657 SHA256 6371ec1d11cb1075012628eb33eb6f7f10396c19f7314e1771a5edb76703a784 SHA512 0b682cb596f905882f2c0682c163d31410b94ca873a468db93e155103aeb1e943bff1c55bde1c9537478ce324d368f468bcb91c98f0aefb9dfa2a2239d7f73d5 WHIRLPOOL ff1a15b34ead7dddfab2af34b98872c5e9450ce661dc87bffe12ec8ef91622da9287267a074e403ff91129d7df1e4e36c80c4a967d96c94d57e805a620e4f0b5
diff --git a/net-analyzer/ettercap/ettercap-0.8.2.ebuild b/net-analyzer/ettercap/ettercap-0.8.2.ebuild
new file mode 100644
index 000000000000..f2f9af225aa5
--- /dev/null
+++ b/net-analyzer/ettercap/ettercap-0.8.2.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+
+inherit cmake-utils
+
+DESCRIPTION="A suite for man in the middle attacks"
+HOMEPAGE="https://github.com/Ettercap/ettercap"
+SRC_URI="https://github.com/Ettercap/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz" #mirror does not work
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="alpha amd64 arm ppc ppc64 sparc x86 ~x86-fbsd"
+IUSE="gtk ipv6 ncurses +plugins"
+
+RDEPEND="dev-libs/libbsd
+	dev-libs/libpcre
+	dev-libs/openssl
+	net-libs/libnet:1.1
+	>=net-libs/libpcap-0.8.1
+	sys-libs/zlib
+	gtk? (
+		>=dev-libs/atk-1.2.4
+		>=dev-libs/glib-2.2.2:2
+		media-libs/freetype
+		x11-libs/cairo
+		x11-libs/gdk-pixbuf:2
+		>=x11-libs/gtk+-2.2.2:2
+		>=x11-libs/pango-1.2.3
+	)
+	ncurses? ( >=sys-libs/ncurses-5.3 )
+	plugins? ( >=net-misc/curl-7.26.0 )"
+DEPEND="${RDEPEND}
+	sys-devel/flex
+	virtual/yacc"
+
+src_prepare() {
+	sed -i "s:Release:Release Gentoo:" CMakeLists.txt || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_enable ncurses CURSES)
+		$(cmake-utils_use_enable gtk)
+		$(cmake-utils_use_enable plugins)
+		$(cmake-utils_use_enable ipv6)
+		-DBUNDLED_LIBS=OFF
+		-DSYSTEM_LIBS=ON
+		-DINSTALL_SYSCONFDIR="${EROOT}"etc
+	)
+		#right now we only support gtk2, but ettercap also supports gtk3
+		#do we care? do we want to support both?
+
+		#we want to enable testing but it fails right now
+		#we want to disable the bundled crap, but we are missing at least "libcheck"
+		#if we want to enable tests, we need to fix it, and either package libcheck or allow bundled version
+		#$(cmake-utils_use_enable test TESTS)
+	cmake-utils_src_configure
+}
diff --git a/net-analyzer/ettercap/ettercap-9999.ebuild b/net-analyzer/ettercap/ettercap-9999.ebuild
new file mode 100644
index 000000000000..548bda336349
--- /dev/null
+++ b/net-analyzer/ettercap/ettercap-9999.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+
+inherit cmake-utils
+
+DESCRIPTION="A suite for man in the middle attacks"
+HOMEPAGE="https://github.com/Ettercap/ettercap"
+
+LICENSE="GPL-2+"
+SLOT="0"
+
+if [[ ${PV} == "9999" ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/Ettercap/${PN}.git"
+else
+	SRC_URI="https://github.com/Ettercap/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz" #mirror does not work
+	KEYWORDS="~alpha ~amd64 ~arm ~sparc ~x86 ~x86-fbsd"
+fi
+#IUSE="doc gtk ipv6 ncurses +plugins test"
+IUSE="doc gtk ipv6 libressl ncurses +plugins"
+
+RDEPEND="dev-libs/libbsd
+	dev-libs/libpcre
+	!libressl? ( dev-libs/openssl:0= )
+	libressl? ( dev-libs/libressl:0= )
+	net-libs/libnet:1.1
+	>=net-libs/libpcap-0.8.1
+	sys-libs/zlib
+	gtk? (
+		>=dev-libs/atk-1.2.4
+		>=dev-libs/glib-2.2.2:2
+		media-libs/freetype
+		x11-libs/cairo
+		x11-libs/gdk-pixbuf:2
+		>=x11-libs/gtk+-2.2.2:2
+		>=x11-libs/pango-1.2.3
+	)
+	ncurses? ( sys-libs/ncurses:0= )
+	plugins? ( >=net-misc/curl-7.26.0 )"
+DEPEND="${RDEPEND}
+	doc? ( app-text/ghostscript-gpl
+		sys-apps/groff )
+	sys-devel/flex
+	virtual/yacc"
+
+src_prepare() {
+	sed -i "s:Release:Release Gentoo:" CMakeLists.txt || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_enable ncurses CURSES)
+		$(cmake-utils_use_enable gtk)
+		$(cmake-utils_use_enable plugins)
+		$(cmake-utils_use_enable ipv6)
+		$(cmake-utils_use_enable doc PDF_DOCS)
+		-DBUNDLED_LIBS=OFF
+		-DSYSTEM_LIBS=ON
+		-DINSTALL_SYSCONFDIR="${EROOT}"etc
+	)
+		#right now we only support gtk2, but ettercap also supports gtk3
+		#do we care? do we want to support both?
+
+		#we want to enable testing but it fails right now
+		#we want to disable the bundled crap, but we are missing at least "libcheck"
+		#if we want to enable tests, we need to fix it, and either package libcheck or allow bundled version
+		#$(cmake-utils_use_enable test TESTS)
+	cmake-utils_src_configure
+}
diff --git a/net-analyzer/ettercap/metadata.xml b/net-analyzer/ettercap/metadata.xml
new file mode 100644
index 000000000000..a98ad417c5f9
--- /dev/null
+++ b/net-analyzer/ettercap/metadata.xml
@@ -0,0 +1,22 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>zerochaos@gentoo.org</email>
+		<name>Rick Farina</name>
+	</maintainer>
+	<maintainer type="person">
+		<email>ago@gentoo.org</email>
+		<name>Agostino Sarubbo</name>
+	</maintainer>
+	<maintainer type="project">
+		<email>netmon@gentoo.org</email>
+		<name>Gentoo network monitoring and analysis project</name>
+	</maintainer>
+	<use>
+		<flag name="plugins">Install ettercap plugins (et_*.so)</flag>
+	</use>
+	<upstream>
+		<remote-id type="github">Ettercap/ettercap</remote-id>
+	</upstream>
+</pkgmetadata>