gentoo auto-resync : 21:08:2023 - 15:44:13

5 files changed, 109 insertions, 0 deletions

diff --git a/media-radio/Manifest.gz b/media-radio/Manifest.gz
index 2e08f36ee9d1..bb8a2acf7f5a 100644
--- a/media-radio/Manifest.gz
+++ b/media-radio/Manifest.gz
diff --git a/media-radio/chirp/Manifest b/media-radio/chirp/Manifest
new file mode 100644
index 000000000000..6bb2589d2e3a
--- /dev/null
+++ b/media-radio/chirp/Manifest
@@ -0,0 +1,4 @@
+AUX chirp-20230818_no-future.patch 737 BLAKE2B 6ee7ad9736e5a5a3c66f72c492ab1587eda4df45a5cca69cc26356b1bd1ec315a9fb1cbce3adf68bd66626791fdb647fb5f70b61e7ac69b5e103d9948b8664d6 SHA512 24f86eacb695a2bacb2b78e65c379fa76e9e3a7d7c0d00905fbe5f959853066a2e9b039e908d033c270038269b8314046e2a9ead248ab592694d5e0345350423
+DIST chirp-20230818.tar.gz 1750957 BLAKE2B 765a3cdffc51372c7012fd59112c00dbe58374e68434ec127e3d7b6702dc80371564244972457cebc44c1e51d5d50f05f413b263a63bbc94c88c0db1f437c380 SHA512 dcc8eadc75ea1e74c32dfc9c73f1857c1745cfbf1272934425a022fa663d1471cc8e79d63da9628369b833f7fc25ce86960924545ad5bfe2fe4d34509e7308eb
+EBUILD chirp-20230818.ebuild 1614 BLAKE2B 1686c87f2179097d499da40fdb1f6bfc7e72f264bbf9088c608437cf83ac453bad91cb88afede26a3e3fc70e61a3de8c10b9f0445aaa6b70717dc5f2c66dbe61 SHA512 9251160924162c16c427e6a72aa78d8e73632356b53225a6e4c1252a57f9c444dc6e809646610ec069a0fef54e3b9aa1e34b017ec3987d6fb010f4354c35f766
+MISC metadata.xml 346 BLAKE2B 224c86372b88a8b9e4bd4bffb8f94ed45f7bfe1b0e7a2a9b6fda0c214b7b42e18288f801057dcd38335122643f6dc8a9dd73a1c018f698a0305f4800805411e7 SHA512 b07a7af44bdff7b60052505ddfe124582a3e11cb06a9b06f8ccd5dfb2e1459ba35733c00fb157253c96b6a0d9e0f0bc1f584270d4102b815304f9f4b0cc8c944
diff --git a/media-radio/chirp/chirp-20230818.ebuild b/media-radio/chirp/chirp-20230818.ebuild
new file mode 100644
index 000000000000..10f5b91e388d
--- /dev/null
+++ b/media-radio/chirp/chirp-20230818.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# py3.12 blocked by wxpython
+PYTHON_COMPAT=( python3_{10..11} )
+DISTUTILS_SINGLE_IMPL=1
+DISTUTILS_USE_PEP517=setuptools
+
+inherit distutils-r1
+
+DESCRIPTION="A free, open-source tool for programming your radio"
+HOMEPAGE="https://chirp.danplanet.com/"
+SRC_URI="https://trac.chirp.danplanet.com/${PN}_next/next-${PV}/${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="+gui"
+
+RDEPEND="$(python_gen_cond_dep '
+	dev-python/pyserial[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	gui? (
+		dev-python/wxpython:4.0[${PYTHON_USEDEP}]
+		dev-python/yattag[${PYTHON_USEDEP}]
+	)
+')"
+BDEPEND="test? ( $(python_gen_cond_dep '
+	dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+') )"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-20230818_no-future.patch
+)
+
+distutils_enable_tests pytest
+
+# The alias map is an internal developer file not included in release tarballs.
+# Other disabled tests require Internet access.
+EPYTEST_DESELECT=(
+	tests/unit/test_directory.py::TestAliasMap
+	tests/unit/test_network_sources.py
+	tests/unit/test_repeaterbook.py
+)
+
+python_test() {
+	# From the contents of tests/ upstream currently only runs unit and driver
+	# tests, and the latter can take so long that they have even got a special
+	# script for only running them on drivers whose code has changed
+	# with respect to origin/master.
+	epytest tests/unit/
+}
+
+src_install() {
+	distutils-r1_src_install
+	if ! use gui; then
+		rm "${ED}"/usr/bin/${PN} || die
+	fi
+}
diff --git a/media-radio/chirp/files/chirp-20230818_no-future.patch b/media-radio/chirp/files/chirp-20230818_no-future.patch
new file mode 100644
index 000000000000..554b614849bc
--- /dev/null
+++ b/media-radio/chirp/files/chirp-20230818_no-future.patch
@@ -0,0 +1,30 @@
+future.standard_library.install_aliases() is a no-op on Python3 anyway.
+
+--- a/chirp/chirp_common.py
++++ b/chirp/chirp_common.py
+@@ -14,7 +14,6 @@
+ # along with this program.  If not, see <http://www.gnu.org/licenses/>.
+ 
+ from builtins import bytes
+-from future import standard_library
+ 
+ import base64
+ import json
+@@ -1920,7 +1919,6 @@
+ def urlretrieve(url, fn):
+     """Grab an URL and save it in a specified file"""
+ 
+-    standard_library.install_aliases()
+     import urllib.request
+     import urllib.error
+ 
+--- a/setup.py
++++ b/setup.py
+@@ -12,7 +12,6 @@
+           'pyserial',
+           'requests',
+           'six',
+-          'future',
+           'importlib-resources;python_version<"3.10"',
+           'yattag',
+       ],
diff --git a/media-radio/chirp/metadata.xml b/media-radio/chirp/metadata.xml
new file mode 100644
index 000000000000..483d06c69224
--- /dev/null
+++ b/media-radio/chirp/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>marecki@gentoo.org</email>
+		<name>Marek Szuba</name>
+	</maintainer>
+	<stabilize-allarches/>
+	<upstream>
+		<remote-id type="github">kk7ds/chirp</remote-id>
+	</upstream>
+</pkgmetadata>