gentoo auto-resync : 05:01:2025 - 06:31:57edge

2 files changed, 210 insertions, 0 deletions

diff --git a/media-libs/libsdl2/Manifest b/media-libs/libsdl2/Manifest
index 1ed10ff46d40..17f5a3ff0cd4 100644
--- a/media-libs/libsdl2/Manifest
+++ b/media-libs/libsdl2/Manifest
@@ -1,7 +1,9 @@
 AUX libsdl2-2.0.16-static-libs.patch 2118 BLAKE2B 836fabd17be1520ad76baaf92a0ad357093bc08a5c1767edb1c81c9099fd27aadbf0525ab0666a560a3c728983f425864f1f513693801a8fa50edde5d32a3703 SHA512 f578e5ab1852705cfad4bf8b4a8aa36fb34637f3b26b83a9821716d08fc1152d7ea18daea623f540c860cd7a7566c4b8902b2cac2ae6d541e36e7bd15363d58a
 AUX libsdl2-2.28.5-fix-libdecor-0.2.patch 1195 BLAKE2B cd07f864e8091796d20ade4f4fd9c62bd61d684da62e1639260b4737bf083f0828bcba116dc45f2db81dc3117853660e8fcaf143ffb192b6b30f41099d3aa256 SHA512 4291d5f8ca2370698ddb795c77673b110f802ab9c8c19213064b5e1268b5a92262b4cd065cf96c277a28ff319e8562ba6b7e74f5c53f0a60e22502d1b1b8fb03
 DIST SDL2-2.28.5.tar.gz 7345355 BLAKE2B c96481bc02af6b6d077247238f7e46b0e3ec216664584add29cafb0a91d06dc6ddc637a01519dbd7182d4fa59cfaf26ad6733f72583021cf65849416f9c4b698 SHA512 12593eb78fcca877a8dfb78cf21a4e6feba7dc87c964de378ac462b36d8e41ecb587222cb41d5f56dd35b838e1b9867b8ae0cf2f4d2a01afaf23ac8c11edc84d
+DIST SDL2-2.30.11.tar.gz 7585207 BLAKE2B e6038cbf79bec299fae9cfdc4b84ff3e28343abe782942af17e052d7da93111ea04a2ae15b063bfa0ad0d13a1810890dd29d895189f7f417f1bccce715badde1 SHA512 cd4c040ebe4ec74250e32b401a292658353721dda30ad1066522b2a9de9a07560313978880a0bad7e7f5103cc14278fcbe27dbc5a188189e7fb6f097e7308550
 DIST SDL2-2.30.7.tar.gz 7525092 BLAKE2B a494ca856f43009957f62ef4e5d401777c2d1f8518e4cc1a1b9fc9a2efedc5031b9cb5e2965aeb7347821310153cf3abc4c898dd493962fb268c5c55081ed7c3 SHA512 1a16c10f500dea97bd4e4ca5f560fe4ab8e746c975d30751b7cf567868743d105ce84055d480e4c18b290adac485e67d1bb14ae1719644d6e42223d96f299a16
 EBUILD libsdl2-2.28.5-r3.ebuild 7506 BLAKE2B 06e0b8e280cb2c4da429e9e06751b8da6022a41d795ee71fdd6c01a7da33e4c3de78a3a53f416e57cf045b9a0695b4693ad0983f55ea02b98463a289773976f1 SHA512 bffadfe4c58b2df3b6f3bb31192a04b83061cf7899299388281525690f6cc0897ce10f5c20f2059223b8f3e4829ec0c044a7c3deba87fbae76204f9f57f2a58d
+EBUILD libsdl2-2.30.11.ebuild 5818 BLAKE2B abbc67c1bc5cbb868556ede44d62c8d22c99630d76c9bee8b635e2344e1b49ff45b0a20a055977300d9befaa447f8e55d0af85505d629e137117b7b7b6fb6f65 SHA512 1872c5da27f2a255d8b0c0ec26a0030c4742cf3864303d8a551aa9bf09b7dab65e813c6b3de3be31999433434cd164ab759fcfbbd9987f18e685a8b0759be369
 EBUILD libsdl2-2.30.7-r1.ebuild 5811 BLAKE2B 509a377438a52b19c86b9a5cba987346aad542f3acd13d14b8f95d36d267634161ce3410c4a4baadd55765bac43b2934f6cc7dd104cc0b09494d282ad23c7233 SHA512 9cecce56d7e7bfc0d052cc49c3e932b95334455d83a0b049dff2511cdcfb93885c428a4c59cdb3a7bec34e7bc66867bc911d99e55cb6ce45b3f90e9441473896
 MISC metadata.xml 1942 BLAKE2B 89c75b0790ba1e8c489c4d4d9fca4451a863068a4f75e5b97b408d7aba35fd9ba6ec5a855465588f5c143f09380835b89b637b8fb1e09c6b2391a79ed69144b9 SHA512 9e37d24a408b748fef53884442fe5ac5db548657675e23571705680b157cadcb584a059d7f066765fb68e80bf2ba247b2a01cfa095a465aa9dbf03db0e1c4334
