gentoo resync : 06.08.2019

3 files changed, 365 insertions, 0 deletions

diff --git a/media-libs/gst-plugins-base/Manifest b/media-libs/gst-plugins-base/Manifest
index b56a78891830..166de97f7166 100644
--- a/media-libs/gst-plugins-base/Manifest
+++ b/media-libs/gst-plugins-base/Manifest
@@ -1,4 +1,7 @@
 DIST gst-plugins-base-1.14.4.tar.xz 3703232 BLAKE2B b22c44b857bc4f1972f03752cc1afb35c8d76e2d0c4a06c574af0ac4f3a91080c584ae4e4fc2a263ee879a53d58505c24a756ebc051d81ec62661c4f9e532f0e SHA512 42c59df9f2d848108f12afa0466acbcfa5ccda64e4d0d44608d4268abed20f2e036713de04e7d71feaed1868ad742c5bcb55ae0eef5dec8e19e053dc8541b8af
+DIST gst-plugins-base-1.14.5.tar.xz 3717076 BLAKE2B 461e90df614c60d7efce6fabcf8ad7a5cb68b5fc01b05761fa441d838d3155b5a2e7f9b9420b7e48b2eec49e4bcfbd39009a662db03a923f42c6f45c782795cd SHA512 4e81c44a5ea3b910f96d3e9251ba38a79feacead4f96adb92eab5a650695ca8d5313e3ec1df78fec04376cf3152d2eefd4d39f6c11dadc98a11e55bbf8c8ccdc
 EBUILD gst-plugins-base-1.14.4-r1.ebuild 5919 BLAKE2B eb497ebed24ba4775e90d05236714a5c65c9576d6c61a7df3ca25b9677a614db7fcdcaf3f6afb61751fee435e0df296b878dd383c142d7d5d3c39e8a6cab7623 SHA512 298e7adb9daa3447aed8d67c9d3d3672c356d20b11b82fbe51bfb970833baa27c8f9be63ebab3913f34c98c2c50872369831177e307750a181b3962190f210f2
 EBUILD gst-plugins-base-1.14.4.ebuild 6061 BLAKE2B bf46ef975e9675c8d55bd807e11074cff4b31dc7d308750ceedd43bb67889473183dc1c83109f4783af4564180b23e14b92787bd4ac2ccc75d28917b03dc14e5 SHA512 9493adf3513a16e4f07fe15d9572e60285817396f43a8ec79fba0a3b37f1e35bf845e3edab2e92454d9b59bcaa69c21702e8de62243905cab45427d6a123f9c1
+EBUILD gst-plugins-base-1.14.5-r1.ebuild 5925 BLAKE2B a18cda341f3165e7b07babd24c5da5b79da835577b8df698f0e9e5a63b9356c88040d1c0ab638eb2489a93c9d042062cf3e34c8129f0f450bd2dde763867d804 SHA512 86332c0a762c8c19002245b7df5b2f117696c7f28ce74541d6e11107ef1c006b6e5abdd2022e04f0f97d3247e8a6bbbb397bfa27d32cc0340ae126f273abc900
+EBUILD gst-plugins-base-1.14.5.ebuild 6063 BLAKE2B dcd3142fe16e772125bf4f178b019c40e58c98ef293e9afac8e68d18ec6228a653acf11377f70071f50869b4d1fdbf0594d87ef13c8b816030cdbbd768fc6462 SHA512 77acc4ddcca654ce6bbc21f28038cd2d4b7a1aca8afecfb330d2889d43a9fa0e0ecb2fb86559ac077dc867cb121f316d8e2f36ae520f13f593bbd501b6336ada
 MISC metadata.xml 1065 BLAKE2B 9736df3218c6157e5cc0f14e96a15ec6ab6140e8774c7361dd4fe9378efd37d1a3da593527313a81591818ad48a5585bd4395fbeb85d357449b00bf7e51bbb5c SHA512 520802b59fc6575e16edd765dacab4ff0ff6e51dd162f03fe7e4e07eb472aeb78f3974a32ba613939932e123179106a450c503234ed806a08416dc6b8dd534c2
