reinit the tree, so we can have metadata

4 files changed, 172 insertions, 0 deletions

diff --git a/media-libs/phonon-vlc/Manifest b/media-libs/phonon-vlc/Manifest
new file mode 100644
index 000000000000..bfa17096907b
--- /dev/null
+++ b/media-libs/phonon-vlc/Manifest
@@ -0,0 +1,6 @@
+DIST phonon-backend-vlc-0.9.1.tar.xz 59972 SHA256 e698729ba8487299105309623722344f2cd84c46482516d51cd6609fac297313 SHA512 104a29159541002d4064486b54d02183c32cf87931c205badf44333d9481b0c0e70e6eae7f9d3c558bef977de37f76cc203dc5c15120f4146d64d451992947aa WHIRLPOOL 579198596b495b4a4dfed2fe163214c04164ea8f665521a88102c21cb6b68ca74732f58546e6a623285996f77d2255f918fc04a5f9d4cc69c55a6423a14fd3fc
+EBUILD phonon-vlc-0.9.1-r1.ebuild 1676 SHA256 67aff1d95dde24843138699472e07871a0f1ef3641e25315dc6383c306a50c4f SHA512 2a4f56f0421d654c76eefcfa6863c3ad22d52a87e50651123d28f32a0b0fff4e40fefe8ed8f272994b04292ac77cd5f0357d9f0383855c97057d57c98e5380d9 WHIRLPOOL 137459d076aabdc9913e838021935530f5579520666d7575092583b75f429638c6dab5c4a61899a223a135a3f54d4a9d0edf76c5ba1299e28a489965dcf08013
+EBUILD phonon-vlc-9999.ebuild 1624 SHA256 507ef651c29aac8831c67a90cc424a3f2d610cc5187e2bae804bda27fe2f91ab SHA512 87c16fc4912156646a98400d4c9624a3916d9df085f4ebf41431806b80e0a8868ff88123815244300135da7b497a2d6709810c074414b6b7d8023c52abffa8d1 WHIRLPOOL b9345a7f3f4cfaf4fbe0b85ee40d41599ed7402f7cced6d687a3927e716a812fa36c68621fe323629b09f2a81f58ec57b5326ba22154f44f37ee9a1f739c01b5
+MISC ChangeLog 5106 SHA256 27631c552e0cfe8cc426fd84ab460a46ffa5dbc2be206a8ba362417fc22cc3b4 SHA512 9ccacf2351897f969fddca9b8c9f1c508771c951e84324a37b8875054f39422c2e2ce2b009da20f471fa2ba8a308dc7b1009289425c75e9f5c1f8b20aaca4dce WHIRLPOOL 7fe5a9e3c0d1d8e1a684c6d71ce3e5766180d458c8ce7ed3619084cf8de66c3b6468dcd24f985d3409e7023187e05926ba19770983ec1392592fb333d348238e
+MISC ChangeLog-2015 8954 SHA256 2c45bd289dc6744716a60ebce98c93edf73abfd212a2235da8527514c4caf4fb SHA512 e775310eb347742aaf19e0bc0cfa5b176184188faed10fd2239e5d7365627cb996b7c88732ba160b7c26198b65c06148523f53ca81da7227996ad9499cb6b224 WHIRLPOOL 9a2e36c44b9cef9fed5c20cb5b7ad33c1177ab289249bda1081ba2870f3f038bae28e7a0c404e277e294e0e2070e4ef381dbb78ab45c6031bcc4428333098f4f
+MISC metadata.xml 249 SHA256 584f1dcf51866dc24a9abf7a89bfba0fad11dde81ae1c1b715da41770d233c99 SHA512 76a5a340b13f0053ca3c5e94ed24380ea8d29b45ac8655419e22eaadb1e4a827c04d2e7e36b65145c4964e6526f656618fc6ac144e277ef53cb7373e6239e3c3 WHIRLPOOL 200c07a8bf7c55b11b7936d5cd30e991a511684913334e72f59def66c0ced5fed0b4a8754e2d98bffbab631cb90d4e17fcccc59d5dcc5a8e988f69e47c85518c
diff --git a/media-libs/phonon-vlc/metadata.xml b/media-libs/phonon-vlc/metadata.xml
new file mode 100644
index 000000000000..2fdbf33d963d
--- /dev/null
+++ b/media-libs/phonon-vlc/metadata.xml
@@ -0,0 +1,8 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>kde@gentoo.org</email>
+		<name>Gentoo KDE Project</name>
+	</maintainer>
+</pkgmetadata>
diff --git a/media-libs/phonon-vlc/phonon-vlc-0.9.1-r1.ebuild b/media-libs/phonon-vlc/phonon-vlc-0.9.1-r1.ebuild
new file mode 100644
index 000000000000..4b261734a9dc
--- /dev/null
+++ b/media-libs/phonon-vlc/phonon-vlc-0.9.1-r1.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+MY_PN="phonon-backend-vlc"
+MY_P="${MY_PN}-${PV}"
+
+if [[ ${PV} != *9999* ]]; then
+	SRC_URI="mirror://kde/stable/phonon/${MY_PN}/${PV}/${MY_P}.tar.xz"
+	KEYWORDS="amd64 ~arm ~arm64 ppc ppc64 x86 ~amd64-fbsd"
+	S="${WORKDIR}/${MY_P}"
+else
+	EGIT_REPO_URI=( "git://anongit.kde.org/${PN}" )
+	inherit git-r3
+fi
+
+inherit cmake-utils multibuild
+
+DESCRIPTION="Phonon VLC backend"
+HOMEPAGE="https://phonon.kde.org/"
+
+LICENSE="LGPL-2.1+ || ( LGPL-2.1 LGPL-3 )"
+SLOT="0"
+IUSE="debug qt4 +qt5"
+
+REQUIRED_USE="|| ( qt4 qt5 )"
+
+RDEPEND="
+	>=media-libs/phonon-4.9.0[qt4=,qt5=]
+	>=media-video/vlc-2.0.1:=[dbus,ogg,vorbis]
+	qt4? (
+		>=dev-qt/qtcore-4.8.7-r2:4
+		>=dev-qt/qtgui-4.8.7:4
+	)
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtwidgets:5
+	)
+"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+"
+
+DOCS=( AUTHORS )
+
+pkg_setup() {
+	if use qt4 && [[ $(gcc-major-version) -lt 5 ]] ; then
+		ewarn "A GCC version older than 5 was detected. There may be trouble. See also Gentoo bug #595618"
+	fi
+
+	MULTIBUILD_VARIANTS=( $(usev qt4) $(usev qt5) )
+}
+
+src_configure() {
+	myconfigure() {
+		local mycmakeargs=()
+		if [[ ${MULTIBUILD_VARIANT} = qt4 ]]; then
+			mycmakeargs+=( -DPHONON_BUILD_PHONON4QT5=OFF )
+		fi
+		if [[ ${MULTIBUILD_VARIANT} = qt5 ]]; then
+			mycmakeargs+=( -DPHONON_BUILD_PHONON4QT5=ON )
+		fi
+		cmake-utils_src_configure
+	}
+
+	multibuild_foreach_variant myconfigure
+}
+
+src_compile() {
+	multibuild_foreach_variant cmake-utils_src_compile
+}
+
+src_test() {
+	multibuild_foreach_variant cmake-utils_src_test
+}
+
+src_install() {
+	multibuild_foreach_variant cmake-utils_src_install
+}
diff --git a/media-libs/phonon-vlc/phonon-vlc-9999.ebuild b/media-libs/phonon-vlc/phonon-vlc-9999.ebuild
new file mode 100644
index 000000000000..9cdb125fdcce
--- /dev/null
+++ b/media-libs/phonon-vlc/phonon-vlc-9999.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+MY_PN="phonon-backend-vlc"
+MY_P="${MY_PN}-${PV}"
+
+if [[ ${PV} != *9999* ]]; then
+	SRC_URI="mirror://kde/stable/phonon/${MY_PN}/${PV}/${MY_P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86 ~amd64-fbsd"
+	S="${WORKDIR}/${MY_P}"
+else
+	EGIT_REPO_URI=( "git://anongit.kde.org/${PN}" )
+	inherit git-r3
+fi
+
+inherit cmake-utils multibuild
+
+DESCRIPTION="Phonon VLC backend"
+HOMEPAGE="https://phonon.kde.org/"
+
+LICENSE="LGPL-2.1+ || ( LGPL-2.1 LGPL-3 )"
+SLOT="0"
+IUSE="debug qt4"
+
+RDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtwidgets:5
+	>=media-libs/phonon-4.9.0[qt4=,qt5(+)]
+	>=media-video/vlc-2.0.1:=[dbus,ogg,vorbis]
+	qt4? (
+		>=dev-qt/qtcore-4.8.7-r2:4
+		>=dev-qt/qtgui-4.8.7:4
+	)
+"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+"
+
+DOCS=( AUTHORS )
+
+pkg_setup() {
+	if use qt4 && [[ $(gcc-major-version) -lt 5 ]] ; then
+		ewarn "A GCC version older than 5 was detected. There may be trouble. See also Gentoo bug #595618"
+	fi
+
+	MULTIBUILD_VARIANTS=( $(usev qt4) qt5 )
+}
+
+src_configure() {
+	myconfigure() {
+		local mycmakeargs=()
+		if [[ ${MULTIBUILD_VARIANT} = qt4 ]]; then
+			mycmakeargs+=( -DPHONON_BUILD_PHONON4QT5=OFF )
+		fi
+		if [[ ${MULTIBUILD_VARIANT} = qt5 ]]; then
+			mycmakeargs+=( -DPHONON_BUILD_PHONON4QT5=ON )
+		fi
+		cmake-utils_src_configure
+	}
+
+	multibuild_foreach_variant myconfigure
+}
+
+src_compile() {
+	multibuild_foreach_variant cmake-utils_src_compile
+}
+
+src_test() {
+	multibuild_foreach_variant cmake-utils_src_test
+}
+
+src_install() {
+	multibuild_foreach_variant cmake-utils_src_install
+}