gentoo resync : 25.03.2022

4 files changed, 195 insertions, 0 deletions

diff --git a/media-libs/libjxl/Manifest b/media-libs/libjxl/Manifest
new file mode 100644
index 000000000000..11db8a9376a7
--- /dev/null
+++ b/media-libs/libjxl/Manifest
@@ -0,0 +1,4 @@
+DIST libjxl-0.7.0_pre20220311.tar.gz 17322724 BLAKE2B a3cf970ea3db67e0890e94a5c74ea66610d4fed608fa3d079e6934a1d5f2bdc3ef4264c1df85e4b4efcd22c060087c712009f6c4a6b69a41f6e96ff3674c6de5 SHA512 f3e46ddea462b31de6df3c615c3cd628adc58c7ff41588e2ec4cc8929590c9272603a66ed4620b9ba550d85b3d1a6da3f51b1c4f8650ef8901347fea8af5d474
+EBUILD libjxl-0.7.0_pre20220311.ebuild 2041 BLAKE2B df2cf000bbea7746788b04b88c2826dd10d1be2998f856746a15dc0af44e7436f506be0fc8f5254e52df79e3e5e578cefc1c6837bbc59f5f7f7847c4b36607a2 SHA512 7f65d81181a3c4472c8f9686ba504ffa524f1ee331b6999e5ac2c1f3ed9be33a9e70b9e295bf4496cfff9f8557991cf962829aae25b20e3d479019f7fc314bfc
+EBUILD libjxl-9999.ebuild 2007 BLAKE2B 48c2a0965cc8db89d318f616fc93128e9e998f5535a74dcf3235a423adc04408972edee79a046b868958d39e83a2c2508e345d5af544cd709994058810546496 SHA512 5ab1f5b1dd76cef89ba945e5c3ed6b8837c87f137fedb60be68591dfe904b1cadeae27806dfd409151d698146ae52a0014b676ccc9489c8e281fa18de308025c
+MISC metadata.xml 736 BLAKE2B b4c49d06f4888fe4714add21be0d8c8b0e5961a03307165384692a07dda463cc0438dfe5a99a878555e5d15f0ad56fe4c66c4dd39c90603147150b4d9d3e088b SHA512 feb1910542331c2c3e8769e172081d59c20bfa082cb353787cb718dbd562114210e5da38c5dd87bba9f11ee5756f426c71b835cd178c5d2bd7bfd661cbeb10ce
diff --git a/media-libs/libjxl/libjxl-0.7.0_pre20220311.ebuild b/media-libs/libjxl/libjxl-0.7.0_pre20220311.ebuild
new file mode 100644
index 000000000000..1afe0678670a
--- /dev/null
+++ b/media-libs/libjxl/libjxl-0.7.0_pre20220311.ebuild
@@ -0,0 +1,87 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CMAKE_ECLASS=cmake
+inherit cmake-multilib xdg
+
+DESCRIPTION="JPEG XL image format reference implementation"
+HOMEPAGE="https://github.com/libjxl/libjxl"
+
+SRC_URI="https://api.github.com/repos/libjxl/libjxl/tarball/3f8e77fcfabe8ca8ddee6be4e662de525667c570 -> ${P}.tar.gz"
+KEYWORDS="~amd64 ~x86"
+
+LICENSE="BSD"
+SLOT="0"
+IUSE="examples openexr"
+
+DEPEND="app-arch/brotli:=[${MULTILIB_USEDEP}]
+	dev-cpp/gflags:=[${MULTILIB_USEDEP}]
+	>=dev-cpp/highway-0.16.0[${MULTILIB_USEDEP}]
+	media-libs/giflib:=[${MULTILIB_USEDEP}]
+	media-libs/lcms:=[${MULTILIB_USEDEP}]
+	media-libs/libpng:=[${MULTILIB_USEDEP}]
+	sys-libs/zlib[${MULTILIB_USEDEP}]
+	virtual/jpeg[${MULTILIB_USEDEP}]
+	x11-misc/shared-mime-info
+	openexr? ( media-libs/openexr:= )
+"
+
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}/libjxl-libjxl-3f8e77f"
+
+multilib_src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_SKIP_RPATH=ON
+		-DBUILD_TESTING=OFF
+		-DJPEGXL_ENABLE_BENCHMARK=OFF
+		-DJPEGXL_ENABLE_COVERAGE=OFF
+		-DJPEGXL_ENABLE_FUZZERS=OFF
+		-DJPEGXL_ENABLE_SJPEG=OFF
+		-DJPEGXL_WARNINGS_AS_ERRORS=OFF
+
+		-DJPEGXL_ENABLE_SKCMS=OFF
+		-DJPEGXL_ENABLE_VIEWERS=OFF
+		-DJPEGXL_ENABLE_PLUGINS=OFF
+		-DJPEGXL_FORCE_SYSTEM_BROTLI=ON
+		-DJPEGXL_FORCE_SYSTEM_HWY=ON
+		-DJPEGXL_FORCE_SYSTEM_LCMS2=ON
+		-DJPEGXL_ENABLE_DOXYGEN=OFF
+		-DJPEGXL_ENABLE_MANPAGES=OFF
+		-DJPEGXL_ENABLE_JNI=OFF
+		-DJPEGXL_ENABLE_TCMALLOC=OFF
+	)
+
+	if multilib_is_native_abi; then
+		mycmakeargs+=(
+			-DJPEGXL_ENABLE_TOOLS=ON
+			-DJPEGXL_ENABLE_EXAMPLES=$(usex examples)
+			-DJPEGXL_ENABLE_OPENEXR=$(usex openexr)
+		)
+	else
+		mycmakeargs+=(
+			-DJPEGXL_ENABLE_TOOLS=OFF
+			-DJPEGXL_ENABLE_EXAMPLES=OFF
+			-DJPEGXL_ENABLE_OPENEXR=OFF
+		)
+	fi
+
+	cmake_src_configure
+}
+
+multilib_src_install() {
+	cmake_src_install
+
+	if multilib_is_native_abi; then
+		if use examples; then
+			dobin "${BUILD_DIR}/jxlinfo"
+		fi
+
+		insinto /usr/share/mime/packages
+		doins -r "${S}"/plugins/mime/image-jxl.xml
+	fi
+
+	find "${D}" -name '*.a' -delete || die
+}
diff --git a/media-libs/libjxl/libjxl-9999.ebuild b/media-libs/libjxl/libjxl-9999.ebuild
new file mode 100644
index 000000000000..1a2abbce5e64
--- /dev/null
+++ b/media-libs/libjxl/libjxl-9999.ebuild
@@ -0,0 +1,83 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CMAKE_ECLASS=cmake
+inherit cmake-multilib git-r3 xdg
+
+DESCRIPTION="JPEG XL image format reference implementation"
+HOMEPAGE="https://github.com/libjxl/libjxl"
+
+EGIT_REPO_URI="https://github.com/libjxl/libjxl.git"
+EGIT_SUBMODULES=(third_party/skcms)
+
+LICENSE="BSD"
+SLOT="0"
+IUSE="examples gdk-pixbuf gimp210 openexr"
+
+DEPEND="app-arch/brotli:=[${MULTILIB_USEDEP}]
+	dev-cpp/gflags:=[${MULTILIB_USEDEP}]
+	>=dev-cpp/highway-0.16.0[${MULTILIB_USEDEP}]
+	media-libs/giflib:=[${MULTILIB_USEDEP}]
+	media-libs/libpng:=[${MULTILIB_USEDEP}]
+	sys-libs/zlib[${MULTILIB_USEDEP}]
+	virtual/jpeg[${MULTILIB_USEDEP}]
+	x11-misc/shared-mime-info
+	gdk-pixbuf? (
+		dev-libs/glib:2
+		x11-libs/gdk-pixbuf:2
+	)
+	gimp210? ( >=media-gfx/gimp-2.10.28:0/2 )
+	openexr? ( media-libs/openexr:= )
+"
+
+RDEPEND="${DEPEND}"
+
+multilib_src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_SKIP_RPATH=ON
+		-DBUILD_TESTING=OFF
+		-DJPEGXL_ENABLE_BENCHMARK=OFF
+		-DJPEGXL_ENABLE_COVERAGE=OFF
+		-DJPEGXL_ENABLE_FUZZERS=OFF
+		-DJPEGXL_ENABLE_SJPEG=OFF
+		-DJPEGXL_WARNINGS_AS_ERRORS=OFF
+
+		-DJPEGXL_ENABLE_SKCMS=ON
+		-DJPEGXL_ENABLE_VIEWERS=OFF
+		-DJPEGXL_FORCE_SYSTEM_BROTLI=ON
+		-DJPEGXL_FORCE_SYSTEM_HWY=ON
+		-DJPEGXL_ENABLE_DOXYGEN=OFF
+		-DJPEGXL_ENABLE_MANPAGES=OFF
+		-DJPEGXL_ENABLE_JNI=OFF
+		-DJPEGXL_ENABLE_TCMALLOC=OFF
+	)
+
+	if multilib_is_native_abi; then
+		mycmakeargs+=(
+			-DJPEGXL_ENABLE_TOOLS=ON
+			-DJPEGXL_ENABLE_EXAMPLES=$(usex examples)
+			-DJPEGXL_ENABLE_OPENEXR=$(usex openexr)
+			-DJPEGXL_ENABLE_PLUGINS=ON
+			-DJPEGXL_ENABLE_PLUGIN_GDKPIXBUF=$(usex gdk-pixbuf)
+			-DJPEGXL_ENABLE_PLUGIN_GIMP210=$(usex gimp210)
+		)
+	else
+		mycmakeargs+=(
+			-DJPEGXL_ENABLE_TOOLS=OFF
+			-DJPEGXL_ENABLE_EXAMPLES=OFF
+			-DJPEGXL_ENABLE_OPENEXR=OFF
+			-DJPEGXL_ENABLE_PLUGINS=OFF
+		)
+	fi
+
+	cmake_src_configure
+}
+
+multilib_src_install() {
+	cmake_src_install
+	if use examples && multilib_is_native_abi; then
+		dobin "${BUILD_DIR}/jxlinfo"
+	fi
+}
diff --git a/media-libs/libjxl/metadata.xml b/media-libs/libjxl/metadata.xml
new file mode 100644
index 000000000000..fe211671a1a3
--- /dev/null
+++ b/media-libs/libjxl/metadata.xml
@@ -0,0 +1,21 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM 'http://www.gentoo.org/dtd/metadata.dtd'>
+<pkgmetadata>
+  <maintainer type="person" proxied="yes">
+    <email>dnovomesky@gmail.com</email>
+    <name>Daniel Novomesky</name>
+  </maintainer>
+  <maintainer type="project" proxied="proxy">
+    <email>proxy-maint@gentoo.org</email>
+    <name>Proxy Maintainers</name>
+  </maintainer>
+  <longdescription>
+    JPEG XL reference implementation
+    (encoder and decoder), called libjxl.
+    Contains command line utilities: cjxl, djxl, jxlinfo.
+  </longdescription>
+  <use>
+    <flag name="gdk-pixbuf">Build a gdk-pixbuf loader</flag>
+    <flag name="gimp210">Enable plugin for GIMP 2.10.x series</flag>
+  </use>
+</pkgmetadata>