diff --git a/media-libs/gst-plugins-base/gst-plugins-base-1.14.5-r1.ebuild b/media-libs/gst-plugins-base/gst-plugins-base-1.14.5-r1.ebuild
new file mode 100644
index 000000000000..9f40a8032600
--- /dev/null
+++ b/media-libs/gst-plugins-base/gst-plugins-base-1.14.5-r1.ebuild
@@ -0,0 +1,181 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GST_ORG_MODULE="gst-plugins-base"
+
+inherit flag-o-matic gstreamer
+
+DESCRIPTION="Basepack of plugins for gstreamer"
+HOMEPAGE="https://gstreamer.freedesktop.org/"
+
+LICENSE="GPL-2+ LGPL-2+"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+# For OpenGL we have three separate concepts, with a list of possibilities in each:
+#  * opengl APIs - opengl and/or gles2; USE=opengl and USE=gles2 enable these accordingly; if neither is enabled, OpenGL helper library and elements are not built at all and all the other options aren't relevant
+#  * opengl platforms - glx and/or egl; also cgl, wgl, eagl for non-linux; USE="X opengl" enables glx platform; USE="egl" enables egl platform. Rest is up for relevant prefix teams.
+#  * opengl windowing system - x11, wayland, win32, cocoa, android, viv_fb, gbm and/or dispmanx; USE=X enables x11 (but for WSI it's automagic - FIXME), USE=wayland enables wayland, USE=gbm enables gbm (automagic upstream - FIXME); rest is up for relevant prefix/arch teams/contributors to test and provide patches
+# With the following limitations:
+#  * If opengl and/or gles2 is enabled, a platform has to be enabled - x11 or egl in our case, but x11 (glx) is acceptable only with opengl
+#  * If opengl and/or gles2 is enabled, a windowing system has to be enabled - x11, wayland or gbm in our case
+#  * glx platform requires opengl API
+#  * wayland, gbm and most other non-glx WSIs require egl platform
+# Additionally there is optional dmabuf support with egl for additional dmabuf based upload/download/eglimage options;
+#  and optional graphene usage for gltransformation and glvideoflip elements and more GLSL Uniforms support in glshader;
+#  and libpng/jpeg are required for gloverlay element;
+
+# Keep default IUSE options for relevant ones mirrored with gst-plugins-gtk and gst-plugins-bad
+IUSE="alsa +egl gbm gles2 +introspection ivorbis +ogg +opengl +orc +pango theora +vorbis wayland +X"
+GL_REQUIRED_USE="
+	|| ( gbm wayland X )
+	wayland? ( egl )
+	gbm? ( egl )
+"
+REQUIRED_USE="
+	ivorbis? ( ogg )
+	theora? ( ogg )
+	vorbis? ( ogg )
+	opengl? ( || ( egl X ) ${GL_REQUIRED_USE} )
+	gles2? ( egl ${GL_REQUIRED_USE} )
+"
+
+# Dependencies needed by opengl library and plugin (enabled via USE gles2 and/or opengl)
+# dmabuf automagic from libdrm headers (drm_fourcc.h) and EGL, so ensure it with USE=egl (platform independent header used only, thus no MULTILIB_USEDEP); provides dmabuf based upload/download/eglimage options
+GL_DEPS="
+	>=media-libs/mesa-9.0[egl?,gbm?,gles2?,wayland?,${MULTILIB_USEDEP}]
+	egl? (
+		x11-libs/libdrm
+	)
+	gbm? (
+		>=dev-libs/libgudev-147[${MULTILIB_USEDEP}]
+		>=x11-libs/libdrm-2.4.55[${MULTILIB_USEDEP}]
+	)
+	wayland? (
+		dev-libs/wayland[${MULTILIB_USEDEP}]
+	)
+
+	>=media-libs/graphene-1.4.0[${MULTILIB_USEDEP}]
+	media-libs/libpng:0[${MULTILIB_USEDEP}]
+	virtual/jpeg:0[${MULTILIB_USEDEP}]
+" # graphene for optional gltransformation and glvideoflip elements and more GLSL Uniforms support in glshader; libpng/jpeg for gloverlay element
+
+RDEPEND="
+	app-text/iso-codes
+	>=dev-libs/glib-2.40.0:2[${MULTILIB_USEDEP}]
+	>=media-libs/gstreamer-${PV}:1.0[introspection?,${MULTILIB_USEDEP}]
+	>=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}]
+	alsa? ( >=media-libs/alsa-lib-1.0.27.2[${MULTILIB_USEDEP}] )
+	introspection? ( >=dev-libs/gobject-introspection-1.31.1:= )
+	ivorbis? ( >=media-libs/tremor-0_pre20130223[${MULTILIB_USEDEP}] )
+	ogg? ( >=media-libs/libogg-1.3.0[${MULTILIB_USEDEP}] )
+	orc? ( >=dev-lang/orc-0.4.24[${MULTILIB_USEDEP}] )
+	pango? ( >=x11-libs/pango-1.36.3[${MULTILIB_USEDEP}] )
+	theora? ( >=media-libs/libtheora-1.1.1[encode,${MULTILIB_USEDEP}] )
+	vorbis? ( >=media-libs/libvorbis-1.3.3-r1[${MULTILIB_USEDEP}] )
+	X? (
+		>=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libXext-1.3.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libXv-1.0.10[${MULTILIB_USEDEP}]
+	)
+
+	gles2? ( ${GL_DEPS} )
+	opengl? ( ${GL_DEPS} )
+
+	!<media-libs/gst-plugins-bad-1.13.1:1.0
+"
+DEPEND="${RDEPEND}
+	dev-util/glib-utils
+	>=dev-util/gtk-doc-am-1.12
+	X? ( x11-base/xorg-proto )
+"
+
+src_prepare() {
+	# Disable GL tests for now; prone to fail with EGL_NOT_INITIALIZED, etc
+	sed -i -e '/^@USE_GL_TRUE@/d' tests/check/Makefile.in
+	default
+}
+
+multilib_src_configure() {
+	filter-flags -mno-sse -mno-sse2 -mno-sse4.1 #610340
+
+	local myconf=()
+	# FIXME: Automagic gbm and x11 wsi
+	if use opengl || use gles2; then
+		myconf+=(
+			--enable-gl
+			$(use_enable egl)
+			$(use_enable gles2)
+			$(use_enable opengl)
+			$(use_enable wayland)
+			$(use_enable X x11)
+		)
+	else
+		myconf+=(
+			--disable-gl
+			--disable-egl
+			--disable-gles2
+			--disable-opengl
+			--disable-wayland
+			--disable-x11
+		)
+	fi
+
+	if use opengl && use X; then
+		# GLX requires desktop OpenGL and X
+		myconf+=( --enable-glx )
+	else
+		myconf+=( --disable-glx )
+	fi
+
+	myconf+=(
+		--disable-cocoa
+		--disable-dispmanx
+		--disable-wgl
+	)
+
+	gstreamer_multilib_src_configure \
+		$(use_enable alsa) \
+		$(multilib_native_use_enable introspection) \
+		$(use_enable ivorbis) \
+		$(use_enable ogg) \
+		$(use_enable orc) \
+		$(use_enable pango) \
+		$(use_enable theora) \
+		$(use_enable vorbis) \
+		$(use_enable X x) \
+		$(use_enable X xshm) \
+		$(use_enable X xvideo) \
+		--enable-iso-codes \
+		--enable-zlib \
+		--disable-debug \
+		--disable-examples \
+		--disable-static \
+		"${myconf[@]}"
+
+	# bug #366931, flag-o-matic for the whole thing is overkill
+	if [[ ${CHOST} == *86-*-darwin* ]] ; then
+		sed -i \
+			-e '/FLAGS = /s|-O[23]|-O1|g' \
+			gst/audioconvert/Makefile \
+			gst/volume/Makefile || die
+	fi
+
+	if multilib_is_native_abi; then
+		local x
+		for x in libs plugins; do
+			ln -s "${S}"/docs/${x}/html docs/${x}/html || die
+		done
+	fi
+}
+
+multilib_src_install_all() {
+	DOCS="AUTHORS NEWS README RELEASE"
+	einstalldocs
+	find "${ED}" -name '*.la' -delete || die
+}
+
+multilib_src_test() {
+	unset GSETTINGS_BACKEND
+	emake check
+}
diff --git a/media-libs/gst-plugins-base/gst-plugins-base-1.14.5.ebuild b/media-libs/gst-plugins-base/gst-plugins-base-1.14.5.ebuild
new file mode 100644
index 000000000000..b0288166ffca
--- /dev/null
+++ b/media-libs/gst-plugins-base/gst-plugins-base-1.14.5.ebuild
@@ -0,0 +1,181 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GST_ORG_MODULE="gst-plugins-base"
+
+inherit flag-o-matic gstreamer
+
+DESCRIPTION="Basepack of plugins for gstreamer"
+HOMEPAGE="https://gstreamer.freedesktop.org/"
+
+LICENSE="GPL-2+ LGPL-2+"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+
+# For OpenGL we have three separate concepts, with a list of possibilities in each:
+#  * opengl APIs - opengl and/or gles2; USE=opengl and USE=gles2 enable these accordingly; if neither is enabled, OpenGL helper library and elements are not built at all and all the other options aren't relevant
+#  * opengl platforms - glx and/or egl; also cgl, wgl, eagl for non-linux; USE="X opengl" enables glx platform; USE="egl" enables egl platform. Rest is up for relevant prefix teams.
+#  * opengl windowing system - x11, wayland, win32, cocoa, android, viv_fb, gbm and/or dispmanx; USE=X enables x11 (but for WSI it's automagic - FIXME), USE=wayland enables wayland, USE=gbm enables gbm (automagic upstream - FIXME); rest is up for relevant prefix/arch teams/contributors to test and provide patches
+# With the following limitations:
+#  * If opengl and/or gles2 is enabled, a platform has to be enabled - x11 or egl in our case, but x11 (glx) is acceptable only with opengl
+#  * If opengl and/or gles2 is enabled, a windowing system has to be enabled - x11, wayland or gbm in our case
+#  * glx platform requires opengl API
+#  * wayland, gbm and most other non-glx WSIs require egl platform
+# Additionally there is optional dmabuf support with egl for additional dmabuf based upload/download/eglimage options;
+#  and optional graphene usage for gltransformation and glvideoflip elements and more GLSL Uniforms support in glshader;
+#  and libpng/jpeg are required for gloverlay element;
+
+# Keep default IUSE options for relevant ones mirrored with gst-plugins-gtk and gst-plugins-bad
+IUSE="alsa +egl gbm gles2 +introspection ivorbis +ogg +opengl +orc +pango theora +vorbis wayland +X"
+GL_REQUIRED_USE="
+	|| ( gbm wayland X )
+	wayland? ( egl )
+	gbm? ( egl )
+"
+REQUIRED_USE="
+	ivorbis? ( ogg )
+	theora? ( ogg )
+	vorbis? ( ogg )
+	opengl? ( || ( egl X ) ${GL_REQUIRED_USE} )
+	gles2? ( egl ${GL_REQUIRED_USE} )
+"
+
+# Dependencies needed by opengl library and plugin (enabled via USE gles2 and/or opengl)
+# dmabuf automagic from libdrm headers (drm_fourcc.h) and EGL, so ensure it with USE=egl (platform independent header used only, thus no MULTILIB_USEDEP); provides dmabuf based upload/download/eglimage options
+GL_DEPS="
+	>=media-libs/mesa-9.0[egl?,gbm?,gles2?,wayland?,${MULTILIB_USEDEP}]
+	egl? (
+		x11-libs/libdrm
+	)
+	gbm? (
+		>=dev-libs/libgudev-147[${MULTILIB_USEDEP}]
+		>=x11-libs/libdrm-2.4.55[${MULTILIB_USEDEP}]
+	)
+	wayland? (
+		dev-libs/wayland[${MULTILIB_USEDEP}]
+	)
+
+	media-libs/libpng:0[${MULTILIB_USEDEP}]
+	virtual/jpeg:0[${MULTILIB_USEDEP}]
+" # graphene for optional gltransformation and glvideoflip elements and more GLSL Uniforms support in glshader; libpng/jpeg for gloverlay element
+# >=media-libs/graphene-1.4.0[${MULTILIB_USEDEP}]
+
+RDEPEND="
+	app-text/iso-codes
+	>=dev-libs/glib-2.40.0:2[${MULTILIB_USEDEP}]
+	>=media-libs/gstreamer-${PV}:1.0[introspection?,${MULTILIB_USEDEP}]
+	>=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}]
+	alsa? ( >=media-libs/alsa-lib-1.0.27.2[${MULTILIB_USEDEP}] )
+	introspection? ( >=dev-libs/gobject-introspection-1.31.1:= )
+	ivorbis? ( >=media-libs/tremor-0_pre20130223[${MULTILIB_USEDEP}] )
+	ogg? ( >=media-libs/libogg-1.3.0[${MULTILIB_USEDEP}] )
+	orc? ( >=dev-lang/orc-0.4.24[${MULTILIB_USEDEP}] )
+	pango? ( >=x11-libs/pango-1.36.3[${MULTILIB_USEDEP}] )
+	theora? ( >=media-libs/libtheora-1.1.1[encode,${MULTILIB_USEDEP}] )
+	vorbis? ( >=media-libs/libvorbis-1.3.3-r1[${MULTILIB_USEDEP}] )
+	X? (
+		>=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libXext-1.3.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libXv-1.0.10[${MULTILIB_USEDEP}]
+	)
+
+	gles2? ( ${GL_DEPS} )
+	opengl? ( ${GL_DEPS} )
+
+	!<media-libs/gst-plugins-bad-1.13.1:1.0
+"
+DEPEND="${RDEPEND}
+	dev-util/glib-utils
+	>=dev-util/gtk-doc-am-1.12
+	X? ( x11-base/xorg-proto )
+"
+
+src_prepare() {
+	# Disable GL tests for now; prone to fail with EGL_NOT_INITIALIZED, etc
+	sed -i -e '/^@USE_GL_TRUE@/d' tests/check/Makefile.in
+	default
+}
+
+multilib_src_configure() {
+	filter-flags -mno-sse -mno-sse2 -mno-sse4.1 #610340
+
+	local myconf=()
+	# FIXME: Automagic gbm and x11 wsi
+	if use opengl || use gles2; then
+		myconf+=(
+			--enable-gl
+			$(use_enable egl)
+			$(use_enable gles2)
+			$(use_enable opengl)
+			$(use_enable wayland)
+			$(use_enable X x11)
+		)
+	else
+		myconf+=(
+			--disable-gl
+			--disable-egl
+			--disable-gles2
+			--disable-opengl
+			--disable-wayland
+			--disable-x11
+		)
+	fi
+
+	if use opengl && use X; then
+		# GLX requires desktop OpenGL and X
+		myconf+=( --enable-glx )
+	else
+		myconf+=( --disable-glx )
+	fi
+
+	myconf+=(
+		--disable-cocoa
+		--disable-dispmanx
+		--disable-wgl
+	)
+
+	gstreamer_multilib_src_configure \
+		$(use_enable alsa) \
+		$(multilib_native_use_enable introspection) \
+		$(use_enable ivorbis) \
+		$(use_enable ogg) \
+		$(use_enable orc) \
+		$(use_enable pango) \
+		$(use_enable theora) \
+		$(use_enable vorbis) \
+		$(use_enable X x) \
+		$(use_enable X xshm) \
+		$(use_enable X xvideo) \
+		--enable-iso-codes \
+		--enable-zlib \
+		--disable-debug \
+		--disable-examples \
+		--disable-static \
+		"${myconf[@]}"
+
+	# bug #366931, flag-o-matic for the whole thing is overkill
+	if [[ ${CHOST} == *86-*-darwin* ]] ; then
+		sed -i \
+			-e '/FLAGS = /s|-O[23]|-O1|g' \
+			gst/audioconvert/Makefile \
+			gst/volume/Makefile || die
+	fi
+
+	if multilib_is_native_abi; then
+		local x
+		for x in libs plugins; do
+			ln -s "${S}"/docs/${x}/html docs/${x}/html || die
+		done
+	fi
+}
+
+multilib_src_install_all() {
+	DOCS="AUTHORS NEWS README RELEASE"
+	einstalldocs
+	find "${ED}" -name '*.la' -delete || die
+}
+
+multilib_src_test() {
+	unset GSETTINGS_BACKEND
+	emake check
+}