reinit the tree, so we can have metadata

1 files changed, 45 insertions, 0 deletions

diff --git a/media-libs/libexif/libexif-0.6.21-r1.ebuild b/media-libs/libexif/libexif-0.6.21-r1.ebuild
new file mode 100644
index 000000000000..31e267a53de4
--- /dev/null
+++ b/media-libs/libexif/libexif-0.6.21-r1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+inherit eutils libtool multilib-minimal
+
+DESCRIPTION="Library for parsing, editing, and saving EXIF data"
+HOMEPAGE="http://libexif.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="alpha amd64 arm ~arm64 hppa ia64 ~mips ppc ppc64 ~s390 ~sh sparc x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x64-solaris ~x86-solaris"
+IUSE="doc nls static-libs"
+
+RDEPEND="nls? ( virtual/libintl )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+	nls? ( sys-devel/gettext )"
+
+ECONF_SOURCE=${S}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-0.6.13-pkgconfig.patch
+	sed -i -e '/FLAGS=/s:-g::' configure || die #390249
+	elibtoolize # For *-bsd
+}
+
+multilib_src_configure() {
+	econf \
+		$(use_enable static-libs static) \
+		$(use_enable nls) \
+		$(use_enable doc docs) \
+		--with-doc-dir="${EPREFIX}"/usr/share/doc/${PF}
+}
+
+multilib_src_install() {
+	emake DESTDIR="${D}" install
+}
+
+multilib_src_install_all() {
+	prune_libtool_files
+	rm -f "${ED}"/usr/share/doc/${PF}/{ABOUT-NLS,COPYING}
+}