gentoo auto-resync : 07:08:2024 - 12:37:20

3 files changed, 252 insertions, 2 deletions

diff --git a/media-video/ffmpeg-chromium/Manifest b/media-video/ffmpeg-chromium/Manifest
index 273373c09e1b..ffe021842a16 100644
--- a/media-video/ffmpeg-chromium/Manifest
+++ b/media-video/ffmpeg-chromium/Manifest
@@ -3,7 +3,9 @@ AUX ffmpeg-chromium-120.patch 1485 BLAKE2B 49ece028bf7da100adc7af93e82b6235fb39f
 DIST ffmpeg-chromium-125.tar.xz 10372892 BLAKE2B 53b805354b55f1dfbe2341b767aaccca7efea4cced02db9090be88e89a4d2d688904ffc996c206d92a99d4eb93733b7f8cb47fd80dc43019c3bb6690903a1140 SHA512 c1b68b16a3dbd6f96e52c313b9ddf1c193ef302e5cbe7e127c511e54a4453c32c84b3df954e397d7ba834ef17fe1cba6efabfde855d3bb9e497bcde1b66c3d8d
 DIST ffmpeg-chromium-126.tar.xz 10402160 BLAKE2B 96a92ff2a5ece8668693f5ef7ed5da3e61a523b98a91d00316494df91edfc42c1622663719a3c192de2a4ebf7a6258f08c53393201ee3fc3261f162e1b529dcd SHA512 8fc10b1d5fe159a1dd718229bf8ec50ed0bea1fedd917859b3a0703f15e94809087e67ccf2031eb14ae8b06ad32d958ed71ff54621fd667f5507abd9738a6f0c
 DIST ffmpeg-chromium-127.tar.xz 10418192 BLAKE2B 2a623ee8e2c0940e4067e6ebecaecdc64c45b16022327a84d77323348c210b091c58eb52b4afea1f2918cd29a27c3457a3294f561a5e6ee2db28c63f432b23bd SHA512 0cddb21761ad3b54f5393d3963ca94518cb4ab8183f2bbe975f8419bd94d8b20131750a22d75fd56b304a2b83be364993a839f727342b7eed6a2d1868f79af4c
+DIST ffmpeg-chromium-128.tar.xz 10420280 BLAKE2B 0b5b3ca891445042c9c1a27713b57a0d99f75fd2d57116b89afa1020dde61a1b2d3d14e0c6d639a17fd0b45359e803580100c600e6ac99eb383630512ab8402b SHA512 a420da69c49c11bf49229066f7f08d837d8bfacfa47c659b8c3e5bb28426b65749a16ce221bf2996541902f2d55750c43e75596102a6449cdf4a845cbad777dc
 EBUILD ffmpeg-chromium-125.ebuild 6657 BLAKE2B db9582314b61909de311d3287577cad8d087a96eb9fd2ac1c9fd8ba0f89622ec8cfbb5790069af68e1f6b42efe0b4be5aea5d6f99425bfa4f99e8ace553ba4d2 SHA512 ec6d625c3d5d6007a3f0f5bea98cf684ddde7087db030e7dacaa93a673a279edf74d62c475c3112927e4a7ab68d3f80621378ad0db77ac7ff3e5b56cc5d6e88d
 EBUILD ffmpeg-chromium-126.ebuild 6657 BLAKE2B 3e08ce545199da60565e97f1328e4c9e31f14fc169aa0e36aeb7f6c772497d1f92c98f0039ce8968a551e9e38bf4acf3f86db0ac5bbeb9f59837a6851adc0d78 SHA512 7f50b01df708adfc2a94509a606f47b2f119a0af4671c7020c7dc21a0ccf24780f340059532cf5eb45cc30859c7394432d7b2f56cb529fb739bea8e8ab7b4480
