gentoo resync : 28.04.2018

2 files changed, 165 insertions, 0 deletions

diff --git a/media-sound/qmmp/Manifest b/media-sound/qmmp/Manifest
index 21933c6f85c2..0460345b9e22 100644
--- a/media-sound/qmmp/Manifest
+++ b/media-sound/qmmp/Manifest
@@ -1,8 +1,10 @@
 DIST qmmp-1.1.12.tar.bz2 1147871 BLAKE2B e511b02c38cbc5fcb478585df14a50c9f67985da9ef5e1e11557f2acbbd454d1b1beb430c8e2e2725a7d9ceea63243746fd41ecf2970fd3c52bcf21857bc1228 SHA512 a45680dcee478a7f03a04dbc87525368ac227a9de7e803252470f517027639d3426bf27a3235996d94ad68212596c03e7a67b5ad00a642532f02a820bf4097ee
 DIST qmmp-1.1.7.tar.bz2 1135005 BLAKE2B fc6574b5baa1aaf89cb13f194e59daafa0fe502c1e5ebe5322ae5564eeeb590b6f531307470dc93ef586d992ac827c114b89559ba83b6daab57d16e364388c53 SHA512 058187d34b848c0917077a167bcb52c63e39b5150409295ea658484d99fcd5582f7871979d3d3eea40aa97f0d9bf2a2d72ae721b827bcc0366b1bbc652aa3a72
 DIST qmmp-1.2.0.tar.bz2 1182024 BLAKE2B 0dc471b053a68ddd1f4e5e09d37776712a7c3f323f801920e34843df54a188c9bc5edfeade5791be67177bb9b7a9435ab41763b156d068522db654d9c5a51809 SHA512 63b3a499efa1886d2bb0da093ab5b495a147a0d9ad23780780fd85011ae571179d71dc4222efab39609fe59ec25b9b62d907c8d10decd7fddb73220d963dcf57
+DIST qmmp-1.2.1.tar.bz2 1187267 BLAKE2B 11577481801c9a89acd327c23c94bbfee8e1d3869da6f271f6fa392623977dea256e3a521493f1de5255ac57bc7b881cd0a47b2bfeb5f516d1a5238dd6ac6912 SHA512 a21483e075934b4f696384737cc852c5054f2b088430db84cd461f6c16d6018ea02c992ae50467093f30c82d671113a4c308040d91328ce941e14fabaeb93e17
 EBUILD qmmp-1.1.12.ebuild 3860 BLAKE2B 3ff315969c52877dfd02651bee97b01ba72ab00383a20f6183ad823e0242b3d4676bcc3d28c6a4c33c1c4a64810757f09d1add8b14d656354ddc81ae88ed19a3 SHA512 cb3b6e484f7f63f6659937362ad090a0534c759f4bcdffe9b8aa1161d1a3733bf3dc2b781bbe8650fdeba88d1b52a1f3db7fe0da0206c9137f161dc7bd99ff1f
 EBUILD qmmp-1.1.7-r1.ebuild 3858 BLAKE2B 544e062718ea06fb28e0920ef7d4c1ee1fa8ad850248a956df78054f1f63b06538af04cd8b09fb5f059af5748ce2530f8fb72dc33f902b1c6b5cfab9c8d62c28 SHA512 88a97842bd3b8f43409c420d391421845a45ce597e9334a6218b13bd36ce18dcc510f82dbe67f175e88ed8da5c8bb28eb3a526c0499f828041fadc9b6c3ba22a
 EBUILD qmmp-1.2.0.ebuild 4174 BLAKE2B f89b2d24351b45622cd4f09b8883d549eb90f1b3d963c3dad4f9230e45fcbf720caa11a97acae7e881414dae61a2939da30a37dac3e24e9a09782fe303b9072f SHA512 7db78b91c76d766f8c5d0251ba3c1d5ee94a47427865b75bcf386f0d0d01969bb4ad169196b7acb8932dfd4d93b40eeb39c8b2e4e8cf4699ed5e92be1bd38b16
