gentoo resync : 28.04.2018

1 files changed, 73 insertions, 0 deletions

diff --git a/media-libs/libwebp/libwebp-1.0.0.ebuild b/media-libs/libwebp/libwebp-1.0.0.ebuild
new file mode 100644
index 000000000000..6ef54b5061d5
--- /dev/null
+++ b/media-libs/libwebp/libwebp-1.0.0.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit autotools libtool multilib-minimal
+
+MY_P="${P/_/-}"
+
+DESCRIPTION="A lossy image compression format"
+HOMEPAGE="https://developers.google.com/speed/webp/download"
+SRC_URI="http://downloads.webmproject.org/releases/webp/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0/7" # subslot = libwebp soname version
+[[ "${PV}" = *_rc* ]] || \
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~x64-macos ~m68k-mint"
+IUSE="cpu_flags_x86_avx2 cpu_flags_x86_sse2 cpu_flags_x86_sse4_1 gif +jpeg neon opengl +png static-libs swap-16bit-csp tiff"
+
+# TODO: dev-lang/swig bindings in swig/ subdirectory
+RDEPEND="gif? ( media-libs/giflib:= )
+	jpeg? ( virtual/jpeg:0= )
+	opengl? (
+		media-libs/freeglut
+		virtual/opengl
+		)
+	png? ( media-libs/libpng:0= )
+	tiff? ( media-libs/tiff:0= )"
+DEPEND="${RDEPEND}"
+
+S="${WORKDIR}/${MY_P}"
+
+ECONF_SOURCE="${S}"
+
+src_prepare() {
+	default
+
+	# Fix libtool relinking, bug 499270.
+	#elibtoolize
+	eautoreconf
+}
+
+multilib_src_configure() {
+	local args=(
+		--enable-libwebpmux
+		--enable-libwebpdemux
+		--enable-libwebpdecoder
+		$(use_enable static-libs static)
+		$(use_enable swap-16bit-csp)
+		$(use_enable jpeg)
+		$(use_enable png)
+		$(use_enable opengl gl)
+		$(use_enable tiff)
+
+		$(use_enable cpu_flags_x86_avx2 avx2)
+		$(use_enable cpu_flags_x86_sse2 sse2)
+		$(use_enable cpu_flags_x86_sse4_1 sse4.1)
+		$(use_enable neon)
+
+		# Only used for gif2webp binary wrt #486646
+		$(multilib_native_use_enable gif)
+	)
+
+	econf "${args[@]}"
+}
+
+multilib_src_install() {
+	emake DESTDIR="${D}" install
+}
+
+multilib_src_install_all() {
+	find "${ED}" -name "*.la" -delete || die
+	dodoc AUTHORS ChangeLog doc/*.txt NEWS README{,.mux}
+}