gentoo resync : 25.08.2020

2 files changed, 151 insertions, 0 deletions

diff --git a/media-video/qmplay2/Manifest b/media-video/qmplay2/Manifest
index 28fdc692e88e..dea3ec38f00c 100644
--- a/media-video/qmplay2/Manifest
+++ b/media-video/qmplay2/Manifest
@@ -1,6 +1,8 @@
 DIST QMPlay2-src-20.05.02.tar.xz 1553364 BLAKE2B f436a8e970278d47ef1ade86d07fd3460c2628d7f93c238093425779f896c44b3e0c7b4c6a40ffc8b79f1749563016cb62ac853c94b236859287066bfbdbe59f SHA512 b587d80128c334450552b2a6f0fa4c7426409b4d7a7bcca2065f83eab3e2f8b7ecc0df92f50fa276f42c84a201222cae2dd7f5c3f4bbdabf321895212db936b6
+DIST QMPlay2-src-20.07.04.tar.xz 1552680 BLAKE2B cc53ef842f91312f72e8d347a2d6d2e4239fe9435d0b7ac39e47e9f1f48a9a570ce614dd496512079d3701e1823ab75123b40ad752fdd2348cdb7bc8de425225 SHA512 4a6316f03d1b77bcd6c08de0daefc3f29b4c8c575eae9f901951e2b43f2739904136b9455f567b66fc9a4e4c64fe92584608f1878dd8c30c0352ea9ee1e2e314
 DIST qmplay2-19.12.19.tar.gz 1285009 BLAKE2B e4f644513ac0e7d33574e4b1b157dfe775222df74ba5041099e9bcaa87f8b052880dfd2c19005380783d9ca7b2bdbf7aedb233e12e2af839d40af224981d593e SHA512 a03d70c5bd3b2644810b9ec5fd39bd0340ddcc460646228a2799053a27117a54ead09f046b58ff7e0ae2cd959a92980cf8336a12d49ef297e1de30dd32f604a0
 EBUILD qmplay2-19.12.19-r2.ebuild 3482 BLAKE2B 79cd37a3a6cf4298dccfe958f7a5d2dd39d28dbf07cf60dacaf90a3a750ca5d41261086ce28c5b3ca28acf733eee2bab18c22465c486b614c0791eefe4a5bd51 SHA512 5298d2fb7995031bb24657254dfc89fb3852e02458c9fee7fae621ee4d9852e5920bb4db5ef67d0a476b66f827ec51644c6c7bb23f84a380754b0d4597a63b71
 EBUILD qmplay2-20.05.02.ebuild 3577 BLAKE2B 01d9a11780e3ef63e9c5e60cd65cd2649090f1e9cd8f4928b8f00296fa99c602458622dab63f282d3e5ab143d0f2e7b422be783d16bc75c37603e97c05633454 SHA512 3e60673d0c778b37ecb80390b2dc7d21b3e6997b7593cefd8730244b17220ba9b87d0ef03b050b2ec8c41968a97ed856f617791e677cedbedcfbddfd273b4c85
+EBUILD qmplay2-20.07.04.ebuild 3577 BLAKE2B 01d9a11780e3ef63e9c5e60cd65cd2649090f1e9cd8f4928b8f00296fa99c602458622dab63f282d3e5ab143d0f2e7b422be783d16bc75c37603e97c05633454 SHA512 3e60673d0c778b37ecb80390b2dc7d21b3e6997b7593cefd8730244b17220ba9b87d0ef03b050b2ec8c41968a97ed856f617791e677cedbedcfbddfd273b4c85
 EBUILD qmplay2-9999.ebuild 3577 BLAKE2B 01d9a11780e3ef63e9c5e60cd65cd2649090f1e9cd8f4928b8f00296fa99c602458622dab63f282d3e5ab143d0f2e7b422be783d16bc75c37603e97c05633454 SHA512 3e60673d0c778b37ecb80390b2dc7d21b3e6997b7593cefd8730244b17220ba9b87d0ef03b050b2ec8c41968a97ed856f617791e677cedbedcfbddfd273b4c85
 MISC metadata.xml 1822 BLAKE2B d6c18ae3653d2a809609ed350c20796a690ecb69e5f3b9b06d134524596379f8ebfb565b22c584a3fccff153b0771ede17d67c91d029f6e26668ba91e0ee5d79 SHA512 5ed1acf242b8e02dd3f31564000b13dc91c9c25f750ba6f93a296e5fa9c83b48a0a6c92f868a5b088187870af8b3c345ab0c79935e8afcea7f86125ceed80afc
