gentoo resync : 13.11.2021

4 files changed, 164 insertions, 5 deletions

diff --git a/media-libs/mlt/Manifest b/media-libs/mlt/Manifest
index 048f3cc55643..2bf1e82f4d43 100644
--- a/media-libs/mlt/Manifest
+++ b/media-libs/mlt/Manifest
@@ -4,6 +4,8 @@ AUX mlt-6.26.1-fix-crash-w-ogg-album-art.patch 2476 BLAKE2B f11ae9637e0143134996
 AUX mlt-7.0.1-cmake-symlink.patch 569 BLAKE2B 06f7c8e7ec78206bb1344bab98f1d9ec816b16c458300964fe31ff30f8f2cc64d8f25a795773fd64db7249b031a164c350b55b6326c4d07d73ffd27f8786a911 SHA512 6deb458c3a89f800b4770460330c1e545c22d3a7304f0713b7ae214145d1413a3061c7c026ab2f6fc44801d1d7505352f03c0da7034e817b684e0ebb25d9a94f
 DIST mlt-6.26.1.tar.gz 1366022 BLAKE2B f5b7e733090ae60cb55556893775ab4a68847705e215b85c90d901d72022f5b57c08122cd8c08c1ba51b71eedc5341adaaad2ad002af76724a2d2cf6a7379974 SHA512 6a3ef572cddee48c3089b19b2920de84936aa913a3f35b6f06e4bece2dc7a5a168daecfbaa8111c799b5316f967c37b09d485c000a4eba69af4f7ee3dc8db9e4
 DIST mlt-7.0.1.tar.gz 1181298 BLAKE2B 90547ebeeb90b5ab20ec39e3fa97454e9c502af08981f20e433deafc5bbbb45caeea485c18b4229821fcdcef2ed7767e8936af273200a233f18251fa8bc73dd0 SHA512 9268889f0fbe69180651a592ac0b328d18f8b60c7d83f9d6c506dc21254afcb2281662f4d19faf3520976ae100600d00cd6eb2aa42c83880fa4c4c36e760c68a
-EBUILD mlt-6.26.1-r1.ebuild 5385 BLAKE2B 64c6779bf90e459905f1b93c28d7f21b4974a1fa8d7b0df205fb6ffe32d57b8516cf43968fc9af140cfdeafa9dce1a85d1b93411ad2f83587a7e837383af6579 SHA512 3f33ed0fd4d22fe7df7a53ed8810f296c1b4829410b7ddde3424bc55e6a321597dc80537488541490bc3536bf8f3de6d995a740f1adb7b65a99c3af74a701a84
-EBUILD mlt-7.0.1-r2.ebuild 3672 BLAKE2B be8acd94afd713c410440bf73e4cd8f718fcb0edf47216692ad3067a3eeb0997f73a4ba33526fdf7380c3b8d825500f0a6019aa5f84e588225415eb9e9b098c7 SHA512 f4f719ad1c34118f6abddebba04845210f432cba8ec235c62c21bfdf48273fc0bb1463b82a6b5af9ed8152d5a1c6b08df338f719504046f47b9db969efe0ae84
+DIST mlt-7.2.0.tar.gz 1203489 BLAKE2B 2b53a813146f4868469c945208b4e7b509f67667357df615954a7d0f02ebe809dba0c15acd302f9a8609978929d00dd1e20fb03fc5d29a7dd5196253f37f70b7 SHA512 cee8d6cef2db5aae5747a80a292eca29d25adedd7754ea88a1857b429c0ccd35f689bcd9381c069c0e9e04b9eae5b7301e7c9548c536b43e4a9d54af664d629f
+EBUILD mlt-6.26.1-r1.ebuild 5389 BLAKE2B ba0720dcd769ea0dea32028acf4593854ec8ca21484e93141c908896085cd425f616ec70df73d9a62954ff99270fe41aa01d90b7b47cbebcdf615b4b53baf9f1 SHA512 4dd20f542553eb3e81dc944a0856efbe67a045881b7c38f0296a19ececa198d0508dda6c583835b2c5ed60a95fd0caf2e269086eaab3b1974decc310019e3d0e
+EBUILD mlt-7.0.1-r2.ebuild 3674 BLAKE2B 2dd9a40cef8ce16a5aa18851a6de79dd9e3ddd7180fda3f91e61e2df99cbd8171ab6f00185db04a99218225573c897adee3eeb53def52f1caca7e1417d481d34 SHA512 16333514c46b9f95a29fc83adf1cd9c3b614a87c001c283563ec979577990fd500206e2f29d10975b1bf273d7be728ef2ad036220323fac4636f2682a7cbb0bf
+EBUILD mlt-7.2.0.ebuild 3658 BLAKE2B 2c9bdca2fc5dfc34c1cf4a5531f9d6f3528d4983df462a16c4c601d3c85d847802d4045839d008e9888e5ee854005b89b26563e283f7c15033233faf1ad3d2d4 SHA512 d6aa64ccb3cc766c1d77342b7d6c8bc16fb8e53ee1d0b766a2999a4581d841f32b2036c32d083587d80d45eb9c60b924b6be3e42b962d926a2e5f9f3cf0006b6
 MISC metadata.xml 1537 BLAKE2B aadfa5445dbf5909835b5d49aee48ca802e601d67a080d9048a3b48c283681c52219ea9ddddc7a7f740e9543dee0eda980d152a1301137c589067d2099a3d14f SHA512 e1f4f1c0703aa0b896856f275c88363aeee35eb371471122893c6edd36abdb6dd8d557c813f1da72e2c51a7af7aa367757fcf7c356225800201ed2866777d6b9
