gentoo resync : 20.03.2022

3 files changed, 138 insertions, 41 deletions

diff --git a/media-video/libva-utils/Manifest b/media-video/libva-utils/Manifest
index 016c0913caa0..643b84ef4bf1 100644
--- a/media-video/libva-utils/Manifest
+++ b/media-video/libva-utils/Manifest
@@ -1,5 +1,7 @@
 AUX libva-utils-2.10.0_test_in_sandbox.patch 526 BLAKE2B 8275555ee777b8e66852730a084911a44b74ebb3cfe378d5f60d2e1a95f3cf8185506788af2e8606a23bc233623a59eaa7554b68f16555ba35b941b1c59dae3a SHA512 980424fbbd5215da672819963fd5e36a7900955752f42632cf8258efef577f5a511e8a961e273141c4acf83f8c6bb5783561c256b730992a03bd9c914510209e
 DIST libva-utils-2.13.0.tar.gz 1230036 BLAKE2B 4e70a13fb9b4362713b6f461a0ee199b8f7e9d9cbac7bc664c11870db92a87873d73306b5777c554830b932a15e726965e1db3591fd1349fb62f068617dd8558 SHA512 81c7c122a4d1bdf8d390a4ea3e0d34499158fb7b7fe0f7aa9d556158895e755139975fd01d73d883897c0a4390612d131b6349febbdf16fa5edcd46a6a82acd2
+DIST libva-utils-2.14.0.tar.gz 1241072 BLAKE2B 17f1e0badb05e39f3979bde652dfe6832e8bfb2accd99fd6c5d972090cfce630e2a93ad96e5d17bc7bd9c393b12c2a7b066cb60a715c2dbb128dd263c480bcca SHA512 631e9becf5b2f6d083906962c004c9080d2e2b2d98b6003638a31dde8ad4e2549606301b97e88822471e29007232fc470a2116be09dc0c55d3cc2df6a45a7be1
 EBUILD libva-utils-2.13.0.ebuild 2365 BLAKE2B 9bf8572aabdbf1eecb5d7ee1d4fb66d1193d1082862e5a1e8839c819c57d2f79f242ecc8dfa83571a9e6e461c0d68b4d68763985797c79436bba78f8d064b4d2 SHA512 78e1c3582322968308b135f165296481881d0cc07d34d4defe2388c6a791283fc077c03e66dd68598c60e967b4648fe349fcf94a9c170dba5612be20e0e47e39
-EBUILD libva-utils-9999.ebuild 2369 BLAKE2B 3685bf3d3c73824ff81b79a24e9997fb163d3625fabc2c69a179ad7474c22a268fa79e1ccf7eda593b34fb7018e5f4e838f54668eec1c88814cb80c079dbad75 SHA512 cf1e632c2a0236f7f7b370ad2c47fc1c363fcb391ac38c46d545f22ec9653f9916fc84e6f817320fb3381b2e0ef693ea3631907af0913532f05b579df869046f
+EBUILD libva-utils-2.14.0.ebuild 2012 BLAKE2B 92feda6a6485ba3ad93f2e29e9d555c93492455bb87c37296ada700311d29b95c45b6504f6ebcfe45cb721cf64a1acd92dd13f7f23386d2b517e4d5b0ce4a382 SHA512 1ec5d41926a58d4d57c7025abcf61c07fde1c211f6a897e314730de8a24eb51ec08458a50b43c86a5e59cc4df38510fa6fe9d691452f32ed9436e1db26414ec3
+EBUILD libva-utils-9999.ebuild 2012 BLAKE2B 92feda6a6485ba3ad93f2e29e9d555c93492455bb87c37296ada700311d29b95c45b6504f6ebcfe45cb721cf64a1acd92dd13f7f23386d2b517e4d5b0ce4a382 SHA512 1ec5d41926a58d4d57c7025abcf61c07fde1c211f6a897e314730de8a24eb51ec08458a50b43c86a5e59cc4df38510fa6fe9d691452f32ed9436e1db26414ec3
 MISC metadata.xml 761 BLAKE2B 5aaf0b0be9bf41a00d7df2bfd5975ea0f0e2b257e091b77752db8e29ed358a919fd9c9aaf6296f665a2d5f8864766893044064f8ccff9be7d66c41993d6bd454 SHA512 e5fdc3992abc81021b2ec939ea4ab11a997ae0374e3bc6ba87b49127a7478e023283614a9fc39ec9f33f5221469587196d932bf85da9f0a99f134673d6d5f006
