gentoo resync : 29.12.2022

2 files changed, 295 insertions, 0 deletions

diff --git a/media-sound/mpd/Manifest b/media-sound/mpd/Manifest
index 8cbb21b4ce91..0c1cd5ab4fbb 100644
--- a/media-sound/mpd/Manifest
+++ b/media-sound/mpd/Manifest
@@ -5,8 +5,10 @@ DIST mpd-0.22.11.tar.xz 737184 BLAKE2B b47dcbd1e01812b66c81f33a53fc0838ddb8b7a14
 DIST mpd-0.22.3.tar.xz 726356 BLAKE2B a821e9fed56c3ad625d155057867747d2c883dd90d110b097dfd4acc56ff583949889b849686d5644687226f205c5ae3f95eec182841f706f56135c7e8f3746b SHA512 deeafbe1a95f777fa4f9f355293a648a3f7121fae8e299c92dbd43d821319ffa4182c558cb0691f65e90f243428cec2cf14f64e9572bc72fc6a2af0fd9c0cd60
 DIST mpd-0.23.5.tar.xz 770700 BLAKE2B 91f0d37bca0632a414083f6ecf8838ba5dc4ef4965692b14e56587d3d145140f61bcc120fe4b2bf83eb41f2a7e085da4d999efc19ca9717d2552d92fc6359c65 SHA512 3a870e79bb82c9e8877958d271e933daa3dd970a4510aff4aeea91feab521d7927cd59c7f1ea16a36e84ff879e4f24e4347602ac449c5da31853acb5a3b46f34
 DIST mpd-0.23.6.tar.xz 770812 BLAKE2B 5ccb4a7c06c4317e3285846a261438bdcc10db5eaf71fcba969bcae8321ca50bb26fe9317e23e38eca1c4a8785015596064d5bfc692bf66f8007d0d2a1b71cbb SHA512 1595fcc53a67f1a68b0c0516697d242da53b91626e37bc2f49095add78eb497a52c67c961a421f20b40f3c57a571557a76559a212838de2a3ec4aec6c7a3288d
+DIST mpd-0.23.7.tar.xz 771992 BLAKE2B 2c75196c37eb8d075cca2881bb7ed10e434a071d3c64bb7cdb3bb96dfea74c30de2dce5bfdbc51da945df325d9f278cdf8dd03b7ba07c0ad51cea50971f4a143 SHA512 2a6b3eb2c8b61a22861ae75fe2f62c8ec6cd391f029438577127e309b910e99d7b735e40afae96d52ed4f161195a0ce7cb89cc51ad45df5a18e04736c16ce3a6
 EBUILD mpd-0.22.11.ebuild 8432 BLAKE2B 8f392818d046de9043ab4687b974e04bef7bd862250eeb9f54781b4379f399685a1c5e494e45737df426de23865b4b7ceda01cef76c3b9a2bf4938ed426b04f6 SHA512 9804fbcd13f02f6476f926502c926b008cbe9d765dabb17a15516cc7ec7d0cb1412274227c8c19564dfe47e6a2f2f397ea3a94b0bab3d812bb19ffd1ef421d11
 EBUILD mpd-0.22.3-r1.ebuild 8126 BLAKE2B 818d798cd6bc84639490e60456023bad57ba0b5e08533b903744e03fff1627811dde55f3b67f7600af10e00b17c6b490acf7fa3a616e3574001ffc5494f95aae SHA512 30f4ce07449598a93429ca88307fd5e9ee9471ce742f350ee0521ea68a6a9b4c7144c2c6ee8c93116a797dd36170189ef907d9cae77cc46b77a58df6be79ad1c
 EBUILD mpd-0.23.5.ebuild 8888 BLAKE2B 720e6e27f453b0a45f758674e15227953ad025a20b2d44e7c7e176a5f8a17126b1dea267b34ada121e39286fd8b90875750e7e75f9129d20a10562a84d331fb0 SHA512 76f547fee10a657ece1d41cbe9b0f4479525973ef616f6b1a5848096322326bd99d47d7f70c55bf48cbc83608c84f18ec60ab296c535a3ea870a2ad04625cb83
 EBUILD mpd-0.23.6-r1.ebuild 7845 BLAKE2B 3d90c4be809d911408d5a2733748d13718518816a9e163997a8b9b70bae4ae43c9f08bf1a4848813250f3c17d6e46b39bb86f61fc367491d7d1aeefe67ebffd4 SHA512 f2fdc13933b6d61b900bd107e81bdeaab17f415b80743684dbb38c912600d04b599665d391f67dcfb890d2b30a7031606a48b54d1dfcab170649eba175f4aefc