-EBUILD ffmpeg-chromium-127.ebuild 6659 BLAKE2B b257982863c168fdc163cb9353108999598917bd6954f27f16abface61edb085a2b268e920ceddee54dbb419861e2185431a316ce3739e90c00b41855e3702a4 SHA512 5de38699bf23a442c1865020b299b666ce38c8ca9cd5424eaf245d6c9b8cc86129c70f6c27c4898cbd28ba92eeb4266f2839219ca4ca74bc732760d0dd0ea334
+EBUILD ffmpeg-chromium-127.ebuild 6657 BLAKE2B 1ef9acdaeba4acd40879caae346d541b0f9f7a57c6f578ae7e506adb4a23638ce81065b07fcdc9062afb2e2533542d5584a6867181862677bf0058d1bd2bf00b SHA512 71a12e7f7d9551f84cb53b343776949f488421678655ebdafe851a0d388f0bcd8e17fbb0ef9dfab5cd9bc14d1a365451b959bcd196c75a8c83ba27448439ee98
+EBUILD ffmpeg-chromium-128.ebuild 6659 BLAKE2B 5a5f16409dbe409c8e9c33c4f47a8d22b7f14a964801176d049ea3390cc175eb7aeaa7650a8fc257c5c01a823392dd4c9ca073a3e3265dda5bead39980c97962 SHA512 34120ab25a9269927e892183977dc16ee93819d02cbc1401de6cd145a7a6c35fe458d65cafa11348a05a1cd8b1b7109e8d64b245176f924319360e0bc30123ce
 MISC metadata.xml 695 BLAKE2B 84fa4967572665812d4da8bb1a86a8b28a749892570cb1fca5c0515f860fbe8c472a91240f1d3b7b3109ccdbd32cf8da941c438cd9f332b763f2824e0e193ac8 SHA512 0069bcf32d2aa083c66e13579295e8ef96b9ac72b02f1436620000c71c4d1e335391838f9a9e56f7768bd13dbe13ce6f3f3674a303cf90cc658360825867c3f9
diff --git a/media-video/ffmpeg-chromium/ffmpeg-chromium-127.ebuild b/media-video/ffmpeg-chromium/ffmpeg-chromium-127.ebuild
index eb68732fd0bc..91d93d2a4d58 100644
--- a/media-video/ffmpeg-chromium/ffmpeg-chromium-127.ebuild
+++ b/media-video/ffmpeg-chromium/ffmpeg-chromium-127.ebuild
@@ -16,7 +16,7 @@ LICENSE="
 "
 SLOT="${PV}"
 
-KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64"
+KEYWORDS="amd64 ~arm arm64 ~loong ~ppc64"
 
 # Options to use as use_enable in the foo[:bar] form.
 # This will feed configure with $(use_enable foo bar)
