gentoo auto-resync : 02:09:2024 - 12:28:17

2 files changed, 211 insertions, 0 deletions

diff --git a/media-libs/libsdl2/Manifest b/media-libs/libsdl2/Manifest
index 26e177b214d0..5b33aa173ef5 100644
--- a/media-libs/libsdl2/Manifest
+++ b/media-libs/libsdl2/Manifest
@@ -4,9 +4,11 @@ DIST SDL2-2.28.5.tar.gz 7345355 BLAKE2B c96481bc02af6b6d077247238f7e46b0e3ec2166
 DIST SDL2-2.30.2.tar.gz 7426565 BLAKE2B 258084c6965281951b78619d7ebcd80b0f6873f54ded93d35b6b898f0533fef9a29bef4a8babe53df50bc589b0565b3a3b1378a930b43fdce575c4a5baa70864 SHA512 19316bb4c483a8c4be2140b70d906b7767beabada481873217a9207bd41e79c1854a837e1394325f59795da010f5344f791a7973a846b8189e3f9b662f408aca
 DIST SDL2-2.30.3.tar.gz 7425677 BLAKE2B 9918723bc3a0bc3abfc6d47b4fc7eeabcafdc9925ee93e4f31b3637e843a5b060ae61aef9b93743340a9df914248cff510e5d38e758e032b5ed4df9eed587746 SHA512 75ddea9ac3c2130e9f6036b4718dbe3d9d1b40dab3cd48d3d488d5a397dd0c226c0573bf18d82eb41498800accf045e259d2ae305f069fad7b34e47a017f2372
 DIST SDL2-2.30.6.tar.gz 7524883 BLAKE2B 9e253d107c2af7ff0f7f67968be2cffc2358fbabd26d4ec46454a11ac53b64ac24a620947601901e43e470ad6b2bb89e273d04c9c2de12c6ab1dd6a4f78733ff SHA512 c73fd0b52e77d248a5dc2808a660ded9e708b87f68f677970da71e9b4a25ec60cf52f319b8b014ced7c9363560f2360262c04551a895f0f83ee62c3feeafba47
+DIST SDL2-2.30.7.tar.gz 7525092 BLAKE2B a494ca856f43009957f62ef4e5d401777c2d1f8518e4cc1a1b9fc9a2efedc5031b9cb5e2965aeb7347821310153cf3abc4c898dd493962fb268c5c55081ed7c3 SHA512 1a16c10f500dea97bd4e4ca5f560fe4ab8e746c975d30751b7cf567868743d105ce84055d480e4c18b290adac485e67d1bb14ae1719644d6e42223d96f299a16
 EBUILD libsdl2-2.28.5-r1.ebuild 7385 BLAKE2B 74314d489f7d6b6d87223779f4a559492ad50b2efe9731b7696149756ddce40d3a193eb72a405d38cff3a88bf26faf2d65339a874f7e68c0316e0d91d5c0aaf4 SHA512 82e8160883795b7dd0a996bd86fad3dcc0c56847e531ecaea28f4edf0a7e449931589697b9e0eeb10328ca768b8be2081b3b9065d49167286d99b77ecb20bd7e
 EBUILD libsdl2-2.28.5-r2.ebuild 7516 BLAKE2B da5807c940561d2e8174c9e2d2a2d46d59c73114a33f257f3818d8e489830a9ed5762810a5961161eb1763ae38411f6a70645198328430135a39e9b5759eba56 SHA512 e6719488f5bcbfff93338421a49cfb0e0c1c1a7546fd42d02e8d18e22a89b880ce73e743b587f06301a6303f95f46f9d2b42af01aa42c79530b1d74770c01242
 EBUILD libsdl2-2.30.2-r1.ebuild 5733 BLAKE2B 1273e09d22913088d85bea63a86e028c519fc9d2b3daa7fd692ac791dba38652675a0bd526f3cb15c58313e65b9ade40fe67df910bef714df94f607cc666f04d SHA512 14830fad12f2af6ee408e94d2f5f7baece0c6028df4e48dae97594b9833ee3da02b80e1c0da148c574d169f42a414cd30e29f21101a132b7b33cdc122a80c127
 EBUILD libsdl2-2.30.3.ebuild 5869 BLAKE2B 0d0d966f51d216b50c7123bb8a888dd059ff4dbd36e78a1b53a52fa0ed39c38d518ddc9da27ea26f12ee655a4d3335a0fc2eb9612c7efca62767fb1b20f73c60 SHA512 b288f5412d8b50816132f98777f4a34d0859270214dff6f68fd734c99316ec2a7a83de8d9c0e90d8362163583c587a35683caf8ebabb71cd626d839b0c992b47
 EBUILD libsdl2-2.30.6.ebuild 5869 BLAKE2B 0d0d966f51d216b50c7123bb8a888dd059ff4dbd36e78a1b53a52fa0ed39c38d518ddc9da27ea26f12ee655a4d3335a0fc2eb9612c7efca62767fb1b20f73c60 SHA512 b288f5412d8b50816132f98777f4a34d0859270214dff6f68fd734c99316ec2a7a83de8d9c0e90d8362163583c587a35683caf8ebabb71cd626d839b0c992b47
