gentoo auto-resync : 30:05:2023 - 21:21:38

3 files changed, 200 insertions, 0 deletions

diff --git a/media-plugins/gst-plugins-vaapi/Manifest b/media-plugins/gst-plugins-vaapi/Manifest
index a12fcdc59bde..59b2e6b5da3b 100644
--- a/media-plugins/gst-plugins-vaapi/Manifest
+++ b/media-plugins/gst-plugins-vaapi/Manifest
@@ -1,7 +1,11 @@
 DIST gstreamer-vaapi-1.20.3.tar.xz 794840 BLAKE2B d422d982dba11175c57f6b6b329c75cbf96810a8653b028ce43dce8dfad0d474ae56ea7b9bde65e5901fb1453517fc1bd6541c0607d071b5b8444e78f30b355f SHA512 029e3e417c185f7aa8386aa3ce543a14bb7b1145e2386a763e109c636f32547c03cc6382fc45bbf1f5f1aab799b0250b852edbfc30dfb0992bcfd4d20b104a90
 DIST gstreamer-vaapi-1.20.4.tar.xz 795596 BLAKE2B d71b21ad0f0b7a1ef2e3d3c9c6c017766b23c928cbb8e63f52682d18c0517e60c2a51de66670d7a65b5d991c2e99dddeee8f20dd48b5cf50a3830ba57a56cb97 SHA512 5cd9a9f08e76aa36f092b18bfa811db8eeec5ff7e49478da4e78b5f876e84a471de6318c8a74ab6941fa1cd3aa1d4a8595df7ee0bad3b62007968d5615d481a3
 DIST gstreamer-vaapi-1.20.5.tar.xz 801628 BLAKE2B 4c3203baefafccbf8983c9e1da17a3455a0566d27b9a12b4d30292289cded803fb4ae8de1f26ff3536c632984227809df69fa9de78af4190acc30b6750c2d27c SHA512 fd24a58c83b0f820b1b2ca3c179228574a16b9f2657988de0c4569d925f01eb131853b0a322ce95b8523578e66ca66443900af1a5e022ecb4081bfe86a2e23bc
+DIST gstreamer-vaapi-1.20.6.tar.xz 801364 BLAKE2B 891e84099a558b31a152b6be2062753201a3958ce5fb67af37525c7b548404636cfeaa9578cdd485fbaddfabfd929f008ea07d0107975cc8174c58e38e791311 SHA512 3c386400b90ce7a90c0bec2244f0ef1a069cea053915abad3803e67ef7b859276f91a859ba1c959aedbfcb395058a0b0d917e9dd2f148b1cc038469996388af3
+DIST gstreamer-vaapi-1.22.3.tar.xz 535108 BLAKE2B a4c7bf18c448a3c1201c4173da02bb14ee0e5ab7c0a841638b8e101800ff85c1709a7faf3655d6ec432ec646405ad394f646b7e77f5aa3670ccd2569dd006429 SHA512 ffbc70d25bc56de0b21fef6cf30f025ccb8d92c981254dcc278a866101812908aacefcbdb745857dff613f81c713ba86ceac1a9b0296324607f0baa7a12f7399
 EBUILD gst-plugins-vaapi-1.20.3.ebuild 4154 BLAKE2B a790b0cf6ae35c35ad645e4bf2fbc6424a58257ce3c93b6713bb15ba19ef03ef1ca86d3c8f035bd9e2a719561a91b24f3416674cf9066e69e2261b64138b3796 SHA512 076b4f925a8e3ac7482ad52facb5bdef7d58139d9feb318ff3adeb64cf4374ca24152336bc38ce3fe52e5c6d0606e17988fc8ab992786e6ce412f90e5fea8cc5
 EBUILD gst-plugins-vaapi-1.20.4.ebuild 4161 BLAKE2B 7e37a07fca595a81720cedb8b67eaf7b23abc2a1cb840754ede5974de8809629359af895bc150c3e397dbc0a8bf3bc8983657f0e8d95f4e0a0e074fe0912ff0c SHA512 3a2ef386020b85b16e9b8020dfaa111e939d41575776e23d7d65e62609a7e9210ca5bf5f3bd62d60e00e011bf8d9f11e3ca0db8cbbc45b1430d4a96b2faadf1d
 EBUILD gst-plugins-vaapi-1.20.5.ebuild 4165 BLAKE2B 40afca0c0d55870e373bc7247829874326e20a3f46e7710fe7537d18e9b2f6fe0dfaa1328e2669f8e2295838796d71fbda6aef9505fc4408343bbf59f7c4417f SHA512 8b994ce9af04964bc7c97d035949f410c5febd37d569bea4d593f33684043213967739dc14174c2d63fda7706f0571bcfcc6002ba67b2bd03880c2078d69139a
