reinit the tree, so we can have metadata

4 files changed, 189 insertions, 0 deletions

diff --git a/media-libs/phonon-gstreamer/Manifest b/media-libs/phonon-gstreamer/Manifest
new file mode 100644
index 000000000000..4b81b01bfe2a
--- /dev/null
+++ b/media-libs/phonon-gstreamer/Manifest
@@ -0,0 +1,6 @@
+DIST phonon-backend-gstreamer-4.9.0.tar.xz 75960 SHA256 cec3e5ece1261d344b68363ef0606ebf49772628ba94bb55b0c0d18773b885f1 SHA512 9c13d37c6c7070c2bd8fcc562f743ac2f55289bc7cc82147ef0ae990e5d380d541cc1d9ce61e6ad1549ed1935d41faafaeeb0cd5463e4c656ea8fee636ff4dfe WHIRLPOOL caaa0e3392e82e120b288d3714ec4987ba70f7b11b920049da9c26fea1b940c15e5e569c855c8b37a26cff8a04959ec5b2c238e6460b324a85c22e444265f136
+EBUILD phonon-gstreamer-4.9.0-r1.ebuild 1978 SHA256 b354fc8a488becedac24fcc8d0b8ce7ba24a4713c888d4054115939ed618f149 SHA512 062854f40de54080251b0490a359b9579941b8f3fd6300ecb505c500e1f373d8ec818fa477d18306463144211e5e1c80b49c896713b50fab201ace9f53aadf30 WHIRLPOOL c5dc68072ed9556e6077a2d4ce5b5f932089a07c6286a8676f4913ae9e1e1884cdb19ae010ece4a6cbaa4cc3fd817aa1023d484c2c0f56e704e508401325c8a9
+EBUILD phonon-gstreamer-9999.ebuild 1919 SHA256 906719fee47edc67a673ef2d2570b112ed453503e6958f700d313e03c6a804ff SHA512 62d607045962eccef32bc84dc0d4f3dc43fdada4b94ef653e8c3dba8df821649cca852b329e011df55b5d0af139c5ff29d434ff5d347df0d1356da000b0b0d0d WHIRLPOOL 9eb888f73015528624effde977dc21bf713c79726b931a99a781b4da05b3afe4c82e7366c70c2eaf14f6f91ad8467d7e1b30e860f6b012aa71191a636605037b
+MISC ChangeLog 7391 SHA256 96c96ca0262e5a05d97c54e6a238122a001e63ddf1fc4c6d2ae8ae83933cbb9a SHA512 6feba86d922fc0b3f1b3080a14f1106df4edca051f6ef30d63542c1c7e33ebd893e1a9acd13a12a20cf11c9741f70f2e207b4ae26776361dc5ffdd007d2fd978 WHIRLPOOL cb1fad91bf30d692cf302bdd3abb8252bf36596233859cf63504479c23ade8eb1a4d5a4db4f7cd6b54acbfb87df0ab6dde46699fcca5705e9a456e7bda83c073
+MISC ChangeLog-2015 10283 SHA256 e31ad27781d37f430d52801687feb8a6005002a2d25e976c02e544a602729c7c SHA512 54521dfdd943f4cca8d5a43ea0749dbab71c2c6b930a05ec988d91459520b386cf90231afcea7a41ae1f036a21f24e2c7718ae88c3e2a3ad9ccc6c1c33c862ae WHIRLPOOL 855b0846710c735f48315aa71b0f0eca22cde79a9cf21b1eea1d51f12f869e37c9fda5bffe804092775c3274ba12c215bfc64e6ac0b82332d24f50a9c89d82b6
+MISC metadata.xml 339 SHA256 3630867165ac61395c881cb3fc4a857363f765aeff24764835ba33a5ae75adea SHA512 c481721ab8e7762b2b951501cc99f7e2d2263ffd682dce3731fb415b677b74f7fbfe7770e9d2b1b1ce496c10254b84bb7489ff971593dac90c151a9ff1623e9a WHIRLPOOL 38447c2aba96f734a81dc9187bd78f4f7577f4fadbefcbd80378ca1cf8d679f05678615823a13654261b032581506a104eb7c76481301ef8269b45b88a561443
diff --git a/media-libs/phonon-gstreamer/metadata.xml b/media-libs/phonon-gstreamer/metadata.xml
new file mode 100644
index 000000000000..b1ca978b007e
--- /dev/null
+++ b/media-libs/phonon-gstreamer/metadata.xml
@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>kde@gentoo.org</email>
+		<name>Gentoo KDE Project</name>
+	</maintainer>
+	<use>
+		<flag name="network">Enable network streaming support via libsoup</flag>
+	</use>
+</pkgmetadata>
diff --git a/media-libs/phonon-gstreamer/phonon-gstreamer-4.9.0-r1.ebuild b/media-libs/phonon-gstreamer/phonon-gstreamer-4.9.0-r1.ebuild
new file mode 100644
index 000000000000..c24ca2f0c163
--- /dev/null
+++ b/media-libs/phonon-gstreamer/phonon-gstreamer-4.9.0-r1.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+MY_PN="phonon-backend-gstreamer"
+MY_P=${MY_PN}-${PV}
+
+if [[ ${PV} != *9999* ]]; then
+	SRC_URI="mirror://kde/stable/phonon/${MY_PN}/${PV}/${MY_P}.tar.xz"
+	KEYWORDS="alpha amd64 arm ~arm64 ppc ppc64 x86 ~amd64-fbsd ~x86-fbsd ~x64-macos"
+else
+	EGIT_REPO_URI=( "git://anongit.kde.org/${PN}" )
+	inherit git-r3
+fi
+
+inherit cmake-utils multibuild
+
+DESCRIPTION="Phonon GStreamer backend"
+HOMEPAGE="https://phonon.kde.org/"
+
+LICENSE="LGPL-2.1+ || ( LGPL-2.1 LGPL-3 )"
+SLOT="0"
+IUSE="alsa debug +network qt4 +qt5"
+
+REQUIRED_USE="|| ( qt4 qt5 )"
+
+RDEPEND="
+	dev-libs/glib:2
+	dev-libs/libxml2:2
+	media-libs/gstreamer:1.0
+	media-libs/gst-plugins-base:1.0
+	>=media-libs/phonon-4.9.0[qt4?,qt5?]
+	media-plugins/gst-plugins-meta:1.0[alsa?,ogg,vorbis]
+	virtual/opengl
+	network? ( media-plugins/gst-plugins-soup:1.0 )
+	qt4? (
+		>=dev-qt/qtcore-4.8.7-r2:4[glib]
+		>=dev-qt/qtgui-4.8.7:4[glib]
+		>=dev-qt/qtopengl-4.8.7:4
+		!<dev-qt/qtwebkit-4.10.4:4[gstreamer]
+	)
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtopengl:5
+		dev-qt/qtwidgets:5
+		dev-qt/qtx11extras:5
+	)
+"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+"
+
+pkg_setup() {
+	if use qt4 && [[ $(gcc-major-version) -lt 5 ]] ; then
+		ewarn "A GCC version older than 5 was detected. There may be trouble. See also Gentoo bug #595618"
+	fi
+
+	MULTIBUILD_VARIANTS=( $(usev qt4) $(usev qt5) )
+}
+
+src_configure() {
+	myconfigure() {
+		local mycmakeargs=()
+		if [[ ${MULTIBUILD_VARIANT} = qt4 ]]; then
+			mycmakeargs+=( -DPHONON_BUILD_PHONON4QT5=OFF )
+		fi
+		if [[ ${MULTIBUILD_VARIANT} = qt5 ]]; then
+			mycmakeargs+=( -DPHONON_BUILD_PHONON4QT5=ON )
+		fi
+		cmake-utils_src_configure
+	}
+
+	multibuild_foreach_variant myconfigure
+}
+
+src_compile() {
+	multibuild_foreach_variant cmake-utils_src_compile
+}
+
+src_test() {
+	multibuild_foreach_variant cmake-utils_src_test
+}
+
+src_install() {
+	multibuild_foreach_variant cmake-utils_src_install
+}
diff --git a/media-libs/phonon-gstreamer/phonon-gstreamer-9999.ebuild b/media-libs/phonon-gstreamer/phonon-gstreamer-9999.ebuild
new file mode 100644
index 000000000000..b0e89138a56c
--- /dev/null
+++ b/media-libs/phonon-gstreamer/phonon-gstreamer-9999.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+MY_PN="phonon-backend-gstreamer"
+MY_P=${MY_PN}-${PV}
+
+if [[ ${PV} != *9999* ]]; then
+	SRC_URI="mirror://kde/stable/phonon/${MY_PN}/${PV}/${MY_P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86 ~amd64-fbsd ~x86-fbsd ~x64-macos"
+else
+	EGIT_REPO_URI=( "git://anongit.kde.org/${PN}" )
+	inherit git-r3
+fi
+
+inherit cmake-utils multibuild
+
+DESCRIPTION="Phonon GStreamer backend"
+HOMEPAGE="https://phonon.kde.org/"
+
+LICENSE="LGPL-2.1+ || ( LGPL-2.1 LGPL-3 )"
+SLOT="0"
+IUSE="alsa debug +network qt4"
+
+RDEPEND="
+	dev-libs/glib:2
+	dev-libs/libxml2:2
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtopengl:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	media-libs/gstreamer:1.0
+	media-libs/gst-plugins-base:1.0
+	>=media-libs/phonon-4.9.0[qt4?,qt5(+)]
+	media-plugins/gst-plugins-meta:1.0[alsa?,ogg,vorbis]
+	virtual/opengl
+	network? ( media-plugins/gst-plugins-soup:1.0 )
+	qt4? (
+		>=dev-qt/qtcore-4.8.7-r2:4[glib]
+		>=dev-qt/qtgui-4.8.7:4[glib]
+		>=dev-qt/qtopengl-4.8.7:4
+		!<dev-qt/qtwebkit-4.10.4:4[gstreamer]
+	)
+"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+"
+
+pkg_setup() {
+	if use qt4 && [[ $(gcc-major-version) -lt 5 ]] ; then
+		ewarn "A GCC version older than 5 was detected. There may be trouble. See also Gentoo bug #595618"
+	fi
+
+	MULTIBUILD_VARIANTS=( $(usev qt4) qt5 )
+}
+
+src_configure() {
+	myconfigure() {
+		local mycmakeargs=()
+		if [[ ${MULTIBUILD_VARIANT} = qt4 ]]; then
+			mycmakeargs+=( -DPHONON_BUILD_PHONON4QT5=OFF )
+		fi
+		if [[ ${MULTIBUILD_VARIANT} = qt5 ]]; then
+			mycmakeargs+=( -DPHONON_BUILD_PHONON4QT5=ON )
+		fi
+		cmake-utils_src_configure
+	}
+
+	multibuild_foreach_variant myconfigure
+}
+
+src_compile() {
+	multibuild_foreach_variant cmake-utils_src_compile
+}
+
+src_test() {
+	multibuild_foreach_variant cmake-utils_src_test
+}
+
+src_install() {
+	multibuild_foreach_variant cmake-utils_src_install
+}