gentoo resync : 29.12.2022

2 files changed, 139 insertions, 0 deletions

diff --git a/media-video/qmplay2/Manifest b/media-video/qmplay2/Manifest
index 1b018d767dae..d63e890b3da2 100644
--- a/media-video/qmplay2/Manifest
+++ b/media-video/qmplay2/Manifest
@@ -1,6 +1,8 @@
 DIST QMPlay2-src-21.12.24.tar.xz 1609604 BLAKE2B 0b2e1ddc0a089ee0d8d37d3d14f2273b53b4df078c6f1571a5ed44c1234133c3eb21461287eb12027ccb686d844f28939b8dfe236c11fd6cb5831dc825708301 SHA512 fddd1d28a0c7f8ad7fa8ef02bb1181ee2fe4babfd8b9c026d2b1d518c1cf28528c64d296b0050d7c51b1ae558baf2d04fe808b276816d98e839a85dbc67ac136
 DIST QMPlay2-src-22.03.19.tar.xz 1612136 BLAKE2B 5b5ff6d4b37c3d1c46e28839e078e3f7bfa4d2d9d88f552a574cc6560ee18996dda8649f47973f2af97224e2ebebbffadf3c6f52b8064fc30ff63c72d7f578e2 SHA512 687fa0b8bc7d3b99432419aeeaedc83773dc3b12d8133872f663419db7123e7093895bc8ac5b64f03acefd1c4e5cf916210ebbef6b6494284e15487763f0d571
+DIST QMPlay2-src-22.06.16.tar.xz 1613312 BLAKE2B b626b184f3d16c85dead8c61a5ccc0bb7b11e6a064fc6a3b4aedbd8a2e9631ac2182a00a5dd9c9de1feb5f357b45ce3d7dc66f9b46d88153cc3bce3d5f869a65 SHA512 f04a83422bcfa105b3ec33843962b844b6efed6700a26426f4a73c0588dc1179985d612748d5c74f6214fdcff86a035272473a35a54a234ec0abef388b0517fe
 EBUILD qmplay2-21.12.24.ebuild 3336 BLAKE2B 3d8976098e21861788cd780ff3f3e305dd87f9ede70210b121500f4acb1d9c23ca06558056f9df5107d632ba090f6548720b750e9b3306be08caf60518566ff1 SHA512 ccd37998da35fcb75b16d8b3387d4234b5990a25f52d552f83f64123275af069077a09179d0817495825d22d3312dce4bf5c75f6c8685044513e74998063f048
 EBUILD qmplay2-22.03.19.ebuild 3324 BLAKE2B 9c4ce7611259460080fbdfb72266426f5b3cd7e71942b87df7cb043f3bb22518a951154bab2bd9ecf2adb424222bff19d3703a015465107c7f17e95f0b541179 SHA512 e4d324867eb01f01f874acd717fe76e30bccc24e8d19d3a2939d977cad168ee4fe6e7ee101c93eff58dc34506e99852f5e08cf53d5a03b1ce65473ab090973a8
+EBUILD qmplay2-22.06.16.ebuild 3324 BLAKE2B 9c4ce7611259460080fbdfb72266426f5b3cd7e71942b87df7cb043f3bb22518a951154bab2bd9ecf2adb424222bff19d3703a015465107c7f17e95f0b541179 SHA512 e4d324867eb01f01f874acd717fe76e30bccc24e8d19d3a2939d977cad168ee4fe6e7ee101c93eff58dc34506e99852f5e08cf53d5a03b1ce65473ab090973a8
 EBUILD qmplay2-9999.ebuild 3324 BLAKE2B 9c4ce7611259460080fbdfb72266426f5b3cd7e71942b87df7cb043f3bb22518a951154bab2bd9ecf2adb424222bff19d3703a015465107c7f17e95f0b541179 SHA512 e4d324867eb01f01f874acd717fe76e30bccc24e8d19d3a2939d977cad168ee4fe6e7ee101c93eff58dc34506e99852f5e08cf53d5a03b1ce65473ab090973a8
 MISC metadata.xml 1342 BLAKE2B c3e3b0477c49c00aec65e05ec5d940f8fc126efe074460a1f67c39b98654ccc3819669e47ad5ba83ed977a72f9ee41606d9409ef3a377cfb511bdc01aff0ce70 SHA512 2eb6b7c2b72abf37a2165f35ed7cab51653a425d294f4ec866d0c6b4dd53ffbf8b30306a987bb4bba1e952ea246815dc59e22a6e9141151a844ae1b7cbd36bde
