gentoo resync : 03.11.2018

3 files changed, 99 insertions, 21 deletions

diff --git a/media-libs/libmtp/Manifest b/media-libs/libmtp/Manifest
index 7b2162688e7a..03f6a7fb1c5d 100644
--- a/media-libs/libmtp/Manifest
+++ b/media-libs/libmtp/Manifest
@@ -1,6 +1,8 @@
 DIST libmtp-1.1.14.tar.gz 804354 BLAKE2B 8a5ec431b3a3c1445b3ae62dd0f6ebee36a473ce3d7da07400263434d6e1be49624b8c807bce015f9e55d450f9e25eb2dcf0831c639b97e39cb900ac4d62f81c SHA512 337d259462cf9700fe5a5f09b38f4652045ee71249d54562661362e6d0ec7fe087ab77ec68d443e4fb84839a8ad9dc686c207d723ab47bc1a542dd0a71b294b1
 DIST libmtp-1.1.15.tar.gz 805983 BLAKE2B f464c58a9844706ecc066a4a744b525ac6e8020ab80e35b01eab2813562ea1452deb5e6fb4477eb243b6631c24f8bc11887ec35279cb6cd89e1a459aca6b36cb SHA512 c85f47ef4e05d7f5b47d06463ca97c123fa068c4b7369aeba496cb1cfa03f0148b3ba73feed7da96269ba94b76b4b81858ee4bda5af67b0aac3b07fe39b5354a
+DIST libmtp-1.1.16.tar.gz 820516 BLAKE2B debc0755b91f44a878c4a5d4eb8d23c92ac17a80cf59ca13ada80bc1884ee7ab771153252258e33c834aba718a064d9e9a1b4618b3e0abe81bbffdfc7e5a2c88 SHA512 0540271930c1c932c5d06dcdd30142d407a4fadd022b195e8339d614fa3ec9b050605bf013b28ac6451f4dfcddf7add949c928acb1382802ab5fd6311c1628a0
 EBUILD libmtp-1.1.14.ebuild 1597 BLAKE2B fb0ff0ba1478dd9c6d8b1e6be56f88d288a0cce2294ff271a1c392881c009dbf41ee457ff8a97282e76faede81a35296fd04507d64c9bd5cdb425e593e50df93 SHA512 ed6d56fa731f121082cc27e7790530ef4c4a02885685a8f0fdaea693c963d0b9a18c6b74bba8772c4965d2d910590131cf4da96fdc1f35568c7135f4da11ccea
 EBUILD libmtp-1.1.15.ebuild 1598 BLAKE2B 77884c0c2d1e4ff58abf53d55e8fcc290aaa053fad947133a24692dde07937cc5d6503aaa6d31723e0996fa3a2f182e37be7766b204276b3324f5dc02bf78f7b SHA512 066fb35601f31f9d610b8951ae7789cda8a8b8f2cc8d77db4dface52bca8dd47d1005b524809fd3dcbde4f5bb3c02dd184bf820f3d24166daf1aa16bed40bf81
-EBUILD libmtp-9999.ebuild 1603 BLAKE2B 68dbef72c8b95ddf2e6f483c4f29edd373190900750f1fe8b14ec9136877fff8c8905e9fca6065daeb447b0ce60359e1f828b92fd457f665a47ce4cc58ef4a66 SHA512 19295d09b442b0fd7bc5961cc38a587edc9f41e0d8a3656f92628db71cf4f542e27af35a2f23535678fba7d76dbe1fa926a58bcf3fdbe612dcf8db7a527c601a
+EBUILD libmtp-1.1.16.ebuild 1628 BLAKE2B bad7949d12c89c03d2d2ab92e83dd19943998aedf2b031f2ce0e60f811653654670388615c43177466fa10110ec077a83c95131df557584197f107624063bd49 SHA512 7942bb95447ea68b21c7da14a2236ba05ea73316350b3a7dfc40db4603a9f16311c3ab0d795278efcbf3550306009209239bdd53a13fec784d4a8ce2d1ca3da7
+EBUILD libmtp-9999.ebuild 1628 BLAKE2B bad7949d12c89c03d2d2ab92e83dd19943998aedf2b031f2ce0e60f811653654670388615c43177466fa10110ec077a83c95131df557584197f107624063bd49 SHA512 7942bb95447ea68b21c7da14a2236ba05ea73316350b3a7dfc40db4603a9f16311c3ab0d795278efcbf3550306009209239bdd53a13fec784d4a8ce2d1ca3da7
 MISC metadata.xml 329 BLAKE2B 4d7d938ffffc075084e5d43ca37040cb1612e7d6bdfed9c12d5edb00e0ce536d2d19b070dcd26d64a46a6664985db1f07aed073e2912c3dfc743ff6d55e8d187 SHA512 99fed0095b41d435c1bf82d7fa9c51b03fadc01646d959735693219cbfe2b69f784610fb296d5f1fdc8bb7c84dca4dbf3718effd350745de6483f8a8f9407d6c