+EBUILD mpd-0.23.7.ebuild 7881 BLAKE2B e4820273b66cbb205dddcfb0a15f0ee9521065da432ec51eeacb9182c9aa659e5b3a856f8e52f8a0fcb7d197ff80159dbfd1fbbac951a5664f7f88442611603b SHA512 45d92eafff221fa6981baa3362a65e05233f2ccff64d3d2c165561aade154a8c257ba7b07e06b54a4f79acc2f0eb94de8ad84e5798d216c431273e3ec047261f
 MISC metadata.xml 2724 BLAKE2B 08bb2402db4224ccced73cb40aa2e3d7e9a9d699277c999e08f12bb0cb1bbd1406c6fb20b9b80cfe3a41eae05e28f4be30d5e59482132723a82d4ef6de81219f SHA512 112a969c9150a17bc99e18949bc32ef15fb2d06903c0ac5ab455d29ca0cae0f2150b90f0e94cd3a4755c5f545b23c0bd5ec2de93bd154df1d70f224a0f8011c0
diff --git a/media-sound/mpd/mpd-0.23.7.ebuild b/media-sound/mpd/mpd-0.23.7.ebuild
new file mode 100644
index 000000000000..a0d2135688ff
--- /dev/null
+++ b/media-sound/mpd/mpd-0.23.7.ebuild
@@ -0,0 +1,293 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit flag-o-matic linux-info meson systemd xdg
+
+DESCRIPTION="The Music Player Daemon (mpd)"
+HOMEPAGE="https://www.musicpd.org https://github.com/MusicPlayerDaemon/MPD"
+SRC_URI="https://www.musicpd.org/download/${PN}/${PV%.*}/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~riscv ~x86"
+IUSE="+alsa ao +audiofile bzip2 cdio chromaprint +cue +curl doc +dbus
+	+eventfd expat faad +ffmpeg +fifo flac fluidsynth gme +icu +id3tag +inotify
+	+ipv6 jack lame libmpdclient libsamplerate libsoxr +mad mikmod mms
+	modplug mpg123 musepack +network nfs openal openmpt opus oss pipe pipewire pulseaudio qobuz
+	recorder samba selinux sid signalfd snapcast sndfile sndio soundcloud sqlite systemd
+	test twolame udisks unicode vorbis wavpack webdav wildmidi upnp
+	zeroconf zip zlib"
+
+OUTPUT_PLUGINS="alsa ao fifo jack network openal oss pipe pipewire pulseaudio snapcast sndio recorder"
+DECODER_PLUGINS="audiofile faad ffmpeg flac fluidsynth mad mikmod
+	modplug mpg123 musepack opus openmpt flac sid vorbis wavpack wildmidi"
+ENCODER_PLUGINS="audiofile flac lame twolame vorbis"
+
+REQUIRED_USE="
+	|| ( ${OUTPUT_PLUGINS} )
+	|| ( ${DECODER_PLUGINS} )
+	network? ( || ( ${ENCODER_PLUGINS} ) )
+	recorder? ( || ( ${ENCODER_PLUGINS} ) )
+	qobuz? ( curl soundcloud )
+	soundcloud? ( curl qobuz )
+	udisks? ( dbus )
+	upnp? ( curl expat )
+	webdav? ( curl expat )
+"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	acct-user/mpd
+	dev-libs/libfmt:=
+	dev-libs/libpcre2
+	media-libs/libogg
+	sys-libs/liburing:=
+	alsa? (
+		media-libs/alsa-lib
+		media-sound/alsa-utils
+	)
+	ao? ( media-libs/libao:=[alsa?,pulseaudio?] )
+	audiofile? ( media-libs/audiofile:= )
+	bzip2? ( app-arch/bzip2 )
+	cdio? (
+		dev-libs/libcdio:=
+		dev-libs/libcdio-paranoia
+	)
+	chromaprint? ( media-libs/chromaprint )
+	curl? ( net-misc/curl )
+	dbus? ( sys-apps/dbus )
+	doc? ( dev-python/sphinx )
+	expat? ( dev-libs/expat )
+	faad? ( media-libs/faad2 )
+	ffmpeg? ( media-video/ffmpeg:0= )
+	flac? ( media-libs/flac )
+	fluidsynth? ( media-sound/fluidsynth )
+	gme? ( >=media-libs/game-music-emu-0.6.0_pre20120802 )
+	icu? (
+		dev-libs/icu:=
+		virtual/libiconv
+	)
+	id3tag? ( media-libs/libid3tag:= )
+	jack? ( virtual/jack )
+	lame? ( network? ( media-sound/lame ) )
+	libmpdclient? ( media-libs/libmpdclient )
+	libsamplerate? ( media-libs/libsamplerate )
+	libsoxr? ( media-libs/soxr )
+	mad? ( media-libs/libmad )
+	mikmod? ( media-libs/libmikmod )
+	mms? ( media-libs/libmms )
+	modplug? ( media-libs/libmodplug )
+	mpg123? ( media-sound/mpg123 )
+	musepack? ( media-sound/musepack-tools )
+	network? ( >=media-libs/libshout-2.4.0 )
+	nfs? ( net-fs/libnfs )
+	openal? ( media-libs/openal )
+	openmpt? ( media-libs/libopenmpt )
+	opus? ( media-libs/opus )
+	pulseaudio? ( media-sound/pulseaudio )
+	pipewire? ( media-video/pipewire:= )
+	qobuz? ( dev-libs/libgcrypt:0 )
+	samba? ( net-fs/samba )
+	selinux? ( sec-policy/selinux-mpd )
+	sid? ( || (
+		media-libs/libsidplay:2
+		media-libs/libsidplayfp
+	) )
+	snapcast? ( media-sound/snapcast )
+	sndfile? ( media-libs/libsndfile )
+	sndio? ( media-sound/sndio )
+	soundcloud? ( >=dev-libs/yajl-2:= )
+	sqlite? ( dev-db/sqlite:3 )
+	systemd? ( sys-apps/systemd:= )
+	twolame? ( media-sound/twolame )
+	udisks? ( sys-fs/udisks:2 )
+	upnp? ( net-libs/libupnp:0 )
+	vorbis? ( media-libs/libvorbis )
+	wavpack? ( media-sound/wavpack )
+	wildmidi? ( media-sound/wildmidi )
+	zeroconf? ( net-dns/avahi[dbus] )
+	zip? ( dev-libs/zziplib:= )
+	zlib? ( sys-libs/zlib:= )"
+
+DEPEND="${RDEPEND}
+	>=dev-libs/boost-1.68:=
+	test? ( dev-cpp/gtest )"
+
+BDEPEND="virtual/pkgconfig"
+
+pkg_setup() {
+	if use eventfd; then
+		CONFIG_CHECK+=" ~EVENTFD"
+		ERROR_EVENTFD="${P} requires eventfd in-kernel support."
+	fi
+
+	if use signalfd; then
+		CONFIG_CHECK+=" ~SIGNALFD"
+		ERROR_SIGNALFD="${P} requires signalfd in-kernel support."
+	fi
+
+	if use inotify; then
+		CONFIG_CHECK+=" ~INOTIFY_USER"
+		ERROR_INOTIFY_USER="${P} requires inotify in-kernel support."
+	fi
+
+	if use eventfd || use signalfd || use inotify; then
+		linux-info_pkg_setup
+	fi
+
+	elog "If you will be starting mpd via /etc/init.d/mpd, please make sure that MPD's pid_file is _set_."
+}
+
+src_prepare() {
+	 sed -i \
+		-e 's:^#filesystem_charset.*$:filesystem_charset "UTF-8":' \
+		-e 's:^#user.*$:user "mpd":' \
+		-e 's:^#bind_to_address.*any.*$:bind_to_address "localhost":' \
+		-e 's:^#bind_to_address.*$:bind_to_address "/var/lib/mpd/socket":' \
+		-e 's:^#music_directory.*$:music_directory "/var/lib/mpd/music":' \
+		-e 's:^#playlist_directory.*$:playlist_directory "/var/lib/mpd/playlists":' \
+		-e 's:^#db_file.*$:db_file "/var/lib/mpd/database":' \
+		-e 's:^#log_file.*$:log_file "/var/lib/mpd/log":' \
+		-e 's:^#pid_file.*$:pid_file "/var/lib/mpd/pid":' \
+		-e 's:^#state_file.*$:state_file "/var/lib/mpd/state":' \
+		doc/mpdconf.example || die
+	default
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature bzip2)
+		$(meson_feature cdio cdio_paranoia)
+		$(meson_feature chromaprint)
+		$(meson_use cue)
+		$(meson_feature curl)
+		$(meson_feature dbus)
+		$(meson_use eventfd)
+		$(meson_feature expat)
+		$(meson_feature icu)
+		$(meson_feature id3tag)
+		$(meson_use inotify)
+		$(meson_feature ipv6)
+		$(meson_feature cdio iso9660)
+		$(meson_feature libmpdclient)
+		$(meson_feature libsamplerate)
+		$(meson_feature mms)
+		$(meson_feature nfs)
+		$(meson_use signalfd)
+		$(meson_feature samba smbclient)
+		$(meson_feature libsoxr soxr)
+		$(meson_feature sqlite)
+		$(meson_feature systemd)
+		$(meson_use test)
+		$(meson_feature udisks)
+		-Dupnp=$(usex upnp pupnp disabled)
+		$(meson_feature webdav)
+		-Dzeroconf=$(usex zeroconf avahi disabled)
+		$(meson_feature zlib)
+		$(meson_feature zip zzip)
+	)
+
+	emesonargs+=(
+		$(meson_feature alsa)
+		$(meson_feature ao)
+		$(meson_use fifo)
+		$(meson_feature jack)
+		$(meson_feature openal)
+		$(meson_feature oss)
+		$(meson_use pipe)
+		$(meson_feature pipewire)
+		$(meson_feature pulseaudio pulse)
+		$(meson_use recorder)
+		$(meson_use snapcast)
+		$(meson_feature sndio)
+	)
+
+	if use samba || use upnp; then
+		emesonargs+=( -Dneighbor=true )
+	fi
+
+	append-lfs-flags
+	append-ldflags "-L${ESYSROOT}/usr/$(get_libdir)/sidplay/builders"
+
+	if use network; then
+		emesonargs+=(
+			-Dshine=disabled
+			-Dshout=enabled
+			$(meson_feature vorbis vorbisenc)
+			-Dhttpd=true
+			$(meson_feature lame)
+			$(meson_feature twolame)
+			$(meson_use audiofile wave_encoder)
+		)
+	fi
+
+	emesonargs+=(
+		# media-libs/adplug is not packaged anymore
+		-Dadplug=disabled
+		$(meson_feature audiofile)
+		$(meson_feature faad)
+		$(meson_feature ffmpeg)
+		$(meson_feature flac)
+		$(meson_feature fluidsynth)
+		$(meson_feature gme)
+		$(meson_feature mad)
+		$(meson_feature mikmod)
+		$(meson_feature modplug)
+		$(meson_feature musepack mpcdec)
+		$(meson_feature mpg123)
+		$(meson_feature openmpt)
+		$(meson_feature opus)
+		$(meson_feature sid sidplay)
+		$(meson_feature sndfile)
+		$(meson_feature vorbis)
+		$(meson_feature wavpack)
+		$(meson_feature wildmidi)
+		$(meson_feature qobuz)
+		$(meson_feature soundcloud)
+
+		--libdir="/usr/$(get_libdir)"
+		$(meson_feature doc documentation)
+		-Dsolaris_output=disabled
+
+		-Ddatabase=true
+		-Ddsd=true
+		-Dio_uring=enabled
+		-Dtcp=true
+
+		-Dsystemd_system_unit_dir="$(systemd_get_systemunitdir)"
+		-Dsystemd_user_unit_dir="$(systemd_get_userunitdir)"
+
+		$(meson_feature icu iconv)
+	)
+
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	insinto /etc
+	newins doc/mpdconf.example mpd.conf
+
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}"/${PN}-0.21.1.logrotate ${PN}
+
+	newinitd "${FILESDIR}"/${PN}-0.21.4.init ${PN}
+
+	if use unicode; then
+		sed -i -e 's:^#filesystem_charset.*$:filesystem_charset "UTF-8":' \
+			"${ED}"/etc/mpd.conf || die "sed failed"
+	fi
+
+	keepdir /var/lib/mpd
+	keepdir /var/lib/mpd/music
+	keepdir /var/lib/mpd/playlists
+
+	rm -r "${ED}"/usr/share/doc/mpd || die
+
+	fowners mpd:audio -R /var/lib/mpd
+
+}