gentoo new year resync : 01.01.2021

3 files changed, 114 insertions, 19 deletions

diff --git a/media-libs/libde265/Manifest b/media-libs/libde265/Manifest
index 146e3ade4c21..2dffd8001e4b 100644
--- a/media-libs/libde265/Manifest
+++ b/media-libs/libde265/Manifest
@@ -2,7 +2,9 @@ AUX libde265-1.0.2-qtbindir.patch 1798 BLAKE2B 22e15a1d4dfe7f602c9b13611c17d4d6b
 AUX libde265-1.0.3-use-new-FFMPEG-enum-names.patch 933 BLAKE2B 50f4f65a7c73365bd6f803c4fe85e029188a184dfe8dce5768e47af15cb489705129a5054aaf6bb12d8822de588c6ed10cf8384db7baeb2b4a6fee1a8a96494d SHA512 cf88bd2d40d9726dbe8bd8c3cddacccfef065635cf20751efd30dd30ac706d640be3b06a284a5bc11b457de63206d699405a6da8fb39cd0d5425371f5d538549
 DIST libde265-1.0.3.tar.gz 399996 BLAKE2B 988b21085f82d3b33b0480542677be96db5219c1b767aae3674f89862fdaf3355dcfea3fa99699798a4fcc6b72a63a3a6f61a3fd8d2ea8483231205cd6d87175 SHA512 0153632afcc9733950e8354997ccd93eddad90e8e0f7362bfe49b93b11cb1756cf803d0ba5c07042aee80e18227613af768ca82baf7891c687edf5e253a129c4
 DIST libde265-1.0.5.tar.gz 381041 BLAKE2B d561a0e5f308bed557237b88317985912537f76701783bc30d81305cf9026a853746449ece5b3092534466ea13d67bac10b3258580c8de07489844bbef0395db SHA512 3ff7310fc4621cac0ef1cb9bbc4df61724f8943d57f5263a3663a77f4d90d84716b2a708ee9fec306e909dc8b5e7fe645a641b6a6db795a89a01799be910831e
+DIST libde265-1.0.8.tar.gz 381963 BLAKE2B 0577623de2ef86e1122b5b5c3642a750bb222c4988a996168e060e8ffd9f5c0787d31331cc8738362d3fc3fb31e8eb659629cab068f0ff1c71de9d15ed1f2ceb SHA512 0007138cb5da0d4cad1e118c01de249580f39c387a11f490d1e1f63ad0968ee2f7951e54580f298b3dbe31e5a3d1a7fa04454e11cbb82beaf8a9aaf56f5532ed
 EBUILD libde265-1.0.3.ebuild 1590 BLAKE2B 48de41d7133072b75f48b2fb954390915085931ec6f90daa56d6d437d130795039c682f36a8b053783e29bdbd4faedda8e15d48f0c50df57ba6b754462ca0360 SHA512 431fdd0871422199e7d9278fb21857e5a9a27cb34ba949767526d9f9ada57e65efe5abe3c4fae464e2bf3f021981a786cdeb84a9917032528cf08de4e30b8ac1
 EBUILD libde265-1.0.5.ebuild 2498 BLAKE2B d001976ca0ac8a6e043d282b673365de75992b25bff06ace079745782db15a94333e3a0a650b4cb23d33710d3e3a49b6ef1eb8dcf24578cc8e107ff58d94ed93 SHA512 c13211859fc8dd695c6e9effd04d15f4771c1be321fb0f8b09c64b8a9c3cdd03c84ab9169a82b507936d76bfcab577906d6c7776fd1c4764e11eab26a3236a87
