gentoo resync : 11.07.2019

4 files changed, 179 insertions, 0 deletions

diff --git a/media-sound/loudness-scanner/Manifest b/media-sound/loudness-scanner/Manifest
new file mode 100644
index 000000000000..d82094854ba7
--- /dev/null
+++ b/media-sound/loudness-scanner/Manifest
@@ -0,0 +1,4 @@
+DIST loudness-scanner-0.5.1_p20190709.tar.xz 65360 BLAKE2B 122a14b1700e0b971d423bb3c6395eddd49663d8980ecc57dec85cbf45b67ef72b68203b15ac21b040af824b71641635bd72c67b40b0ba757ed536e121c7e3ae SHA512 2160a1dcba92efeb308f65e2dbd32405ad6c9b72355a4161f12579d767757e709c0ffe17df988105210cbb8f05f727f6b143cbe0540edeb8c7c6585b14998fe1
+EBUILD loudness-scanner-0.5.1_p20190709.ebuild 1844 BLAKE2B 6efd5d9f02b98700695a8ec139b88a2c32189959704ce0b88ce42bba596b4113bc43006f53f2ddd251154c6ec506484c2416cc35d6a8bc9088d778387a4d07f4 SHA512 879047d0bfafdf43fe22d50b2f71c6116c8f7a91d23c0cc26bf844d2adc5ab5c46d9d2c5b3dd1027ff39afc3e412b2a87ba7dbf9da472db9fa2573759013650d
+EBUILD loudness-scanner-9999.ebuild 1818 BLAKE2B 238da37078dedb874bf47a42ab43a97d5412bd0a0d260ec105a0520f7d8a3be742ad8981d9c31e63685f1da5c7116edbc35665c24c62e3f9df866cb836bf6d0d SHA512 49154649a0cf33f74d8d751c82c442f94f0e296221817b1fdf1e079cf76da40a0dc148d566f043f80b32710fab812b2ccec7316feb05d983aa5af2641aa564c6
+MISC metadata.xml 977 BLAKE2B b68f84774b5494c9735661e858630eefd51bf8fc48fadee3b75237e688c96454355a0e9d728d4c0d919ed1c92871b21f7b9c4e694e9972b4f833f259bf5e8a1b SHA512 d1cfbef820d90d8b38b2baf038b06bd2bcd31c307c42f3edbf79c2d0dea98ee04b5fb30bcfc61b2336767b1a6e1afb6c2dd37cf7202f56a3673767ca471f7c74
diff --git a/media-sound/loudness-scanner/loudness-scanner-0.5.1_p20190709.ebuild b/media-sound/loudness-scanner/loudness-scanner-0.5.1_p20190709.ebuild
new file mode 100644
index 000000000000..6570f3d70fc1
--- /dev/null
+++ b/media-sound/loudness-scanner/loudness-scanner-0.5.1_p20190709.ebuild
@@ -0,0 +1,74 @@
+# Copyright 2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils
+
+DESCRIPTION="Scans your music files and tags them with loudness information"
+HOMEPAGE="https://github.com/jiixyj/loudness-scanner/"
+SRC_URI="https://dev.gentoo.org/~tamiko/distfiles/${P}.tar.xz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="ffmpeg gtk mpg123 musepack qt5 sndfile"
+REQUIRED_USE="|| ( sndfile ffmpeg mpg123 musepack )"
+
+DEPEND="
+	dev-libs/glib
+	media-libs/libebur128
+	media-libs/taglib
+	ffmpeg? ( media-video/ffmpeg )
+	mpg123? ( media-sound/mpg123 )
+	musepack? ( media-sound/musepack-tools )
+	sndfile? ( media-libs/libsndfile )
+	gtk? (
+		gnome-base/librsvg:2
+		x11-libs/cairo
+		x11-libs/gtk+:2
+	)
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtsvg:5
+		dev-qt/qtwidgets:5
+	)
+"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}/${PN}"
+
+src_prepare() {
+	cmake-utils_src_prepare
+	sed -i -e 's|".",|"'${EROOT}'/usr/'$(get_libdir)'/loudness-scanner",|g' \
+		"${S}"/scanner/inputaudio/input.c
+}
+
+src_configure() {
+	local -a mycmakeargs=(
+		-DCMAKE_SKIP_RPATH=ON
+		-DBUILD_SHARED_LIBS:BOOL=OFF # use static internal libraries
+		-DDISABLE_FFMPEG:BOOL=$(usex ffmpeg no yes)
+		-DDISABLE_GSTREAMER:BOOL=ON # depends on obsolete gstreamer-0.10
+		-DDISABLE_GTK2:BOOL=$(usex gtk no yes)
+		-DDISABLE_MPCDEC:BOOL=$(usex musepack no yes)
+		-DDISABLE_MPG123:BOOL=$(usex mpg123 no yes)
+		-DDISABLE_QT4:BOOL=ON
+		-DDISABLE_QT5:BOOL=$(usex qt5 no yes)
+		-DDISABLE_RSVG2:BOOL=$(usex gtk no yes)
+		-DDISABLE_SNDFILE:BOOL=$(usex sndfile no yes)
+	)
+	cmake-utils_src_configure
+}
+
+src_install() {
+	dobin "${BUILD_DIR}"/loudness
+	use gtk && dobin "${BUILD_DIR}"/loudness-drop-gtk
+	use qt5 && dobin "${BUILD_DIR}"/loudness-drop-qt5
+
+	insinto /usr/$(get_libdir)/loudness-scanner
+	doins "${BUILD_DIR}"/libinput_*.so
+
+	einstalldocs
+}
diff --git a/media-sound/loudness-scanner/loudness-scanner-9999.ebuild b/media-sound/loudness-scanner/loudness-scanner-9999.ebuild
new file mode 100644
index 000000000000..c2e409a5c311
--- /dev/null
+++ b/media-sound/loudness-scanner/loudness-scanner-9999.ebuild
@@ -0,0 +1,72 @@
+# Copyright 2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils git-r3
+
+DESCRIPTION="Scans your music files and tags them with loudness information"
+HOMEPAGE="https://github.com/jiixyj/loudness-scanner/"
+EGIT_REPO_URI="https://github.com/jiixyj/loudness-scanner.git"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS=""
+IUSE="ffmpeg gtk mpg123 musepack qt5 sndfile"
+REQUIRED_USE="|| ( sndfile ffmpeg mpg123 musepack )"
+
+DEPEND="
+	dev-libs/glib
+	media-libs/libebur128
+	media-libs/taglib
+	ffmpeg? ( media-video/ffmpeg )
+	mpg123? ( media-sound/mpg123 )
+	musepack? ( media-sound/musepack-tools )
+	sndfile? ( media-libs/libsndfile )
+	gtk? (
+		gnome-base/librsvg:2
+		x11-libs/cairo
+		x11-libs/gtk+:2
+	)
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtsvg:5
+		dev-qt/qtwidgets:5
+	)
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	cmake-utils_src_prepare
+	sed -i -e 's|".",|"'${EROOT}'/usr/'$(get_libdir)'/loudness-scanner",|g' \
+		"${S}"/scanner/inputaudio/input.c
+}
+
+src_configure() {
+	local -a mycmakeargs=(
+		-DCMAKE_SKIP_RPATH=ON
+		-DBUILD_SHARED_LIBS:BOOL=OFF # use static internal libraries
+		-DDISABLE_FFMPEG:BOOL=$(usex ffmpeg no yes)
+		-DDISABLE_GSTREAMER:BOOL=ON # depends on obsolete gstreamer-0.10
+		-DDISABLE_GTK2:BOOL=$(usex gtk no yes)
+		-DDISABLE_MPCDEC:BOOL=$(usex musepack no yes)
+		-DDISABLE_MPG123:BOOL=$(usex mpg123 no yes)
+		-DDISABLE_QT4:BOOL=ON
+		-DDISABLE_QT5:BOOL=$(usex qt5 no yes)
+		-DDISABLE_RSVG2:BOOL=$(usex gtk no yes)
+		-DDISABLE_SNDFILE:BOOL=$(usex sndfile no yes)
+	)
+	cmake-utils_src_configure
+}
+
+src_install() {
+	dobin "${BUILD_DIR}"/loudness
+	use gtk && dobin "${BUILD_DIR}"/loudness-drop-gtk
+	use qt5 && dobin "${BUILD_DIR}"/loudness-drop-qt5
+
+	insinto /usr/$(get_libdir)/loudness-scanner
+	doins "${BUILD_DIR}"/libinput_*.so
+
+	einstalldocs
+}
diff --git a/media-sound/loudness-scanner/metadata.xml b/media-sound/loudness-scanner/metadata.xml
new file mode 100644
index 000000000000..399d30caf9c4
--- /dev/null
+++ b/media-sound/loudness-scanner/metadata.xml
@@ -0,0 +1,29 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>tamiko@gentoo.org</email>
+		<name>Matthias Maier</name>
+	</maintainer>
+	<maintainer type="person">
+		<name>Stefan Briesenick</name>
+		<email>gentoo@sbriesen.de</email>
+	</maintainer>
+	<maintainer type="project">
+		<email>proxy-maint@gentoo.org</email>
+		<name>Proxy Maintainers</name>
+	</maintainer>
+	<longdescription lang="en">
+		loudness-scanner is a tool that scans your music files according
+		to the EBU R128 standard for loudness normalisation. It optionally
+		adds ReplayGain compatible tags to the files.
+	</longdescription>
+	<use>
+		<flag name="mpg123">build the mpg123 plugin</flag>
+		<flag name="musepack">build the musepack plugin</flag>
+		<flag name="sndfile">build the sndfile plugin</flag>
+	</use>
+	<upstream>
+		<remote-id type="github">jiixyj/loudness-scanner</remote-id>
+	</upstream>
+</pkgmetadata>