gentoo auto-resync : 23:06:2023 - 01:23:10

4 files changed, 454 insertions, 1 deletions

diff --git a/media-libs/Manifest.gz b/media-libs/Manifest.gz
index d3b59825e0e6..63c3cf8d3372 100644
--- a/media-libs/Manifest.gz
+++ b/media-libs/Manifest.gz
diff --git a/media-libs/mesa/Manifest b/media-libs/mesa/Manifest
index bbe7a003595d..3a0e7df9c079 100644
--- a/media-libs/mesa/Manifest
+++ b/media-libs/mesa/Manifest
@@ -7,11 +7,13 @@ DIST mesa-23.0.3.tar.xz 17627728 BLAKE2B e716d9ddce3da649239c1bc37ec208b9669f316
 DIST mesa-23.1.0.tar.xz 18204148 BLAKE2B 47cc90da14a2c33bb54c7811e99b439fadef81a15b63e535210a329bad5e2524fcb415cc5ed51a8deb65ccc9a341af78f02178c93758f09946978179e494382c SHA512 bbcfd0dd8e5414826631e80edbbe48218115a7461ef4ac1f2e4e090a48d6c0e1ab3b51dd45e988d5f1572f29bfc03c33769263c0f3e04033138d5b1ec102e8c9
 DIST mesa-23.1.1.tar.xz 18299068 BLAKE2B b17a71205248f2e97c60aa944d8b5b19d51592ba9288d2f04a8498eabaa19308f7ec7a813b948d3fad1001ae14da8771e403c68f7a4159c7f3b8830b919d64dc SHA512 ac5522307d75ff71289a62e2e5827edca70a88e028563ed11907504b9727925186893cd40e5948f1f16c29d8ad9fad39012d7569276e2c75be97aef9c106baf8
 DIST mesa-23.1.2.tar.xz 18333300 BLAKE2B a98dddf9c6cd0f69ec980e1080b53c92513ac03161dfba3355b83da674d6148dbd66c7e0403795eea7c3ce28fb5ff392a96607f34e4caf68a58ac8eb157cf146 SHA512 728e79720d950b0f39fa55c21dff7caed3650e88dff52a2f3e70540a049f1baf78178e62e5d6b1e59c76f6555ab0be3f0043cfbddd4745c0a742ccef2f5774d4
