gentoo resync : 20.11.2017

2 files changed, 191 insertions, 0 deletions

diff --git a/media-libs/mediastreamer/Manifest b/media-libs/mediastreamer/Manifest
index a32b071f56b3..6ada4c35b888 100644
--- a/media-libs/mediastreamer/Manifest
+++ b/media-libs/mediastreamer/Manifest
@@ -18,6 +18,7 @@ DIST mediastreamer-2.9.0.tar.gz 3578877 SHA256 c245b9444c2abb4c84433606e01f0b3ce
 EBUILD mediastreamer-2.7.3-r3.ebuild 3898 SHA256 2077b820c16fc457955bafd310db7690540696f3621c810894529f55305bf7fa SHA512 941d6199e23c2e2d42e5e784fb125ab6ca128e839f691a45a3c5faf2ffe1cbc7189e506f8c1a129e92283fc4428573d78d4f9971b3d75f6c25d36e1f77ff176e WHIRLPOOL b282a6606c3570d29b18c77919c56acb960cc8309f7f3c61d1b6d5874d8d8b0c818252a6c25b75a8f2b62577d969590f25c329a8eea99f0623db03e78c5a4d3a
 EBUILD mediastreamer-2.8.2.ebuild 3824 SHA256 5faadb8c8a2d0927b216a6f0bdb35f217f1f47ab8ee6cc20921d5c2ca4a79198 SHA512 9336b58a8b0ef34d58ee9f3d37cb40911e25a5c1979bbf9507370f3d9018de5c13833d8cfbaeb3482810bf1c9d366a0541ea576c345af5837fc4e4ca9d0579c1 WHIRLPOOL aba97ac0447ba5a4e106a07cd49ab76ddd0dab8c5a0e896b72527722b35c8b53e1ead57e534c929eea7785336b60aa33af65ba4972c423df1d1d88677b7872ce
 EBUILD mediastreamer-2.9.0-r1.ebuild 4584 SHA256 6fc9b068e3039063acdeca5b86b46a9c45d0f7f78ba84426947bb237ba7fde56 SHA512 2b05c989175bb8fccf7d5bccce914ddfeec8c5ef28e76d34bbcdf811aa19b0343ead4b41fbcd5aa3fd0aa8cba9921d7d1ecabf253842108b45b01c69b162ade9 WHIRLPOOL c36559129c88429139e7432990310e222cb52c246a819e93e04f1c1fcd560c0ec5a8960c898ea7d39f0eab981c17462a5e011174a60b9a3c64062a077695e827
+EBUILD mediastreamer-2.9.0-r2.ebuild 4636 SHA256 c42b421fec4f715466574d26381f644836a0a27b0c1c680799a5cdc9d360f188 SHA512 2153f2eb4ee90ffcc5e049f53341ad84261c9fff6de7087d8166a885809e1ad112ac85405b17814a8a869dc58354bcfca1c342ab730e1177837d460177a48569 WHIRLPOOL 168017090ff236855d9ed59670e2ad7404fa47950c045d61144d7d217d6bf9fa716e731ebc1e86272403fd9b71d63e54a63d367f836ec3e996e7cc2303f215bf
 EBUILD mediastreamer-2.9.0.ebuild 4469 SHA256 3d17d02ca0eb5000f29ed005535d73ec1be9a3a7ea354ef0882c2576170ee15c SHA512 acf3c4d57f6e34e576ed7793c7b44da186ca48f667f4749e628ed2e3b9da0768ad49802063e782140964e8bd21286d6b470f394574a89c4004308791383dc610 WHIRLPOOL d6d0b17017b8d58e5c820d199c7232daf5de8bd96f69f68e6c11fce198a962ef1be4d9c5cdeecf5903295cad2ce307833709f97d037b99d06352cbce4336e922
 MISC ChangeLog 3214 SHA256 24296e592166c5d92785c54136e8abc8aa8175b8c01255efa4a5869a727f89f8 SHA512 c3bb18a80f85413dc871c98c8e2ea9461df4bee7d96eb817e80f8f5c7c57435060e39cf01476d37bdd720885b3e7a3547a5a3194add94b10463b28937938e0f8 WHIRLPOOL 6d423c370294784e43932463ee592ad9d8b6ee430b65f126f5c9a2fde7a9d578d9e915ee4011316307ff33fe28bf877d4a66db835e58a7d396a44de41bf5d2f6
 MISC ChangeLog-2015 12379 SHA256 3a133d76dba8a19dd4089acc331cfe6934ba43b9257db57d34c5bf2afa4e8420 SHA512 b2ecc5bd583c3cc6fff33c8d80a5854ed9737603d943bdc8aeb26c1723a9c7de60a266fb8551c056c4af843146b21bd973369e0eeec446322b0db00b1c37593d WHIRLPOOL b54f36dce60826fe1efd23c5c897fce921322940ce9eb5e747f849c27ff3f36e59898fb8f03a2569194441772111b0f4ef35ccd8b7129ccb08325e590c059881