diff --git a/media-libs/mlt/mlt-6.26.1-r1.ebuild b/media-libs/mlt/mlt-6.26.1-r1.ebuild
index b811f88b94bf..ec1d953a549a 100644
--- a/media-libs/mlt/mlt-6.26.1-r1.ebuild
+++ b/media-libs/mlt/mlt-6.26.1-r1.ebuild
@@ -23,7 +23,7 @@ REQUIRED_USE="lua? ( ${LUA_REQUIRED_USE} )
 	python? ( ${PYTHON_REQUIRED_USE} )"
 
 SWIG_DEPEND=">=dev-lang/swig-2.0"
-#	java? ( ${SWIG_DEPEND} >=virtual/jdk-1.5 )
+#	java? ( ${SWIG_DEPEND} >=virtual/jdk-1.8:* )
 #	perl? ( ${SWIG_DEPEND} )
 #	php? ( ${SWIG_DEPEND} )
 #	tcl? ( ${SWIG_DEPEND} )
@@ -75,7 +75,7 @@ DEPEND="
 	vidstab? ( media-libs/vidstab )
 	xine? ( >=media-libs/xine-lib-1.1.2_pre20060328-r7 )
 	xml? ( >=dev-libs/libxml2-2.5 )"
-#	java? ( >=virtual/jre-1.5 )
+#	java? ( >=virtual/jre-1.8:* )
 #	perl? ( dev-lang/perl )
 #	php? ( dev-lang/php )
 #	ruby? ( ${RUBY_DEPS} )
diff --git a/media-libs/mlt/mlt-7.0.1-r2.ebuild b/media-libs/mlt/mlt-7.0.1-r2.ebuild
index 0766ee0dea89..643d91660279 100644
--- a/media-libs/mlt/mlt-7.0.1-r2.ebuild
+++ b/media-libs/mlt/mlt-7.0.1-r2.ebuild
@@ -64,7 +64,7 @@ DEPEND="
 	xine? ( >=media-libs/xine-lib-1.1.2_pre20060328-r7 )
 	xml? ( >=dev-libs/libxml2-2.5 )
 "
-#	java? ( >=virtual/jre-1.5 )
+#	java? ( >=virtual/jre-1.8:* )
 #	perl? ( dev-lang/perl )
 #	php? ( dev-lang/php )
 #	ruby? ( ${RUBY_DEPS} )
