reinit the tree, so we can have metadata

4 files changed, 205 insertions, 0 deletions

diff --git a/media-sound/jack2/Manifest b/media-sound/jack2/Manifest
new file mode 100644
index 000000000000..644345628ffd
--- /dev/null
+++ b/media-sound/jack2/Manifest
@@ -0,0 +1,6 @@
+DIST jack2-1.9.10.tar.gz 6415555 SHA256 88f1b6601b7c8950e6a2d5940b423a33ee628ae5583da40bdce3d9317d8c600d SHA512 0bee815356e9e572224e7cc484c402f38797d70257c4bc79a47552ae30a25a4600c61f712a73cbbede52cd8cb8dc144c9334e28c10e23354a11b7223ee0bb0ca WHIRLPOOL a7b4e14fb1e0490955a363fe0680558d89f80c3cdf18a840991b636518ecf55d872d91d9024770874b5d28494e2cbadc0f21ce4b73ee7873f62842fb0339b0c5
+DIST jack2-1.9.11-RC1.tar.gz 6481650 SHA256 730eee0de2136e62b358f4b65d9e30109d706d2627eb2998e43763b47b17474f SHA512 4fd7d82ab6536b8c6061023858ae5b978903608b149498818971481da75c6e9e0e7e7aef5e1343730c259f4378aebfbf25916b9736e0ad8aa19584a44f894436 WHIRLPOOL 6401f16b5ef5331602c6b3c14c709adf17f765700959d87494738960c8e1407cc894789ef8b11452ca9621a9e18e93407d81ede0846118efbb81560bbe9435e6
+EBUILD jack2-1.9.10.ebuild 2344 SHA256 fc3db265ad7ab896438fa58f943d3a890ba4fe5bb9edda6980e3d421e4efc3d3 SHA512 5a9ab02ab4e9e8cdf1bcf558b90d1d5f890548492058cb679685e700ba3c538d694e7506ccdb2f44c81d98e90c3d3caf7fe72e60b6b24cbee6664c9f4efa2ae3 WHIRLPOOL c1ea5b9e0e6864d1e0f03c63ed9c80b6314db59a19bca0a0caeb2a1218bb8bc6b77de092f4692f125febd9a662d7db8d70c160567fe261ad7d85295cc4539fe9
+EBUILD jack2-1.9.11_rc1.ebuild 2233 SHA256 23f5c067afbff0e89589b6f422db2c29f54bfa4a4e8005fa6c83635de65b74c5 SHA512 e029d81ff459bfeb080c190189f99ebedf3c87ee266eef54a1c9d8fc3bcc2b4d8bb05822c1269bbb374e6f752c7673f44f36ef4bfbaf1cde79168ebabd87a43f WHIRLPOOL 558d46cfc5b235cc32a558d6f5fc9c40cc89fef15f6999d70e1c8d94c76406d17741492aec675ded070013ac190de9ef81ec43875d2812341975e643a747b1cd
+MISC ChangeLog 474 SHA256 e4b972153d7232363276a7d71c4dc73d1e0538ea5a7762a4df8184ad0ef76ea0 SHA512 286a42423b6477db4aabb82660da9e756358f5892fcdb0be5b1e0e4e600ca89b92d11e5608e3798eb19c436e1131c124f34d9251809882306692788c57726b93 WHIRLPOOL d282fd72b31e0f1817ecb3f7c0de2db547367b01c0a052b55f2e518733fe598d65d748d353d3b6bdfe1a9abc257be50fe3fb6286f5e5426cacd020bec63e96f4
+MISC metadata.xml 679 SHA256 4b2676eab2302acb18592bdfabc4eaa9851c90be9328c0f1c2d2730cc4f9a93a SHA512 8c6fc8ce9dc151cdc8adc2092a661a76ef0fd12fc8f2c922be3e7a75215e40ed5b352f8099906ae6a883fd3a3edb674d0a6784831d2cd9b881b474cf6c419152 WHIRLPOOL 3c5039f3dfccdc85d0b1664c353cb3c4fe2db3de09e495a7fa166eb4d6777642008edbf4d3821793d287be0a5d1f4c00c7a542f9d907a3b90fe52ce32e18203d
diff --git a/media-sound/jack2/jack2-1.9.10.ebuild b/media-sound/jack2/jack2-1.9.10.ebuild
new file mode 100644
index 000000000000..e14f43d964f7
--- /dev/null
+++ b/media-sound/jack2/jack2-1.9.10.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="5"
+
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE="threads(+)"
+[[ "${PV}" = "2.9999" ]] && inherit git-r3
+inherit eutils python-single-r1 waf-utils multilib-minimal
+
+DESCRIPTION="Jackdmp jack implemention for multi-processor machine"
+HOMEPAGE="http://jackaudio.org/"
+
+RESTRICT="mirror"
+if [[ "${PV}" = "2.9999" ]]; then
+	EGIT_REPO_URI="https://github.com/jackaudio/${PN}.git"
+	KEYWORDS=""
+else
+	SRC_URI="https://github.com/jackaudio/${PN}/archive/v${PV}.tar.gz -> jack2-${PV}.tar.gz"
+	KEYWORDS="~amd64 ~ppc ~x86"
+fi
+
+LICENSE="GPL-2"
+SLOT="2"
+IUSE="alsa celt dbus doc opus pam"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+# FIXME: automagic deps: readline, samplerate, sndfile, celt, opus
+# FIXME: even though sndfile is just used for binaries, the check is flawed
+#	making the build fail if multilib libsndfile is not found.
+CDEPEND="media-libs/libsamplerate[${MULTILIB_USEDEP}]
+	media-libs/libsndfile[${MULTILIB_USEDEP}]
+	sys-libs/readline:0
+	${PYTHON_DEPS}
+	alsa? ( media-libs/alsa-lib[${MULTILIB_USEDEP}] )
+	celt? ( media-libs/celt:0[${MULTILIB_USEDEP}] )
+	dbus? (
+		dev-libs/expat[${MULTILIB_USEDEP}]
+		sys-apps/dbus[${MULTILIB_USEDEP}]
+	)
+	opus? ( media-libs/opus[custom-modes,${MULTILIB_USEDEP}] )"
+DEPEND="${CDEPEND}
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )"
+RDEPEND="${CDEPEND}
+	dbus? ( dev-python/dbus-python[${PYTHON_USEDEP}] )
+	pam? ( sys-auth/realtime-base )
+	!media-sound/jack-audio-connection-kit:0"
+
+[[ "${PV}" = "2.9999" ]] || S="${WORKDIR}/jack2-${PV}"
+
+DOCS=( ChangeLog README README_NETJACK2 TODO )
+
+src_unpack() {
+	if [[ "${PV}" = "2.9999" ]]; then
+		git-r3_src_unpack
+	else
+		default
+	fi
+}
+
+src_prepare() {
+	default
+	multilib_copy_sources
+}
+
+multilib_src_configure() {
+	local mywafconfargs=(
+		$(usex alsa --alsa "")
+		$(usex dbus --dbus --classic)
+	)
+
+	WAF_BINARY="${BUILD_DIR}"/waf waf-utils_src_configure ${mywafconfargs[@]}
+}
+
+multilib_src_compile() {
+	WAF_BINARY="${BUILD_DIR}"/waf waf-utils_src_compile
+
+	if multilib_is_native_abi && use doc; then
+		doxygen || die "doxygen failed"
+	fi
+}
+
+multilib_src_install() {
+	multilib_is_native_abi && use doc && \
+		HTML_DOCS=( "${BUILD_DIR}"/html/ )
+	WAF_BINARY="${BUILD_DIR}"/waf waf-utils_src_install
+}
+
+multilib_src_install_all() {
+	python_fix_shebang "${ED}"
+}
diff --git a/media-sound/jack2/jack2-1.9.11_rc1.ebuild b/media-sound/jack2/jack2-1.9.11_rc1.ebuild
new file mode 100644
index 000000000000..4f0738fc56c4
--- /dev/null
+++ b/media-sound/jack2/jack2-1.9.11_rc1.ebuild
@@ -0,0 +1,89 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="5"
+
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE="threads(+)"
+inherit eutils python-single-r1 waf-utils multilib-minimal
+
+DESCRIPTION="Jackdmp jack implemention for multi-processor machine"
+HOMEPAGE="http://jackaudio.org/"
+
+if [[ "${PV}" = "2.9999" ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/jackaudio/${PN}.git"
+	KEYWORDS=""
+else
+	MY_PV="${PV/_rc/-RC}"
+	MY_P="${PN}-${MY_PV}"
+	S="${WORKDIR}/${MY_P}"
+	SRC_URI="https://github.com/jackaudio/${PN}/archive/v${MY_PV}.tar.gz -> ${MY_P}.tar.gz"
+	KEYWORDS="~amd64 ~ppc ~x86"
+fi
+
+LICENSE="GPL-2"
+SLOT="2"
+IUSE="alsa celt dbus doc opus pam classic sndfile libsamplerate readline"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+CDEPEND="media-libs/libsamplerate
+	media-libs/libsndfile
+	sys-libs/readline:0=
+	${PYTHON_DEPS}
+	alsa? ( media-libs/alsa-lib[${MULTILIB_USEDEP}] )
+	celt? ( media-libs/celt:0[${MULTILIB_USEDEP}] )
+	dbus? (
+		dev-libs/expat[${MULTILIB_USEDEP}]
+		sys-apps/dbus[${MULTILIB_USEDEP}]
+	)
+	opus? ( media-libs/opus[custom-modes,${MULTILIB_USEDEP}] )"
+DEPEND="${CDEPEND}
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )"
+RDEPEND="${CDEPEND}
+	dbus? ( dev-python/dbus-python[${PYTHON_USEDEP}] )
+	pam? ( sys-auth/realtime-base )
+	!media-sound/jack-audio-connection-kit:0"
+
+DOCS=( ChangeLog README README_NETJACK2 TODO )
+
+src_prepare() {
+	default
+	multilib_copy_sources
+}
+
+multilib_src_configure() {
+	local mywafconfargs=(
+		--htmldir=/usr/share/doc/${PF}/html
+		$(usex dbus --dbus "")
+		$(usex classic --classic "")
+		--alsa=$(usex alsa yes no)
+		--celt=$(usex celt yes no)
+		--doxygen=$(multilib_native_usex doc yes no)
+		--firewire=no
+		--freebob=no
+		--iio=no
+		--opus=$(usex opus yes no)
+		--portaudio=no
+		--readline=$(multilib_native_usex readline yes no)
+		--samplerate=$(multilib_native_usex libsamplerate yes no)
+		--sndfile=$(multilib_native_usex sndfile yes no)
+		--winmme=no
+	)
+
+	waf-utils_src_configure ${mywafconfargs[@]}
+}
+
+multilib_src_compile() {
+	WAF_BINARY="${BUILD_DIR}"/waf waf-utils_src_compile
+}
+
+multilib_src_install() {
+	WAF_BINARY="${BUILD_DIR}"/waf waf-utils_src_install
+}
+
+multilib_src_install_all() {
+	python_fix_shebang "${ED}"
+}
diff --git a/media-sound/jack2/metadata.xml b/media-sound/jack2/metadata.xml
new file mode 100644
index 000000000000..5156eca67d7a
--- /dev/null
+++ b/media-sound/jack2/metadata.xml
@@ -0,0 +1,17 @@
+<?xml version='1.0' encoding='UTF-8'?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>proaudio@gentoo.org</email>
+    <name>Gentoo ProAudio Project</name>
+  </maintainer>
+  <use>
+    <flag name="pam">Add basic realtime configuration via <pkg>sys-auth/realtime-base</pkg></flag>
+    <flag name="celt">Support CELT low delay audio codec (<pkg>media-libs/celt</pkg>)</flag>
+    <flag name="opus">Support <pkg>media-libs/opus</pkg></flag>
+    <flag name="classic">Enable building of jackd</flag>
+  </use>
+  <upstream>
+    <remote-id type="github">jackaudio/jack2</remote-id>
+  </upstream>
+</pkgmetadata>