+EBUILD qmmp-1.2.1.ebuild 4174 BLAKE2B f89ba88df7ddcca820028778416ece543951481e82bd6136a45e95349f934e2a3683e2c5dc5248c606c51e44d2eae4c1ef5686e8eec8a93ba1b2fd2ea958a538 SHA512 b33fbca7a5e380f08adcb182caf3772b30e3bdb092e88684e16b8298646b89fae14cb9ebbaf3f1292c2e44689863515d4f87bc944ff5e1f37ff1abd314a8bb49
 EBUILD qmmp-9999.ebuild 4174 BLAKE2B f89b2d24351b45622cd4f09b8883d549eb90f1b3d963c3dad4f9230e45fcbf720caa11a97acae7e881414dae61a2939da30a37dac3e24e9a09782fe303b9072f SHA512 7db78b91c76d766f8c5d0251ba3c1d5ee94a47427865b75bcf386f0d0d01969bb4ad169196b7acb8932dfd4d93b40eeb39c8b2e4e8cf4699ed5e92be1bd38b16
 MISC metadata.xml 1888 BLAKE2B 32fdf16e8d12c830b72d46d887c9573f583c83c69a405ebb32bb9ac6b46f2100fd29b78241e0982df54fac2b2f7f9ee0e53f56d5f06e388f177514a427ad10ad SHA512 8d17a27caa187aca78e9fbbd64a6226a4055232a39f68e8b211ec8d4062343885e2c4efd47a551e157fbb1cb674cefb3be26c645223e68a57e0b75e4b3a40fe0
