gentoo auto-resync : 22:01:2023 - 12:52:10

1 files changed, 56 insertions, 0 deletions

diff --git a/media-libs/sratom/sratom-0.6.14-r1.ebuild b/media-libs/sratom/sratom-0.6.14-r1.ebuild
new file mode 100644
index 000000000000..fdb0acae1dcb
--- /dev/null
+++ b/media-libs/sratom/sratom-0.6.14-r1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+PYTHON_REQ_USE='threads(+)'
+inherit meson-multilib python-any-r1
+
+DESCRIPTION="Library for serialising LV2 atoms to/from RDF, particularly the Turtle syntax"
+HOMEPAGE="https://drobilla.net/software/sratom.html"
+SRC_URI="https://download.drobilla.net/${P}.tar.xz"
+
+LICENSE="ISC"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~loong ppc ppc64 ~riscv ~sparc x86"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	virtual/pkgconfig
+	doc? (
+		app-doc/doxygen
+		dev-python/sphinx
+		dev-python/sphinx_lv2_theme
+)
+"
+RDEPEND="
+	>=dev-libs/serd-0.30.10
+	>=dev-libs/sord-0.16.10
+	>=media-libs/lv2-1.18.4
+"
+DEPEND="${RDEPEND}
+	${PYTHON_DEPS}
+"
+
+src_prepare() {
+	default
+
+	# fix doc installation path
+	sed -iE "s%install_dir: docdir / 'sratom-0',%install_dir: docdir / '${PF}',%g" doc/c/meson.build || die
+}
+
+multilib_src_configure() {
+	local emesonargs=(
+		$(meson_native_use_feature doc docs)
+		$(meson_feature test tests)
+	)
+
+	meson_src_configure
+}
+
+multilib_src_install_all() {
+	local DOCS=( NEWS README.md )
+	einstalldocs
+}