diff --git a/media-video/libva-utils/libva-utils-2.14.0.ebuild b/media-video/libva-utils/libva-utils-2.14.0.ebuild
new file mode 100644
index 000000000000..4decf846c639
--- /dev/null
+++ b/media-video/libva-utils/libva-utils-2.14.0.ebuild
@@ -0,0 +1,96 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit meson
+
+DESCRIPTION="Collection of utilities and tests for VA-API"
+HOMEPAGE="https://01.org/linuxmedia/vaapi"
+if [[ ${PV} = *9999 ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/intel/libva-utils"
+else
+	SRC_URI="https://github.com/intel/libva-utils/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86 ~amd64-linux ~x86-linux"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="examples putsurface test +vainfo wayland X"
+RESTRICT="test" # Tests must be run manually
+
+REQUIRED_USE="
+	putsurface? ( || ( wayland X ) )
+	|| ( examples putsurface test vainfo )
+"
+
+BDEPEND="virtual/pkgconfig"
+
+if [[ ${PV} = *9999 ]] ; then
+	DEPEND="~x11-libs/libva-${PV}:=[drm(+),wayland?,X?]"
+else
+	DEPEND=">=x11-libs/libva-$(ver_cut 1-2).0:=[drm(+),wayland?,X?]"
+fi
+
+DEPEND+="
+	wayland? ( >=dev-libs/wayland-1.0.6 )
+	X? ( >=x11-libs/libX11-1.6.2 )
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	default
+
+	local sed_args=()
+
+	# Fix broken dependency check
+	# https://github.com/intel/libva-utils/pull/260
+	sed_args+=(-e "s/dependency('drm'/dependency('libdrm'/")
+
+	if ! use examples ; then
+		sed_args+=(
+			-e "/^subdir('decode')$/d"
+			-e "/^subdir('encode')$/d"
+			-e "/^subdir('videoprocess')$/d"
+			-e "/^subdir('vendor\/intel')$/d"
+			-e "/^subdir('vendor\/intel\/sfcsample')$/d"
+		)
+	fi
+
+	if ! use putsurface ; then
+		sed_args+=(-e "/^subdir('putsurface')$/d")
+	fi
+
+	if ! use vainfo ; then
+		sed_args+=(-e "/^subdir('vainfo')$/d")
+	fi
+
+	if [[ ${#sed_args[@]} -gt 0 ]] ; then
+		sed "${sed_args[@]}" -i meson.build || die
+	fi
+}
+
+src_configure() {
+	local emesonargs=(
+		-Ddrm=true
+		$(meson_use X x11)
+		$(meson_use wayland)
+		$(meson_use test tests)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	if ! use test ; then
+		rm -f "${ED}"/usr/bin/test_va_api || die
+	fi
+}
+
+pkg_postinst() {
+	if use test ; then
+		elog "Tests must be run manually with the test_va_api binary"
+	fi
+}
diff --git a/media-video/libva-utils/libva-utils-9999.ebuild b/media-video/libva-utils/libva-utils-9999.ebuild
index 2f790d95839d..4decf846c639 100644
--- a/media-video/libva-utils/libva-utils-9999.ebuild
+++ b/media-video/libva-utils/libva-utils-9999.ebuild
@@ -1,9 +1,9 @@
-# Copyright 1999-2021 Gentoo Authors
+# Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
 
-inherit autotools
+inherit meson
 
 DESCRIPTION="Collection of utilities and tests for VA-API"
 HOMEPAGE="https://01.org/linuxmedia/vaapi"
@@ -11,31 +11,26 @@ if [[ ${PV} = *9999 ]] ; then
 	inherit git-r3
 	EGIT_REPO_URI="https://github.com/intel/libva-utils"
 else
-	# Tarball with pre-built 'configure' not always available, portage use tarballs
-	# without pre-built 'configure' as they are always available upstream.
-	# SRC_URI="https://github.com/intel/libva-utils/releases/download/${PV}/${P}.tar.bz2"
 	SRC_URI="https://github.com/intel/libva-utils/archive/${PV}.tar.gz -> ${P}.tar.gz"
 	KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86 ~amd64-linux ~x86-linux"
 fi
 
 LICENSE="MIT"
 SLOT="0"
-IUSE="+drm examples putsurface test test-va-api +vainfo wayland X"
-RESTRICT="!test? ( test )"
+IUSE="examples putsurface test +vainfo wayland X"
+RESTRICT="test" # Tests must be run manually
 
 REQUIRED_USE="
-	|| ( drm wayland X )
 	putsurface? ( || ( wayland X ) )
-	putsurface? ( drm )
-	|| ( examples putsurface test-va-api vainfo )
+	|| ( examples putsurface test vainfo )
 "
 
 BDEPEND="virtual/pkgconfig"
 
 if [[ ${PV} = *9999 ]] ; then
-	DEPEND="~x11-libs/libva-${PV}:=[drm?,wayland?,X?]"
+	DEPEND="~x11-libs/libva-${PV}:=[drm(+),wayland?,X?]"
 else
-	DEPEND=">=x11-libs/libva-$(ver_cut 1-2).0:=[drm?,wayland?,X?]"
+	DEPEND=">=x11-libs/libva-$(ver_cut 1-2).0:=[drm(+),wayland?,X?]"
 fi
 
 DEPEND+="
@@ -44,54 +39,58 @@ DEPEND+="
 "
 RDEPEND="${DEPEND}"
 
-PATCHES=( "${FILESDIR}/${PN}-2.10.0_test_in_sandbox.patch" )
-
-# CONTRIBUTING.md and README.md are avaialbe only in .tar.gz tarballs and in git
-DOCS=( NEWS CONTRIBUTING.md README.md )
-
 src_prepare() {
 	default
 
-	sed -e 's/-Werror//' -i test/Makefile.am || die
+	local sed_args=()
+
+	# Fix broken dependency check
+	# https://github.com/intel/libva-utils/pull/260
+	sed_args+=(-e "s/dependency('drm'/dependency('libdrm'/")
 
 	if ! use examples ; then
-		sed -E -e '/^SUBDIRS \+?=/s!( decode\>| encode\>| videoprocess\>| vendor/intel\>| vendor/intel/sfcsample\>)!!g' -i Makefile.am || die
+		sed_args+=(
+			-e "/^subdir('decode')$/d"
+			-e "/^subdir('encode')$/d"
+			-e "/^subdir('videoprocess')$/d"
+			-e "/^subdir('vendor\/intel')$/d"
+			-e "/^subdir('vendor\/intel\/sfcsample')$/d"
+		)
 	fi
 
 	if ! use putsurface ; then
-		sed -E -e '/^SUBDIRS \+?=/s! putsurface\>!!g' -i Makefile.am || die
+		sed_args+=(-e "/^subdir('putsurface')$/d")
 	fi
 
 	if ! use vainfo ; then
-		sed -E -e '/^SUBDIRS \+?=/s! vainfo\>!!g' -i Makefile.am || die
+		sed_args+=(-e "/^subdir('vainfo')$/d")
 	fi
 
-	eautoreconf
+	if [[ ${#sed_args[@]} -gt 0 ]] ; then
+		sed "${sed_args[@]}" -i meson.build || die
+	fi
 }
 
 src_configure() {
-	local myeconfargs=(
-		$(use_enable drm)
-		$(use_enable test tests)
-		$(use_enable wayland)
-		$(use_enable X x11)
+	local emesonargs=(
+		-Ddrm=true
+		$(meson_use X x11)
+		$(meson_use wayland)
+		$(meson_use test tests)
 	)
-
-	if use test || use test-va-api ; then
-		myeconfargs+=( --enable-tests )
-	else
-		myeconfargs+=( --disable-tests )
-	fi
-
-	econf "${myeconfargs[@]}"
+	meson_src_configure
 }
 
 src_install() {
-	default
+	meson_src_install
+
+	if ! use test ; then
+		rm -f "${ED}"/usr/bin/test_va_api || die
+	fi
+}
 
-	if ! use test-va-api ; then
-		if [[ -e "${ED}"/usr/bin/test_va_api ]] ; then
-			rm -f "${ED}"/usr/bin/test_va_api || die
-		fi
+pkg_postinst() {
+	if use test ; then
+		elog "Tests must be run manually with the test_va_api binary"
 	fi
 }