gentoo resync : 03.11.2019

3 files changed, 91 insertions, 9 deletions

diff --git a/media-libs/vulkan-loader/Manifest b/media-libs/vulkan-loader/Manifest
index bd14e328d009..d77a29a68a98 100644
--- a/media-libs/vulkan-loader/Manifest
+++ b/media-libs/vulkan-loader/Manifest
@@ -1,4 +1,6 @@
 DIST vulkan-loader-1.1.114.tar.gz 1343624 BLAKE2B 1212c837d86f29160b19bbc14a82564d57722d0d8b540e9360af0a470db59d8c5ad76a1f9f5f892a09b7f43ae62792262b1713c8cabace087c37c2cbb103215b SHA512 90fe8fa7b0a0028faaf8e3aea0724799eb57989a0297e416b3b651a81e0de99b0506eb6b17f84bfc1a6ed33edcc806a5b6c1b187d0d49ea0c8d99ae9dcb5338c
+DIST vulkan-loader-1.1.125.tar.gz 1398802 BLAKE2B 7cf1f99f60b4b37bfad12580fc8809012a0540d928366b465a532fbf90e7d87bf42eeeff70b1a46efeadef9c599cad6009b122ed9c5c7298973207f05acc1032 SHA512 40e1e5c16491f0549eae3efc065c375c258b475d81e1c781a756c71ec329f390e2aba55ced5ed2005e938f9d074dffc1692e7e1e330a35f55460cae1606fdf2e
 EBUILD vulkan-loader-1.1.114.ebuild 1544 BLAKE2B 54d59237e53fc6da87c6c1f4acee474354b382cfc3416cb702514d34ea7db1df59329e18fed9f954137610db2b64dff25ea901c3754d83f5e49de266661554b1 SHA512 b3b3dca31fe3b43d1a09312f0590679d026126f3e34d01659ee144d2bad4bcef651ff15b6be824cb731e1c740cc716ec97195094693a2c5e7c927174850449e6
-EBUILD vulkan-loader-9999.ebuild 1541 BLAKE2B 203234a07960cfd576212095173a1ac3e8b94d7db8aa06a16b5e63ca2b35c8c0a21d942bbef73b75ca7337a99a7611e384a41d6d4b365b9b398fbfac55c38458 SHA512 d15c216c8346e7c3efa5864deb8d0a586b9a2b4b5929ce7a34e149cf30e01fc93ce4433b1b8dfaab3032e07cc8716d2d2254ac4708ce215af98783099ecb04bc
+EBUILD vulkan-loader-1.1.125.ebuild 1787 BLAKE2B 3859eeb424f8240a057c8630e172f07152bedc2df69b0282a0fb5521f92dece37e95ba6b3ccc8d99261442bf51f4065071eb09ed478b0a677de4d83cc69f7e3b SHA512 54e9105d0d3c7f09c28e366a3eb05a8ba97b99e03be6f920dfb6e9de94285d849eedb4b210bf0ac265f6a0e98d5b854e0a8816308a5081a57abdfd74c42c3afe
+EBUILD vulkan-loader-9999.ebuild 1787 BLAKE2B 3859eeb424f8240a057c8630e172f07152bedc2df69b0282a0fb5521f92dece37e95ba6b3ccc8d99261442bf51f4065071eb09ed478b0a677de4d83cc69f7e3b SHA512 54e9105d0d3c7f09c28e366a3eb05a8ba97b99e03be6f920dfb6e9de94285d849eedb4b210bf0ac265f6a0e98d5b854e0a8816308a5081a57abdfd74c42c3afe
 MISC metadata.xml 414 BLAKE2B 53100d7021d8350e960e2b087bba612ee99f6ce960b63964aa2ba50b1172f5b9fe13fb9addb069ae74cc03292b92fc88838b41eac1083c8779dcb8e0e480d1dc SHA512 6328c52f607ed4ea3ba31430f63df84e942ea3e6726b5107c8840e3869725bd7407b446d4f905765a0c6d6dd04fda643bd2b5e06681f6ac771bbb4fbc8d4c417