diff --git a/media-libs/libsdl2/libsdl2-2.30.11.ebuild b/media-libs/libsdl2/libsdl2-2.30.11.ebuild
new file mode 100644
index 000000000000..665f62671fd8
--- /dev/null
+++ b/media-libs/libsdl2/libsdl2-2.30.11.ebuild
@@ -0,0 +1,208 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake-multilib flag-o-matic
+
+MY_P="SDL2-${PV}"
+DESCRIPTION="Simple Direct Media Layer"
+HOMEPAGE="https://www.libsdl.org/"
+SRC_URI="https://www.libsdl.org/release/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="ZLIB"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+IUSE="alsa aqua cpu_flags_ppc_altivec cpu_flags_x86_3dnow cpu_flags_x86_mmx cpu_flags_x86_sse cpu_flags_x86_sse2 cpu_flags_x86_sse3 custom-cflags dbus doc fcitx gles1 gles2 +haptic ibus jack +joystick kms libsamplerate nas opengl oss pipewire pulseaudio sndio +sound static-libs test udev +video vulkan wayland X xscreensaver"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="
+	alsa? ( sound )
+	fcitx? ( dbus )
+	gles1? ( video )
+	gles2? ( video )
+	haptic? ( joystick )
+	ibus? ( dbus )
+	jack? ( sound )
+	nas? ( sound )
+	opengl? ( video )
+	pulseaudio? ( sound )
+	sndio? ( sound )
+	test? ( static-libs )
+	vulkan? ( video )
+	wayland? ( gles2 )
+	xscreensaver? ( X )
+"
+
+COMMON_DEPEND="
+	virtual/libiconv[${MULTILIB_USEDEP}]
+	alsa? ( >=media-libs/alsa-lib-1.0.27.2[${MULTILIB_USEDEP}] )
+	dbus? ( >=sys-apps/dbus-1.6.18-r1[${MULTILIB_USEDEP}] )
+	ibus? ( app-i18n/ibus )
+	jack? ( virtual/jack[${MULTILIB_USEDEP}] )
+	kms? (
+		>=x11-libs/libdrm-2.4.82[${MULTILIB_USEDEP}]
+		>=media-libs/mesa-9.0.0[${MULTILIB_USEDEP},gbm(+)]
+	)
+	libsamplerate? ( media-libs/libsamplerate[${MULTILIB_USEDEP}] )
+	nas? (
+		>=media-libs/nas-1.9.4[${MULTILIB_USEDEP}]
+		>=x11-libs/libXt-1.1.4[${MULTILIB_USEDEP}]
+	)
+	opengl? (
+		>=virtual/opengl-7.0-r1[${MULTILIB_USEDEP}]
+		>=virtual/glu-9.0-r1[${MULTILIB_USEDEP}]
+	)
+	pipewire? ( media-video/pipewire:=[${MULTILIB_USEDEP}] )
+	pulseaudio? ( media-libs/libpulse[${MULTILIB_USEDEP}] )
+	sndio? ( media-sound/sndio:=[${MULTILIB_USEDEP}] )
+	udev? ( >=virtual/libudev-208:=[${MULTILIB_USEDEP}] )
+	wayland? (
+		>=dev-libs/wayland-1.20[${MULTILIB_USEDEP}]
+		gui-libs/libdecor[${MULTILIB_USEDEP}]
+		>=media-libs/mesa-9.1.6[${MULTILIB_USEDEP},egl(+),gles2(+),wayland]
+		>=x11-libs/libxkbcommon-0.2.0[${MULTILIB_USEDEP}]
+	)
+	X? (
+		>=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libXcursor-1.1.14[${MULTILIB_USEDEP}]
+		>=x11-libs/libXext-1.3.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libXfixes-6.0.0[${MULTILIB_USEDEP}]
+		>=x11-libs/libXi-1.7.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libXrandr-1.4.2[${MULTILIB_USEDEP}]
+		xscreensaver? ( >=x11-libs/libXScrnSaver-1.2.2-r1[${MULTILIB_USEDEP}] )
+	)
+"
+RDEPEND="
+	${COMMON_DEPEND}
+	fcitx? ( app-i18n/fcitx:* )
+	gles1? ( media-libs/mesa[${MULTILIB_USEDEP},gles1(+)] )
+	gles2? ( media-libs/mesa[${MULTILIB_USEDEP},gles2(+)] )
+	vulkan? ( media-libs/vulkan-loader )
+"
+DEPEND="
+	${COMMON_DEPEND}
+	gles1? ( media-libs/libglvnd )
+	gles2? ( media-libs/libglvnd )
+	ibus? ( dev-libs/glib:2[${MULTILIB_USEDEP}] )
+	test? ( x11-libs/libX11[${MULTILIB_USEDEP}] )
+	vulkan? ( dev-util/vulkan-headers )
+	X? ( x11-base/xorg-proto )
+"
+BDEPEND="
+	virtual/pkgconfig
+	doc? (
+		app-text/doxygen
+		media-gfx/graphviz
+	)
+	wayland? ( >=dev-util/wayland-scanner-1.20 )
+"
+
+MULTILIB_WRAPPED_HEADERS=(
+	/usr/include/SDL2/SDL_config.h
+	/usr/include/SDL2/SDL_platform.h
+	/usr/include/SDL2/begin_code.h
+	/usr/include/SDL2/close_code.h
+)
+
+src_prepare() {
+	cmake_src_prepare
+
+	# Unbundle some headers.
+	rm -r src/video/khronos || die
+	ln -s "${ESYSROOT}/usr/include" src/video/khronos || die
+}
+
+src_configure() {
+	use custom-cflags || strip-flags
+
+	local mycmakeargs=(
+		-DSDL_STATIC=$(usex static-libs)
+		-DSDL_SYSTEM_ICONV=ON
+		-DSDL_GCC_ATOMICS=ON
+		-DSDL_AUDIO=$(usex sound)
+		-DSDL_VIDEO=$(usex video)
+		-DSDL_JOYSTICK=$(usex joystick)
+		-DSDL_HAPTIC=$(usex haptic)
+		-DSDL_POWER=ON
+		-DSDL_FILESYSTEM=ON
+		-DSDL_TIMERS=ON
+		-DSDL_FILE=ON
+		-DSDL_LOADSO=ON
+		-DSDL_ASSEMBLY=ON
+		-DSDL_ALTIVEC=$(usex cpu_flags_ppc_altivec)
+		-DSDL_SSEMATH=$(usex cpu_flags_x86_sse)
+		-DSDL_MMX=$(usex cpu_flags_x86_mmx)
+		-DSDL_3DNOW=$(usex cpu_flags_x86_3dnow)
+		-DSDL_SSE=$(usex cpu_flags_x86_sse)
+		-DSDL_SSE2=$(usex cpu_flags_x86_sse2)
+		-DSDL_SSE3=$(usex cpu_flags_x86_sse3)
+		-DSDL_OSS=$(usex oss)
+		-DSDL_ALSA=$(usex alsa)
+		-DSDL_ALSA_SHARED=OFF
+		-DSDL_JACK=$(usex jack)
+		-DSDL_JACK_SHARED=OFF
+		-DSDL_ESD=OFF
+		-DSDL_PIPEWIRE=$(usex pipewire)
+		-DSDL_PIPEWIRE_SHARED=OFF
+		-DSDL_PULSEAUDIO=$(usex pulseaudio)
+		-DSDL_PULSEAUDIO_SHARED=OFF
+		-DSDL_ARTS=OFF
+		-DSDL_LIBSAMPLERATE=$(usex libsamplerate)
+		-DSDL_LIBSAMPLERATE_SHARED=OFF
+		-DSDL_WERROR=OFF
+		-DSDL_NAS=$(usex nas)
+		-DSDL_NAS_SHARED=OFF
+		-DSDL_SNDIO=$(usex sndio)
+		-DSDL_SNDIO_SHARED=OFF
+		-DSDL_DISKAUDIO=$(usex sound)
+		-DSDL_DUMMYAUDIO=$(usex sound)
+		-DSDL_WAYLAND=$(usex wayland)
+		-DSDL_WAYLAND_SHARED=OFF
+		-DSDL_WAYLAND_LIBDECOR=$(usex wayland)
+		-DSDL_WAYLAND_LIBDECOR_SHARED=OFF
+		-DSDL_RPI=OFF
+		-DSDL_X11=$(usex X)
+		-DSDL_X11_SHARED=OFF
+		-DSDL_X11_XSCRNSAVER=$(usex xscreensaver)
+		-DSDL_COCOA=$(usex aqua)
+		-DSDL_DIRECTFB=OFF
+		-DSDL_FUSIONSOUND=OFF
+		-DSDL_KMSDRM=$(usex kms)
+		-DSDL_KMSDRM_SHARED=OFF
+		-DSDL_DUMMYVIDEO=$(usex video)
+		-DSDL_OPENGL=$(usex opengl)
+		-DSDL_OPENGLES=$(use gles1 || use gles2 && echo ON || echo OFF)
+		-DSDL_VULKAN=$(usex vulkan)
+		-DSDL_LIBUDEV=$(usex udev)
+		-DSDL_DBUS=$(usex dbus)
+		-DSDL_IBUS=$(usex ibus)
+		-DSDL_CCACHE=OFF
+		-DSDL_DIRECTX=OFF
+		-DSDL_RPATH=OFF
+		-DSDL_VIDEO_RENDER_D3D=OFF
+		-DSDL_TESTS=$(usex test)
+	)
+	cmake-multilib_src_configure
+}
+
+src_compile() {
+	multilib-minimal_src_compile
+
+	if use doc; then
+		cd docs || die
+		doxygen || die
+	fi
+}
+
+src_test() {
+	unset SDL_GAMECONTROLLERCONFIG SDL_GAMECONTROLLER_USE_BUTTON_LABELS
+	cmake-multilib_src_test
+}
+
+multilib_src_install_all() {
+	rm -r "${ED}"/usr/share/licenses/ || die
+	dodoc {BUGS,CREDITS,README-SDL,TODO,WhatsNew}.txt README.md docs/README*.md
+	use doc && dodoc -r docs/output/html/
+}