+DIST mesa-23.1.3.tar.xz 18358052 BLAKE2B 99ce2a458c049b60cf13278d5e2e04d9eebefe04d5cbfcba7ff13421724bfd7877ec24086e513d249f1e7b1d537acea90e2ae53d71ef420213a5764ce61d8c4f SHA512 44f0658138ef99dcede5e4c33d5733af836283f05b031b07f3f8b3bc03b301bc7ab9dc15248829cf3dfc423f2da8935b372b25df8b9ef15a511ba16ccd913959
 EBUILD mesa-22.3.7-r1.ebuild 12102 BLAKE2B 5c922d962095386dd1e0bc1a97b5906c984be4973181c747d3704c61b5250dc7406971811c7633cadde6119dc3ba133f8b9b5bdac06bb0099de1d541d3c9d4e3 SHA512 6660223e22ff2804de0b92809c82bbd0ae112d8986975ab9d5d9625d757f651657efc14e82e97fb010f884b748591ff4c0f3574af66a35aa23224185e75abcd2
 EBUILD mesa-23.0.3-r1.ebuild 12250 BLAKE2B 4e6add8f5a8a6758b12f5c72e42e2b7df839ea793f155b6653b9cd6eed82eccca39768cdc8deb6b718627c4df7b0ad1ddcdf54a4db48eaf4c55fbcf570e7168e SHA512 9f4ca64c734a77f175abbc4037cb4291ab9f9d8f329087aa487fc628926bec163fdf43abef43e75cde6f08327e3b8c04c7c24a36150fb2444de9d7fae3e37c0d
 EBUILD mesa-23.1.0.ebuild 12311 BLAKE2B e7e8114c5c59b7c7f7b68f8146a7190017cdaabb04a397143720c8c04bc32142f47a949a7540f0227a1e1fb3802b21d5806bd6d5a76c3ae30fba2811cd4d9a2c SHA512 d2e516f1f7d3a54bee2fa5a6b51f815400be31ce916058c0b8833b8ecbf9dc2fadd39327dd1289c919b4326e40539cb01da8a810139280ee5120e2b5885385e9
 EBUILD mesa-23.1.1.ebuild 12223 BLAKE2B a892145bba1e24fb93abe8b9b26a2dc782299ac26de3886cd533ff0f8d37596a10abe59ecf3547e30bc8482f28369fd877aa2f61414927315bf026d3bfb0509d SHA512 172527e98ac0782d4717381b84c5c4b7dad4a6ce5799c8a6e19ea4bfd6938e68205d2e129eff341e53fb854f523d4e79d3251322ee906a5c8760673b8a9bb03c
 EBUILD mesa-23.1.2-r1.ebuild 12315 BLAKE2B 79244582d2b1e984fc90c96acff7494d92b6ce74724ed97fc75cf6a392e298fbebf2eca8547b94d31cca70f3cf9504fc5ffed1c0f305689621367ae9aac1a7b0 SHA512 377d3879334328b1edf5a8631bc7f26630cb3445fa237d54f6b2996f2cd8cc4e916fb77a690987042e50f67e3077ec0cb8e9106b3d5582a9e765ea8527c7b082
 EBUILD mesa-23.1.2.ebuild 12223 BLAKE2B a892145bba1e24fb93abe8b9b26a2dc782299ac26de3886cd533ff0f8d37596a10abe59ecf3547e30bc8482f28369fd877aa2f61414927315bf026d3bfb0509d SHA512 172527e98ac0782d4717381b84c5c4b7dad4a6ce5799c8a6e19ea4bfd6938e68205d2e129eff341e53fb854f523d4e79d3251322ee906a5c8760673b8a9bb03c
-EBUILD mesa-9999.ebuild 12315 BLAKE2B 79244582d2b1e984fc90c96acff7494d92b6ce74724ed97fc75cf6a392e298fbebf2eca8547b94d31cca70f3cf9504fc5ffed1c0f305689621367ae9aac1a7b0 SHA512 377d3879334328b1edf5a8631bc7f26630cb3445fa237d54f6b2996f2cd8cc4e916fb77a690987042e50f67e3077ec0cb8e9106b3d5582a9e765ea8527c7b082
+EBUILD mesa-23.1.3.ebuild 12333 BLAKE2B 7b25cb565c50cf9d9e0f906ae1edb38376f7f6a3b59b0f4b514bde7e927b54fdec53923dc9cfdaaf6b84aaa708f494550a2e9e3d19ebd91c7f726d6efeee662e SHA512 77b7c4d2c94104ee8e3e8a0957eef62b1363f5d8215951ced8d9c9d979543fa6e3a4e412627b28b34a47f0c40145783e83cd9506abd8274ae90f836bff4dbfcd
+EBUILD mesa-9999.ebuild 12333 BLAKE2B 7b25cb565c50cf9d9e0f906ae1edb38376f7f6a3b59b0f4b514bde7e927b54fdec53923dc9cfdaaf6b84aaa708f494550a2e9e3d19ebd91c7f726d6efeee662e SHA512 77b7c4d2c94104ee8e3e8a0957eef62b1363f5d8215951ced8d9c9d979543fa6e3a4e412627b28b34a47f0c40145783e83cd9506abd8274ae90f836bff4dbfcd
 MISC metadata.xml 1488 BLAKE2B 7b776f0a6d92b34baec90c58d019d61af537044766ce34a6e139ef679a0724e57fe65d600307c7f9dc0c48618445527618322e2af737191082dece3e547d5533 SHA512 1d573d534f1099eb1f1912567cf559aeae28111eabefa806b292a66d1f1e539e86394a76ca40a1481a6bfb4b6f7a0b117344e39d7b4d2eac615ef49b8f62acb9