diff --git a/media-libs/libmtp/libmtp-1.1.16.ebuild b/media-libs/libmtp/libmtp-1.1.16.ebuild
new file mode 100644
index 000000000000..412b5b9c4da3
--- /dev/null
+++ b/media-libs/libmtp/libmtp-1.1.16.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit udev user
+
+if [[ ${PV} == 9999* ]]; then
+	EGIT_REPO_URI="https://git.code.sf.net/p/${PN}/code"
+	inherit autotools git-r3
+else
+	SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~x86 ~amd64-fbsd ~x86-fbsd"
+fi
+
+DESCRIPTION="Implementation of Microsoft's Media Transfer Protocol (MTP)"
+HOMEPAGE="http://libmtp.sourceforge.net/"
+
+LICENSE="LGPL-2.1" # LGPL-2+ and LGPL-2.1+ ?
+SLOT="0/9" # Based on SONAME of libmtp shared library
+IUSE="+crypt doc examples static-libs"
+
+RDEPEND="virtual/libusb:1
+	crypt? ( >=dev-libs/libgcrypt-1.5.4:0= )"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	>sys-devel/gettext-0.18.3
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )"
+
+DOCS=( AUTHORS README TODO )
+
+pkg_setup() {
+	enewgroup plugdev
+}
+
+src_prepare() {
+	default
+
+	# ChangeLog says "RETIRING THIS FILE ..pause..  GIT" (Last entry from start of 2011)
+	rm ChangeLog || die
+
+	if [[ ${PV} == 9999* ]]; then
+		if [[ -e /usr/share/gettext/config.rpath ]]; then
+			cp /usr/share/gettext/config.rpath . || die
+		else
+			touch config.rpath || die # This is from upstream autogen.sh
+		fi
+		eautoreconf
+	fi
+}
+
+src_configure() {
+	local myeconfargs=(
+		$(use_enable crypt mtpz)
+		$(use_enable doc doxygen)
+		$(use_enable static-libs static)
+		--with-udev="$(get_udevdir)"
+		--with-udev-group=plugdev
+		--with-udev-mode=0660
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	find "${ED}" -name "*.la" -delete || die
+
+	if use examples; then
+		docinto examples
+		dodoc examples/*.{c,h,sh}
+	fi
+}
diff --git a/media-libs/libmtp/libmtp-9999.ebuild b/media-libs/libmtp/libmtp-9999.ebuild
index b009b4abaff4..412b5b9c4da3 100644
--- a/media-libs/libmtp/libmtp-9999.ebuild
+++ b/media-libs/libmtp/libmtp-9999.ebuild
@@ -1,18 +1,19 @@
-# Copyright 1999-2017 Gentoo Foundation
+# Copyright 1999-2018 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=6
-inherit eutils udev user
+EAPI=7
+
+inherit udev user
 
 if [[ ${PV} == 9999* ]]; then
-	EGIT_REPO_URI="git://git.code.sf.net/p/${PN}/code"
+	EGIT_REPO_URI="https://git.code.sf.net/p/${PN}/code"
 	inherit autotools git-r3
 else
 	SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
 	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~x86 ~amd64-fbsd ~x86-fbsd"
 fi
 
-DESCRIPTION="An implementation of Microsoft's Media Transfer Protocol (MTP)"
+DESCRIPTION="Implementation of Microsoft's Media Transfer Protocol (MTP)"
 HOMEPAGE="http://libmtp.sourceforge.net/"
 
 LICENSE="LGPL-2.1" # LGPL-2+ and LGPL-2.1+ ?
@@ -21,11 +22,13 @@ IUSE="+crypt doc examples static-libs"
 
 RDEPEND="virtual/libusb:1
 	crypt? ( >=dev-libs/libgcrypt-1.5.4:0= )"
-DEPEND="${RDEPEND}
+DEPEND="${RDEPEND}"
+BDEPEND="
+	>sys-devel/gettext-0.18.3
 	virtual/pkgconfig
 	doc? ( app-doc/doxygen )"
 
-DOCS="AUTHORS README TODO"
+DOCS=( AUTHORS README TODO )
 
 pkg_setup() {
 	enewgroup plugdev
@@ -35,33 +38,33 @@ src_prepare() {
 	default
 
 	# ChangeLog says "RETIRING THIS FILE ..pause..  GIT" (Last entry from start of 2011)
-	rm -f ChangeLog
+	rm ChangeLog || die
 
 	if [[ ${PV} == 9999* ]]; then
-		local crpthf=config.rpath
-		local crpthd=/usr/share/gettext/${crpthf}
-		if has_version '>sys-devel/gettext-0.18.3' && [[ -e ${crpthd} ]]; then
-			cp "${crpthd}" .
+		if [[ -e /usr/share/gettext/config.rpath ]]; then
+			cp /usr/share/gettext/config.rpath . || die
 		else
-			touch ${crpthf} # This is from upstream autogen.sh
+			touch config.rpath || die # This is from upstream autogen.sh
 		fi
 		eautoreconf
 	fi
 }
 
 src_configure() {
-	econf \
-		$(use_enable static-libs static) \
-		$(use_enable doc doxygen) \
-		$(use_enable crypt mtpz) \
-		--with-udev="$(get_udevdir)" \
-		--with-udev-group=plugdev \
+	local myeconfargs=(
+		$(use_enable crypt mtpz)
+		$(use_enable doc doxygen)
+		$(use_enable static-libs static)
+		--with-udev="$(get_udevdir)"
+		--with-udev-group=plugdev
 		--with-udev-mode=0660
+	)
+	econf "${myeconfargs[@]}"
 }
 
 src_install() {
 	default
-	prune_libtool_files --all
+	find "${ED}" -name "*.la" -delete || die
 
 	if use examples; then
 		docinto examples