+EBUILD libsdl2-2.30.7.ebuild 5869 BLAKE2B 0d0d966f51d216b50c7123bb8a888dd059ff4dbd36e78a1b53a52fa0ed39c38d518ddc9da27ea26f12ee655a4d3335a0fc2eb9612c7efca62767fb1b20f73c60 SHA512 b288f5412d8b50816132f98777f4a34d0859270214dff6f68fd734c99316ec2a7a83de8d9c0e90d8362163583c587a35683caf8ebabb71cd626d839b0c992b47
 MISC metadata.xml 1945 BLAKE2B 0f4c4a1526296bfbef001169c45626f0393cfcb6f5003d3d644c1ff1ef0197fdd38ddc2f16f1c1590ef895448bd6aa85ea3619a31487609d9ea2569077decd64 SHA512 d25c6e3b2cf3055f2faf71d926d5ad01c5b528f1349284dc3097607015ed93c70116223db0078d8ae764b598bc13a99f1b82cebe1e65206ea737508bdede12df
diff --git a/media-libs/libsdl2/libsdl2-2.30.7.ebuild b/media-libs/libsdl2/libsdl2-2.30.7.ebuild
new file mode 100644
index 000000000000..ce051d586a9f
--- /dev/null
+++ b/media-libs/libsdl2/libsdl2-2.30.7.ebuild
@@ -0,0 +1,209 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake-multilib flag-o-matic
+
+MY_P="SDL2-${PV}"
+DESCRIPTION="Simple Direct Media Layer"
+HOMEPAGE="https://www.libsdl.org/"
+SRC_URI="https://www.libsdl.org/release/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="ZLIB"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+IUSE="alsa aqua cpu_flags_ppc_altivec cpu_flags_x86_3dnow cpu_flags_x86_mmx cpu_flags_x86_sse cpu_flags_x86_sse2 cpu_flags_x86_sse3 custom-cflags dbus doc fcitx4 gles1 gles2 +haptic ibus jack +joystick kms libsamplerate nas opengl oss pipewire pulseaudio sndio +sound static-libs test +threads udev +video vulkan wayland X xscreensaver"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="
+	alsa? ( sound )
+	fcitx4? ( dbus )
+	gles1? ( video )
+	gles2? ( video )
+	haptic? ( joystick )
+	ibus? ( dbus )
+	jack? ( sound )
+	nas? ( sound )
+	opengl? ( video )
+	pulseaudio? ( sound )
+	sndio? ( sound )
+	test? ( static-libs )
+	vulkan? ( video )
+	wayland? ( gles2 )
+	xscreensaver? ( X )
+"
+
+COMMON_DEPEND="
+	virtual/libiconv[${MULTILIB_USEDEP}]
+	alsa? ( >=media-libs/alsa-lib-1.0.27.2[${MULTILIB_USEDEP}] )
+	dbus? ( >=sys-apps/dbus-1.6.18-r1[${MULTILIB_USEDEP}] )
+	ibus? ( app-i18n/ibus )
+	jack? ( virtual/jack[${MULTILIB_USEDEP}] )
+	kms? (
+		>=x11-libs/libdrm-2.4.82[${MULTILIB_USEDEP}]
+		>=media-libs/mesa-9.0.0[${MULTILIB_USEDEP},gbm(+)]
+	)
+	libsamplerate? ( media-libs/libsamplerate[${MULTILIB_USEDEP}] )
+	nas? (
+		>=media-libs/nas-1.9.4[${MULTILIB_USEDEP}]
+		>=x11-libs/libXt-1.1.4[${MULTILIB_USEDEP}]
+	)
+	opengl? (
+		>=virtual/opengl-7.0-r1[${MULTILIB_USEDEP}]
+		>=virtual/glu-9.0-r1[${MULTILIB_USEDEP}]
+	)
+	pipewire? ( media-video/pipewire:=[${MULTILIB_USEDEP}] )
+	pulseaudio? ( media-libs/libpulse[${MULTILIB_USEDEP}] )
+	sndio? ( media-sound/sndio:=[${MULTILIB_USEDEP}] )
+	udev? ( >=virtual/libudev-208:=[${MULTILIB_USEDEP}] )
+	wayland? (
+		>=dev-libs/wayland-1.20[${MULTILIB_USEDEP}]
+		gui-libs/libdecor[${MULTILIB_USEDEP}]
+		>=media-libs/mesa-9.1.6[${MULTILIB_USEDEP},egl(+),gles2(+),wayland]
+		>=x11-libs/libxkbcommon-0.2.0[${MULTILIB_USEDEP}]
+	)
+	X? (
+		>=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libXcursor-1.1.14[${MULTILIB_USEDEP}]
+		>=x11-libs/libXext-1.3.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libXfixes-6.0.0[${MULTILIB_USEDEP}]
+		>=x11-libs/libXi-1.7.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libXrandr-1.4.2[${MULTILIB_USEDEP}]
+		xscreensaver? ( >=x11-libs/libXScrnSaver-1.2.2-r1[${MULTILIB_USEDEP}] )
+	)
+"
+RDEPEND="
+	${COMMON_DEPEND}
+	fcitx4? ( app-i18n/fcitx:4 )
+	gles1? ( media-libs/mesa[${MULTILIB_USEDEP},gles1(+)] )
+	gles2? ( media-libs/mesa[${MULTILIB_USEDEP},gles2(+)] )
+	vulkan? ( media-libs/vulkan-loader )
+"
+DEPEND="
+	${COMMON_DEPEND}
+	gles1? ( media-libs/libglvnd )
+	gles2? ( media-libs/libglvnd )
+	ibus? ( dev-libs/glib:2[${MULTILIB_USEDEP}] )
+	test? ( x11-libs/libX11[${MULTILIB_USEDEP}] )
+	vulkan? ( dev-util/vulkan-headers )
+	X? ( x11-base/xorg-proto )
+"
+BDEPEND="
+	virtual/pkgconfig
+	doc? (
+		app-text/doxygen
+		media-gfx/graphviz
+	)
+	wayland? ( >=dev-util/wayland-scanner-1.20 )
+"
+
+MULTILIB_WRAPPED_HEADERS=(
+	/usr/include/SDL2/SDL_config.h
+	/usr/include/SDL2/SDL_platform.h
+	/usr/include/SDL2/begin_code.h
+	/usr/include/SDL2/close_code.h
+)
+
+src_prepare() {
+	cmake_src_prepare
+
+	# Unbundle some headers.
+	rm -r src/video/khronos || die
+	ln -s "${ESYSROOT}/usr/include" src/video/khronos || die
+}
+
+src_configure() {
+	use custom-cflags || strip-flags
+
+	local mycmakeargs=(
+		-DSDL_STATIC=$(usex static-libs)
+		-DSDL_SYSTEM_ICONV=ON
+		-DSDL_GCC_ATOMICS=ON
+		-DSDL_AUDIO=$(usex sound)
+		-DSDL_VIDEO=$(usex video)
+		-DSDL_JOYSTICK=$(usex joystick)
+		-DSDL_HAPTIC=$(usex haptic)
+		-DSDL_POWER=ON
+		-DSDL_FILESYSTEM=ON
+		-DSDL_PTHREADS=$(usex threads)
+		-DSDL_TIMERS=ON
+		-DSDL_FILE=ON
+		-DSDL_LOADSO=ON
+		-DSDL_ASSEMBLY=ON
+		-DSDL_ALTIVEC=$(usex cpu_flags_ppc_altivec)
+		-DSDL_SSEMATH=$(usex cpu_flags_x86_sse)
+		-DSDL_MMX=$(usex cpu_flags_x86_mmx)
+		-DSDL_3DNOW=$(usex cpu_flags_x86_3dnow)
+		-DSDL_SSE=$(usex cpu_flags_x86_sse)
+		-DSDL_SSE2=$(usex cpu_flags_x86_sse2)
+		-DSDL_SSE3=$(usex cpu_flags_x86_sse3)
+		-DSDL_OSS=$(usex oss)
+		-DSDL_ALSA=$(usex alsa)
+		-DSDL_ALSA_SHARED=OFF
+		-DSDL_JACK=$(usex jack)
+		-DSDL_JACK_SHARED=OFF
+		-DSDL_ESD=OFF
+		-DSDL_PIPEWIRE=$(usex pipewire)
+		-DSDL_PIPEWIRE_SHARED=OFF
+		-DSDL_PULSEAUDIO=$(usex pulseaudio)
+		-DSDL_PULSEAUDIO_SHARED=OFF
+		-DSDL_ARTS=OFF
+		-DSDL_LIBSAMPLERATE=$(usex libsamplerate)
+		-DSDL_LIBSAMPLERATE_SHARED=OFF
+		-DSDL_WERROR=OFF
+		-DSDL_NAS=$(usex nas)
+		-DSDL_NAS_SHARED=OFF
+		-DSDL_SNDIO=$(usex sndio)
+		-DSDL_SNDIO_SHARED=OFF
+		-DSDL_DISKAUDIO=$(usex sound)
+		-DSDL_DUMMYAUDIO=$(usex sound)
+		-DSDL_WAYLAND=$(usex wayland)
+		-DSDL_WAYLAND_SHARED=OFF
+		-DSDL_WAYLAND_LIBDECOR=$(usex wayland)
+		-DSDL_WAYLAND_LIBDECOR_SHARED=OFF
+		-DSDL_RPI=OFF
+		-DSDL_X11=$(usex X)
+		-DSDL_X11_SHARED=OFF
+		-DSDL_X11_XSCRNSAVER=$(usex xscreensaver)
+		-DSDL_COCOA=$(usex aqua)
+		-DSDL_DIRECTFB=OFF
+		-DSDL_FUSIONSOUND=OFF
+		-DSDL_KMSDRM=$(usex kms)
+		-DSDL_KMSDRM_SHARED=OFF
+		-DSDL_DUMMYVIDEO=$(usex video)
+		-DSDL_OPENGL=$(usex opengl)
+		-DSDL_OPENGLES=$(use gles1 || use gles2 && echo ON || echo OFF)
+		-DSDL_VULKAN=$(usex vulkan)
+		-DSDL_LIBUDEV=$(usex udev)
+		-DSDL_DBUS=$(usex dbus)
+		-DSDL_IBUS=$(usex ibus)
+		-DSDL_CCACHE=OFF
+		-DSDL_DIRECTX=OFF
+		-DSDL_RPATH=OFF
+		-DSDL_VIDEO_RENDER_D3D=OFF
+		-DSDL_TESTS=$(usex test)
+	)
+	cmake-multilib_src_configure
+}
+
+src_compile() {
+	multilib-minimal_src_compile
+
+	if use doc; then
+		cd docs || die
+		doxygen || die
+	fi
+}
+
+src_test() {
+	unset SDL_GAMECONTROLLERCONFIG SDL_GAMECONTROLLER_USE_BUTTON_LABELS
+	cmake-multilib_src_test
+}
+
+multilib_src_install_all() {
+	rm -r "${ED}"/usr/share/licenses/ || die
+	dodoc {BUGS,CREDITS,README-SDL,TODO,WhatsNew}.txt README.md docs/README*.md
+	use doc && dodoc -r docs/output/html/
+}