diff --git a/media-video/ffmpeg-chromium/ffmpeg-chromium-128.ebuild b/media-video/ffmpeg-chromium/ffmpeg-chromium-128.ebuild
new file mode 100644
index 000000000000..6b5bd6600a97
--- /dev/null
+++ b/media-video/ffmpeg-chromium/ffmpeg-chromium-128.ebuild
@@ -0,0 +1,248 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit flag-o-matic toolchain-funcs
+
+COMMIT=d941d9677bb4802f01750fd908ec284fb72c84df
+DESCRIPTION="FFmpeg built specifically for codec support in Chromium-based browsers"
+HOMEPAGE="https://ffmpeg.org/"
+SRC_URI="https://deps.gentoo.zip/media-video/${P}.tar.xz"
+
+LICENSE="
+	!gpl? ( LGPL-2.1 )
+	gpl? ( GPL-2 )
+"
+SLOT="${PV}"
+
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64"
+
+# Options to use as use_enable in the foo[:bar] form.
+# This will feed configure with $(use_enable foo bar)
+# or $(use_enable foo foo) if no :bar is set.
+# foo is added to IUSE.
+FFMPEG_FLAG_MAP=(
+		cpudetection:runtime-cpudetect debug
+		+gpl
+		vaapi vdpau vulkan
+		nvenc:ffnvcodec
+		# Threads; we only support pthread for now but ffmpeg supports more
+		+threads:pthreads
+)
+
+IUSE="
+	${FFMPEG_FLAG_MAP[@]%:*}
+"
+
+# Strings for CPU features in the useflag[:configure_option] form
+# if :configure_option isn't set, it will use 'useflag' as configure option
+ARM_CPU_FEATURES=(
+	cpu_flags_arm_thumb:armv5te
+	cpu_flags_arm_v6:armv6
+	cpu_flags_arm_thumb2:armv6t2
+	cpu_flags_arm_neon:neon
+	cpu_flags_arm_vfp:vfp
+	cpu_flags_arm_vfpv3:vfpv3
+	cpu_flags_arm_v8:armv8
+	cpu_flags_arm_asimddp:dotprod
+	cpu_flags_arm_i8mm:i8mm
+)
+ARM_CPU_REQUIRED_USE="
+	arm64? ( cpu_flags_arm_v8 )
+	cpu_flags_arm_v8? ( cpu_flags_arm_vfpv3 cpu_flags_arm_neon )
+	cpu_flags_arm_neon? (
+		cpu_flags_arm_vfp
+		arm? ( cpu_flags_arm_thumb2 )
+	)
+	cpu_flags_arm_vfpv3? ( cpu_flags_arm_vfp )
+	cpu_flags_arm_thumb2? ( cpu_flags_arm_v6 )
+	cpu_flags_arm_v6? (
+		arm? ( cpu_flags_arm_thumb )
+	)
+"
+X86_CPU_FEATURES_RAW=( 3dnow:amd3dnow 3dnowext:amd3dnowext aes:aesni avx:avx avx2:avx2 fma3:fma3 fma4:fma4 mmx:mmx
+					   mmxext:mmxext sse:sse sse2:sse2 sse3:sse3 ssse3:ssse3 sse4_1:sse4 sse4_2:sse42 xop:xop )
+X86_CPU_FEATURES=( ${X86_CPU_FEATURES_RAW[@]/#/cpu_flags_x86_} )
+X86_CPU_REQUIRED_USE="
+	cpu_flags_x86_avx2? ( cpu_flags_x86_avx )
+	cpu_flags_x86_fma4? ( cpu_flags_x86_avx )
+	cpu_flags_x86_fma3? ( cpu_flags_x86_avx )
+	cpu_flags_x86_xop?  ( cpu_flags_x86_avx )
+	cpu_flags_x86_avx?  ( cpu_flags_x86_sse4_2 )
+	cpu_flags_x86_aes? ( cpu_flags_x86_sse4_2 )
+	cpu_flags_x86_sse4_2?  ( cpu_flags_x86_sse4_1 )
+	cpu_flags_x86_sse4_1?  ( cpu_flags_x86_ssse3 )
+	cpu_flags_x86_ssse3?  ( cpu_flags_x86_sse3 )
+	cpu_flags_x86_sse3?  ( cpu_flags_x86_sse2 )
+	cpu_flags_x86_sse2?  ( cpu_flags_x86_sse )
+	cpu_flags_x86_sse?  ( cpu_flags_x86_mmxext )
+	cpu_flags_x86_mmxext?  ( cpu_flags_x86_mmx )
+	cpu_flags_x86_3dnowext?  ( cpu_flags_x86_3dnow )
+	cpu_flags_x86_3dnow?  ( cpu_flags_x86_mmx )
+"
+
+CPU_FEATURES_MAP=(
+	${ARM_CPU_FEATURES[@]}
+	${X86_CPU_FEATURES[@]}
+)
+IUSE="${IUSE}
+	${CPU_FEATURES_MAP[@]%:*}"
+
+CPU_REQUIRED_USE="
+	${ARM_CPU_REQUIRED_USE}
+	${X86_CPU_REQUIRED_USE}
+"
+
+RDEPEND="
+	>=media-libs/opus-1.0.2-r2
+	vaapi? ( >=media-libs/libva-1.2.1-r1:0= )
+	nvenc? ( >=media-libs/nv-codec-headers-11.1.5.3 )
+	vdpau? ( >=x11-libs/libvdpau-0.7 )
+	vulkan? ( >=media-libs/vulkan-loader-1.3.277:= )
+"
+
+DEPEND="${RDEPEND}
+	vulkan? ( >=dev-util/vulkan-headers-1.3.277 )
+"
+BDEPEND="
+	>=dev-build/make-3.81
+	virtual/pkgconfig
+	cpu_flags_x86_mmx? ( || ( >=dev-lang/nasm-2.13 >=dev-lang/yasm-1.3 ) )
+"
+
+REQUIRED_USE="
+	vulkan? ( threads )
+	${CPU_REQUIRED_USE}"
+RESTRICT="
+	test
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-120.patch
+	"${FILESDIR}"/chromium.patch
+)
+
+src_prepare() {
+	export revision=git-N-g${COMMIT:0:10}
+	default
+
+	# -fdiagnostics-color=auto gets appended after user flags which
+	# will ignore user's preference.
+	sed -i -e '/check_cflags -fdiagnostics-color=auto/d' configure || die
+
+	echo 'include $(SRC_PATH)/ffbuild/libffmpeg.mak' >> Makefile || die
+}
+
+src_configure() {
+	local myconf=( )
+
+	# Bug #918997. Will probably be fixed upstream in the next release.
+	use vulkan && append-ldflags -Wl,-z,muldefs
+
+	# bug 842201
+	use ia64 && tc-is-gcc && append-flags \
+		-fno-tree-ccp \
+		-fno-tree-dominator-opts \
+		-fno-tree-fre \
+		-fno-code-hoisting \
+		-fno-tree-pre \
+		-fno-tree-vrp
+
+	local ffuse=( "${FFMPEG_FLAG_MAP[@]}" )
+
+	for i in "${ffuse[@]#+}" ; do
+		myconf+=( $(use_enable ${i%:*} ${i#*:}) )
+	done
+
+	# CPU features
+	for i in "${CPU_FEATURES_MAP[@]}" ; do
+		use ${i%:*} || myconf+=( --disable-${i#*:} )
+	done
+
+	# Try to get cpu type based on CFLAGS.
+	# Bug #172723
+	# We need to do this so that features of that CPU will be better used
+	# If they contain an unknown CPU it will not hurt since ffmpeg's configure
+	# will just ignore it.
+	for i in $(get-flag mcpu) $(get-flag march) ; do
+		[[ ${i} = native ]] && i="host" # bug #273421
+		myconf+=( --cpu=${i} )
+		break
+	done
+
+	# LTO support, bug #566282, bug #754654, bug #772854
+	if [[ ${ABI} != x86 ]] && tc-is-lto; then
+		# Respect -flto value, e.g -flto=thin
+		local v="$(get-flag flto)"
+		[[ -n ${v} ]] && myconf+=( "--enable-lto=${v}" ) || myconf+=( "--enable-lto" )
+	fi
+	filter-lto
+
+	# Mandatory configuration
+	myconf=(
+		--disable-stripping
+		# This is only for hardcoded cflags; those are used in configure checks that may
+		# interfere with proper detections, bug #671746 and bug #645778
+		# We use optflags, so that overrides them anyway.
+		--disable-optimizations
+		--disable-libcelt # bug #664158
+		"${myconf[@]}"
+	)
+
+	# cross compile support
+	if tc-is-cross-compiler ; then
+		myconf+=( --enable-cross-compile --arch=$(tc-arch-kernel) --cross-prefix=${CHOST}- --host-cc="$(tc-getBUILD_CC)" )
+		case ${CHOST} in
+			*mingw32*)
+				myconf+=( --target-os=mingw32 )
+				;;
+			*linux*)
+				myconf+=( --target-os=linux )
+				;;
+		esac
+	fi
+
+	# Use --extra-libs if needed for LIBS
+	set -- "${S}/configure" \
+		--prefix="${EPREFIX}/usr" \
+		--libdir="${EPREFIX}/usr/$(get_libdir)" \
+		--shlibdir="${EPREFIX}/usr/$(get_libdir)" \
+		--cc="$(tc-getCC)" \
+		--cxx="$(tc-getCXX)" \
+		--ar="$(tc-getAR)" \
+		--nm="$(tc-getNM)" \
+		--strip="$(tc-getSTRIP)" \
+		--ranlib="$(tc-getRANLIB)" \
+		--pkg-config="$(tc-getPKG_CONFIG)" \
+		--optflags="${CFLAGS}" \
+		--disable-all \
+		--disable-autodetect \
+		--disable-error-resilience \
+		--disable-everything \
+		--disable-faan \
+		--disable-iconv \
+		--disable-network \
+		--enable-avcodec \
+		--enable-avformat \
+		--enable-avutil \
+		--enable-libopus \
+		--enable-decoder=aac,flac,h264,libopus,mp3,pcm_alaw,pcm_f32le,pcm_mulaw,pcm_s16be,pcm_s16le,pcm_s24be,pcm_s24le,pcm_s32le,pcm_u8,theora,vorbis,vp8 \
+		--enable-demuxer=aac,flac,matroska,mov,mp3,ogg,wav \
+		--enable-parser=aac,flac,h264,mpegaudio,opus,vorbis,vp3,vp8,vp9 \
+		--enable-pic \
+		--enable-static \
+		"${myconf[@]}" \
+		${EXTRA_FFMPEG_CONF}
+
+	echo "${@}"
+	"${@}" || die
+}
+
+src_compile() {
+	emake V=1 libffmpeg
+}
+
+src_install() {
+	emake V=1 DESTDIR="${D}" install-libffmpeg
+}