+EBUILD gst-plugins-vaapi-1.20.6.ebuild 4165 BLAKE2B 40afca0c0d55870e373bc7247829874326e20a3f46e7710fe7537d18e9b2f6fe0dfaa1328e2669f8e2295838796d71fbda6aef9505fc4408343bbf59f7c4417f SHA512 8b994ce9af04964bc7c97d035949f410c5febd37d569bea4d593f33684043213967739dc14174c2d63fda7706f0571bcfcc6002ba67b2bd03880c2078d69139a
+EBUILD gst-plugins-vaapi-1.22.3-r1.ebuild 4130 BLAKE2B d48cdf30e075ddaec6accab840ff4b4b6b3033e8ad636d2116da6432668d262274e51cfcd3b38c281f3323103cb0e287538ac35367b9e4041d4786651c0dec8f SHA512 fe8886e9e244e9d400827834010da6c7d20acefd297642e5ea9dfeed19b6ef8d770f67032f81212092b9c1511efb46eef056fcf345366b89fb3cba7fe9858ede
 MISC metadata.xml 434 BLAKE2B bbc974951dbeb5b15d6c1aef4d79f0df6a9fb66ddcb370170deba060ea0c39be3d58dee5605de2c1cae8758621c548a4aff9fd26e59e6abe6aaedf7c33349cfb SHA512 64878569d6579302a606f6f9ef13cba96dcd950116653be2d1e7cdba51ae02d50b73ffb3f222ef9a009b720a425061cf3768eca8141b98dfb9513ee11cc9135b
