gentoo resync : 22.06.2019

8 files changed, 619 insertions, 0 deletions

diff --git a/media-sound/elisa/elisa-0.4.1.ebuild b/media-sound/elisa/elisa-0.4.1.ebuild
new file mode 100644
index 000000000000..59c4f96313ab
--- /dev/null
+++ b/media-sound/elisa/elisa-0.4.1.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KDE_TEST="forceoptional"
+KDE_HANDBOOK="optional"
+inherit kde5
+
+if [[ ${KDE_BUILD_TYPE} = release ]]; then
+	SRC_URI="mirror://kde/stable/${PN}/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64"
+fi
+
+DESCRIPTION="Simple music player by KDE"
+HOMEPAGE="https://community.kde.org/Elisa"
+LICENSE="LGPL-3+"
+IUSE="mpris semantic-desktop vlc"
+
+BDEPEND="sys-devel/gettext"
+DEPEND="
+	$(add_frameworks_dep kcmutils)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kcrash)
+	$(add_frameworks_dep kdeclarative)
+	$(add_frameworks_dep kfilemetadata)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep kirigami)
+	$(add_frameworks_dep kitemviews)
+	$(add_frameworks_dep kxmlgui)
+	$(add_qt_dep qtdeclarative)
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtmultimedia 'gstreamer')
+	$(add_qt_dep qtsql)
+	$(add_qt_dep qtwidgets)
+	mpris? (
+		$(add_frameworks_dep kdbusaddons)
+		$(add_qt_dep qtdbus)
+	)
+	semantic-desktop? (
+		$(add_frameworks_dep baloo)
+	)
+	vlc? ( media-video/vlc:= )
+"
+RDEPEND="${DEPEND}
+	$(add_qt_dep qtgraphicaleffects)
+	$(add_qt_dep qtquickcontrols)
+	$(add_qt_dep qtquickcontrols2)
+"
+
+RESTRICT+=" test"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_find_package mpris KF5DBusAddons)
+		$(cmake-utils_use_find_package semantic-desktop KF5Baloo)
+		$(cmake-utils_use_find_package vlc LIBVLC)
+	)
+
+	kde5_src_configure
+}
diff --git a/media-sound/lollypop/lollypop-1.0.12.ebuild b/media-sound/lollypop/lollypop-1.0.12.ebuild
new file mode 100644
index 000000000000..3d527f7332d4
--- /dev/null
+++ b/media-sound/lollypop/lollypop-1.0.12.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_6 )
+PYTHON_REQ_USE="sqlite"
+HASH="011cb4140566625941a0fc645ac6d528"
+inherit python-r1 gnome2-utils meson xdg-utils
+
+DESCRIPTION="Modern music player for GNOME"
+HOMEPAGE="https://wiki.gnome.org/Apps/Lollypop"
+SRC_URI="https://gitlab.gnome.org/World/${PN}/uploads/${HASH}/${P}.tar.xz"
+KEYWORDS="~amd64"
+
+LICENSE="GPL-3"
+SLOT="0"
+
+DEPEND="${PYTHON_DEPS}
+	dev-libs/appstream-glib[introspection]
+	dev-libs/glib:2
+	dev-libs/gobject-introspection[cairo]
+	dev-python/pycairo[${PYTHON_USEDEP}]
+	dev-python/pygobject:3[${PYTHON_USEDEP}]
+	gnome-base/gnome-common
+	x11-libs/gtk+:3
+"
+BDEPEND="${DEPEND}
+	dev-python/pkgconfig[${PYTHON_USEDEP}]
+	dev-util/desktop-file-utils
+	dev-util/itstool
+	dev-util/intltool
+"
+RDEPEND="${DEPEND}
+	app-crypt/libsecret[introspection]
+	dev-libs/totem-pl-parser
+	dev-python/beautifulsoup:4[${PYTHON_USEDEP}]
+	dev-python/dbus-python
+	dev-python/pillow[${PYTHON_USEDEP}]
+	>=dev-python/pylast-1.0.0[${PYTHON_USEDEP}]
+	media-libs/gst-plugins-base:1.0[introspection]
+"
+
+RESTRICT="test"
+
+pkg_preinst() {
+	gnome2_schemas_savelist
+}
+
+pkg_postinst() {
+	gnome2_gconf_install
+	gnome2_schemas_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	gnome2_gconf_uninstall
+	gnome2_schemas_update
+	xdg_desktop_database_update
+}
diff --git a/media-sound/lollypop/lollypop-1.1.0.ebuild b/media-sound/lollypop/lollypop-1.1.0.ebuild
new file mode 100644
index 000000000000..ccafb82635e5
--- /dev/null
+++ b/media-sound/lollypop/lollypop-1.1.0.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_6 )
+PYTHON_REQ_USE="sqlite"
+HASH="dd514380c92e2f2e6ef20d366ccb96a5"
+inherit python-r1 gnome2-utils meson xdg-utils
+
+DESCRIPTION="Modern music player for GNOME"
+HOMEPAGE="https://wiki.gnome.org/Apps/Lollypop"
+SRC_URI="https://gitlab.gnome.org/World/${PN}/uploads/${HASH}/${P}.tar.xz"
+KEYWORDS="~amd64"
+
+LICENSE="GPL-3"
+SLOT="0"
+
+DEPEND="${PYTHON_DEPS}
+	dev-libs/appstream-glib[introspection]
+	dev-libs/glib:2
+	dev-libs/gobject-introspection[cairo]
+	dev-python/pycairo[${PYTHON_USEDEP}]
+	dev-python/pygobject:3[${PYTHON_USEDEP}]
+	gnome-base/gnome-common
+	x11-libs/gtk+:3
+"
+BDEPEND="${DEPEND}
+	dev-python/pkgconfig[${PYTHON_USEDEP}]
+	dev-util/desktop-file-utils
+	dev-util/itstool
+	dev-util/intltool
+"
+RDEPEND="${DEPEND}
+	app-crypt/libsecret[introspection]
+	dev-libs/totem-pl-parser
+	dev-python/beautifulsoup:4[${PYTHON_USEDEP}]
+	dev-python/dbus-python
+	dev-python/pillow[${PYTHON_USEDEP}]
+	>=dev-python/pylast-1.0.0[${PYTHON_USEDEP}]
+	media-libs/gst-plugins-base:1.0[introspection]
+"
+
+RESTRICT="test"
+
+pkg_preinst() {
+	gnome2_schemas_savelist
+}
+
+pkg_postinst() {
+	gnome2_gconf_install
+	gnome2_schemas_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	gnome2_gconf_uninstall
+	gnome2_schemas_update
+	xdg_desktop_database_update
+}
diff --git a/media-sound/mp3check/files/mp3check-0.8.7-fix-buildsystem.patch b/media-sound/mp3check/files/mp3check-0.8.7-fix-buildsystem.patch
new file mode 100644
index 000000000000..86c69c162c42
--- /dev/null
+++ b/media-sound/mp3check/files/mp3check-0.8.7-fix-buildsystem.patch
@@ -0,0 +1,17 @@
+--- a/Makefile
++++ b/Makefile
+@@ -2,12 +2,10 @@
+ # Please see COPYING for license.
+ 
+ # --- config ----------------------------------------------------------------
+-WARN = -Wall -W -g
++WARN = -Wall -W
+ #OPT = -O2
+ OPT =
+-CPPFLAGS = $(ADDITIONAL_CPPFLAGS)
+-CXXFLAGS = $(WARN) $(OPT)
+-CXX = g++
++CXXFLAGS += $(WARN)
+ CC = $(CXX)
+ 
+ # --- default target
diff --git a/media-sound/mp3check/files/mp3check-0.8.7-fix-c++14-operator-delete.patch b/media-sound/mp3check/files/mp3check-0.8.7-fix-c++14-operator-delete.patch
new file mode 100644
index 000000000000..de19421ac57b
--- /dev/null
+++ b/media-sound/mp3check/files/mp3check-0.8.7-fix-c++14-operator-delete.patch
@@ -0,0 +1,19 @@
+https://bugs.gentoo.org/685880
+tstring.cc: In static member function ‘static tstring::Rep* tstring::Rep::create(size_t)’:
+tstring.cc:114:39: error: exception cleanup for this placement new selects non-placement operator delete [-fpermissive]
+  114 |    Rep *p = new (m - 1 - sizeof(Rep)) Rep;
+      |                                       ^~~
+In file included from tstring.cc:26:
+
+--- a/tstring.h
++++ b/tstring.h
+@@ -75,6 +75,9 @@
+ 	 return ::operator new (size + tmem + 1);}
+       static void operator delete (void *p, size_t) {
+ 	 ::operator delete (p); }
++      // Gentoo Bug #685880
++      static void operator delete (void *p) {
++        ::operator delete (p); }
+       
+       // create a new representation
+       static Rep *create(size_t tmem);
diff --git a/media-sound/mumble/mumble-1.3.0_rc1-r1.ebuild b/media-sound/mumble/mumble-1.3.0_rc1-r1.ebuild
new file mode 100644
index 000000000000..30b2055c37fb
--- /dev/null
+++ b/media-sound/mumble/mumble-1.3.0_rc1-r1.ebuild
@@ -0,0 +1,159 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit desktop multilib-build qmake-utils xdg
+
+DESCRIPTION="Mumble is an open source, low-latency, high quality voice chat software"
+HOMEPAGE="https://wiki.mumble.info"
+if [[ "${PV}" == 9999 ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/mumble-voip/mumble.git"
+	EGIT_SUBMODULES=( '-*' celt-0.7.0-src celt-0.11.0-src themes/Mumble 3rdparty/rnnoise-src )
+else
+	if [[ "${PV}" == *_pre* ]] ; then
+		SRC_URI="https://dev.gentoo.org/~polynomial-c/dist/${P}.tar.xz"
+	else
+		MY_PV="${PV/_/-}"
+		MY_P="${PN}-${MY_PV}"
+		SRC_URI="https://github.com/mumble-voip/mumble/releases/download/${MY_PV}/${MY_P}.tar.gz"
+		S="${WORKDIR}/${P/_*}"
+	fi
+	KEYWORDS="~amd64 ~arm64 ~x86"
+fi
+
+LICENSE="BSD MIT"
+SLOT="0"
+IUSE="+alsa +dbus debug g15 jack libressl +opus oss pch portaudio pulseaudio +rnnoise speech zeroconf"
+
+RDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtsql:5[sqlite]
+	dev-qt/qtsvg:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	>=dev-libs/protobuf-2.2.0:=
+	>=media-libs/libsndfile-1.0.20[-minimal]
+	>=media-libs/speex-1.2.0
+	media-libs/speexdsp
+	sys-apps/lsb-release
+	x11-libs/libX11
+	x11-libs/libXi
+	alsa? ( media-libs/alsa-lib )
+	dbus? ( dev-qt/qtdbus:5 )
+	g15? ( app-misc/g15daemon )
+	jack? ( virtual/jack )
+	!libressl? ( >=dev-libs/openssl-1.0.0b:0= )
+	libressl? ( dev-libs/libressl )
+	opus? ( >=media-libs/opus-1.0.1 )
+	portaudio? ( media-libs/portaudio )
+	pulseaudio? ( media-sound/pulseaudio )
+	speech? ( >=app-accessibility/speech-dispatcher-0.8.0 )
+	zeroconf? ( net-dns/avahi[mdnsresponder-compat] )
+"
+DEPEND="${RDEPEND}
+	>=dev-libs/boost-1.41.0
+	x11-base/xorg-proto
+"
+BDEPEND="
+	dev-qt/linguist-tools:5
+	virtual/pkgconfig
+"
+
+# NB: qmake does not support multilib but it's fine to configure
+# for the native ABI here
+src_configure() {
+	myuse() {
+		[[ -n "${1}" ]] || die "myuse: No use option given"
+		use ${1} || echo no-${1}
+	}
+
+	local conf_add=(
+		bundled-celt
+		no-bundled-opus
+		no-bundled-speex
+		no-embed-qt-translations
+		no-server
+		no-update
+		$(myuse alsa)
+		$(myuse dbus)
+		$(usex debug 'symbols debug' release)
+		$(myuse g15)
+		$(usex jack '' no-jackaudio)
+		$(myuse opus)
+		$(myuse oss)
+		$(myuse portaudio)
+		$(myuse pulseaudio)
+		$(myuse rnnoise)
+		$(usex speech '' no-speechd)
+		$(usex zeroconf '' no-bonjour)
+	)
+
+	use pch || conf_add+=( no-pch )
+
+	eqmake5 "${S}/main.pro" -recursive \
+		CONFIG+="${conf_add[*]}" \
+		DEFINES+="PLUGIN_PATH=/usr/$(get_libdir)/mumble"
+}
+
+multilib_src_compile() {
+	local emake_args=(
+		# place libmumble* in a subdirectory
+		DESTDIR_ADD="/${MULTILIB_ABI_FLAG}"
+		{C,L}FLAGS_ADD="$(get_abi_CFLAGS)"
+	)
+	# build only overlay library for other ABIs
+	multilib_is_native_abi || emake_args+=( -C overlay_gl )
+	emake "${emake_args[@]}"
+	emake clean
+}
+
+src_compile() {
+	multilib_foreach_abi multilib_src_compile
+}
+
+multilib_src_install() {
+	local dir=$(usex debug debug release)
+	dolib.so "${dir}/${MULTILIB_ABI_FLAG}"/libmumble.so*
+	if multilib_is_native_abi; then
+		dobin "${dir}"/mumble
+		dolib.so "${dir}"/libcelt0.so* "${dir}"/plugins/lib*.so*
+	fi
+}
+
+src_install() {
+	multilib_foreach_abi multilib_src_install
+
+	newdoc README.Linux README
+	dodoc CHANGES
+	dobin scripts/mumble-overlay
+
+	insinto /usr/share/services
+	doins scripts/mumble.protocol
+
+	domenu scripts/mumble.desktop
+
+	doicon -s scalable icons/mumble.svg
+
+	doman man/mumble-overlay.1
+	doman man/mumble.1
+}
+
+pkg_preinst() {
+	xdg_pkg_preinst
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	echo
+	elog "Visit http://mumble.sourceforge.net/ for futher configuration instructions."
+	elog "Run mumble-overlay to start the OpenGL overlay (after starting mumble)."
+	echo
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+}
diff --git a/media-sound/pulseeffects/pulseeffects-4.6.4.ebuild b/media-sound/pulseeffects/pulseeffects-4.6.4.ebuild
new file mode 100644
index 000000000000..0e6624cf2428
--- /dev/null
+++ b/media-sound/pulseeffects/pulseeffects-4.6.4.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit gnome2-utils meson
+
+DESCRIPTION="Limiter, compressor, reverberation, equalizer auto volume effects for Pulseaudio"
+HOMEPAGE="https://github.com/wwmm/pulseeffects"
+
+if [[ ${PV} == *9999 ]];then
+	inherit git-r3
+	SRC_URI=""
+	EGIT_REPO_URI="${HOMEPAGE}"
+else
+	SRC_URI="${HOMEPAGE}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="bs2b calf mda-lv2 rubberband"
+
+#TODO: optional : lilv, zam-plugins (check from archlinux pkg)
+RDEPEND="
+	>=dev-libs/boost-1.41
+	>=dev-cpp/glibmm-2.56.0
+	>=dev-cpp/gtkmm-3.20:3.0
+	>=dev-libs/glib-2.56:2
+	>=dev-libs/libsigc++-2.10:2
+	>=x11-libs/gtk+-3.18:3
+	>=media-libs/lilv-0.24.2-r1
+	>=media-libs/lsp-plugins-1.1.7[lv2]
+	>=media-libs/gstreamer-1.12.0:1.0
+	>=media-libs/gst-plugins-good-1.12.0:1.0
+	>=media-libs/gst-plugins-bad-1.12.0:1.0
+	bs2b? ( >=media-plugins/gst-plugins-bs2b-1.12.0:1.0 )
+	>=media-plugins/gst-plugins-ladspa-1.12.0:1.0
+	>=media-plugins/gst-plugins-lv2-1.12.0:1.0
+	>=media-plugins/gst-plugins-pulse-1.12.0:1.0
+	calf? ( >=media-plugins/calf-0.90.0[lv2] )
+	mda-lv2? ( media-plugins/mda-lv2 )
+	rubberband? ( media-libs/rubberband )
+	>=media-libs/zita-convolver-3.0.0
+	media-libs/libebur128
+	media-sound/pulseaudio
+	sys-apps/dbus"
+# see 47a950b00c6db383ad07502a8fc396ecca98c1ce for dev-libs/appstream-glib
+# and sys-devel/gettext depends reasoning
+DEPEND="
+	${RDEPEND}
+	dev-libs/appstream-glib
+	sys-devel/gettext
+"
+BDEPEND="
+	>=sys-devel/gcc-7.3.0
+	dev-util/itstool
+	media-libs/libsamplerate
+	virtual/pkgconfig
+"
+
+pkg_postinst(){
+	gnome2_gconf_install
+	gnome2_schemas_update
+	gnome2_icon_cache_update
+}
+
+pkg_postrm(){
+	gnome2_gconf_uninstall
+	gnome2_schemas_update
+	gnome2_icon_cache_update
+}
diff --git a/media-sound/qmmp/qmmp-1.3.3.ebuild b/media-sound/qmmp/qmmp-1.3.3.ebuild
new file mode 100644
index 000000000000..13f7bd0c2f20
--- /dev/null
+++ b/media-sound/qmmp/qmmp-1.3.3.ebuild
@@ -0,0 +1,168 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils xdg-utils
+[[ ${PV} = 9999 ]] && inherit subversion
+
+DESCRIPTION="Qt5-based audio player with winamp/xmms skins support"
+HOMEPAGE="http://qmmp.ylsoftware.com"
+if [[ ${PV} != 9999 ]]; then
+	SRC_URI="http://qmmp.ylsoftware.com/files/${P}.tar.bz2
+		mirror://sourceforge/${PN}-dev/files/${P}.tar.bz2"
+	KEYWORDS="~amd64 ~x86"
+else
+	QMMP_DEV_BRANCH="1.3"
+	ESVN_REPO_URI="svn://svn.code.sf.net/p/${PN}-dev/code/branches/${PN}-${QMMP_DEV_BRANCH}"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+# KEYWORDS further up
+IUSE="aac +alsa analyzer archive bs2b cdda cover crossfade cue curl +dbus enca ffmpeg flac game
+gnome jack ladspa libav lyrics +mad midi mms modplug mplayer musepack notifier opus oss projectm
+pulseaudio qsui qtmedia scrobbler shout sid sndfile soxr stereo tray udisks +vorbis wavpack"
+
+REQUIRED_USE="
+	gnome? ( dbus )
+	shout? ( soxr vorbis )
+	udisks? ( dbus )
+"
+
+RDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtsql:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	media-libs/taglib
+	x11-libs/libX11
+	aac? ( media-libs/faad2 )
+	alsa? ( media-libs/alsa-lib )
+	archive? ( app-arch/libarchive )
+	bs2b? ( media-libs/libbs2b )
+	cdda? (
+		dev-libs/libcdio:=
+		dev-libs/libcdio-paranoia
+	)
+	cue? ( media-libs/libcue )
+	curl? ( net-misc/curl )
+	dbus? ( dev-qt/qtdbus:5 )
+	enca? ( app-i18n/enca )
+	ffmpeg? (
+		!libav? ( media-video/ffmpeg:= )
+		libav? ( media-video/libav:= )
+	)
+	flac? ( media-libs/flac )
+	game? ( media-libs/game-music-emu )
+	jack? (
+		media-libs/libsamplerate
+		media-sound/jack-audio-connection-kit
+	)
+	ladspa? ( media-libs/ladspa-cmt )
+	mad? ( || (
+		media-libs/libmad
+		media-sound/mpg123
+	) )
+	midi? ( media-sound/wildmidi )
+	mms? ( media-libs/libmms )
+	modplug? ( >=media-libs/libmodplug-0.8.4 )
+	mplayer? ( media-video/mplayer )
+	musepack? ( >=media-sound/musepack-tools-444 )
+	opus? ( media-libs/opusfile )
+	projectm? (
+		dev-qt/qtgui:5[-gles2]
+		dev-qt/qtopengl:5
+		media-libs/libprojectm
+	)
+	pulseaudio? ( >=media-sound/pulseaudio-0.9.9 )
+	qtmedia? ( dev-qt/qtmultimedia:5 )
+	scrobbler? ( net-misc/curl )
+	shout? ( media-libs/libshout )
+	sid? ( >=media-libs/libsidplayfp-1.1.0 )
+	sndfile? ( media-libs/libsndfile )
+	soxr? ( media-libs/soxr )
+	udisks? ( sys-fs/udisks:2 )
+	vorbis? (
+		media-libs/libogg
+		media-libs/libvorbis
+	)
+	wavpack? ( media-sound/wavpack )
+"
+DEPEND="${RDEPEND}
+	dev-qt/linguist-tools:5
+"
+
+DOCS=( AUTHORS ChangeLog README )
+
+src_prepare() {
+	if has_version dev-libs/libcdio-paranoia; then
+		sed -i \
+			-e 's:cdio/cdda.h:cdio/paranoia/cdda.h:' \
+			src/plugins/Input/cdaudio/decoder_cdaudio.cpp || die
+	fi
+
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DUSE_AAC="$(usex aac)"
+		-DUSE_ALSA="$(usex alsa)"
+		-DUSE_ANALYZER="$(usex analyzer)"
+		-DUSE_ARCHIVE="$(usex archive)"
+		-DUSE_BS2B="$(usex bs2b)"
+		-DUSE_CDA="$(usex cdda)"
+		-DUSE_COVER="$(usex cover)"
+		-DUSE_CROSSFADE="$(usex crossfade)"
+		-DUSE_CUE="$(usex cue)"
+		-DUSE_CURL="$(usex curl)"
+		-DUSE_KDENOTIFY="$(usex dbus)"
+		-DUSE_MPRIS="$(usex dbus)"
+		-DUSE_ENCA="$(usex enca)"
+		-DUSE_FFMPEG="$(usex ffmpeg)"
+		-DUSE_FILEWRITER="$(usex vorbis)"
+		-DUSE_FLAC="$(usex flac)"
+		-DUSE_GME="$(usex game)"
+		-DUSE_GNOMEHOTKEY="$(usex gnome)"
+		-DUSE_HAL=OFF
+		-DUSE_JACK="$(usex jack)"
+		-DUSE_LADSPA="$(usex ladspa)"
+		-DUSE_LYRICS="$(usex lyrics)"
+		-DUSE_MAD="$(usex mad)"
+		-DUSE_MIDI="$(usex midi)"
+		-DUSE_MMS="$(usex mms)"
+		-DUSE_MODPLUG="$(usex modplug)"
+		-DUSE_MPLAYER="$(usex mplayer)"
+		-DUSE_MPC="$(usex musepack)"
+		-DUSE_NOTIFIER="$(usex notifier)"
+		-DUSE_OPUS="$(usex opus)"
+		-DUSE_OSS="$(usex oss)"
+		-DUSE_PROJECTM="$(usex projectm)"
+		-DUSE_PULSE="$(usex pulseaudio)"
+		-DUSE_QSUI="$(usex qsui)"
+		-DUSE_QTMULTIMEDIA="$(usex qtmedia)"
+		-DUSE_SCROBBLER="$(usex scrobbler)"
+		-DUSE_SHOUT="$(usex shout)"
+		-DUSE_SID="$(usex sid)"
+		-DUSE_SNDFILE="$(usex sndfile)"
+		-DUSE_SOXR="$(usex soxr)"
+		-DUSE_STEREO="$(usex stereo)"
+		-DUSE_STATICON="$(usex tray)"
+		-DUSE_UDISKS2="$(usex udisks)"
+		-DUSE_VORBIS="$(usex vorbis)"
+		-DUSE_WAVPACK="$(usex wavpack)"
+	)
+
+	cmake-utils_src_configure
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+}