-EBUILD libde265-9999.ebuild 2496 BLAKE2B 645c7f8d7d267eee7b3cbf376ccc12463ca3fb0f3fd823f1a91016021b047f3b60726886e711006640f28843ac8883b64662740c0cbdd0820e44400b72b0f191 SHA512 b33524c9cc21c9cce9b71b29c2de42b248725aff4d790f8bcd2a2da517584b3b9ca641ab51e5a3bae5ce365b3cb6695d624c01db4ac706d70a96c5cf0ee37df7
+EBUILD libde265-1.0.8.ebuild 2355 BLAKE2B 2b0701a6f2c9c2bb24e08fe76844c613befdc9bf16c81695b3ae2e4dc8db3bf58225ad5897e5072ad1ad3e30126e89ca829338812decd31c663ca0530b501d82 SHA512 2605125ee6c33605f6a03282e3c51b1577eb9bc124e348f8a9b197a5dfb5a4698fa3752baec7baf44c592f998b48bcc8125423a83d45e648a577ab8f2505c337
+EBUILD libde265-9999.ebuild 2355 BLAKE2B 2b0701a6f2c9c2bb24e08fe76844c613befdc9bf16c81695b3ae2e4dc8db3bf58225ad5897e5072ad1ad3e30126e89ca829338812decd31c663ca0530b501d82 SHA512 2605125ee6c33605f6a03282e3c51b1577eb9bc124e348f8a9b197a5dfb5a4698fa3752baec7baf44c592f998b48bcc8125423a83d45e648a577ab8f2505c337
 MISC metadata.xml 691 BLAKE2B 24cf4f5585ca49df6aa5fbed6ab8daa55451446b1ab2d47953e05ce726b22457f1f2adc18774b745206a2f7342996b210edf83867578f86049e23823e43c1788 SHA512 c121ebe35ce66deb54c5d046fb74fb8096d134348b15607f7bc7f0b7239ce76a2ecc43ecee72382adb6078ac6f50859d0ac3a60bd8a3daf52f6cd04c9a56ecf9
