gentoo resync : 14.07.2019

1 files changed, 58 insertions, 0 deletions

diff --git a/media-libs/vulkan-loader/vulkan-loader-1.1.114.ebuild b/media-libs/vulkan-loader/vulkan-loader-1.1.114.ebuild
new file mode 100644
index 000000000000..0b90fe573373
--- /dev/null
+++ b/media-libs/vulkan-loader/vulkan-loader-1.1.114.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python3_{5,6} )
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/KhronosGroup/Vulkan-Loader.git"
+	EGIT_SUBMODULES=()
+	inherit git-r3
+else
+	KEYWORDS="~amd64 ~x86"
+	EGIT_COMMIT="1bb7f68564fe565de2927071c79008bd6ede5af5"
+	SRC_URI="https://github.com/KhronosGroup/Vulkan-Loader/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}/Vulkan-Loader-${EGIT_COMMIT}"
+fi
+
+inherit python-any-r1 cmake-multilib
+
+DESCRIPTION="Vulkan Installable Client Driver (ICD) Loader"
+HOMEPAGE="https://github.com/KhronosGroup/Vulkan-Loader"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="layers wayland X"
+
+PDEPEND="layers? ( media-libs/vulkan-layers:=[${MULTILIB_USEDEP}] )"
+DEPEND="${PYTHON_DEPS}
+	>=dev-util/vulkan-headers-1.1.114
+	wayland? ( dev-libs/wayland:=[${MULTILIB_USEDEP}] )
+	X? (
+		x11-libs/libX11:=[${MULTILIB_USEDEP}]
+		x11-libs/libXrandr:=[${MULTILIB_USEDEP}]
+	)"
+
+multilib_src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_SKIP_RPATH=True
+		-DBUILD_TESTS=False
+		-DBUILD_LOADER=True
+		-DBUILD_WSI_WAYLAND_SUPPORT=$(usex wayland)
+		-DBUILD_WSI_XCB_SUPPORT=$(usex X)
+		-DBUILD_WSI_XLIB_SUPPORT=$(usex X)
+		-DVULKAN_HEADERS_INSTALL_DIR="/usr"
+	)
+	cmake-utils_src_configure
+}
+
+multilib_src_install() {
+	keepdir /etc/vulkan/icd.d
+
+	cmake-utils_src_install
+}
+
+pkg_postinst() {
+	einfo "USE=demos has been dropped as per upstream packaging"
+	einfo "vulkaninfo is now available in the dev-util/vulkan-tools package"
+}