diff --git a/media-libs/vulkan-loader/vulkan-loader-1.1.125.ebuild b/media-libs/vulkan-loader/vulkan-loader-1.1.125.ebuild
new file mode 100644
index 000000000000..2d672fe1761d
--- /dev/null
+++ b/media-libs/vulkan-loader/vulkan-loader-1.1.125.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{5,6,7} )
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/KhronosGroup/Vulkan-Loader.git"
+	EGIT_SUBMODULES=()
+	inherit git-r3
+else
+	if [[ -z ${SNAPSHOT_COMMIT} ]]; then
+		MY_PV=v${PV}
+		MY_P=Vulkan-Loader-${PV}
+	else
+		MY_PV=${SNAPSHOT_COMMIT}
+		MY_P=Vulkan-Loader-${SNAPSHOT_COMMIT}
+	fi
+	KEYWORDS="~amd64 ~x86"
+	SRC_URI="https://github.com/KhronosGroup/Vulkan-Loader/archive/${MY_PV}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}"/${MY_P}
+fi
+
+inherit toolchain-funcs python-any-r1 cmake-multilib
+
+DESCRIPTION="Vulkan Installable Client Driver (ICD) Loader"
+HOMEPAGE="https://github.com/KhronosGroup/Vulkan-Loader"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="layers wayland X"
+
+PDEPEND="layers? ( media-libs/vulkan-layers:=[${MULTILIB_USEDEP}] )"
+DEPEND="${PYTHON_DEPS}
+	>=dev-util/vulkan-headers-${PV}
+	wayland? ( dev-libs/wayland:=[${MULTILIB_USEDEP}] )
+	X? (
+		x11-libs/libX11:=[${MULTILIB_USEDEP}]
+		x11-libs/libXrandr:=[${MULTILIB_USEDEP}]
+	)"
+
+multilib_src_configure() {
+	# Integrated clang assembler doesn't work with x86 - Bug #698164
+	if tc-is-clang && [[ ${ABI} == x86 ]]; then
+		append-cflags -fno-integrated-as
+	fi
+
+	local mycmakeargs=(
+		-DCMAKE_SKIP_RPATH=True
+		-DBUILD_TESTS=False
+		-DBUILD_LOADER=True
+		-DBUILD_WSI_WAYLAND_SUPPORT=$(usex wayland)
+		-DBUILD_WSI_XCB_SUPPORT=$(usex X)
+		-DBUILD_WSI_XLIB_SUPPORT=$(usex X)
+		-DVULKAN_HEADERS_INSTALL_DIR="/usr"
+	)
+	cmake-utils_src_configure
+}
+
+multilib_src_install() {
+	keepdir /etc/vulkan/icd.d
+
+	cmake-utils_src_install
+}
+
+pkg_postinst() {
+	einfo "USE=demos has been dropped as per upstream packaging"
+	einfo "vulkaninfo is now available in the dev-util/vulkan-tools package"
+}
diff --git a/media-libs/vulkan-loader/vulkan-loader-9999.ebuild b/media-libs/vulkan-loader/vulkan-loader-9999.ebuild
index e1b75cb13198..2d672fe1761d 100644
--- a/media-libs/vulkan-loader/vulkan-loader-9999.ebuild
+++ b/media-libs/vulkan-loader/vulkan-loader-9999.ebuild
@@ -1,21 +1,27 @@
 # Copyright 1999-2019 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=6
-PYTHON_COMPAT=( python3_{5,6} )
+EAPI=7
+PYTHON_COMPAT=( python3_{5,6,7} )
 
 if [[ "${PV}" == "9999" ]]; then
 	EGIT_REPO_URI="https://github.com/KhronosGroup/Vulkan-Loader.git"
 	EGIT_SUBMODULES=()
 	inherit git-r3
 else
-	KEYWORDS="~amd64"
-	EGIT_COMMIT="979f925d939e4daa3c823bd2b9d46ca479481fe9"
-	SRC_URI="https://github.com/KhronosGroup/Vulkan-Loader/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
-	S="${WORKDIR}/Vulkan-Loader-${EGIT_COMMIT}"
+	if [[ -z ${SNAPSHOT_COMMIT} ]]; then
+		MY_PV=v${PV}
+		MY_P=Vulkan-Loader-${PV}
+	else
+		MY_PV=${SNAPSHOT_COMMIT}
+		MY_P=Vulkan-Loader-${SNAPSHOT_COMMIT}
+	fi
+	KEYWORDS="~amd64 ~x86"
+	SRC_URI="https://github.com/KhronosGroup/Vulkan-Loader/archive/${MY_PV}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}"/${MY_P}
 fi
 
-inherit python-any-r1 cmake-multilib
+inherit toolchain-funcs python-any-r1 cmake-multilib
 
 DESCRIPTION="Vulkan Installable Client Driver (ICD) Loader"
 HOMEPAGE="https://github.com/KhronosGroup/Vulkan-Loader"
@@ -26,7 +32,7 @@ IUSE="layers wayland X"
 
 PDEPEND="layers? ( media-libs/vulkan-layers:=[${MULTILIB_USEDEP}] )"
 DEPEND="${PYTHON_DEPS}
-	>=dev-util/vulkan-headers-1.1.114
+	>=dev-util/vulkan-headers-${PV}
 	wayland? ( dev-libs/wayland:=[${MULTILIB_USEDEP}] )
 	X? (
 		x11-libs/libX11:=[${MULTILIB_USEDEP}]
@@ -34,6 +40,11 @@ DEPEND="${PYTHON_DEPS}
 	)"
 
 multilib_src_configure() {
+	# Integrated clang assembler doesn't work with x86 - Bug #698164
+	if tc-is-clang && [[ ${ABI} == x86 ]]; then
+		append-cflags -fno-integrated-as
+	fi
+
 	local mycmakeargs=(
 		-DCMAKE_SKIP_RPATH=True
 		-DBUILD_TESTS=False