diff --git a/media-libs/libde265/libde265-1.0.8.ebuild b/media-libs/libde265/libde265-1.0.8.ebuild
new file mode 100644
index 000000000000..29c28d991c82
--- /dev/null
+++ b/media-libs/libde265/libde265-1.0.8.ebuild
@@ -0,0 +1,96 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools multilib-minimal
+
+if [[ ${PV} == *9999 ]] ; then
+	EGIT_REPO_URI="https://github.com/strukturag/${PN}.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/strukturag/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+fi
+
+DESCRIPTION="Open h.265 video codec implementation"
+HOMEPAGE="https://github.com/strukturag/libde265"
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="enc265 dec265 sdl tools debug cpu_flags_x86_sse4_1 cpu_flags_arm_neon cpu_flags_arm_thumb"
+# IUSE+=" sherlock265" # Require libvideogfx or libswscale
+
+RDEPEND="
+	dec265? (
+		sdl? ( media-libs/libsdl )
+	)"
+
+# Sherlock265 require libvideogfx or libswscale
+#RDEPEND+="
+#	sherlock265? (
+#		media-libs/libsdl
+#		dev-qt/qtcore:5
+#		dev-qt/qtgui:5
+#		dev-qt/qtwidgets:5
+#		media-libs/libswscale
+#	)
+#"
+
+DEPEND="${RDEPEND}"
+BDEPEND="dec265? ( virtual/pkgconfig )"
+
+# Sherlock265 require libvideogfx or libswscale
+#BDEPEND+=" sherlock265? ( virtual/pkgconfig )"
+
+PATCHES=( "${FILESDIR}"/${PN}-1.0.2-qtbindir.patch )
+
+src_prepare() {
+	default
+
+	eautoreconf
+
+	# without this, headers would be missing and make would fail
+	multilib_copy_sources
+}
+
+multilib_src_configure() {
+	local myeconfargs=(
+		--disable-static
+		--enable-log-error
+		ax_cv_check_cflags___msse4_1=$(usex cpu_flags_x86_sse4_1)
+		ax_cv_check_cflags___mfpu_neon=$(usex cpu_flags_arm_neon)
+		$(use_enable cpu_flags_arm_thumb thumb)
+		$(use_enable debug log-info)
+		$(use_enable debug log-debug)
+		$(use_enable debug log-trace)
+		$(multilib_native_use_enable enc265 encoder)
+		$(multilib_native_use_enable dec265)
+	)
+
+	# myeconfargs+=( $(multilib_native_use_enable sherlock265) ) # Require libvideogfx or libswscale
+	myeconfargs+=( --disable-sherlock265 )
+
+	econf "${myeconfargs[@]}"
+}
+
+multilib_src_install() {
+	default
+
+	if multilib_is_native_abi; then
+		# Remove useless, unready and test tools
+		rm "${ED}"/usr/bin/{tests,gen-enc-table,yuv-distortion} || die
+		if ! use tools; then
+			rm "${ED}"/usr/bin/{bjoentegaard,block-rate-estim,rd-curves} || die
+			rm "${ED}"/usr/bin/acceleration_speed || die
+		fi
+	else
+		# Remove all non-native binary tools
+		rm "${ED}"/usr/bin/* || die
+	fi
+}
+
+multilib_src_install_all() {
+	find "${ED}" -name '*.la' -delete || die
+	einstalldocs
+}
diff --git a/media-libs/libde265/libde265-9999.ebuild b/media-libs/libde265/libde265-9999.ebuild
index 1b591f16c364..29c28d991c82 100644
--- a/media-libs/libde265/libde265-9999.ebuild
+++ b/media-libs/libde265/libde265-9999.ebuild
@@ -5,14 +5,12 @@ EAPI=7
 
 inherit autotools multilib-minimal
 
-PATCHES=( "${FILESDIR}/${PN}-1.0.2-qtbindir.patch" )
-
-if [[ ${PV} == "9999" ]] ; then
+if [[ ${PV} == *9999 ]] ; then
 	EGIT_REPO_URI="https://github.com/strukturag/${PN}.git"
 	inherit git-r3
 else
 	SRC_URI="https://github.com/strukturag/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
-	KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
 fi
 
 DESCRIPTION="Open h.265 video codec implementation"
@@ -20,14 +18,14 @@ HOMEPAGE="https://github.com/strukturag/libde265"
 
 LICENSE="GPL-3"
 SLOT="0"
-IUSE="enc265 dec265 sdl tools debug static-libs cpu_flags_x86_sse4_1 cpu_flags_arm_neon cpu_flags_arm_thumb"
+IUSE="enc265 dec265 sdl tools debug cpu_flags_x86_sse4_1 cpu_flags_arm_neon cpu_flags_arm_thumb"
 # IUSE+=" sherlock265" # Require libvideogfx or libswscale
 
 RDEPEND="
 	dec265? (
 		sdl? ( media-libs/libsdl )
-	)
-"
+	)"
+
 # Sherlock265 require libvideogfx or libswscale
 #RDEPEND+="
 #	sherlock265? (
@@ -40,12 +38,13 @@ RDEPEND="
 #"
 
 DEPEND="${RDEPEND}"
-
 BDEPEND="dec265? ( virtual/pkgconfig )"
 
 # Sherlock265 require libvideogfx or libswscale
 #BDEPEND+=" sherlock265? ( virtual/pkgconfig )"
 
+PATCHES=( "${FILESDIR}"/${PN}-1.0.2-qtbindir.patch )
+
 src_prepare() {
 	default
 
@@ -57,16 +56,16 @@ src_prepare() {
 
 multilib_src_configure() {
 	local myeconfargs=(
+		--disable-static
+		--enable-log-error
 		ax_cv_check_cflags___msse4_1=$(usex cpu_flags_x86_sse4_1)
 		ax_cv_check_cflags___mfpu_neon=$(usex cpu_flags_arm_neon)
 		$(use_enable cpu_flags_arm_thumb thumb)
-		$(use_enable static-libs static)
 		$(use_enable debug log-info)
 		$(use_enable debug log-debug)
 		$(use_enable debug log-trace)
 		$(multilib_native_use_enable enc265 encoder)
 		$(multilib_native_use_enable dec265)
-		--enable-log-error
 	)
 
 	# myeconfargs+=( $(multilib_native_use_enable sherlock265) ) # Require libvideogfx or libswscale
@@ -79,21 +78,19 @@ multilib_src_install() {
 	default
 
 	if multilib_is_native_abi; then
-		# Remove useless, unready and test tools (Why package ever tried to install them??)
-		rm -f "${ED}/usr/bin/"{tests,gen-enc-table,yuv-distortion} || die
+		# Remove useless, unready and test tools
+		rm "${ED}"/usr/bin/{tests,gen-enc-table,yuv-distortion} || die
 		if ! use tools; then
-			rm -f "${ED}/usr/bin/"{bjoentegaard,block-rate-estim,rd-curves} || die
-			rm -f "${ED}/usr/bin/acceleration_speed" || die
+			rm "${ED}"/usr/bin/{bjoentegaard,block-rate-estim,rd-curves} || die
+			rm "${ED}"/usr/bin/acceleration_speed || die
 		fi
 	else
 		# Remove all non-native binary tools
-		rm -f "${ED}/usr/bin/"* || die
+		rm "${ED}"/usr/bin/* || die
 	fi
 }
 
 multilib_src_install_all() {
 	find "${ED}" -name '*.la' -delete || die
-	if ! use static-libs ; then
-		find "${ED}" -name "*.a" -delete || die
-	fi
+	einstalldocs
 }