gentoo auto-resync : 17:11:2024 - 03:03:09

3 files changed, 241 insertions, 0 deletions

diff --git a/media-video/Manifest.gz b/media-video/Manifest.gz
index 8e5ba3ad3914..3be139d68fff 100644
--- a/media-video/Manifest.gz
+++ b/media-video/Manifest.gz
diff --git a/media-video/ffmpeg-chromium/Manifest b/media-video/ffmpeg-chromium/Manifest
index 65b3b9a774c5..ed3995d6f94f 100644
--- a/media-video/ffmpeg-chromium/Manifest
+++ b/media-video/ffmpeg-chromium/Manifest
@@ -8,6 +8,7 @@ DIST ffmpeg-chromium-129.tar.xz 10424032 BLAKE2B dbe0b8c2d799958660b6a3ca0f1a8e6
 DIST ffmpeg-chromium-130.tar.xz 10420352 BLAKE2B 1b7711a3ee349d1e0d8ad8f761c8a38f78a5088dcf985d5da6423938fd93512b177d749949d4a6a3894f6b1faa4e4a0a0584067448d2ac5c886c00bbc25db89c SHA512 ee1a13634695ef5fb3e1a812420662e17449cab5e3c4e29611f9503b771ccb60c4821136160c51faeb4e18919efc3138ca8e034a27f44739a60cc3452d31572a
 DIST ffmpeg-chromium-131.tar.xz 10550352 BLAKE2B 985a4d0caede506050d2277af956723ae74236e2373d766862cef669031e91e44bcb51de219a76a1663f5cac5d85c74bd85215e96dffb14e6090d05ba6031f6c SHA512 1ccba5547ead2a64bcf72b6cdc9b6f9f8a6f817840125248b4d41efdf8376f8a69e8f7d3e4527cf155bb0a058ea6fc9f4cdb12d40a4b74189682e0db7b501ba3
 DIST ffmpeg-chromium-132.tar.xz 10588420 BLAKE2B 988fa447019d4fc3a26685bffd9345b4cf31ace3d39c31a070551f4d4f664cf2982b47c4b6265c2f3e2e7b0eca65effb68a9e25840b6a5ca61600a33d5901b8b SHA512 51856a226e29345c708356e1c6ae478239f1f634937e0ad4caa73e33c7bef1dbaeae97d8670ccd8f15e628fc3d399fdb3a4be1769c57d1283704743b6ce23b72
+DIST ffmpeg-chromium-133.tar.xz 10592716 BLAKE2B 81aac47dfb694c605242e762e6ced29714bc9780907afda6f61f55afef5416d1d998dda6785e8e64b7968f8b9cfc03bdcc4711535ccad65e6a9c55c626d30226 SHA512 798704455973439d3a1990e6344fe7bf1ebef370e7316cb813e898b84b4a39809e5681d54554a765a8f474731fcdf69897fb00f0b5e7ecc6b2e1bd6eef46a77a
 EBUILD ffmpeg-chromium-125.ebuild 6479 BLAKE2B f71dbdd8922f14df1bca7a085645fdf48b843efe57c022bb31e2728e886c57f80b7993c675a71fd25641b995332d6a8b8015ff6eef988d2b005fb8a1ae980878 SHA512 21c167a3ba28277ac66a400fce531848a5a04a4be344ac94a7de421b8e8814f3c7f3b5612ba91c5ef1607bba371211655f7dfc87a44b8c239b473c8a7f7062a1
 EBUILD ffmpeg-chromium-126.ebuild 6479 BLAKE2B 31d1f47cf086e7617bcabc9b342c0155a0bc2782c569e65c391a4d15161165ec6869027b7498d5a20cad433f00d5bc4d64944498170b8b408be4147390ea3910 SHA512 8e7fe997f6ab7ebe4a3e24ab695b8d978296cb368ba2aeda0e5acd4e0dba5ed32bb95b4ae4210ebeef6b178004da153d4fd530ed509c050e777924f786752c37
 EBUILD ffmpeg-chromium-127.ebuild 6479 BLAKE2B 7357fe026fd686a96c6098e5259cbbd745b9b3e16afe088f3f0001a40994599439b2638d387b3dbc2aa66eba28a366ec3d032a4ed5d18948d501f8ab8cad086b SHA512 59380fcf97cc23930f8c3ff4023a8351881e8cf11dcfdad16d8c40ebb9891074ae6661455cd3395f0ca55552e8c0782458a9409bb175401d0af2e8a4222b82f4
