gentoo auto-resync : 21:11:2023 - 23:10:38

2 files changed, 284 insertions, 0 deletions

diff --git a/media-video/mpv/Manifest b/media-video/mpv/Manifest
index f9d6c927cbf7..56bc8f32c075 100644
--- a/media-video/mpv/Manifest
+++ b/media-video/mpv/Manifest
@@ -1,6 +1,8 @@
 AUX mpv-0.36.0-sub-match-audio.patch 1621 BLAKE2B aa774960703d3b5f2f5a8c3dc327bba0fa8865fdc676c68fdaf79cf46f7209fd629db5e523f4f845ce0aaf17d0a8c910c6c1c2c8fabe98340e5c61a31d8c4d36 SHA512 c260ad68a7e003f43b0b4525fb7eff5f5784851beba303a934b90b0e69476c5912cc75217a78820884d1fdcc1e7431574bdb6b55cb9e434735cdfbdeadfb3a0e
 AUX mpv-0.36.0-tests-odr.patch 1118 BLAKE2B 8a87385922af6ee08adc3972ce2271f1f700842dba8415ac27f04ba7147b070b665279c7b4d50e06b85d258a9ab47db23a82a9f9a4db444efb97a677ef2f6317 SHA512 8ccec2ce0108468c8fc048d3e892b1c8f177f434809d899f38a00526515b1453e0cb5cd2bfd5843568a025fda314fd172c94c548c8e144514353904066b917f3
 DIST mpv-0.36.0.tar.gz 3409178 BLAKE2B 7260c265f02918d4caf72d8d8ecc9d4ab9783d66d675bd683a2f9c228404ad978c6fe0aa50f486b5257740176bc26f8abde7eff20d89019d5f701ec78c7743e1 SHA512 51f455a425ea5aac47acb3582d0f958a34248a2290a8d6887d22bcb9385fe8d1ab5d7f09d5408cfecfb73c1ec85d1b8ec8958e45a4941d3f711a2e580187472f
+DIST mpv-0.37.0.tar.gz 3384190 BLAKE2B 31d8d47ed7ae94540189fe05b7ea63f5b0d5c987a22191f931e4bd90664d05dca4c7e0bd0e05fcdf48b977e38e5f8eec0d2572265f2cf4a969a8a9a9dbf83d68 SHA512 a2f7fb3837312ec59c50427af7be3b2b1b6175a53ccc7463e81503284fc4047dff32cb105d665d80be77ee1ae775d4512b71584f324d6d202c9a7fc1fab53257
 EBUILD mpv-0.36.0-r1.ebuild 7516 BLAKE2B a100b97f0ccd7d85c5188740a1aa008a1d2958cf897de1dc346710570eecf055e7236d6898f93cb3c3a7773a7565a973aebebd72a6b3626037215e5058c4122d SHA512 31e3bc8fb3d87f55c5ff8037a2662359b00f3d005e31e7033cb3eaf3b2c0cb531a604e61ce964977a633efa104189deeca9ec579ef0ad5db3ee4e5538658c59a
+EBUILD mpv-0.37.0.ebuild 7035 BLAKE2B 9abfe0ab4e55a4ea05f90bd2aa0e3e1b4a4ede174db39d40b8f14a4d71efc084f7388eeac43c1e3b6e32e82f5e505b1b8476f603c796c0b764f2b9961688fb08 SHA512 9a1c9d648433437150dab1105dfb09f64c7051423971be26e6f90d564460c42aa138266f117eb0771f10229e9b49f1e99415bb40832808bf26aa768b51cf510c
 EBUILD mpv-9999.ebuild 7046 BLAKE2B 438d3c48b4caead14e5ac7767586b62b4ef570132cfb2a4088f8addb41172c71bf50a95a7b64c3b6352624fc7d4a874284e0209be1970111a8299f5cc5a8bc97 SHA512 ac97e421fdc49914b87829083c5884dff6d7a4806063936bde55fe4e41fb52589231dcbe77ffb0d5b76cd7e603b79704d2435b94e0107d1bda7f2321a1bc305b
 MISC metadata.xml 2324 BLAKE2B 6fe57270fef9275f47b0d7f282fbf4ff5c4a76c74e43820a8e0a4d56348eb72dc89dfdb06a9ff9a2b6f73d35102f861200d6c8c6f4dc41cfb4e42ff69d70da8a SHA512 0418e3315b4ded29714099d80075f61f6d1b38d9109bbb3bc372abbaceb14f705d5798eac2c14ef0fd0e1c557785291a4acb5e773dffb46f0b7f7962bf38d041