diff --git a/media-sound/qmmp/qmmp-1.2.1.ebuild b/media-sound/qmmp/qmmp-1.2.1.ebuild
new file mode 100644
index 000000000000..b0b24f039928
--- /dev/null
+++ b/media-sound/qmmp/qmmp-1.2.1.ebuild
@@ -0,0 +1,163 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils xdg-utils
+[[ ${PV} = 9999 ]] && inherit subversion
+
+DESCRIPTION="Qt5-based audio player with winamp/xmms skins support"
+HOMEPAGE="http://qmmp.ylsoftware.com"
+if [[ ${PV} != 9999 ]]; then
+	SRC_URI="http://qmmp.ylsoftware.com/files/${P}.tar.bz2"
+	KEYWORDS="~amd64 ~x86"
+else
+	QMMP_DEV_BRANCH="1.2"
+	ESVN_REPO_URI="svn://svn.code.sf.net/p/${PN}-dev/code/branches/${PN}-${QMMP_DEV_BRANCH}"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+# KEYWORDS further up
+IUSE="aac +alsa analyzer archive bs2b cdda cover crossfade cue curl +dbus enca ffmpeg flac game
+gnome jack ladspa libav lyrics +mad midi mms modplug mplayer musepack notifier opus oss projectm
+pulseaudio qsui qtmedia scrobbler shout sid sndfile soxr stereo tray udisks +vorbis wavpack"
+
+REQUIRED_USE="
+	gnome? ( dbus )
+	shout? ( soxr vorbis )
+	udisks? ( dbus )
+"
+
+RDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	media-libs/taglib
+	x11-libs/libX11
+	aac? ( media-libs/faad2 )
+	alsa? ( media-libs/alsa-lib )
+	archive? ( app-arch/libarchive )
+	bs2b? ( media-libs/libbs2b )
+	cdda? (
+		dev-libs/libcdio:=
+		dev-libs/libcdio-paranoia
+	)
+	cue? ( media-libs/libcue )
+	curl? ( net-misc/curl )
+	dbus? ( dev-qt/qtdbus:5 )
+	enca? ( app-i18n/enca )
+	ffmpeg? (
+		!libav? ( media-video/ffmpeg:= )
+		libav? ( media-video/libav:= )
+	)
+	flac? ( media-libs/flac )
+	game? ( media-libs/game-music-emu )
+	jack? (
+		media-libs/libsamplerate
+		media-sound/jack-audio-connection-kit
+	)
+	ladspa? ( media-libs/ladspa-cmt )
+	mad? ( media-libs/libmad )
+	midi? ( media-sound/wildmidi )
+	mms? ( media-libs/libmms )
+	modplug? ( >=media-libs/libmodplug-0.8.4 )
+	mplayer? ( media-video/mplayer )
+	musepack? ( >=media-sound/musepack-tools-444 )
+	opus? ( media-libs/opusfile )
+	projectm? (
+		dev-qt/qtgui:5[-gles2]
+		dev-qt/qtopengl:5
+		media-libs/libprojectm
+	)
+	pulseaudio? ( >=media-sound/pulseaudio-0.9.9 )
+	qtmedia? ( dev-qt/qtmultimedia:5 )
+	scrobbler? ( net-misc/curl )
+	shout? ( media-libs/libshout )
+	sid? ( >=media-libs/libsidplayfp-1.1.0 )
+	sndfile? ( media-libs/libsndfile )
+	soxr? ( media-libs/soxr )
+	udisks? ( sys-fs/udisks:2 )
+	vorbis? (
+		media-libs/libogg
+		media-libs/libvorbis
+	)
+	wavpack? ( media-sound/wavpack )
+"
+DEPEND="${RDEPEND}
+	dev-qt/linguist-tools:5
+"
+
+DOCS=( AUTHORS ChangeLog README )
+
+src_prepare() {
+	if has_version dev-libs/libcdio-paranoia; then
+		sed -i \
+			-e 's:cdio/cdda.h:cdio/paranoia/cdda.h:' \
+			src/plugins/Input/cdaudio/decoder_cdaudio.cpp || die
+	fi
+
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DUSE_AAC="$(usex aac)"
+		-DUSE_ALSA="$(usex alsa)"
+		-DUSE_ANALYZER="$(usex analyzer)"
+		-DUSE_ARCHIVE="$(usex archive)"
+		-DUSE_BS2B="$(usex bs2b)"
+		-DUSE_CDA="$(usex cdda)"
+		-DUSE_COVER="$(usex cover)"
+		-DUSE_CROSSFADE="$(usex crossfade)"
+		-DUSE_CUE="$(usex cue)"
+		-DUSE_CURL="$(usex curl)"
+		-DUSE_KDENOTIFY="$(usex dbus)"
+		-DUSE_MPRIS="$(usex dbus)"
+		-DUSE_ENCA="$(usex enca)"
+		-DUSE_FFMPEG="$(usex ffmpeg)"
+		-DUSE_FILEWRITER="$(usex vorbis)"
+		-DUSE_FLAC="$(usex flac)"
+		-DUSE_GME="$(usex game)"
+		-DUSE_GNOMEHOTKEY="$(usex gnome)"
+		-DUSE_HAL=OFF
+		-DUSE_JACK="$(usex jack)"
+		-DUSE_LADSPA="$(usex ladspa)"
+		-DUSE_LYRICS="$(usex lyrics)"
+		-DUSE_MAD="$(usex mad)"
+		-DUSE_MIDI="$(usex midi)"
+		-DUSE_MMS="$(usex mms)"
+		-DUSE_MODPLUG="$(usex modplug)"
+		-DUSE_MPLAYER="$(usex mplayer)"
+		-DUSE_MPC="$(usex musepack)"
+		-DUSE_NOTIFIER="$(usex notifier)"
+		-DUSE_OPUS="$(usex opus)"
+		-DUSE_OSS="$(usex oss)"
+		-DUSE_PROJECTM="$(usex projectm)"
+		-DUSE_PULSE="$(usex pulseaudio)"
+		-DUSE_QSUI="$(usex qsui)"
+		-DUSE_QTMULTIMEDIA="$(usex qtmedia)"
+		-DUSE_SCROBBLER="$(usex scrobbler)"
+		-DUSE_SHOUT="$(usex shout)"
+		-DUSE_SID="$(usex sid)"
+		-DUSE_SNDFILE="$(usex sndfile)"
+		-DUSE_SOXR="$(usex soxr)"
+		-DUSE_STEREO="$(usex stereo)"
+		-DUSE_STATICON="$(usex tray)"
+		-DUSE_UDISKS2="$(usex udisks)"
+		-DUSE_VORBIS="$(usex vorbis)"
+		-DUSE_WAVPACK="$(usex wavpack)"
+	)
+
+	cmake-utils_src_configure
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+}