gentoo resync : 20.12.2017

6 files changed, 663 insertions, 2 deletions

diff --git a/media-tv/Manifest.gz b/media-tv/Manifest.gz
index 96f4965e5158..5c3a4217bec5 100644
--- a/media-tv/Manifest.gz
+++ b/media-tv/Manifest.gz
diff --git a/media-tv/kodi/Manifest b/media-tv/kodi/Manifest
index fe12b73ecd4f..96af13351e13 100644
--- a/media-tv/kodi/Manifest
+++ b/media-tv/kodi/Manifest
@@ -18,6 +18,7 @@ DIST libdvdread-17d99db97e7b8f23077b342369d3c22a6250affd.tar.gz 124326 BLAKE2B 3
 EBUILD kodi-17.3-r1.ebuild 8577 BLAKE2B 89b0b422d7aafcd17a23d85e9821185e2afb7ae86e39cd0bee8355b7dbbd4478dc08f2010312d6af7a1987e33578b3a6db2c1b28549e2541c843617594168989 SHA512 be9bf1b24d6bcd3d797ee9f12a9495a7bd1245904b1a361a5bb67fff64eae69a9c5f8f3ae9b2a9c2aebe28b62c755135daeea7ae4f077e68ce5f0cad3169a78c
 EBUILD kodi-17.5-r1.ebuild 8830 BLAKE2B 8f09f8a724708f406157cb6a3acb81e06ca2c2f54bc81dab24b44b539ac1f3ca20cc450ce369fb516f7e8f80e0586af7e654418bca701e9df897e5f0f579a04d SHA512 68e7232a7a45afdfe8b042b4b999e2b7d803bf2812d021155636c40789ec713da025c7c8d01e094bc94121e7f8b22e6cccfc6871f99086646886059476da8df0
 EBUILD kodi-17.6-r1.ebuild 8741 BLAKE2B 63512c0c3c77736a551d2b0a255048a7579f852a5c3b592cb70581747dd7fc04a7beb9b1ceee60222266cb9e478e01f39dbb07f4e84f1a35b509bdb6552ff779 SHA512 6be7bb9f2bc68ef8dfbdf71972d221c503133f99ad42d1b434256d4c55fa6b9edeadc097f928c5176b1038d687b3dc5b38ce083aae969af6147e64562f68cf9e
+EBUILD kodi-17.6-r2.ebuild 8743 BLAKE2B d0d6014cc8735bf9cc273ca9848aff83c466257f551694c3dbd67ce3882b85f7dfab8c29302289f3406848935f8ee4700ad16e8ab7e9445ead5dca29d7d12fd4 SHA512 01ef54d3ae4404f768c126fac8a39ba66ebcf038104322a2f14bd903d336430d935f0201dc84d1025f9d1fd1ea4109de73c7de2342c8f47154a8b08e9c73a571
 EBUILD kodi-17.6.ebuild 8745 BLAKE2B 98d3a0a1b855474eb0bf68b49bbf26a229ad0e8d7a825f10aa131e423401de090bc237a1dae00da87575a851b5f62e27c086964f58afdc6b8e3649b5093b3bab SHA512 e0ab4f578136da46ae6910886d2a8239bf81acdb39256158d616d12a4a6ee168fb45424a3fbd5f31d110117223dcae85d9d881485d238c9c7f59101ca112cc57
-EBUILD kodi-9999.ebuild 8915 BLAKE2B 362622730de6ded1057a5daf85ddab263aa1e26180ade754670fbfb5be6b9fb633f47832981147e3fe66d82c218fb21f40e78feb0b5d6f481af526217f3f225b SHA512 d1d0945b12a262438923d09273c1b0e0c5e0ac59cdc7fa6259a7d1fb8d7fed4e8965c21299f3e763791d32e35879bc441a7f2778dd8e41985bf72f54207b4e83
+EBUILD kodi-9999.ebuild 8917 BLAKE2B b9349b837378087a5ec6db08b664fd436fbe6275b7164de93af0cffeab8ef5ab9fc35459736924a49b68dba7d53d7df05f90dba08810c658990bff9de85009ad SHA512 30e695d9fa3e8ae1bc9b46953c3499a20bc8e10ac36b7080e7a4eaf5873faec7cd2ad420105ac6db145068d04ceffadd59d59ee5598d10cc602315d27637732e
 MISC metadata.xml 1716 BLAKE2B cc5a56b572fc4bc5b17a303e266e66c06450e9ef111f080a57bef31f847d522edd01354be20cbd5450b6773321c49618ae74f9a5caed39948d672314b06c27c0 SHA512 4ea0d31caa3a4c10ff5a421fa830c9db3eeb2628cecc19759ad218eb551d2c4382016ec5655a5c5be1e257eec29cad0717523a9fe3f251ff762cdf0ba60b4355