diff --git a/media-video/mpv/mpv-0.37.0.ebuild b/media-video/mpv/mpv-0.37.0.ebuild
new file mode 100644
index 000000000000..0fc7a044aa14
--- /dev/null
+++ b/media-video/mpv/mpv-0.37.0.ebuild
@@ -0,0 +1,282 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+LUA_COMPAT=( lua5-1 luajit )
+PYTHON_COMPAT=( python3_{10..12} )
+inherit flag-o-matic lua-single meson optfeature pax-utils python-single-r1 xdg
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/mpv-player/mpv.git"
+else
+	SRC_URI="https://github.com/mpv-player/mpv/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86 ~amd64-linux"
+fi
+
+DESCRIPTION="Media player for the command line"
+HOMEPAGE="https://mpv.io/"
+
+LICENSE="LGPL-2.1+ GPL-2+ BSD ISC MIT" #506946
+SLOT="0/2" # soname
+IUSE="
+	+X +alsa aqua archive bluray cdda +cli coreaudio debug +drm dvb
+	dvd +egl gamepad +iconv jack javascript jpeg lcms libcaca +libmpv
+	+lua mmal nvenc openal opengl pipewire pulseaudio raspberry-pi
+	rubberband sdl selinux sixel sndio test tools +uchardet vaapi
+	vdpau vulkan wayland xv zimg zlib
+"
+REQUIRED_USE="
+	${PYTHON_REQUIRED_USE}
+	|| ( cli libmpv )
+	egl? ( || ( X drm wayland ) )
+	lua? ( ${LUA_REQUIRED_USE} )
+	nvenc? ( || ( egl opengl vulkan ) )
+	opengl? ( || ( X aqua ) )
+	test? ( cli )
+	tools? ( cli )
+	uchardet? ( iconv )
+	vaapi? ( || ( X drm wayland ) )
+	vdpau? ( X )
+	vulkan? ( || ( X wayland ) )
+	xv? ( X )
+"
+RESTRICT="!test? ( test )"
+
+# raspberry-pi: default to -bin given non-bin is known broken (bug #893422)
+COMMON_DEPEND="
+	media-libs/libass:=[fontconfig]
+	>=media-libs/libplacebo-6.338:=[opengl?,vulkan?]
+	>=media-video/ffmpeg-4.4:=[encode,threads,vaapi?,vdpau?]
+	X? (
+		x11-libs/libX11
+		x11-libs/libXScrnSaver
+		x11-libs/libXext
+		x11-libs/libXpresent
+		x11-libs/libXrandr
+		xv? ( x11-libs/libXv )
+	)
+	alsa? ( media-libs/alsa-lib )
+	archive? ( app-arch/libarchive:= )
+	bluray? ( media-libs/libbluray:= )
+	cdda? (
+		dev-libs/libcdio-paranoia:=
+		dev-libs/libcdio:=
+	)
+	drm? (
+		x11-libs/libdrm
+		egl? ( media-libs/mesa[gbm(+)] )
+	)
+	dvd? (
+		media-libs/libdvdnav
+		media-libs/libdvdread:=
+	)
+	egl? (
+		media-libs/libglvnd
+		media-libs/libplacebo[opengl]
+	)
+	gamepad? ( media-libs/libsdl2[joystick] )
+	iconv? (
+		virtual/libiconv
+		uchardet? ( app-i18n/uchardet )
+	)
+	jack? ( virtual/jack )
+	javascript? ( dev-lang/mujs:= )
+	jpeg? ( media-libs/libjpeg-turbo:= )
+	lcms? ( media-libs/lcms:2 )
+	libcaca? ( media-libs/libcaca )
+	lua? ( ${LUA_DEPS} )
+	openal? ( media-libs/openal )
+	opengl? ( media-libs/libglvnd[X?] )
+	pipewire? ( media-video/pipewire:= )
+	pulseaudio? ( media-libs/libpulse )
+	raspberry-pi? (
+		|| (
+			media-libs/raspberrypi-userland-bin
+			media-libs/raspberrypi-userland
+		)
+	)
+	rubberband? ( media-libs/rubberband )
+	sdl? ( media-libs/libsdl2[sound,threads,video] )
+	sixel? ( media-libs/libsixel )
+	sndio? ( media-sound/sndio:= )
+	vaapi? ( media-libs/libva:=[X?,drm(+)?,wayland?] )
+	vdpau? ( x11-libs/libvdpau )
+	vulkan? (
+		media-libs/shaderc
+		media-libs/vulkan-loader[X?,wayland?]
+	)
+	wayland? (
+		dev-libs/wayland
+		dev-libs/wayland-protocols
+		x11-libs/libxkbcommon
+	)
+	zimg? ( media-libs/zimg )
+	zlib? ( sys-libs/zlib:= )
+"
+RDEPEND="
+	${COMMON_DEPEND}
+	selinux? ( sec-policy/selinux-mplayer )
+	tools? ( ${PYTHON_DEPS} )
+"
+DEPEND="
+	${COMMON_DEPEND}
+	X? ( x11-base/xorg-proto )
+	dvb? ( virtual/linuxtv-dvb-headers )
+	nvenc? ( media-libs/nv-codec-headers )
+	wayland? ( dev-libs/wayland-protocols )
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	virtual/pkgconfig
+	cli? ( dev-python/docutils )
+	wayland? ( dev-util/wayland-scanner )
+"
+
+pkg_setup() {
+	use lua && lua-single_pkg_setup
+	python-single-r1_pkg_setup
+}
+
+src_configure() {
+	if use !debug; then
+		if use test; then
+			einfo "Skipping -DNDEBUG due to USE=test"
+		else
+			append-cppflags -DNDEBUG # treated specially
+		fi
+	fi
+
+	mpv_feature_multi() {
+		local use set
+		for use in ${1} ${2}; do
+			use ${use} || set=disabled
+		done
+		echo -D${3-${2}}=${set-enabled}
+	}
+
+	local emesonargs=(
+		$(meson_use cli cplayer)
+		$(meson_use libmpv)
+		$(meson_use test tests)
+
+		$(meson_feature cli html-build)
+		$(meson_feature cli manpage-build)
+		-Dpdf-build=disabled
+
+		-Dbuild-date=false
+
+		# misc options
+		$(meson_feature archive libarchive)
+		$(meson_feature bluray libbluray)
+		$(meson_feature cdda)
+		-Dcplugins=enabled
+		$(meson_feature dvb dvbin)
+		$(meson_feature dvd dvdnav)
+		$(meson_feature gamepad sdl2-gamepad)
+		$(meson_feature iconv)
+		$(meson_feature javascript)
+		-Dlibavdevice=enabled
+		$(meson_feature lcms lcms2)
+		-Dlua=$(usex lua "${ELUA}" disabled)
+		$(meson_feature rubberband)
+		-Dsdl2=$(use gamepad || use sdl && echo enabled || echo disabled) #857156
+		$(meson_feature uchardet)
+		-Dvapoursynth=disabled # only available in overlays
+		$(meson_feature zimg)
+		$(meson_feature zlib)
+
+		# audio output
+		$(meson_feature alsa)
+		$(meson_feature coreaudio)
+		$(meson_feature jack)
+		$(meson_feature openal)
+		$(meson_feature pipewire)
+		$(meson_feature pulseaudio pulse)
+		$(meson_feature sdl sdl2-audio)
+		$(meson_feature sndio)
+
+		# video output
+		$(meson_feature X x11)
+		$(meson_feature aqua cocoa)
+		$(meson_feature drm)
+		$(meson_feature jpeg)
+		$(meson_feature libcaca caca)
+		$(meson_feature mmal rpi-mmal)
+		$(meson_feature sdl sdl2-video)
+		$(meson_feature sixel)
+		$(meson_feature wayland)
+		$(meson_feature xv)
+
+		-Dgl=$(use egl || use libmpv || use opengl || use raspberry-pi &&
+			echo enabled || echo disabled)
+		$(meson_feature egl)
+		$(mpv_feature_multi egl X egl-x11)
+		$(mpv_feature_multi egl drm gbm) # gbm is only used by egl-drm
+		$(mpv_feature_multi egl drm egl-drm)
+		$(mpv_feature_multi egl wayland egl-wayland)
+		$(meson_feature libmpv plain-gl)
+		$(mpv_feature_multi opengl X gl-x11)
+		$(mpv_feature_multi opengl aqua gl-cocoa)
+		$(meson_feature raspberry-pi rpi)
+
+		$(meson_feature vulkan)
+		$(meson_feature vulkan shaderc)
+
+		# hardware decoding
+		$(meson_feature nvenc cuda-hwaccel)
+		$(meson_feature nvenc cuda-interop)
+
+		$(meson_feature vaapi)
+		$(mpv_feature_multi vaapi X vaapi-x11)
+		$(mpv_feature_multi vaapi drm vaapi-drm)
+		$(mpv_feature_multi vaapi wayland vaapi-wayland)
+
+		$(meson_feature vdpau)
+		$(mpv_feature_multi vdpau opengl vdpau-gl-x11)
+
+		$(mpv_feature_multi aqua opengl videotoolbox-gl)
+
+		# notable options left to automagic
+		#dmabuf-wayland: USE="drm wayland" + plus memfd_create support
+		#vulkan-interop: USE="vulkan" + >=ffmpeg-6.1
+		# TODO?: perhaps few more similar compound options should be left auto
+	)
+
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	if use lua; then
+		insinto /usr/share/${PN}
+		doins -r TOOLS/lua
+
+		if use cli && use lua_single_target_luajit; then
+			pax-mark -m "${ED}"/usr/bin/${PN}
+		fi
+	fi
+
+	if use tools; then
+		dobin TOOLS/{mpv_identify.sh,umpv}
+		newbin TOOLS/idet.sh mpv_idet.sh
+		python_fix_shebang "${ED}"/usr/bin/umpv
+	fi
+
+	if use cli; then
+		dodir /usr/share/doc/${PF}/html
+		mv "${ED}"/usr/share/doc/{mpv,${PF}/html}/mpv.html || die
+		mv "${ED}"/usr/share/doc/{mpv,${PF}/examples} || die
+	fi
+
+	local GLOBIGNORE=*/*build*:*/*policy*
+	dodoc RELEASE_NOTES DOCS/*.{md,rst}
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	optfeature "URL support with USE=lua" net-misc/yt-dlp
+}