gentoo resync : 09.03.2018

1 files changed, 48 insertions, 0 deletions

diff --git a/media-libs/sdl2-gfx/sdl2-gfx-1.0.4.ebuild b/media-libs/sdl2-gfx/sdl2-gfx-1.0.4.ebuild
new file mode 100644
index 000000000000..50a8e683dc38
--- /dev/null
+++ b/media-libs/sdl2-gfx/sdl2-gfx-1.0.4.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit autotools multilib-minimal
+
+MY_P="${P/sdl2-/SDL2_}"
+DESCRIPTION="Graphics drawing primitives library for SDL2"
+HOMEPAGE="http://www.ferzkopp.net/joomla/content/view/19/14/"
+SRC_URI="http://www.ferzkopp.net/Software/SDL2_gfx/${MY_P}.tar.gz"
+
+LICENSE="ZLIB"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc cpu_flags_x86_mmx static-libs"
+
+DEPEND=">=media-libs/libsdl2-2.0.1-r1[video,${MULTILIB_USEDEP}]"
+RDEPEND="${DEPEND}"
+
+DOCS=( AUTHORS ChangeLog README )
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	default
+	mv configure.in configure.ac || die
+	sed -i \
+		-e 's/ -O / /' \
+		configure.ac || die
+	eautoreconf
+}
+
+multilib_src_configure() {
+	local myeconfargs=(
+		$(use_enable cpu_flags_x86_mmx mmx)
+		$(use_enable static-libs static)
+	)
+	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	if use doc ; then
+		docinto html
+		dodoc -r Docs/html/*
+	fi
+	find "${ED}" \( -name "*.a" -o -name "*.la" \) -delete || die
+}