diff --git a/media-video/qmplay2/qmplay2-20.07.04.ebuild b/media-video/qmplay2/qmplay2-20.07.04.ebuild
new file mode 100644
index 000000000000..264d28c79f26
--- /dev/null
+++ b/media-video/qmplay2/qmplay2-20.07.04.ebuild
@@ -0,0 +1,149 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake xdg-utils
+
+DESCRIPTION="A Qt-based video player, which can play most formats and codecs"
+HOMEPAGE="https://github.com/zaps166/QMPlay2"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/zaps166/QMPlay2"
+else
+	SRC_URI="https://github.com/zaps166/QMPlay2/releases/download/${PV}/QMPlay2-src-${PV}.tar.xz"
+	KEYWORDS="~amd64 ~x86"
+	S="${WORKDIR}/QMPlay2-src-${PV}"
+fi
+
+LICENSE="LGPL-3"
+SLOT="0"
+
+IUSE="avdevice +audiofilters +alsa cdio cuvid dbus extensions
+	gme inputs libass modplug notifications opengl portaudio
+	pulseaudio sid shaders vaapi vdpau +videofilters visualizations vulkan xv"
+
+REQUIRED_USE="
+	audiofilters? ( || ( alsa portaudio pulseaudio ) )
+	extensions? ( dbus )
+	shaders? ( vulkan )"
+
+RDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtsvg:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	media-video/ffmpeg
+	|| (
+		dev-qt/qtgui:5[X(-)]
+		dev-qt/qtgui:5[xcb(-)]
+	)
+	alsa? ( media-libs/alsa-lib )
+	cdio? ( dev-libs/libcdio[cddb] )
+	dbus? ( dev-qt/qtdbus:5 )
+	extensions? (
+		dev-qt/qtdeclarative:5
+		media-libs/taglib
+	)
+	gme? ( media-libs/game-music-emu )
+	libass? ( media-libs/libass )
+	opengl? ( virtual/opengl )
+	portaudio? ( media-libs/portaudio )
+	pulseaudio? ( media-sound/pulseaudio )
+	sid? ( media-libs/libsidplayfp )
+	shaders? ( >=media-libs/shaderc-2020.1 )
+	vaapi? (
+		>=media-video/ffmpeg-4.1.3[vaapi]
+		x11-libs/libva[drm,opengl]
+	)
+	vdpau? ( media-video/ffmpeg[vdpau] )
+	videofilters? ( dev-qt/qtconcurrent:5 )
+	vulkan? (
+		>=dev-qt/qtgui-5.14.1:5[vulkan]
+		>=media-libs/vulkan-loader-1.2.133
+	)
+	xv? ( x11-libs/libXv )"
+
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-qt/linguist-tools:5
+	virtual/pkgconfig"
+
+src_prepare() {
+	# disable compress man pages
+	sed -r \
+		-e 's/if\(GZIP\)/if\(TRUE\)/' \
+		-e 's/(install.+QMPlay2\.1)\.gz/\1/' \
+		-i src/gui/CMakeLists.txt || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		# core
+		-DUSE_LINK_TIME_OPTIMIZATION=false
+		-DUSE_ALSA=$(usex alsa)
+		-DUSE_AUDIOCD=$(usex cdio)
+		-DUSE_FREEDESKTOP_NOTIFICATIONS=$(usex dbus) # https://github.com/zaps166/QMPlay2/issues/134
+		-DUSE_LIBASS=$(usex libass)
+		-DUSE_NOTIFY=$(usex notifications)
+		-DUSE_OPENGL=$(usex opengl)
+		-DUSE_VULKAN=$(usex vulkan)
+		-DUSE_GLSLC=$(usex shaders)
+		-DUSE_XVIDEO=$(usex xv)
+
+		# ffmpeg
+		-DUSE_FFMPEG_AVDEVICE=$(usex avdevice)
+		-DUSE_FFMPEG_VAAPI=$(usex vaapi)
+		-DUSE_FFMPEG_VDPAU=$(usex vdpau)
+
+		# chiptune
+		-DUSE_CHIPTUNE_GME=$(usex gme)
+		-DUSE_CHIPTUNE_SID=$(usex sid)
+
+		# modules
+		-DUSE_AUDIOFILTERS=$(usex audiofilters)
+		-DUSE_CUVID=$(usex cuvid)
+		-DUSE_INPUTS=$(usex inputs)
+		-DUSE_MODPLUG=$(usex modplug)
+		-DUSE_PORTAUDIO=$(usex portaudio)
+		-DUSE_PULSEAUDIO=$(usex pulseaudio)
+		-DUSE_VIDEOFILTERS=$(usex videofilters)
+		-DUSE_VISUALIZATIONS=$(usex visualizations)
+
+		# extensions
+		-DUSE_EXTENSIONS=$(usex extensions)
+		-DUSE_TAGLIB=$(usex extensions)
+		-DUSE_LASTFM=$(usex extensions)
+		-DUSE_LYRICS=$(usex extensions)
+		-DUSE_MEDIABROWSER=$(usex extensions)
+		-DUSE_MPRIS2=$(usex extensions)
+	)
+
+	# find and link vulkan libs permanently
+	if use vulkan; then
+		mycmakeargs+=( -DQMVK_FIND_VULKAN=true )
+	fi
+
+	if [[ ${PV} == *9999 ]]; then
+		mycmakeargs+=( USE_GIT_VERSION=true )
+	else
+		mycmakeargs+=( USE_GIT_VERSION=false )
+	fi
+
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+	xdg_desktop_database_update
+}