diff --git a/media-libs/mlt/mlt-7.2.0.ebuild b/media-libs/mlt/mlt-7.2.0.ebuild
new file mode 100644
index 000000000000..8f733c14013f
--- /dev/null
+++ b/media-libs/mlt/mlt-7.2.0.ebuild
@@ -0,0 +1,157 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8,9,10} )
+inherit python-single-r1 cmake
+
+DESCRIPTION="Open source multimedia framework for television broadcasting"
+HOMEPAGE="https://www.mltframework.org/"
+SRC_URI="https://github.com/mltframework/${PN}/releases/download/v${PV}/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0/7"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug ffmpeg frei0r gtk jack kernel_linux libsamplerate opencv opengl python qt5 rtaudio rubberband sdl test vdpau vidstab xine xml"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+# Needs unpackaged 'kwalify'
+RESTRICT="test"
+
+# rtaudio will use OSS on non linux OSes
+DEPEND="
+	>=media-libs/libebur128-1.2.2:=
+	ffmpeg? ( media-video/ffmpeg:0=[vdpau?,-flite] )
+	frei0r? ( media-plugins/frei0r-plugins )
+	gtk? (
+		media-libs/libexif
+		x11-libs/pango
+	)
+	jack? (
+		>=dev-libs/libxml2-2.5
+		media-libs/ladspa-sdk
+		virtual/jack
+	)
+	libsamplerate? ( >=media-libs/libsamplerate-0.1.2 )
+	opencv? ( >=media-libs/opencv-4.5.1:=[contrib] )
+	opengl? (
+		media-libs/libglvnd
+		media-video/movit
+	)
+	python? ( ${PYTHON_DEPS} )
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtsvg:5
+		dev-qt/qtwidgets:5
+		dev-qt/qtxml:5
+		media-libs/libexif
+		sci-libs/fftw:3.0=
+		x11-libs/libX11
+	)
+	rtaudio? (
+		>=media-libs/rtaudio-4.1.2
+		kernel_linux? ( media-libs/alsa-lib )
+	)
+	rubberband? ( media-libs/rubberband )
+	sdl? (
+		media-libs/libsdl2[X,opengl,video]
+		media-libs/sdl2-image
+	)
+	vidstab? ( media-libs/vidstab )
+	xine? ( >=media-libs/xine-lib-1.1.2_pre20060328-r7 )
+	xml? ( >=dev-libs/libxml2-2.5 )
+"
+#	java? ( >=virtual/jre-1.8:* )
+#	perl? ( dev-lang/perl )
+#	php? ( dev-lang/php )
+#	ruby? ( ${RUBY_DEPS} )
+#	sox? ( media-sound/sox )
+#	tcl? ( dev-lang/tcl:0= )
+RDEPEND="${DEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	python? ( >=dev-lang/swig-2.0 )
+"
+
+DOCS=( AUTHORS NEWS README.md )
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-6.10.0-swig-underlinking.patch
+	"${FILESDIR}"/${PN}-6.22.1-no_lua_bdepend.patch
+	"${FILESDIR}"/${PN}-7.0.1-cmake-symlink.patch
+)
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	# respect CFLAGS LDFLAGS when building shared libraries. Bug #308873
+	if use python; then
+		sed -i "/mlt.so/s/ -lmlt++ /& ${CFLAGS} ${LDFLAGS} /" src/swig/python/build || die
+		python_fix_shebang src/swig/python
+	fi
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_SKIP_RPATH=ON
+		-DGPL=ON
+		-DGPL3=ON
+		-DBUILD_TESTING=$(usex test)
+		-DMOD_KDENLIVE=ON
+		-DMOD_SDL1=OFF
+		-DMOD_SDL2=$(usex sdl)
+		-DMOD_AVFORMAT=$(usex ffmpeg)
+		# TODO: does anything need plus?
+		# plus or qt
+		#$(use_enable fftw plus)
+		-DMOD_FREI0R=$(usex frei0r)
+		-DMOD_GDK=$(usex gtk)
+		-DMOD_JACKRACK=$(usex jack)
+		-DMOD_RESAMPLE=$(usex libsamplerate)
+		-DMOD_OPENCV=$(usex opencv)
+		-DMOD_MOVIT=$(usex opengl)
+		-DMOD_QT=$(usex qt5)
+		-DMOD_RTAUDIO=$(usex rtaudio)
+		-DMOD_RUBBERBAND=$(usex rubberband)
+		-DMOD_VIDSTAB=$(usex vidstab)
+		-DMOD_XINE=$(usex xine)
+		-DMOD_XML=$(usex xml)
+		-DMOD_SOX=OFF
+	)
+
+	# TODO: We currently have USE=fftw but both Qt and plus require it, removing flag for now.
+	# TODO: rework upstream CMake to allow controlling MMX/SSE/SSE2
+	# TODO: add swig language bindings?
+	# see also https://www.mltframework.org/twiki/bin/view/MLT/ExtremeMakeover
+
+	if use python; then
+		mycmakeargs+=( -DSWIG_PYTHON=ON )
+	fi
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	insinto /usr/share/${PN}
+	doins -r demo
+
+	#
+	# Install SWIG bindings
+	#
+
+	docinto swig
+
+	if use python; then
+		dodoc "${S}"/src/swig/python/play.py
+		python_optimize
+	fi
+}