diff --git a/media-tv/kodi/kodi-17.6-r2.ebuild b/media-tv/kodi/kodi-17.6-r2.ebuild
new file mode 100644
index 000000000000..2cabe7ef521d
--- /dev/null
+++ b/media-tv/kodi/kodi-17.6-r2.ebuild
@@ -0,0 +1,296 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+# Does not work with py3 here
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE="sqlite"
+
+inherit autotools cmake-utils eutils linux-info pax-utils python-single-r1 versionator
+
+LIBDVDCSS_COMMIT="2f12236bc1c92f73c21e973363f79eb300de603f"
+LIBDVDREAD_COMMIT="17d99db97e7b8f23077b342369d3c22a6250affd"
+LIBDVDNAV_COMMIT="43b5f81f5fe30bceae3b7cecf2b0ca57fc930dac"
+FFMPEG_VERSION="3.1.11"
+FFMPEG_KODI_VERSION="17.5"
+CODENAME="Krypton"
+SRC_URI="https://github.com/xbmc/libdvdcss/archive/${LIBDVDCSS_COMMIT}.tar.gz -> libdvdcss-${LIBDVDCSS_COMMIT}.tar.gz
+	https://github.com/xbmc/libdvdread/archive/${LIBDVDREAD_COMMIT}.tar.gz -> libdvdread-${LIBDVDREAD_COMMIT}.tar.gz
+	https://github.com/xbmc/libdvdnav/archive/${LIBDVDNAV_COMMIT}.tar.gz -> libdvdnav-${LIBDVDNAV_COMMIT}.tar.gz
+	!system-ffmpeg? ( https://github.com/xbmc/FFmpeg/archive/${FFMPEG_VERSION}-${CODENAME}-${FFMPEG_KODI_VERSION}.tar.gz -> ffmpeg-${PN}-${FFMPEG_VERSION}-${CODENAME}-${FFMPEG_KODI_VERSION}.tar.gz )"
+
+DESCRIPTION="Kodi is a free and open source media-player and entertainment hub"
+HOMEPAGE="https://kodi.tv/ http://kodi.wiki/"
+
+LICENSE="GPL-2"
+SLOT="0"
+# use flag is called libusb so that it doesn't fool people in thinking that
+# it is _required_ for USB support. Otherwise they'll disable udev and
+# that's going to be worse.
+IUSE="airplay alsa bluetooth bluray caps cec +css dbus debug dvd gles lcms libressl libusb lirc mysql nfs nonfree +opengl pulseaudio samba sftp systemd +system-ffmpeg test +udev udisks upnp upower vaapi vdpau webserver +X +xslt zeroconf"
+REQUIRED_USE="
+	${PYTHON_REQUIRED_USE}
+	|| ( gles opengl )
+	gles? ( X )
+	opengl? ( X )
+	udev? ( !libusb )
+	udisks? ( dbus )
+	upower? ( dbus )
+"
+
+COMMON_DEPEND="${PYTHON_DEPS}
+	airplay? (
+		app-pda/libplist
+		net-libs/shairplay
+	)
+	alsa? ( media-libs/alsa-lib )
+	bluetooth? ( net-wireless/bluez )
+	bluray? ( >=media-libs/libbluray-0.7.0 )
+	caps? ( sys-libs/libcap )
+	dbus? ( sys-apps/dbus )
+	dev-db/sqlite
+	dev-libs/expat
+	dev-libs/fribidi
+	cec? ( >=dev-libs/libcec-4.0 )
+	dev-libs/libpcre[cxx]
+	dev-libs/libxml2
+	>=dev-libs/lzo-2.04
+	dev-libs/tinyxml[stl]
+	>=dev-libs/yajl-2
+	dev-python/pillow[${PYTHON_USEDEP}]
+	dev-libs/libcdio
+	gles? ( media-libs/mesa[gles2] )
+	lcms? ( media-libs/lcms:2 )
+	libusb? ( virtual/libusb:1 )
+	virtual/ttf-fonts
+	>=media-fonts/noto-20160531
+	media-fonts/roboto
+	media-libs/fontconfig
+	media-libs/freetype
+	>=media-libs/libass-0.13.4
+	media-libs/mesa[egl]
+	>=media-libs/taglib-1.11.1
+	system-ffmpeg? (
+		>=media-video/ffmpeg-${FFMPEG_VERSION}:=[encode,openssl,postproc]
+		<media-video/ffmpeg-3.4
+	)
+	mysql? ( virtual/mysql )
+	>=net-misc/curl-7.51.0
+	nfs? ( net-fs/libnfs:= )
+	opengl? ( media-libs/glu )
+	!libressl? ( >=dev-libs/openssl-1.0.2j:0= )
+	libressl? ( dev-libs/libressl:0= )
+	pulseaudio? ( media-sound/pulseaudio )
+	samba? ( >=net-fs/samba-3.4.6[smbclient(+)] )
+	sftp? ( net-libs/libssh[sftp] )
+	sys-libs/zlib
+	udev? ( virtual/udev )
+	vaapi? ( x11-libs/libva:=[opengl] )
+	vdpau? (
+		|| ( >=x11-libs/libvdpau-1.1 >=x11-drivers/nvidia-drivers-180.51 )
+		system-ffmpeg? ( media-video/ffmpeg[vdpau] )
+	)
+	webserver? ( >=net-libs/libmicrohttpd-0.9.50[messages] )
+	X? (
+		x11-libs/libdrm
+		x11-libs/libX11
+		x11-libs/libXrandr
+		x11-libs/libXrender
+	)
+	xslt? ( dev-libs/libxslt )
+	zeroconf? ( net-dns/avahi[dbus] )
+"
+RDEPEND="${COMMON_DEPEND}
+	lirc? (
+		|| ( app-misc/lirc app-misc/inputlircd )
+	)
+	!media-tv/xbmc
+	udisks? ( sys-fs/udisks:0 )
+	upower? (
+		systemd? ( sys-power/upower )
+		!systemd? (
+			|| ( sys-power/upower-pm-utils sys-power/upower )
+		)
+	)
+"
+DEPEND="${COMMON_DEPEND}
+	app-arch/bzip2
+	app-arch/unzip
+	app-arch/xz-utils
+	app-arch/zip
+	dev-lang/swig
+	dev-libs/crossguid
+	dev-util/cmake
+	dev-util/gperf
+	media-libs/giflib
+	>=media-libs/libjpeg-turbo-1.5.1:=
+	>=media-libs/libpng-1.6.26:0=
+	test? ( dev-cpp/gtest )
+	virtual/pkgconfig
+	x86? ( dev-lang/nasm )
+"
+case ${PV} in
+9999)
+	EGIT_REPO_URI="https://github.com/xbmc/xbmc.git"
+	inherit git-r3
+	# Force java for latest git version to avoid having to hand maintain the
+	# generated addons package.  #488118
+	DEPEND+="
+		virtual/jre
+		"
+	;;
+*)
+	MY_PV=${PV/_p/_r}
+	MY_PV=${MY_PV/_alpha/a}
+	MY_PV=${MY_PV/_beta/b}
+	MY_PV=${MY_PV/_rc/rc}
+	MY_P="${PN}-${MY_PV}"
+	SRC_URI+=" https://github.com/xbmc/xbmc/archive/${MY_PV}-${CODENAME}.tar.gz -> ${MY_P}.tar.gz
+		 !java? ( https://github.com/candrews/gentoo-kodi/raw/master/${MY_P}-generated-addons.tar.xz )"
+	KEYWORDS="~amd64 ~x86"
+	IUSE+=" java"
+	DEPEND+="
+		java? ( virtual/jre )
+		"
+
+	S=${WORKDIR}/xbmc-${MY_PV}-${CODENAME}
+	;;
+esac
+
+CONFIG_CHECK="~IP_MULTICAST"
+ERROR_IP_MULTICAST="
+In some cases Kodi needs to access multicast addresses.
+Please consider enabling IP_MULTICAST under Networking options.
+"
+
+CMAKE_USE_DIR=${S}/project/cmake/
+
+pkg_setup() {
+	check_extra_config
+	python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	if in_iuse java && use !java; then
+		eapply "${FILESDIR}"/${PN}-cmake-no-java.patch
+	fi
+	cmake-utils_src_prepare
+
+	# avoid long delays when powerkit isn't running #348580
+	sed -i \
+		-e '/dbus_connection_send_with_reply_and_block/s:-1:3000:' \
+		xbmc/linux/*.cpp || die
+
+	# Prepare tools and libs witch are configured with autotools during compile time
+	AUTOTOOLS_DIRS=(
+		"${S}"/lib/cpluff
+		"${S}"/tools/depends/native/TexturePacker/src
+		"${S}"/tools/depends/native/JsonSchemaBuilder/src
+	)
+
+	local d
+	for d in "${AUTOTOOLS_DIRS[@]}" ; do
+		pushd ${d} >/dev/null || die
+		AT_NOELIBTOOLIZE="yes" AT_TOPLEVEL_EAUTORECONF="yes" eautoreconf
+		popd >/dev/null || die
+	done
+	elibtoolize
+
+	# Prevent autoreconf rerun
+	sed -e 's/autoreconf -vif/echo "autoreconf already done in src_prepare()"/' -i \
+		"${S}"/project/cmake/modules/FindCpluff.cmake \
+		"${S}"/tools/depends/native/TexturePacker/src/autogen.sh \
+		"${S}"/tools/depends/native/JsonSchemaBuilder/src/autogen.sh \
+		|| die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-Ddocdir="${EPREFIX}/usr/share/doc/${PF}"
+		-DENABLE_LDGOLD=OFF # https://bugs.gentoo.org/show_bug.cgi?id=606124
+		-DENABLE_ALSA=$(usex alsa)
+		-DENABLE_AIRTUNES=$(usex airplay)
+		-DENABLE_AVAHI=$(usex zeroconf)
+		-DENABLE_BLUETOOTH=$(usex bluetooth)
+		-DENABLE_BLURAY=$(usex bluray)
+		-DENABLE_CCACHE=OFF
+		-DENABLE_CEC=$(usex cec)
+		-DENABLE_DBUS=$(usex dbus)
+		-DENABLE_DVDCSS=$(usex css)
+		-DENABLE_INTERNAL_CROSSGUID=OFF
+		-DENABLE_INTERNAL_FFMPEG="$(usex !system-ffmpeg)"
+		-DENABLE_CAP=$(usex caps)
+		-DENABLE_LCMS2=$(usex lcms)
+		-DENABLE_LIRC=$(usex lirc)
+		-DENABLE_MICROHTTPD=$(usex webserver)
+		-DENABLE_MYSQLCLIENT=$(usex mysql)
+		-DENABLE_NFS=$(usex nfs)
+		-DENABLE_NONFREE=$(usex nonfree)
+		-DENABLE_OPENGLES=$(usex gles)
+		-DENABLE_OPENGL=$(usex opengl)
+		-DENABLE_OPENSSL=ON
+		-DENABLE_OPTICAL=$(usex dvd)
+		-DENABLE_PLIST=$(usex airplay)
+		-DENABLE_PULSEAUDIO=$(usex pulseaudio)
+		-DENABLE_SMBCLIENT=$(usex samba)
+		-DENABLE_SSH=$(usex sftp)
+		-DENABLE_UDEV=$(usex udev)
+		-DENABLE_UPNP=$(usex upnp)
+		-DENABLE_VAAPI=$(usex vaapi)
+		-DENABLE_VDPAU=$(usex vdpau)
+		-DENABLE_X11=$(usex X)
+		-DENABLE_XSLT=$(usex xslt)
+		-Dlibdvdread_URL="${DISTDIR}/libdvdread-${LIBDVDREAD_COMMIT}.tar.gz"
+		-Dlibdvdnav_URL="${DISTDIR}/libdvdnav-${LIBDVDNAV_COMMIT}.tar.gz"
+		-Dlibdvdcss_URL="${DISTDIR}/libdvdcss-${LIBDVDCSS_COMMIT}.tar.gz"
+	)
+
+	use libusb && mycmakeargs+=( -DENABLE_LIBUSB=$(usex libusb) )
+
+	if use system-ffmpeg; then
+		mycmakeargs+=( -DWITH_FFMPEG="yes" )
+	else
+		mycmakeargs+=( -DFFMPEG_URL="${DISTDIR}/ffmpeg-${PN}-${FFMPEG_VERSION}-${CODENAME}-${FFMPEG_KODI_VERSION}.tar.gz" )
+	fi
+
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_compile all
+	use test && emake -C "${BUILD_DIR}" kodi-test
+}
+
+src_test() {
+	emake -C "${BUILD_DIR}" test
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	pax-mark Em "${ED%/}"/usr/$(get_libdir)/${PN}/${PN}.bin
+
+	rm "${ED%/}"/usr/share/doc/*/{LICENSE.GPL,copying.txt}* || die
+
+	newicon media/icon48x48.png kodi.png
+
+	# Replace bundled fonts with system ones.
+	rm "${ED%/}"/usr/share/kodi/addons/skin.estouchy/fonts/NotoSans-Regular.ttf || die
+	dosym ../../../../fonts/noto/NotoSans-Regular.ttf \
+		usr/share/kodi/addons/skin.estouchy/fonts/NotoSans-Regular.ttf
+
+	local f
+	for f in NotoMono-Regular.ttf NotoSans-Bold.ttf NotoSans-Regular.ttf ; do
+		rm "${ED%/}"/usr/share/kodi/addons/skin.estuary/fonts/"${f}" || die
+		dosym ../../../../fonts/noto/"${f}" \
+			usr/share/kodi/addons/skin.estuary/fonts/"${f}"
+	done
+
+	rm "${ED%/}"/usr/share/kodi/addons/skin.estuary/fonts/Roboto-Thin.ttf || die
+	dosym ../../../../fonts/roboto/Roboto-Thin.ttf \
+		usr/share/kodi/addons/skin.estuary/fonts/Roboto-Thin.ttf
+
+	python_domodule tools/EventClients/lib/python/xbmcclient.py
+	python_newscript "tools/EventClients/Clients/Kodi Send/kodi-send.py" kodi-send
+}
diff --git a/media-tv/kodi/kodi-9999.ebuild b/media-tv/kodi/kodi-9999.ebuild
index 974be45715a5..9a33b956fc43 100644
--- a/media-tv/kodi/kodi-9999.ebuild
+++ b/media-tv/kodi/kodi-9999.ebuild
@@ -84,7 +84,7 @@ COMMON_DEPEND="${PYTHON_DEPS}
 	>=sys-libs/zlib-1.2.11
 	udev? ( virtual/udev )
 	vaapi? (
-		x11-libs/libva
+		x11-libs/libva:=
 		opengl? ( x11-libs/libva[opengl] )
 		system-ffmpeg? ( media-video/ffmpeg[vaapi] )
 		vdpau? ( x11-libs/libva[vdpau] )
diff --git a/media-tv/mythtv/Manifest b/media-tv/mythtv/Manifest
index 1fb2391c3be2..9c78b1a68bac 100644
--- a/media-tv/mythtv/Manifest
+++ b/media-tv/mythtv/Manifest
@@ -9,4 +9,5 @@ AUX mythtv.logrotate.d-r4 235 BLAKE2B 4f6df360f5191aaf4a2b55bd3edc7bc4aab92c46db
 AUX xinitrc-r1 234 BLAKE2B 0227ea065f1c43e1b2f1583bcbc798db76e9a08d345bbd8ed8837a6ba424b187c814e3ff0d7690d2d9f7a7617f4fbcce20df926e43bc6e89aec3e352aab6de8f SHA512 885adfe395fe553f6d5cf518856be7be9a6bf6073888f8e055271ed7c3d9ad85a162e9e9ff95a68e54047948ac280796c69ef55d0b4e549eb0beabbf0fec1188
 DIST mythtv-0.28.1.tar.gz 104477892 BLAKE2B bdecfc5723ec3495ab6e49c72caaa5c2dc62c75a11ce7524d3fd5cb8daec82b53b415591b6198eab00322bbbcaff2de7d4f1b7a165d449007f4c3742a69d304b SHA512 67a81858cd19b90f519113b234119ecc248366d8545c862d887755f256cddf04d9ca16a7bf67f63e06f7628730e7dbde2a2099ca8aaeb9061b2e55a5a0b7d5e7
 EBUILD mythtv-0.28.1-r1.ebuild 10147 BLAKE2B 64a1b4d4032f89953982c45c42c8844e68dc095bb00bc25134bf489bca9c5c4a07e7ab631ee5932aee3a5910e0ac2ab610da63eacd1a345f870421a1820ef261 SHA512 23f45a9cba8793bf25238ae889d03de3e378afbd08528b748810c0cb43520b33d40ec3822243c5298c8996156c8b1f30f0ddf14fbd9b538aa2b91054660a4383
+EBUILD mythtv-0.28.1-r2.ebuild 10149 BLAKE2B 6ea43274c7270dbb83b09e4b60300b820ce3744630f9c65d3f38db81df56a88df64399fcc98477ebfad7f934b27b1553758da9e799139e5bb8848f8ef2ca1b61 SHA512 9da9b0c4998f005953415911c289a3712c20bcf7e6304d737461b34a7eb9628cf28c241f53badca00f952cb9d5c5c5e5d174f3cb80706ba4a23aa6085f8833d4
 MISC metadata.xml 3168 BLAKE2B 15510e601ad060eb20358e4177a59abd4b83b7a7fb1f7daba5ac48b779757d35edfe3e80ab96b73a0eeddff60117646509f0cb11bba0c01729e34917e723cf2a SHA512 4bf85c050f41bfee848e52c45fd7e8bf577a07b4448b63b57448caa18abe9026827a07d90a8c7bb1d9f24ff5e61523a93725a3c8a2c6bf547e01f7de0a49d417
diff --git a/media-tv/mythtv/mythtv-0.28.1-r2.ebuild b/media-tv/mythtv/mythtv-0.28.1-r2.ebuild
new file mode 100644
index 000000000000..d18c09ff7a1d
--- /dev/null
+++ b/media-tv/mythtv/mythtv-0.28.1-r2.ebuild
@@ -0,0 +1,363 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 )
+
+# git diff --relative=mythtv v0.27.6.. > ~/mythtv-0.27.6/patches/mythtv.patch
+BACKPORTS="03f44039848bd09444ff4baa8dc158bd61454079"
+MY_P=${P%_p*}
+MY_PV=${PV%_p*}
+
+inherit flag-o-matic multilib eutils python-single-r1 qmake-utils user systemd vcs-snapshot
+
+MYTHTV_BRANCH="fixes/0.28"
+
+DESCRIPTION="Homebrew PVR project"
+HOMEPAGE="https://www.mythtv.org"
+SRC_URI="https://github.com/MythTV/mythtv/archive/${BACKPORTS}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~x86"
+SLOT="0/${PV}"
+
+IUSE_INPUT_DEVICES="input_devices_joystick"
+IUSE="alsa altivec autostart bluray cec crystalhd debug dvb dvd egl fftw +hls \
+ieee1394 jack lcd libass lirc +mythlogserver perl pulseaudio python systemd +theora \
+vaapi vdpau +vorbis +wrapper +xml xmltv +xvid zeroconf ${IUSE_INPUT_DEVICES}"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}
+	bluray? ( xml )
+	theora? ( vorbis )"
+
+COMMON="
+	dev-libs/glib:2
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtscript:5
+	dev-qt/qtsql:5[mysql]
+	dev-qt/qtopengl:5
+	dev-qt/qtwebkit:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	media-gfx/exiv2:=
+	media-libs/freetype:2
+	media-libs/taglib
+	>=media-sound/lame-3.93.1
+	sys-libs/zlib
+	virtual/mysql
+	virtual/opengl
+	x11-libs/libX11
+	x11-libs/libXext
+	x11-libs/libXinerama
+	x11-libs/libXv
+	x11-libs/libXrandr
+	x11-libs/libXxf86vm
+	x11-misc/wmctrl
+	alsa? ( >=media-libs/alsa-lib-1.0.24 )
+	bluray? (
+		dev-libs/libcdio:=
+		media-libs/libbluray:=
+		sys-fs/udisks:2
+	)
+	cec? ( dev-libs/libcec )
+	dvb? (
+		media-libs/libdvb
+		virtual/linuxtv-dvb-headers
+	)
+	dvd? (
+		dev-libs/libcdio:=
+		sys-fs/udisks:2
+	)
+	egl? ( media-libs/mesa[egl] )
+	fftw? ( sci-libs/fftw:3.0= )
+	hls? (
+		media-libs/faac
+		<media-libs/libvpx-1.7.0:=
+		>=media-libs/x264-0.0.20111220:=
+	)
+	ieee1394? (
+		>=media-libs/libiec61883-1.0.0
+		>=sys-libs/libavc1394-0.5.3
+		>=sys-libs/libraw1394-1.2.0
+	)
+	jack? ( media-sound/jack-audio-connection-kit )
+	lcd? ( app-misc/lcdproc )
+	libass? ( >=media-libs/libass-0.9.11:= )
+	lirc? ( app-misc/lirc )
+	perl? (
+		>=dev-perl/libwww-perl-5
+		dev-perl/DBD-mysql
+		dev-perl/HTTP-Message
+		dev-perl/IO-Socket-INET6
+		dev-perl/LWP-Protocol-https
+		dev-perl/Net-UPnP
+	)
+	pulseaudio? ( media-sound/pulseaudio )
+	python? (
+		${PYTHON_DEPS}
+		dev-python/lxml
+		dev-python/mysql-python
+		dev-python/urlgrabber
+	)
+	systemd? ( sys-apps/systemd:= )
+	theora? ( media-libs/libtheora media-libs/libogg )
+	vaapi? ( x11-libs/libva:=[opengl] )
+	vdpau? ( x11-libs/libvdpau )
+	vorbis? ( >=media-libs/libvorbis-1.0 media-libs/libogg )
+	xml? ( >=dev-libs/libxml2-2.6.0 )
+	xvid? ( >=media-libs/xvid-1.1.0 )
+	zeroconf? (
+		dev-libs/openssl:0=
+		net-dns/avahi[mdnsresponder-compat]
+	)
+"
+RDEPEND="${COMMON}
+	!media-tv/mythtv-bindings
+	!x11-themes/mythtv-themes
+	media-fonts/corefonts
+	media-fonts/dejavu
+	media-fonts/liberation-fonts
+	x11-apps/xinit
+	autostart? (
+		net-dialup/mingetty
+		x11-apps/xset
+		x11-wm/evilwm
+	)
+	dvd? ( media-libs/libdvdcss )
+	xmltv? ( >=media-tv/xmltv-0.5.43 )
+"
+DEPEND="${COMMON}
+	dev-lang/yasm
+	x11-proto/xf86vidmodeproto
+	x11-proto/xineramaproto
+"
+
+S="${WORKDIR}/${P}/mythtv"
+
+MYTHTV_GROUPS="video,audio,tty,uucp"
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+	enewuser mythtv -1 /bin/bash /home/mythtv ${MYTHTV_GROUPS}
+	usermod -a -G ${MYTHTV_GROUPS} mythtv
+}
+
+src_prepare() {
+	# Perl bits need to go into vender_perl and not site_perl
+	sed -e "s:pure_install:pure_install INSTALLDIRS=vendor:" \
+		-i "${S}"/bindings/perl/Makefile
+
+	# Fix up the version info since we are using the fixes/${PV} branch
+	echo "SOURCE_VERSION=\"v${MY_PV}\"" > "${S}"/VERSION
+	echo "BRANCH=\"${MYTHTV_BRANCH}\"" >> "${S}"/VERSION
+	echo "SOURCE_VERSION=\"${BACKPORTS}\"" > "${S}"/EXPORTED_VERSION
+	echo "BRANCH=\"${MYTHTV_BRANCH}\"" >> "${S}"/EXPORTED_VERSION
+
+	echo "setting.extra -= -ldconfig" >> "${S}"/programs/mythfrontend/mythfrontend.pro
+
+	epatch "${FILESDIR}/${P}-glibc225.patch"
+	epatch_user
+}
+
+src_configure() {
+	local myconf=
+
+	# Setup paths
+	myconf="${myconf} --prefix=${EPREFIX}/usr"
+	myconf="${myconf} --libdir=${EPREFIX}/usr/$(get_libdir)"
+	myconf="${myconf} --libdir-name=$(get_libdir)"
+	myconf="${myconf} --mandir=${EPREFIX}/usr/share/man"
+
+	# Audio
+	myconf="${myconf} $(use_enable alsa audio-alsa)"
+	myconf="${myconf} $(use_enable jack audio-jack)"
+	use pulseaudio || myconf="${myconf} --disable-audio-pulseoutput"
+
+	use altivec    || myconf="${myconf} --disable-altivec"
+	myconf="${myconf} $(use_enable dvb)"
+	myconf="${myconf} $(use_enable ieee1394 firewire)"
+	myconf="${myconf} $(use_enable lirc)"
+	myconf="${myconf} $(use_enable xvid libxvid)"
+	myconf="${myconf} --dvb-path=/usr/include"
+	myconf="${myconf} --enable-xrandr"
+	myconf="${myconf} --enable-xv"
+	myconf="${myconf} --enable-x11"
+	myconf="${myconf} --enable-nonfree"
+	myconf="${myconf} --enable-libmp3lame"
+	use cec || myconf="${myconf} --disable-libcec"
+	use zeroconf || myconf="${myconf} --disable-libdns-sd"
+	myconf="${myconf} $(use_enable theora libtheora)"
+	myconf="${myconf} $(use_enable vorbis libvorbis)"
+
+	if use hls; then
+		myconf="${myconf} --enable-libx264"
+		myconf="${myconf} --enable-libvpx"
+		myconf="${myconf} --enable-libfaac"
+	fi
+
+	myconf="${myconf} $(use_enable libass)"
+
+	if use perl && use python; then
+		myconf="${myconf} --with-bindings=perl,python"
+	elif use perl; then
+		myconf="${myconf} --without-bindings=python"
+		myconf="${myconf} --with-bindings=perl"
+	elif use python; then
+		myconf="${myconf} --without-bindings=perl"
+		myconf="${myconf} --with-bindings=python"
+	else
+		myconf="${myconf} --without-bindings=perl,python"
+	fi
+
+	use python && myconf="${myconf} --python=${EPYTHON}"
+
+	if use debug; then
+		myconf="${myconf} --compile-type=debug"
+	else
+		myconf="${myconf} --compile-type=release"
+		#myconf="${myconf} --enable-debug" does nothing per sphery
+		#myconf="${myconf} --disable-stripping" does nothing per sphery
+	fi
+
+	# Video
+	myconf="${myconf} $(use_enable vdpau)"
+	myconf="${myconf} $(use_enable vaapi)"
+	myconf="${myconf} $(use_enable crystalhd)"
+
+	# Input
+	use input_devices_joystick || myconf="${myconf} --disable-joystick-menu"
+
+	# Clean up DSO load times and other compiler bits
+	myconf="${myconf} --enable-symbol-visibility"
+	myconf="${myconf} --enable-pic"
+
+	# CPU settings
+	for i in $(get-flag march) $(get-flag mcpu) $(get-flag mtune) ; do
+		[ "${i}" = "native" ] && i="host"
+		myconf="${myconf} --cpu=${i}"
+		break
+	done
+
+	if tc-is-cross-compiler ; then
+		myconf="${myconf} --enable-cross-compile --arch=$(tc-arch-kernel)"
+		myconf="${myconf} --cross-prefix=${CHOST}-"
+	fi
+
+	# Build boosters
+	has distcc ${FEATURES} || myconf="${myconf} --disable-distcc"
+	has ccache ${FEATURES} || myconf="${myconf} --disable-ccache"
+
+	myconf="${myconf} $(use_enable systemd systemd_notify)"
+	use systemd || myconf="${myconf} $(use_enable mythlogserver)"
+
+	chmod +x ./external/FFmpeg/version.sh
+
+	einfo "Running ./configure ${myconf}"
+	./configure \
+		--cc="$(tc-getCC)" \
+		--cxx="$(tc-getCXX)" \
+		--ar="$(tc-getAR)" \
+		--extra-cflags="${CFLAGS}" \
+		--extra-cxxflags="${CXXFLAGS}" \
+		--extra-ldflags="${LDFLAGS}" \
+		--qmake=$(qt5_get_bindir)/qmake \
+		${myconf} || die "configure died"
+}
+
+src_install() {
+	emake INSTALL_ROOT="${D}" install || die "install failed"
+	dodoc AUTHORS UPGRADING README
+
+	insinto /usr/share/mythtv/database
+	doins database/*
+
+	newinitd "${FILESDIR}"/mythbackend.init-r2 mythbackend
+	newconfd "${FILESDIR}"/mythbackend.conf-r1 mythbackend
+	systemd_newunit "${FILESDIR}"/mythbackend.service-28 mythbackend.service
+
+	dodoc keys.txt
+
+	keepdir /etc/mythtv
+	chown -R mythtv "${ED}"/etc/mythtv
+	keepdir /var/log/mythtv
+	chown -R mythtv "${ED}"/var/log/mythtv
+	dodir /var/log/mythtv/old
+
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}"/mythtv.logrotate.d-r4 mythtv
+
+	insinto /usr/share/mythtv/contrib
+	# Ensure we don't install scripts needing the perl bindings (bug #516968)
+	use perl || find contrib/ -name '*.pl' -exec rm -f {} \;
+	# Ensure we don't install scripts needing the python bindings (bug #516968)
+	use python || find contrib/ -name '*.py' -exec rm -f {} \;
+	doins -r contrib/*
+
+	# Install our mythfrontend wrapper which is similar to Mythbuntu's
+	if use wrapper; then
+		mv "${ED}/usr/bin/mythfrontend" "${ED}/usr/bin/mythfrontend.real"
+		newbin "${FILESDIR}"/mythfrontend.wrapper mythfrontend
+		newconfd "${FILESDIR}"/mythfrontend.conf mythfrontend
+	fi
+
+	if use autostart; then
+		dodir /etc/env.d/
+		echo 'CONFIG_PROTECT="/home/mythtv/"' > "${ED}"/etc/env.d/95mythtv
+
+		insinto /home/mythtv
+		newins "${FILESDIR}"/bash_profile .bash_profile
+		newins "${FILESDIR}"/xinitrc-r1 .xinitrc
+	fi
+
+	# Make Python files executable
+	find "${ED}/usr/share/mythtv" -type f -name '*.py' | while read file; do
+		if [[ ! "${file##*/}" = "__init__.py" ]]; then
+			chmod a+x "${file}"
+		fi
+	done
+
+	# Ensure that Python scripts are executed by Python 2
+	python_fix_shebang "${ED}/usr/share/mythtv"
+
+	# Make shell & perl scripts executable
+	find "${ED}" -type f -name '*.sh' -o -type f -name '*.pl' | \
+		while read file; do
+		chmod a+x "${file}"
+	done
+}
+
+pkg_preinst() {
+	export CONFIG_PROTECT="${CONFIG_PROTECT} ${EROOT}/home/mythtv/"
+}
+
+pkg_postinst() {
+	elog "To have this machine operate as recording host for MythTV, "
+	elog "mythbackend must be running. Run the following:"
+	elog "rc-update add mythbackend default"
+	elog
+	elog "Your recordings folder must be owned 'mythtv'. e.g."
+	elog "chown -R mythtv /var/lib/mythtv"
+
+	elog "Want mythfrontend to start automatically?"
+	elog "Set USE=autostart. Details can be found at:"
+	elog "https://dev.gentoo.org/~cardoe/mythtv/autostart.html"
+	elog
+	elog "Note that the systemd unit now restarts by default and logs"
+	elog "to journald via the console at the notice verbosity."
+}
+
+pkg_info() {
+	if [[ -f "${EROOT}"/usr/bin/mythfrontend ]]; then
+		"${EROOT}"/usr/bin/mythfrontend --version
+	fi
+}
+
+pkg_config() {
+	echo "Creating mythtv MySQL user and mythconverg database if it does not"
+	echo "already exist. You will be prompted for your MySQL root password."
+	"${EROOT}"/usr/bin/mysql -u root -p < "${EROOT}"/usr/share/mythtv/database/mc.sql
+}