diff --git a/media-libs/mediastreamer/mediastreamer-2.9.0-r2.ebuild b/media-libs/mediastreamer/mediastreamer-2.9.0-r2.ebuild
new file mode 100644
index 000000000000..48cb07c5b2d7
--- /dev/null
+++ b/media-libs/mediastreamer/mediastreamer-2.9.0-r2.ebuild
@@ -0,0 +1,190 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit autotools ltprune
+
+DESCRIPTION="Mediastreaming library for telephony application"
+HOMEPAGE="https://www.linphone.org/"
+SRC_URI="mirror://nongnu/linphone/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0/3"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+# Many cameras will not work or will crash an application if mediastreamer2 is
+# not built with v4l2 support (taken from configure.ac)
+# TODO: run-time test for ipv6: does it really need ortp[ipv6] ?
+IUSE="+alsa amr bindist coreaudio debug doc examples +filters g726 g729 gsm ilbc
+	ipv6 libav ntp-timestamp opengl opus +ortp oss pcap portaudio pulseaudio sdl
+	silk +speex static-libs test theora upnp v4l video x264 X"
+
+REQUIRED_USE="|| ( oss alsa portaudio coreaudio pulseaudio )
+	opengl? ( video )
+	theora? ( video )
+	v4l? ( video )
+	video? ( || ( opengl sdl X ) )
+	X? ( video )"
+
+RDEPEND="
+	alsa? ( media-libs/alsa-lib )
+	g726? ( >=media-libs/spandsp-0.0.6_pre1 )
+	gsm? ( media-sound/gsm )
+	opus? ( media-libs/opus )
+	ortp? ( >=net-libs/ortp-0.21.0:=[ipv6?] )
+	pcap? ( sys-libs/libcap )
+	portaudio? ( media-libs/portaudio )
+	pulseaudio? ( >=media-sound/pulseaudio-0.9.21 )
+	speex? (
+		>=media-libs/speex-1.2.0
+		media-libs/speexdsp
+	)
+	upnp? ( net-libs/libupnp:0 )
+	video? (
+		libav? ( >=media-video/libav-9.12:0= )
+		!libav? ( >=media-video/ffmpeg-1.2.6-r1:0= )
+		opengl? (
+			media-libs/glew:=
+			virtual/opengl
+			x11-libs/libX11
+		)
+		sdl? ( media-libs/libsdl[video,X] )
+		theora? ( media-libs/libtheora )
+		v4l? (
+			media-libs/libv4l
+			sys-kernel/linux-headers
+		)
+		X? (
+			x11-libs/libX11
+			x11-libs/libXv
+		)
+	)
+"
+DEPEND="${RDEPEND}
+	dev-util/intltool
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+	test? ( >=dev-util/cunit-2.1_p2[ncurses] )
+	video? ( dev-util/xxdi )
+	X? ( x11-proto/videoproto )
+"
+PDEPEND="
+	amr? ( !bindist? ( media-plugins/mediastreamer-amr ) )
+	g729? ( !bindist? ( media-plugins/mediastreamer-bcg729 ) )
+	ilbc? ( media-plugins/mediastreamer-ilbc )
+	silk? ( !bindist? ( media-plugins/mediastreamer-silk ) )
+	video? ( x264? ( media-plugins/mediastreamer-x264 ) )
+"
+
+PATCHES=(
+	"${FILESDIR}/${P}-v4l-automagic.patch"
+	"${FILESDIR}/${P}-libav9.patch"
+	"${FILESDIR}/${P}-underlinking.patch"
+	"${FILESDIR}/${P}-tests.patch"
+	"${FILESDIR}/${P}-xxd.patch"
+	"${FILESDIR}/${P}-ffmpeg3.patch"
+)
+
+src_prepare() {
+	default
+
+	# variable causes "command not found" warning and is not
+	# needed anyway
+	sed -i \
+		-e 's/$(ACLOCAL_MACOS_FLAGS)//' \
+		Makefile.am || die
+
+	# respect user's CFLAGS
+	sed -i \
+		-e "s:-O2::;s: -g::" \
+		configure.ac || die "patching configure.ac failed"
+
+	# change default paths
+	sed -i \
+		-e "s:\(prefix/share\):\1/${PN}:" \
+		configure.ac || die "patching configure.ac failed"
+
+	# fix doc installation dir
+	sed -i \
+		-e "s:\$(pkgdocdir):\$(docdir):" \
+		help/Makefile.am || die "patching help/Makefile.am failed"
+
+	# fix html installation dir
+	sed -i \
+		-e "s:\(doc_htmldir=\).*:\1\$(htmldir):" \
+		help/Makefile.am || die "patching help/Makefile.am failed"
+
+	# linux/videodev.h dropped in 2.6.38
+	sed -i \
+		-e 's:linux/videodev.h ::' \
+		configure.ac || die
+
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--htmldir="${EPREFIX}"/usr/share/doc/${PF}/html
+		--datadir="${EPREFIX}"/usr/share/${PN}
+		# arts is deprecated
+		--disable-artsc
+		# don't want -Werror
+		--disable-strict
+		--disable-libv4l1
+		# don't use bundled libs
+		--enable-external-ortp
+		$(use_enable alsa)
+		$(use_enable coreaudio macsnd)
+		$(use_enable debug)
+		$(use_enable filters)
+		$(use_enable g726 spandsp)
+		$(use_enable gsm)
+		$(use_enable ipv6)
+		$(use_enable ntp-timestamp)
+		$(use_enable opengl glx)
+		$(use_enable opus)
+		$(use_enable ortp)
+		$(use_enable oss)
+		$(use_enable pcap)
+		$(use_enable portaudio)
+		$(use_enable pulseaudio)
+		$(use_enable sdl)
+		$(use_enable speex)
+		$(use_enable static-libs static)
+		$(use_enable theora)
+		$(use_enable upnp)
+		$(use_enable v4l)
+		$(use_enable v4l libv4l2)
+		$(use_enable video)
+		$(use_enable X x11)
+		$(use_enable X xv)
+		$(use doc || echo ac_cv_path_DOXYGEN=false)
+	)
+
+	# Mac OS X Audio Queue is an audio recording facility, available on
+	# 10.5 (Leopard, Darwin9) and onward
+	if use coreaudio && [[ ${CHOST} == *-darwin* && ${CHOST##*-darwin} -ge 9 ]]
+	then
+		myeconfargs+=( --enable-macaqsnd )
+	else
+		myeconfargs+=( --disable-macaqsnd )
+	fi
+
+	econf "${myeconfargs[@]}"
+}
+
+src_test() {
+	default
+	cd tester || die
+	./mediastreamer2_tester || die
+}
+
+src_install() {
+	default
+	prune_libtool_files
+
+	if use examples; then
+		insinto /usr/share/doc/${PF}/examples
+		doins tester/*.c
+	fi
+}