diff --git a/media-plugins/gst-plugins-vaapi/gst-plugins-vaapi-1.20.6.ebuild b/media-plugins/gst-plugins-vaapi/gst-plugins-vaapi-1.20.6.ebuild
new file mode 100644
index 000000000000..d43cde42d49a
--- /dev/null
+++ b/media-plugins/gst-plugins-vaapi/gst-plugins-vaapi-1.20.6.ebuild
@@ -0,0 +1,98 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit gstreamer-meson python-any-r1
+
+MY_PN="gstreamer-vaapi"
+DESCRIPTION="Hardware accelerated video decoding through VA-API plugin for GStreamer"
+HOMEPAGE="https://gitlab.freedesktop.org/gstreamer/gstreamer-vaapi"
+SRC_URI="https://gstreamer.freedesktop.org/src/${MY_PN}/${MY_PN}-${PV}.tar.xz"
+
+LICENSE="LGPL-2.1+"
+SLOT="1.0"
+KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="+drm +egl gles2 +opengl wayland +X" # Keep default enabled IUSE in sync with gst-plugins-base and libva
+
+# gst-vaapi configure is based around GL platform mainly, unlike gst-plugins-bad that goes by GL API mainly; for less surprises,
+# we design gst-vaapi ebuild in terms of GL API as main choice as well, meaning that USE opengl and/or gles2 is required to
+# enable opengl support at all and choices get chained from there.
+# One or multiple video output are required: drm, x11, glx, egl and/or wayland;
+# but GL API is our main trigger, thus USE=egl should be ineffective if neither gles2 or opengl is enabled;
+# So "|| ( drm egl opengl wayland X )" would be wrong, because egl isn't built with USE="egl -opengl -gles2", ending up with no video outputs.
+# As we ensure at least one working GL output with other REQUIRED_USE, we can put gles2/opengl in REQUIRED_USE instead of egl, solving the issue.
+# gles2 API only supported windowing system (on linux) is EGL, so require it
+# opengl API only supported windowing systems (on linux) are EGL and GLX, so require one of them (glx is enabled with USE="opengl X")
+REQUIRED_USE="
+	|| ( drm gles2 opengl wayland X )
+	gles2? ( egl )
+	opengl? ( || ( egl X ) )
+"
+
+# glx doesn't require libva-glx (libva[opengl]) afaics, only by tests/test-display.c
+# USE flag behavior:
+# 'drm' enables vaapi drm support
+# 'egl' enables EGL platform support (but only if also 'opengl||gles2')
+# - 'egl' is exposed as a USE flag mainly to get EGL support instead of or in addition to GLX support with desktop GL while keeping it optional for pure GLX cases;
+#   it's always required with USE=gles2, thus USE="gles2 opengl X" will require and build desktop GL EGL platform support as well on top of GLX, which doesn't add extra deps at that point.
+# 'gles2' enables GLESv2 or GLESv3 based GL API support
+# 'opengl' enables desktop OpenGL based GL API support
+# 'wayland' enables non-GL Wayland support; wayland EGL support when combined with 'egl' (but only if also 'opengl||gles2')
+# 'X' enables non-GL X support; GLX support when combined with 'opengl'
+# gst-plugins-bad still needed for codecparsers (GL libraries moved to -base); checked for 1.14 (recheck for 1.16)
+GST_REQ="${PV}"
+GL_DEPS="
+	>=media-libs/gst-plugins-base-${GST_REQ}:${SLOT}[egl?,gles2?,opengl?,wayland?,X?]
+	media-libs/mesa[gles2?,egl(+)?,X?,${MULTILIB_USEDEP}]
+"
+RDEPEND="
+	>=media-libs/gst-plugins-base-${GST_REQ}:${SLOT}[${MULTILIB_USEDEP}]
+	>=media-libs/gst-plugins-bad-${GST_REQ}:${SLOT}[${MULTILIB_USEDEP}]
+	>=media-libs/libva-1.4.0:=[drm(+)?,wayland?,X?,${MULTILIB_USEDEP}]
+	drm? (
+		>=virtual/libudev-208:=[${MULTILIB_USEDEP}]
+		>=x11-libs/libdrm-2.4.98[${MULTILIB_USEDEP}]
+	)
+	gles2? ( ${GL_DEPS} )
+	opengl? ( ${GL_DEPS} )
+	wayland? ( >=dev-libs/wayland-1.11.0[${MULTILIB_USEDEP}] )
+	X? (
+		>=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libXrandr-1.4.2[${MULTILIB_USEDEP}]
+		x11-libs/libXrender[${MULTILIB_USEDEP}] )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="${PYTHON_DEPS}"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+# FIXME: "Failed to create vaapipostproc element"
+RESTRICT="test"
+
+multilib_src_configure() {
+	local emesonargs=(
+		-Dwith_encoders=yes
+		-Dwith_drm=$(usex drm yes no)
+		-Dwith_x11=$(usex X yes no)
+		-Dwith_wayland=$(usex wayland yes no)
+	)
+
+	if use opengl || use gles2; then
+		emesonargs+=( -Dwith_egl=$(usex egl yes no) )
+	else
+		emesonargs+=( -Dwith_egl=no )
+	fi
+
+	if use opengl && use X; then
+		emesonargs+=( -Dwith_glx=yes )
+	else
+		emesonargs+=( -Dwith_glx=no )
+	fi
+
+	# Workaround EGL/eglplatform.h being built with X11 present
+	use X || export CFLAGS="${CFLAGS} -DEGL_NO_X11"
+
+	gstreamer_multilib_src_configure
+}
diff --git a/media-plugins/gst-plugins-vaapi/gst-plugins-vaapi-1.22.3-r1.ebuild b/media-plugins/gst-plugins-vaapi/gst-plugins-vaapi-1.22.3-r1.ebuild
new file mode 100644
index 000000000000..69a7ccfc8d05
--- /dev/null
+++ b/media-plugins/gst-plugins-vaapi/gst-plugins-vaapi-1.22.3-r1.ebuild
@@ -0,0 +1,98 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit gstreamer-meson python-any-r1
+
+MY_PN="gstreamer-vaapi"
+DESCRIPTION="Hardware accelerated video decoding through VA-API plugin for GStreamer"
+HOMEPAGE="https://gitlab.freedesktop.org/gstreamer/gstreamer-vaapi"
+SRC_URI="https://gstreamer.freedesktop.org/src/${MY_PN}/${MY_PN}-${PV}.tar.xz"
+
+LICENSE="LGPL-2.1+"
+SLOT="1.0"
+KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="+drm +egl gles2 +opengl wayland +X" # Keep default enabled IUSE in sync with gst-plugins-base and libva
+
+# gst-vaapi configure is based around GL platform mainly, unlike gst-plugins-bad that goes by GL API mainly; for less surprises,
+# we design gst-vaapi ebuild in terms of GL API as main choice as well, meaning that USE opengl and/or gles2 is required to
+# enable opengl support at all and choices get chained from there.
+# One or multiple video output are required: drm, x11, glx, egl and/or wayland;
+# but GL API is our main trigger, thus USE=egl should be ineffective if neither gles2 or opengl is enabled;
+# So "|| ( drm egl opengl wayland X )" would be wrong, because egl isn't built with USE="egl -opengl -gles2", ending up with no video outputs.
+# As we ensure at least one working GL output with other REQUIRED_USE, we can put gles2/opengl in REQUIRED_USE instead of egl, solving the issue.
+# gles2 API only supported windowing system (on linux) is EGL, so require it
+# opengl API only supported windowing systems (on linux) are EGL and GLX, so require one of them (glx is enabled with USE="opengl X")
+REQUIRED_USE="
+	|| ( drm gles2 opengl wayland X )
+	gles2? ( egl )
+	opengl? ( || ( egl X ) )
+"
+
+# glx doesn't require libva-glx (libva[opengl]) afaics, only by tests/test-display.c
+# USE flag behavior:
+# 'drm' enables vaapi drm support
+# 'egl' enables EGL platform support (but only if also 'opengl||gles2')
+# - 'egl' is exposed as a USE flag mainly to get EGL support instead of or in addition to GLX support with desktop GL while keeping it optional for pure GLX cases;
+#   it's always required with USE=gles2, thus USE="gles2 opengl X" will require and build desktop GL EGL platform support as well on top of GLX, which doesn't add extra deps at that point.
+# 'gles2' enables GLESv2 or GLESv3 based GL API support
+# 'opengl' enables desktop OpenGL based GL API support
+# 'wayland' enables non-GL Wayland support; wayland EGL support when combined with 'egl' (but only if also 'opengl||gles2')
+# 'X' enables non-GL X support; GLX support when combined with 'opengl'
+# gst-plugins-bad still needed for codecparsers (GL libraries moved to -base); checked for 1.14 (recheck for 1.16)
+GST_REQ="${PV}"
+GL_DEPS="
+	>=media-libs/gst-plugins-base-${GST_REQ}:${SLOT}[egl?,gles2?,opengl?,wayland?,X?]
+	media-libs/mesa[gles2?,egl(+)?,X?,${MULTILIB_USEDEP}]
+"
+RDEPEND="
+	>=media-libs/gst-plugins-base-${GST_REQ}:${SLOT}[${MULTILIB_USEDEP}]
+	>=media-libs/gst-plugins-bad-${GST_REQ}:${SLOT}[${MULTILIB_USEDEP}]
+	>=media-libs/libva-1.10.0:=[drm(+)?,wayland?,X?,${MULTILIB_USEDEP}]
+	drm? (
+		>=virtual/libudev-208:=[${MULTILIB_USEDEP}]
+		>=x11-libs/libdrm-2.4.98[${MULTILIB_USEDEP}]
+	)
+	gles2? ( ${GL_DEPS} )
+	opengl? ( ${GL_DEPS} )
+	wayland? ( >=dev-libs/wayland-1.11.0[${MULTILIB_USEDEP}] )
+	X? (
+		>=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libXrandr-1.4.2[${MULTILIB_USEDEP}]
+		x11-libs/libXrender[${MULTILIB_USEDEP}] )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="${PYTHON_DEPS}"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+# FIXME: "Failed to create vaapipostproc element"
+RESTRICT="test"
+
+multilib_src_configure() {
+	local emesonargs=(
+		-Dencoders=enabled
+		$(meson_feature drm)
+		$(meson_feature X x11)
+		$(meson_feature wayland)
+	)
+
+	if use opengl || use gles2; then
+		emesonargs+=( $(meson_feature egl) )
+	else
+		emesonargs+=( -Degl=disabled )
+	fi
+
+	if use opengl && use X; then
+		emesonargs+=( -Dglx=enabled )
+	else
+		emesonargs+=( -Dglx=disabled )
+	fi
+
+	# Workaround EGL/eglplatform.h being built with X11 present
+	use X || export CFLAGS="${CFLAGS} -DEGL_NO_X11"
+
+	gstreamer_multilib_src_configure
+}