@@ -16,4 +17,5 @@ EBUILD ffmpeg-chromium-129.ebuild 6479 BLAKE2B 291953066345a7e3018ba56e1cd7ebb12
 EBUILD ffmpeg-chromium-130.ebuild 6481 BLAKE2B 195a106874439d9465ba8674a32c3192c0166ec840f179c8b15b90fc68a68440d4312c649fa4af63100bd1d4da7caf58184bbc1267327604c5027e5b56e8c05a SHA512 c3da69729075c2a4ca3ebb4f76e4d115c3b8b9f8971c89ef2b7489447184d81070a9fb954ba1d23a71b1fd896798dee63cbacdd21a996a9f94e30986b7144ac6
 EBUILD ffmpeg-chromium-131.ebuild 6481 BLAKE2B ee5b2d6aa7753dab3e8682e3c01a7a715017efc1497d669d9b1660d6637e7d77693fc1985f03cb983ce94e620a3e224b0d8721c4a810c91219e6aed31479d206 SHA512 057c3247ba3224e365e7b092a7bbd13ed03c2a69554af3ada24853df92fee6be07818d2b45e13130d09995c3364b699e0fa50483a882ed5f7ba40149a0aa7f02
 EBUILD ffmpeg-chromium-132.ebuild 6481 BLAKE2B 995a021e434a6cdb09a70967e33257f6c35a53fa2358cd0a3b8dbd49db701afee04626d88b01ecafcf4274b1316b45c49370bfe28760db08b579e4f958efb7c3 SHA512 ec690c21ec3b21634ff08ccc1b9e88f7547e8d884cfbec231de54b16999e1dc1dc46ad1de30ce556440f9a3abb5db2c32dda50348dd7ddef862e71f75bb800c7
+EBUILD ffmpeg-chromium-133.ebuild 6481 BLAKE2B 995a021e434a6cdb09a70967e33257f6c35a53fa2358cd0a3b8dbd49db701afee04626d88b01ecafcf4274b1316b45c49370bfe28760db08b579e4f958efb7c3 SHA512 ec690c21ec3b21634ff08ccc1b9e88f7547e8d884cfbec231de54b16999e1dc1dc46ad1de30ce556440f9a3abb5db2c32dda50348dd7ddef862e71f75bb800c7
 MISC metadata.xml 695 BLAKE2B 84fa4967572665812d4da8bb1a86a8b28a749892570cb1fca5c0515f860fbe8c472a91240f1d3b7b3109ccdbd32cf8da941c438cd9f332b763f2824e0e193ac8 SHA512 0069bcf32d2aa083c66e13579295e8ef96b9ac72b02f1436620000c71c4d1e335391838f9a9e56f7768bd13dbe13ce6f3f3674a303cf90cc658360825867c3f9