diff --git a/media-video/qmplay2/qmplay2-22.06.16.ebuild b/media-video/qmplay2/qmplay2-22.06.16.ebuild
new file mode 100644
index 000000000000..b7b2b595e0e7
--- /dev/null
+++ b/media-video/qmplay2/qmplay2-22.06.16.ebuild
@@ -0,0 +1,137 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake xdg
+
+DESCRIPTION="A Qt-based video player, which can play most formats and codecs"
+HOMEPAGE="https://github.com/zaps166/QMPlay2"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/zaps166/QMPlay2"
+else
+	SRC_URI="https://github.com/zaps166/QMPlay2/releases/download/${PV}/QMPlay2-src-${PV}.tar.xz"
+	S="${WORKDIR}/QMPlay2-src-${PV}"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="LGPL-3"
+SLOT="0"
+
+IUSE="avdevice +audiofilters +alsa cdio cuvid extensions gme inputs libass
+	modplug notifications opengl pipewire portaudio pulseaudio sid shaders
+	+taglib vaapi vdpau videofilters visualizations vulkan xv"
+
+REQUIRED_USE="
+	audiofilters? ( || ( alsa pipewire portaudio pulseaudio ) )
+	shaders? ( vulkan )"
+
+RDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtsvg:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	media-video/ffmpeg
+	|| (
+		dev-qt/qtgui:5[X(-)]
+		dev-qt/qtgui:5[xcb(-)]
+	)
+	alsa? ( media-libs/alsa-lib )
+	cdio? ( dev-libs/libcdio[cddb] )
+	extensions? ( dev-qt/qtdeclarative:5 )
+	gme? ( media-libs/game-music-emu )
+	libass? ( media-libs/libass )
+	opengl? ( virtual/opengl )
+	pipewire? ( media-video/pipewire )
+	portaudio? ( media-libs/portaudio )
+	pulseaudio? ( media-sound/pulseaudio )
+	sid? ( media-libs/libsidplayfp )
+	shaders? ( >=media-libs/shaderc-2020.1 )
+	taglib? ( media-libs/taglib	)
+	vaapi? (
+		>=media-video/ffmpeg-4.1.3[vaapi]
+		x11-libs/libva
+	)
+	vdpau? ( media-video/ffmpeg[vdpau] )
+	videofilters? ( dev-qt/qtconcurrent:5 )
+	vulkan? (
+		>=dev-qt/qtgui-5.14.1:5[vulkan]
+		>=media-libs/vulkan-loader-1.2.133
+	)
+	xv? ( x11-libs/libXv )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="dev-qt/linguist-tools:5"
+
+src_prepare() {
+	# disable compress man pages
+	sed -r \
+		-e 's/if\(GZIP\)/if\(TRUE\)/' \
+		-e 's/(install.+QMPlay2\.1)\.gz/\1/' \
+		-i src/gui/CMakeLists.txt || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		# core
+		-DUSE_LINK_TIME_OPTIMIZATION=false
+		-DUSE_UPDATES=OFF
+		-DUSE_ALSA=$(usex alsa)
+		-DUSE_AUDIOCD=$(usex cdio)
+		-DUSE_DBUS_SUSPEND=ON
+		-DUSE_FREEDESKTOP_NOTIFICATIONS=ON
+		-DUSE_LIBASS=$(usex libass)
+		-DUSE_NOTIFY=$(usex notifications)
+		-DUSE_OPENGL=$(usex opengl)
+		-DUSE_VULKAN=$(usex vulkan)
+		-DUSE_GLSLC=$(usex shaders)
+		-DUSE_XVIDEO=$(usex xv)
+
+		# ffmpeg
+		-DUSE_FFMPEG_AVDEVICE=$(usex avdevice)
+		-DUSE_FFMPEG_VAAPI=$(usex vaapi)
+		-DUSE_FFMPEG_VDPAU=$(usex vdpau)
+
+		# chiptune
+		-DUSE_CHIPTUNE_GME=$(usex gme)
+		-DUSE_CHIPTUNE_SID=$(usex sid)
+
+		# modules
+		-DUSE_AUDIOFILTERS=$(usex audiofilters)
+		-DUSE_CUVID=$(usex cuvid)
+		-DUSE_INPUTS=$(usex inputs)
+		-DUSE_MODPLUG=$(usex modplug)
+		-DUSE_PIPEWIRE=$(usex pipewire)
+		-DUSE_PORTAUDIO=$(usex portaudio)
+		-DUSE_PULSEAUDIO=$(usex pulseaudio)
+		-DUSE_TAGLIB=$(usex taglib)
+		-DUSE_VIDEOFILTERS=$(usex videofilters)
+		-DUSE_VISUALIZATIONS=$(usex visualizations)
+
+		# extensions
+		-DUSE_EXTENSIONS=$(usex extensions)
+	)
+
+	if use extensions; then
+		# Move inside an if, to remove unused option warning
+		mycmakeargs+=(
+			-DUSE_LASTFM=ON
+			-DUSE_LYRICS=ON
+			-DUSE_MEDIABROWSER=ON
+			-DUSE_MPRIS2=ON
+		)
+	fi
+
+	if [[ ${PV} == *9999 ]]; then
+		mycmakeargs+=( -DUSE_GIT_VERSION=true )
+	else
+		mycmakeargs+=( -DUSE_GIT_VERSION=false )
+	fi
+
+	cmake_src_configure
+}