diff --git a/media-libs/mesa/mesa-23.1.3.ebuild b/media-libs/mesa/mesa-23.1.3.ebuild
new file mode 100644
index 000000000000..9967d104c9cf
--- /dev/null
+++ b/media-libs/mesa/mesa-23.1.3.ebuild
@@ -0,0 +1,450 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..12} )
+
+inherit llvm meson-multilib python-any-r1 linux-info
+
+MY_P="${P/_/-}"
+
+DESCRIPTION="OpenGL-like graphic library for Linux"
+HOMEPAGE="https://www.mesa3d.org/ https://mesa.freedesktop.org/"
+
+if [[ ${PV} == 9999 ]]; then
+	EGIT_REPO_URI="https://gitlab.freedesktop.org/mesa/mesa.git"
+	inherit git-r3
+else
+	SRC_URI="https://archive.mesa3d.org/${MY_P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-solaris"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+RESTRICT="!test? ( test )"
+
+RADEON_CARDS="r300 r600 radeon radeonsi"
+VIDEO_CARDS="${RADEON_CARDS} d3d12 freedreno intel lavapipe lima nouveau panfrost v3d vc4 virgl vivante vmware"
+for card in ${VIDEO_CARDS}; do
+	IUSE_VIDEO_CARDS+=" video_cards_${card}"
+done
+
+IUSE="${IUSE_VIDEO_CARDS}
+	cpu_flags_x86_sse2 d3d9 debug gles1 +gles2 +llvm
+	lm-sensors opencl osmesa +proprietary-codecs selinux
+	test unwind vaapi valgrind vdpau vulkan
+	vulkan-overlay wayland +X xa zink +zstd"
+
+REQUIRED_USE="
+	d3d9? (
+		|| (
+			video_cards_intel
+			video_cards_r300
+			video_cards_r600
+			video_cards_radeonsi
+			video_cards_nouveau
+			video_cards_vmware
+		)
+	)
+	vulkan? ( video_cards_radeonsi? ( llvm ) )
+	vulkan-overlay? ( vulkan )
+	video_cards_lavapipe? ( llvm vulkan )
+	video_cards_radeon? ( x86? ( llvm ) amd64? ( llvm ) )
+	video_cards_r300?   ( x86? ( llvm ) amd64? ( llvm ) )
+	video_cards_radeonsi?   ( llvm )
+	vdpau? ( X )
+	xa? ( X )
+	zink? ( vulkan )
+"
+
+LIBDRM_DEPSTRING=">=x11-libs/libdrm-2.4.110"
+RDEPEND="
+	>=dev-libs/expat-2.1.0-r3[${MULTILIB_USEDEP}]
+	>=media-libs/libglvnd-1.3.2[X?,${MULTILIB_USEDEP}]
+	>=sys-libs/zlib-1.2.8[${MULTILIB_USEDEP}]
+	unwind? ( sys-libs/libunwind[${MULTILIB_USEDEP}] )
+	llvm? (
+		video_cards_radeonsi? (
+			virtual/libelf:0=[${MULTILIB_USEDEP}]
+		)
+		video_cards_r600? (
+			virtual/libelf:0=[${MULTILIB_USEDEP}]
+		)
+		video_cards_radeon? (
+			virtual/libelf:0=[${MULTILIB_USEDEP}]
+		)
+	)
+	lm-sensors? ( sys-apps/lm-sensors:=[${MULTILIB_USEDEP}] )
+	opencl? (
+		>=virtual/opencl-3
+		dev-libs/libclc[spirv(-)]
+		>=dev-util/spirv-tools-1.3.231.0
+		virtual/libelf:0=
+	)
+	vaapi? (
+		>=media-libs/libva-1.7.3:=[${MULTILIB_USEDEP}]
+	)
+	vdpau? ( >=x11-libs/libvdpau-1.1:=[${MULTILIB_USEDEP}] )
+	vulkan? (
+		video_cards_intel? (
+			amd64? (
+				dev-libs/libclc[spirv(-)]
+				>=dev-util/spirv-tools-1.3.231.0
+			)
+		)
+	)
+	selinux? ( sys-libs/libselinux[${MULTILIB_USEDEP}] )
+	wayland? ( >=dev-libs/wayland-1.18.0[${MULTILIB_USEDEP}] )
+	${LIBDRM_DEPSTRING}[video_cards_freedreno?,video_cards_intel?,video_cards_nouveau?,video_cards_vc4?,video_cards_vivante?,video_cards_vmware?,${MULTILIB_USEDEP}]
+	X? (
+		>=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libxshmfence-1.1[${MULTILIB_USEDEP}]
+		>=x11-libs/libXext-1.3.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libXxf86vm-1.1.3[${MULTILIB_USEDEP}]
+		>=x11-libs/libxcb-1.13:=[${MULTILIB_USEDEP}]
+		x11-libs/libXfixes[${MULTILIB_USEDEP}]
+	)
+	zink? ( media-libs/vulkan-loader:=[${MULTILIB_USEDEP}] )
+	zstd? ( app-arch/zstd:=[${MULTILIB_USEDEP}] )
+"
+for card in ${RADEON_CARDS}; do
+	RDEPEND="${RDEPEND}
+		video_cards_${card}? ( ${LIBDRM_DEPSTRING}[video_cards_radeon] )
+	"
+done
+RDEPEND="${RDEPEND}
+	video_cards_radeonsi? ( ${LIBDRM_DEPSTRING}[video_cards_amdgpu] )
+"
+
+# Please keep the LLVM dependency block separate. Since LLVM is slotted,
+# we need to *really* make sure we're not pulling one than more slot
+# simultaneously.
+#
+# How to use it:
+# 1. Specify LLVM_MAX_SLOT (inclusive), e.g. 16.
+# 2. Specify LLVM_MIN_SLOT (inclusive), e.g. 15.
+LLVM_MAX_SLOT="16"
+LLVM_MIN_SLOT="15"
+LLVM_USE_DEPS="llvm_targets_AMDGPU(+),${MULTILIB_USEDEP}"
+PER_SLOT_DEPSTR="
+	(
+		!opencl? ( sys-devel/llvm:@SLOT@[${LLVM_USE_DEPS}] )
+		opencl? ( sys-devel/clang:@SLOT@[${LLVM_USE_DEPS}] )
+		opencl? ( dev-util/spirv-llvm-translator:@SLOT@ )
+		vulkan? ( video_cards_intel? ( dev-util/spirv-llvm-translator:@SLOT@ ) )
+	)
+"
+LLVM_DEPSTR="
+	|| (
+		$(for ((slot=LLVM_MAX_SLOT; slot>=LLVM_MIN_SLOT; slot--)); do
+			echo "${PER_SLOT_DEPSTR//@SLOT@/${slot}}"
+		done)
+	)
+	!opencl? ( <sys-devel/llvm-$((LLVM_MAX_SLOT + 1)):=[${LLVM_USE_DEPS}] )
+	opencl? ( <sys-devel/clang-$((LLVM_MAX_SLOT + 1)):=[${LLVM_USE_DEPS}] )
+"
+RDEPEND="${RDEPEND}
+	llvm? ( ${LLVM_DEPSTR} )
+"
+unset LLVM_MIN_SLOT {LLVM,PER_SLOT}_DEPSTR
+
+DEPEND="${RDEPEND}
+	video_cards_d3d12? ( dev-util/directx-headers[${MULTILIB_USEDEP}] )
+	valgrind? ( dev-util/valgrind )
+	wayland? ( >=dev-libs/wayland-protocols-1.24 )
+	X? (
+		x11-libs/libXrandr[${MULTILIB_USEDEP}]
+		x11-base/xorg-proto
+	)
+"
+BDEPEND="
+	>=dev-util/meson-1.0.0
+	${PYTHON_DEPS}
+	opencl? (
+		>=virtual/rust-1.62.0
+		>=dev-util/bindgen-0.58.0
+	)
+	sys-devel/bison
+	sys-devel/flex
+	virtual/pkgconfig
+	$(python_gen_any_dep ">=dev-python/mako-0.8.0[\${PYTHON_USEDEP}]")
+	vulkan? (
+		dev-util/glslang
+		video_cards_intel? (
+			amd64? (
+				$(python_gen_any_dep "dev-python/ply[\${PYTHON_USEDEP}]")
+			)
+		)
+	)
+	wayland? ( dev-util/wayland-scanner )
+"
+
+S="${WORKDIR}/${MY_P}"
+EGIT_CHECKOUT_DIR=${S}
+
+QA_WX_LOAD="
+x86? (
+	usr/lib/libglapi.so.0.0.0
+	usr/lib/libOSMesa.so.8.0.0
+	usr/lib/libGLX_mesa.so.0.0.0
+)"
+
+llvm_check_deps() {
+	if use opencl; then
+		has_version "sys-devel/clang:${LLVM_SLOT}[${LLVM_USE_DEPS}]" || return 1
+	fi
+	if use opencl || { use vulkan && use video_cards_intel; }; then
+		has_version "dev-util/spirv-llvm-translator:${LLVM_SLOT}" || return 1
+	fi
+	has_version "sys-devel/llvm:${LLVM_SLOT}[${LLVM_USE_DEPS}]"
+}
+
+PATCHES=(
+	# Temporary rusticl workaround: https://gitlab.freedesktop.org/mesa/mesa/-/issues/7717#note_1832122
+	"${FILESDIR}/clang_resource_dir.patch"
+)
+
+pkg_pretend() {
+	if use vulkan; then
+		if ! use video_cards_d3d12 &&
+		   ! use video_cards_freedreno &&
+		   ! use video_cards_intel &&
+		   ! use video_cards_radeonsi &&
+		   ! use video_cards_v3d; then
+			ewarn "Ignoring USE=vulkan     since VIDEO_CARDS does not contain d3d12, freedreno, intel, radeonsi, or v3d"
+		fi
+	fi
+
+	if use vaapi; then
+		if ! use video_cards_d3d12 &&
+		   ! use video_cards_r600 &&
+		   ! use video_cards_radeonsi &&
+		   ! use video_cards_nouveau; then
+			ewarn "Ignoring USE=vaapi      since VIDEO_CARDS does not contain d3d12, r600, radeonsi, or nouveau"
+		fi
+	fi
+
+	if use vdpau; then
+		if ! use video_cards_d3d12 &&
+		   ! use video_cards_r300 &&
+		   ! use video_cards_r600 &&
+		   ! use video_cards_radeonsi &&
+		   ! use video_cards_nouveau; then
+			ewarn "Ignoring USE=vdpau      since VIDEO_CARDS does not contain d3d12, r300, r600, radeonsi, or nouveau"
+		fi
+	fi
+
+	if use xa; then
+		if ! use video_cards_freedreno &&
+		   ! use video_cards_nouveau &&
+		   ! use video_cards_vmware; then
+			ewarn "Ignoring USE=xa         since VIDEO_CARDS does not contain freedreno, nouveau, or vmware"
+		fi
+	fi
+
+	if ! use llvm; then
+		use opencl     && ewarn "Ignoring USE=opencl     since USE does not contain llvm"
+	fi
+
+	if use osmesa && ! use llvm; then
+		ewarn "OSMesa will be slow without enabling USE=llvm"
+	fi
+}
+
+python_check_deps() {
+	python_has_version -b ">=dev-python/mako-0.8.0[${PYTHON_USEDEP}]" || return 1
+	if use vulkan && use video_cards_intel && use amd64; then
+		python_has_version -b "dev-python/ply[${PYTHON_USEDEP}]" || return 1
+	fi
+}
+
+pkg_setup() {
+	# warning message for bug 459306
+	if use llvm && has_version sys-devel/llvm[!debug=]; then
+		ewarn "Mismatch between debug USE flags in media-libs/mesa and sys-devel/llvm"
+		ewarn "detected! This can cause problems. For details, see bug 459306."
+	fi
+
+	if use video_cards_intel ||
+	   use video_cards_radeonsi; then
+		if kernel_is -ge 5 11 3; then
+			CONFIG_CHECK="~KCMP"
+		elif kernel_is -ge 5 11; then
+			CONFIG_CHECK="~CHECKPOINT_RESTORE"
+		elif kernel_is -ge 5 10 20; then
+			CONFIG_CHECK="~KCMP"
+		else
+			CONFIG_CHECK="~CHECKPOINT_RESTORE"
+		fi
+		linux-info_pkg_setup
+	fi
+
+	if use llvm; then
+		llvm_pkg_setup
+	fi
+	python-any-r1_pkg_setup
+}
+
+multilib_src_configure() {
+	local emesonargs=()
+
+	local platforms
+	use X && platforms+="x11"
+	use wayland && platforms+=",wayland"
+	emesonargs+=(-Dplatforms=${platforms#,})
+
+	if use video_cards_intel ||
+	   use video_cards_r300 ||
+	   use video_cards_r600 ||
+	   use video_cards_radeonsi ||
+	   use video_cards_nouveau ||
+	   use video_cards_vmware; then
+		emesonargs+=($(meson_use d3d9 gallium-nine))
+	else
+		emesonargs+=(-Dgallium-nine=false)
+	fi
+
+	if use video_cards_d3d12 ||
+	   use video_cards_r600 ||
+	   use video_cards_radeonsi ||
+	   use video_cards_nouveau; then
+		emesonargs+=($(meson_feature vaapi gallium-va))
+		use vaapi && emesonargs+=( -Dva-libs-path="${EPREFIX}"/usr/$(get_libdir)/va/drivers )
+	else
+		emesonargs+=(-Dgallium-va=disabled)
+	fi
+
+	if use video_cards_d3d12; then
+		emesonargs+=($(meson_feature vaapi gallium-d3d12-video))
+	fi
+
+	if use video_cards_d3d12 ||
+	   use video_cards_r300 ||
+	   use video_cards_r600 ||
+	   use video_cards_radeonsi ||
+	   use video_cards_nouveau; then
+		emesonargs+=($(meson_feature vdpau gallium-vdpau))
+	else
+		emesonargs+=(-Dgallium-vdpau=disabled)
+	fi
+
+	if use video_cards_freedreno ||
+	   use video_cards_nouveau ||
+	   use video_cards_vmware; then
+		emesonargs+=($(meson_feature xa gallium-xa))
+	else
+		emesonargs+=(-Dgallium-xa=disabled)
+	fi
+
+	if use video_cards_freedreno ||
+	   use video_cards_lima ||
+	   use video_cards_panfrost ||
+	   use video_cards_v3d ||
+	   use video_cards_vc4 ||
+	   use video_cards_vivante; then
+		gallium_enable -- kmsro
+	fi
+
+	gallium_enable -- swrast
+	gallium_enable video_cards_freedreno freedreno
+	gallium_enable video_cards_intel crocus i915 iris
+	gallium_enable video_cards_lima lima
+	gallium_enable video_cards_d3d12 d3d12
+	gallium_enable video_cards_nouveau nouveau
+	gallium_enable video_cards_panfrost panfrost
+	gallium_enable video_cards_v3d v3d
+	gallium_enable video_cards_vc4 vc4
+	gallium_enable video_cards_virgl virgl
+	gallium_enable video_cards_vivante etnaviv
+	gallium_enable video_cards_vmware svga
+	gallium_enable zink zink
+
+	gallium_enable video_cards_r300 r300
+	gallium_enable video_cards_r600 r600
+	gallium_enable video_cards_radeonsi radeonsi
+	if ! use video_cards_r300 && \
+		! use video_cards_r600; then
+		gallium_enable video_cards_radeon r300 r600
+	fi
+
+	if use llvm && use opencl; then
+		PKG_CONFIG_PATH="$(get_llvm_prefix)/$(get_libdir)/pkgconfig"
+		# See https://gitlab.freedesktop.org/mesa/mesa/-/blob/main/docs/rusticl.rst
+		emesonargs+=(
+			$(meson_native_true gallium-rusticl)
+			-Drust_std=2021
+		)
+	fi
+
+	if use vulkan; then
+		vulkan_enable video_cards_lavapipe swrast
+		vulkan_enable video_cards_freedreno freedreno
+		vulkan_enable video_cards_intel intel intel_hasvk
+		vulkan_enable video_cards_d3d12 microsoft-experimental
+		vulkan_enable video_cards_radeonsi amd
+		vulkan_enable video_cards_v3d broadcom
+	fi
+
+	driver_list() {
+		local drivers="$(sort -u <<< "${1// /$'\n'}")"
+		echo "${drivers//$'\n'/,}"
+	}
+
+	local vulkan_layers
+	use vulkan && vulkan_layers+="device-select"
+	use vulkan-overlay && vulkan_layers+=",overlay"
+	emesonargs+=(-Dvulkan-layers=${vulkan_layers#,})
+
+	if use vulkan && use video_cards_intel; then
+		PKG_CONFIG_PATH="$(get_llvm_prefix)/$(get_libdir)/pkgconfig"
+		emesonargs+=($(meson_feature llvm intel-clc))
+	fi
+
+	emesonargs+=(
+		$(meson_use test build-tests)
+		-Dglx=$(usex X dri disabled)
+		-Dshared-glapi=enabled
+		-Ddri3=enabled
+		-Degl=enabled
+		-Dexpat=enabled
+		-Dgbm=enabled
+		-Dglvnd=true
+		$(meson_feature gles1)
+		$(meson_feature gles2)
+		$(meson_feature llvm)
+		$(meson_feature lm-sensors lmsensors)
+		$(meson_use osmesa)
+		$(meson_use selinux)
+		$(meson_feature unwind libunwind)
+		$(meson_feature zstd)
+		$(meson_use cpu_flags_x86_sse2 sse2)
+		-Dvalgrind=$(usex valgrind auto disabled)
+		-Dvideo-codecs=$(usex proprietary-codecs "h264dec,h264enc,h265dec,h265enc,vc1dec" "")
+		-Dgallium-drivers=$(driver_list "${GALLIUM_DRIVERS[*]}")
+		-Dvulkan-drivers=$(driver_list "${VULKAN_DRIVERS[*]}")
+		--buildtype $(usex debug debug plain)
+		-Db_ndebug=$(usex debug false true)
+	)
+	meson_src_configure
+}
+
+multilib_src_test() {
+	meson_src_test -t 100
+}
+
+# $1 - VIDEO_CARDS flag (check skipped for "--")
+# other args - names of DRI drivers to enable
+gallium_enable() {
+	if [[ $1 == -- ]] || use $1; then
+		shift
+		GALLIUM_DRIVERS+=("$@")
+	fi
+}
+
+vulkan_enable() {
+	if [[ $1 == -- ]] || use $1; then
+		shift
+		VULKAN_DRIVERS+=("$@")
+	fi
+}
diff --git a/media-libs/mesa/mesa-9999.ebuild b/media-libs/mesa/mesa-9999.ebuild
index 0b34a1fa96ec..9967d104c9cf 100644
--- a/media-libs/mesa/mesa-9999.ebuild
+++ b/media-libs/mesa/mesa-9999.ebuild
@@ -407,6 +407,7 @@ multilib_src_configure() {
 		-Dshared-glapi=enabled
 		-Ddri3=enabled
 		-Degl=enabled
+		-Dexpat=enabled
 		-Dgbm=enabled
 		-Dglvnd=true
 		$(meson_feature gles1)