diff --git a/media-video/ffmpeg-chromium/ffmpeg-chromium-133.ebuild b/media-video/ffmpeg-chromium/ffmpeg-chromium-133.ebuild
new file mode 100644
index 000000000000..eab885d6038b
--- /dev/null
+++ b/media-video/ffmpeg-chromium/ffmpeg-chromium-133.ebuild
@@ -0,0 +1,239 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit flag-o-matic toolchain-funcs
+
+COMMIT=591ae4b02eaff9a03e2ec863da895128b0b49910
+DESCRIPTION="FFmpeg built specifically for codec support in Chromium-based browsers"
+HOMEPAGE="https://ffmpeg.org/"
+SRC_URI="https://deps.gentoo.zip/media-video/${P}.tar.xz"
+
+LICENSE="
+	!gpl? ( LGPL-2.1 )
+	gpl? ( GPL-2 )
+"
+SLOT="${PV}"
+
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64"
+
+# Options to use as use_enable in the foo[:bar] form.
+# This will feed configure with $(use_enable foo bar)
+# or $(use_enable foo foo) if no :bar is set.
+# foo is added to IUSE.
+FFMPEG_FLAG_MAP=(
+		cpudetection:runtime-cpudetect debug
+		+gpl
+		vaapi vdpau vulkan
+		nvenc:ffnvcodec
+		# Threads; we only support pthread for now but ffmpeg supports more
+		+threads:pthreads
+)
+
+IUSE="
+	${FFMPEG_FLAG_MAP[@]%:*}
+"
+
+# Strings for CPU features in the useflag[:configure_option] form
+# if :configure_option isn't set, it will use 'useflag' as configure option
+ARM_CPU_FEATURES=(
+	cpu_flags_arm_thumb:armv5te
+	cpu_flags_arm_v6:armv6
+	cpu_flags_arm_thumb2:armv6t2
+	cpu_flags_arm_neon:neon
+	cpu_flags_arm_vfp:vfp
+	cpu_flags_arm_vfpv3:vfpv3
+	cpu_flags_arm_v8:armv8
+	cpu_flags_arm_asimddp:dotprod
+	cpu_flags_arm_i8mm:i8mm
+)
+ARM_CPU_REQUIRED_USE="
+	arm64? ( cpu_flags_arm_v8 )
+	cpu_flags_arm_v8? ( cpu_flags_arm_vfpv3 cpu_flags_arm_neon )
+	cpu_flags_arm_neon? (
+		cpu_flags_arm_vfp
+		arm? ( cpu_flags_arm_thumb2 )
+	)
+	cpu_flags_arm_vfpv3? ( cpu_flags_arm_vfp )
+	cpu_flags_arm_thumb2? ( cpu_flags_arm_v6 )
+	cpu_flags_arm_v6? (
+		arm? ( cpu_flags_arm_thumb )
+	)
+"
+X86_CPU_FEATURES_RAW=( 3dnow:amd3dnow 3dnowext:amd3dnowext aes:aesni avx:avx avx2:avx2 fma3:fma3 fma4:fma4 mmx:mmx
+					   mmxext:mmxext sse:sse sse2:sse2 sse3:sse3 ssse3:ssse3 sse4_1:sse4 sse4_2:sse42 xop:xop )
+X86_CPU_FEATURES=( ${X86_CPU_FEATURES_RAW[@]/#/cpu_flags_x86_} )
+X86_CPU_REQUIRED_USE="
+	cpu_flags_x86_avx2? ( cpu_flags_x86_avx )
+	cpu_flags_x86_fma4? ( cpu_flags_x86_avx )
+	cpu_flags_x86_fma3? ( cpu_flags_x86_avx )
+	cpu_flags_x86_xop?  ( cpu_flags_x86_avx )
+	cpu_flags_x86_avx?  ( cpu_flags_x86_sse4_2 )
+	cpu_flags_x86_aes? ( cpu_flags_x86_sse4_2 )
+	cpu_flags_x86_sse4_2?  ( cpu_flags_x86_sse4_1 )
+	cpu_flags_x86_sse4_1?  ( cpu_flags_x86_ssse3 )
+	cpu_flags_x86_ssse3?  ( cpu_flags_x86_sse3 )
+	cpu_flags_x86_sse3?  ( cpu_flags_x86_sse2 )
+	cpu_flags_x86_sse2?  ( cpu_flags_x86_sse )
+	cpu_flags_x86_sse?  ( cpu_flags_x86_mmxext )
+	cpu_flags_x86_mmxext?  ( cpu_flags_x86_mmx )
+	cpu_flags_x86_3dnowext?  ( cpu_flags_x86_3dnow )
+	cpu_flags_x86_3dnow?  ( cpu_flags_x86_mmx )
+"
+
+CPU_FEATURES_MAP=(
+	${ARM_CPU_FEATURES[@]}
+	${X86_CPU_FEATURES[@]}
+)
+IUSE="${IUSE}
+	${CPU_FEATURES_MAP[@]%:*}"
+
+CPU_REQUIRED_USE="
+	${ARM_CPU_REQUIRED_USE}
+	${X86_CPU_REQUIRED_USE}
+"
+
+RDEPEND="
+	>=media-libs/opus-1.0.2-r2
+	vaapi? ( >=media-libs/libva-1.2.1-r1:0= )
+	nvenc? ( >=media-libs/nv-codec-headers-11.1.5.3 )
+	vdpau? ( >=x11-libs/libvdpau-0.7 )
+	vulkan? ( >=media-libs/vulkan-loader-1.3.277:= )
+"
+
+DEPEND="${RDEPEND}
+	vulkan? ( >=dev-util/vulkan-headers-1.3.277 )
+"
+BDEPEND="
+	>=dev-build/make-3.81
+	virtual/pkgconfig
+	cpu_flags_x86_mmx? ( || ( >=dev-lang/nasm-2.13 >=dev-lang/yasm-1.3 ) )
+"
+
+REQUIRED_USE="
+	vulkan? ( threads )
+	${CPU_REQUIRED_USE}"
+RESTRICT="
+	test
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-120.patch
+	"${FILESDIR}"/chromium.patch
+)
+
+src_prepare() {
+	export revision=git-N-g${COMMIT:0:10}
+	default
+
+	# -fdiagnostics-color=auto gets appended after user flags which
+	# will ignore user's preference.
+	sed -i -e '/check_cflags -fdiagnostics-color=auto/d' configure || die
+
+	echo 'include $(SRC_PATH)/ffbuild/libffmpeg.mak' >> Makefile || die
+}
+
+src_configure() {
+	local myconf=( )
+
+	# Bug #918997. Will probably be fixed upstream in the next release.
+	use vulkan && append-ldflags -Wl,-z,muldefs
+
+	local ffuse=( "${FFMPEG_FLAG_MAP[@]}" )
+
+	for i in "${ffuse[@]#+}" ; do
+		myconf+=( $(use_enable ${i%:*} ${i#*:}) )
+	done
+
+	# CPU features
+	for i in "${CPU_FEATURES_MAP[@]}" ; do
+		use ${i%:*} || myconf+=( --disable-${i#*:} )
+	done
+
+	# Try to get cpu type based on CFLAGS.
+	# Bug #172723
+	# We need to do this so that features of that CPU will be better used
+	# If they contain an unknown CPU it will not hurt since ffmpeg's configure
+	# will just ignore it.
+	for i in $(get-flag mcpu) $(get-flag march) ; do
+		[[ ${i} = native ]] && i="host" # bug #273421
+		myconf+=( --cpu=${i} )
+		break
+	done
+
+	# LTO support, bug #566282, bug #754654, bug #772854
+	if [[ ${ABI} != x86 ]] && tc-is-lto; then
+		# Respect -flto value, e.g -flto=thin
+		local v="$(get-flag flto)"
+		[[ -n ${v} ]] && myconf+=( "--enable-lto=${v}" ) || myconf+=( "--enable-lto" )
+	fi
+	filter-lto
+
+	# Mandatory configuration
+	myconf=(
+		--disable-stripping
+		# This is only for hardcoded cflags; those are used in configure checks that may
+		# interfere with proper detections, bug #671746 and bug #645778
+		# We use optflags, so that overrides them anyway.
+		--disable-optimizations
+		--disable-libcelt # bug #664158
+		"${myconf[@]}"
+	)
+
+	# cross compile support
+	if tc-is-cross-compiler ; then
+		myconf+=( --enable-cross-compile --arch=$(tc-arch-kernel) --cross-prefix=${CHOST}- --host-cc="$(tc-getBUILD_CC)" )
+		case ${CHOST} in
+			*mingw32*)
+				myconf+=( --target-os=mingw32 )
+				;;
+			*linux*)
+				myconf+=( --target-os=linux )
+				;;
+		esac
+	fi
+
+	# Use --extra-libs if needed for LIBS
+	set -- "${S}/configure" \
+		--prefix="${EPREFIX}/usr" \
+		--libdir="${EPREFIX}/usr/$(get_libdir)" \
+		--shlibdir="${EPREFIX}/usr/$(get_libdir)" \
+		--cc="$(tc-getCC)" \
+		--cxx="$(tc-getCXX)" \
+		--ar="$(tc-getAR)" \
+		--nm="$(tc-getNM)" \
+		--strip="$(tc-getSTRIP)" \
+		--ranlib="$(tc-getRANLIB)" \
+		--pkg-config="$(tc-getPKG_CONFIG)" \
+		--optflags="${CFLAGS}" \
+		--disable-all \
+		--disable-autodetect \
+		--disable-error-resilience \
+		--disable-everything \
+		--disable-faan \
+		--disable-iconv \
+		--disable-network \
+		--enable-avcodec \
+		--enable-avformat \
+		--enable-avutil \
+		--enable-libopus \
+		--enable-decoder=aac,flac,h264,libopus,mp3,pcm_alaw,pcm_f32le,pcm_mulaw,pcm_s16be,pcm_s16le,pcm_s24be,pcm_s24le,pcm_s32le,pcm_u8,theora,vorbis,vp8 \
+		--enable-demuxer=aac,flac,matroska,mov,mp3,ogg,wav \
+		--enable-parser=aac,flac,h264,mpegaudio,opus,vorbis,vp3,vp8,vp9 \
+		--enable-pic \
+		--enable-static \
+		"${myconf[@]}" \
+		${EXTRA_FFMPEG_CONF}
+
+	echo "${@}"
+	"${@}" || die
+}
+
+src_compile() {
+	emake V=1 libffmpeg
+}
+
+src_install() {
+	emake V=1 DESTDIR="${D}" install-libffmpeg
+}