gentoo auto-resync : 05:01:2025 - 06:31:57edge

3 files changed, 155 insertions, 3 deletions

diff --git a/media-libs/gst-plugins-base/Manifest b/media-libs/gst-plugins-base/Manifest
index 6d50232b16bb..9d441f84b7ae 100644
--- a/media-libs/gst-plugins-base/Manifest
+++ b/media-libs/gst-plugins-base/Manifest
@@ -1,5 +1,7 @@
 DIST gst-plugins-base-1.22.11.tar.xz 2373020 BLAKE2B 0809629afae7b82a12079dc40dd5a6a7c86876b591389c3179a74cea975b0ef3c66d9fc2f42a2f722892de2c75ef87eb0cfc5cc5df65f0ebefa02a891b0c392a SHA512 cfd8f7fe66f4707e043c8f070110eb80f9804cec529c8d29b13dbc8604db90e3f010c9614d538ad076b826df54f75ce5ebac355bd05a874e44dccead6a953c60
 DIST gst-plugins-base-1.22.12.tar.xz 2374324 BLAKE2B 7600d5a10a3d7d4f6874cc166cdca2d45d3daedec3fbb56982db172bd4f6c0463fcde812e31c42f912d8fbda793730695ab39e44b7f126b49581f7c87858b988 SHA512 f72edccd49ce2a35577dff80feb1d0f667df54d6b8f61ef2320b5d4564442b907954d015bccec7a915acf25d2197a507c32b72c1ab18dd38d254f57a3277b334
+DIST gst-plugins-base-1.24.10.tar.xz 2453672 BLAKE2B 0935a21d344b7d1328d1958325c49d23dadddd5bb72b2639ed2598efd2a2d35a8bb322583c2e6b9865c9d4d922400abcd20512ef28c1de8e7f6c11369008e23c SHA512 d5eae27c70999fd3a02294354a30e24d82ee9a7920e2e5f6bf63fcd8a321c7541dbbd402dbcee7c44ba4a67f9e5b0b264d28e295b91ccf67ce577c613f427244
 EBUILD gst-plugins-base-1.22.11-r1.ebuild 5643 BLAKE2B bebdcd333669924df273c3b287993ef4be01a40b0737f207a505445d15ebab2ab413689a225c677536b1095f813613b196e99c8e3457606ec16c844eac66971d SHA512 ee7ce316402da7b965b5d758f3d55fe980bdde8bd8eb85abdc1902c076acc86b273289f430a5409e879b3d0034b605497454302f84d64afc8091df88689cd48d
-EBUILD gst-plugins-base-1.22.12.ebuild 5649 BLAKE2B 9e52d136a1026685541e78ccf774c8429afe072167dda5231ccadee07dc7c6408c2752e8f6b65df51c8d44ae25127d5e6e4926ec7edce4bef4b61bb1347a1f9e SHA512 028a1adf37210b9b8846346a5aee2bed222dcc05fde811f2cef4991ccd83324fe5f3a3b8edc512ac89bc4027f1e8c4eedf1eb9129e8d190d96f8901a81f84af1
+EBUILD gst-plugins-base-1.22.12.ebuild 5643 BLAKE2B 67e374b6a65fd97fed6a1977244c04ac6c25e58c199d03f2333e55c8c2119ed5792633b5cb79739b636e78ecb6758be4c9c10a5d63c26ae7757dcffe9607c089 SHA512 8b8d746032ac5c85003d49a8f68024aaf240af4505b6afe23da0e8b3a47d5c3899bee8a091fee6d083db95f0e186f6e80604d82596f4a5bb8a0a93c6e625619e
+EBUILD gst-plugins-base-1.24.10.ebuild 5748 BLAKE2B 1fa8140de69f7a691c7881878d70615e2ad7a4aa671f543f4f7ba9f6f3f1f258cc4890096a895d9ff559b2956323e40950cc7e600da999d19b2c59bd9ce014b8 SHA512 e974bdfda21f396b3ba6ab1daabab1860a0d05bebd7cccdb5206424dc1be81402a9b2d5c8a12e82442678ec0a3a692fb13009aabac607102653cc2fe30bd3fd9
 MISC metadata.xml 1013 BLAKE2B 97a1460e8774c2a5b51a2a19e0c770794439af5e661eb26e365f0eb4edc6887b7b7e02335f4d8ef9dee0dea84cfc5f6f550f0569d1ecbbf9c715d91f3b5fbd9b SHA512 9e69852f7dda892dd3e395a403d06319d7438db93c03e8c82e4584acc2493d7f91d79d6ad6c02149419a08b81ca08428ccbc8472cb4848d60428b5d29992d907
diff --git a/media-libs/gst-plugins-base/gst-plugins-base-1.22.12.ebuild b/media-libs/gst-plugins-base/gst-plugins-base-1.22.12.ebuild
index 4610b9698839..7ff6a0837362 100644
--- a/media-libs/gst-plugins-base/gst-plugins-base-1.22.12.ebuild
+++ b/media-libs/gst-plugins-base/gst-plugins-base-1.22.12.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2024 Gentoo Authors
+# Copyright 1999-2025 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -10,7 +10,7 @@ DESCRIPTION="Basepack of plugins for gstreamer"
 HOMEPAGE="https://gstreamer.freedesktop.org/"
 
 LICENSE="GPL-2+ LGPL-2+"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~mips ppc ppc64 ~riscv ~sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
 
 # For OpenGL we have three separate concepts, with a list of possibilities in each:
 #  * opengl APIs - opengl and/or gles2; USE=opengl and USE=gles2 enable these accordingly; if neither is enabled, OpenGL helper library and elements are not built at all and all the other options aren't relevant
diff --git a/media-libs/gst-plugins-base/gst-plugins-base-1.24.10.ebuild b/media-libs/gst-plugins-base/gst-plugins-base-1.24.10.ebuild
new file mode 100644
index 000000000000..14a809042334
--- /dev/null
+++ b/media-libs/gst-plugins-base/gst-plugins-base-1.24.10.ebuild
@@ -0,0 +1,150 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+GST_ORG_MODULE="gst-plugins-base"
+
+inherit flag-o-matic gstreamer-meson
+
+DESCRIPTION="Basepack of plugins for gstreamer"
+HOMEPAGE="https://gstreamer.freedesktop.org/"
+
+LICENSE="GPL-2+ LGPL-2+"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
+
+# For OpenGL we have three separate concepts, with a list of possibilities in each:
+#  * opengl APIs - opengl and/or gles2; USE=opengl and USE=gles2 enable these accordingly; if neither is enabled, OpenGL helper library and elements are not built at all and all the other options aren't relevant
+#  * opengl platforms - glx and/or egl; also cgl, wgl, eagl for non-linux; USE="X opengl" enables glx platform; USE="egl" enables egl platform. Rest is up for relevant prefix teams.
+#  * opengl windowing system - x11, wayland, win32, cocoa, android, viv_fb, gbm and/or dispmanx; USE=X enables x11 (but for WSI it's automagic - FIXME), USE=wayland enables wayland, USE=gbm enables gbm (automagic upstream - FIXME); rest is up for relevant prefix/arch teams/contributors to test and provide patches
+# With the following limitations:
+#  * If opengl and/or gles2 is enabled, a platform has to be enabled - x11 or egl in our case, but x11 (glx) is acceptable only with opengl
+#  * If opengl and/or gles2 is enabled, a windowing system has to be enabled - x11, wayland or gbm in our case
+#  * glx platform requires opengl API (but we don't REQUIRED_USE that as USE=X is common, glx is just disabled with USE=-opengl or USE=-X)
+#  * wayland, gbm and most other non-glx WSIs require egl platform
+# Additionally there is optional dmabuf support with egl for additional dmabuf based upload/download/eglimage options;
+#  and optional graphene usage for gltransformation and glvideoflip elements and more GLSL Uniforms support in glshader;
+#  and libpng/jpeg are required for gloverlay element;
+
+# Keep default IUSE options for relevant ones mirrored with gst-plugins-gtk and gst-plugins-bad
+IUSE="alsa +egl gbm +gles2 +introspection ivorbis +ogg opengl +orc +pango theora +vorbis wayland +X"
+GL_REQUIRED_USE="
+	|| ( gbm wayland X )
+	wayland? ( egl )
+	gbm? ( egl )
+"
+REQUIRED_USE="
+	ivorbis? ( ogg )
+	theora? ( ogg )
+	vorbis? ( ogg )
+	opengl? ( || ( egl X ) ${GL_REQUIRED_USE} )
+	gles2? ( egl ${GL_REQUIRED_USE} )
+"
+
+# Dependencies needed by opengl library and plugin (enabled via USE gles2 and/or opengl)
+# dmabuf automagic from libdrm headers (drm_fourcc.h) and EGL, so ensure it with USE=egl (platform independent header used only, thus no MULTILIB_USEDEP); provides dmabuf based upload/download/eglimage options
+GL_DEPS="
+	|| (
+		>=media-libs/mesa-24.1.0_rc1[opengl,wayland?,${MULTILIB_USEDEP}]
+		<media-libs/mesa-24.1.0_rc1[egl(+)?,gbm(+)?,gles2?,wayland?,${MULTILIB_USEDEP}]
+	)
+	egl? (
+		x11-libs/libdrm
+	)
+	gbm? (
+		>=dev-libs/libgudev-147[${MULTILIB_USEDEP}]
+		>=x11-libs/libdrm-2.4.55[${MULTILIB_USEDEP}]
+	)
+	wayland? (
+		>=dev-libs/wayland-1.20.0[${MULTILIB_USEDEP}]
+		>=dev-libs/wayland-protocols-1.15
+	)
+
+	>=media-libs/graphene-1.4.0[${MULTILIB_USEDEP}]
+	media-libs/libpng:0[${MULTILIB_USEDEP}]
+	media-libs/libjpeg-turbo:0=[${MULTILIB_USEDEP}]
+" # graphene for optional gltransformation and glvideoflip elements and more GLSL Uniforms support in glshader; libpng/jpeg for gloverlay element
+# >=media-libs/graphene-1.4.0[${MULTILIB_USEDEP}]
+
+RDEPEND="
+	app-text/iso-codes
+	>=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}]
+	alsa? ( >=media-libs/alsa-lib-1.0.27.2[${MULTILIB_USEDEP}] )
+	introspection? ( >=dev-libs/gobject-introspection-1.31.1:= )
+	ivorbis? ( >=media-libs/tremor-0_pre20130223[${MULTILIB_USEDEP}] )
+	ogg? ( >=media-libs/libogg-1.3.0[${MULTILIB_USEDEP}] )
+	orc? ( >=dev-lang/orc-0.4.33[${MULTILIB_USEDEP}] )
+	kernel_linux? ( >=x11-libs/libdrm-2.4.55[${MULTILIB_USEDEP}] )
+	pango? ( >=x11-libs/pango-1.36.3[${MULTILIB_USEDEP}] )
+	theora? ( >=media-libs/libtheora-1.1.1[encode,${MULTILIB_USEDEP}] )
+	vorbis? ( >=media-libs/libvorbis-1.3.3-r1[${MULTILIB_USEDEP}] )
+	X? (
+		>=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libXext-1.3.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libXv-1.0.10[${MULTILIB_USEDEP}]
+	)
+
+	gles2? ( ${GL_DEPS} )
+	opengl? ( ${GL_DEPS} )
+"
+DEPEND="${RDEPEND}
+	dev-util/glib-utils
+	X? ( x11-base/xorg-proto )
+"
+
+DOCS=( AUTHORS NEWS README.md RELEASE )
+
+PATCHES=(
+)
+
+multilib_src_configure() {
+	filter-flags -mno-sse -mno-sse2 -mno-sse4.1 #610340
+
+	# opus: split to media-plugins/gst-plugins-opus
+	GST_PLUGINS_NOAUTO="alsa gl ogg pango theora vorbis x11 xshm xvideo"
+
+	local emesonargs=(
+		-Dtools=enabled
+
+		$(meson_feature alsa)
+		$(meson_feature kernel_linux drm)
+		$(meson_feature ogg)
+		$(meson_feature pango)
+		$(meson_feature theora)
+		$(meson_feature vorbis)
+		$(meson_feature X x11)
+		$(meson_feature X xshm)
+		$(meson_feature X xvideo)
+	)
+
+	if use opengl || use gles2; then
+		# because meson doesn't like extraneous commas
+		local gl_api=( $(use opengl && echo opengl) $(use gles2 && echo gles2) )
+		local gl_platform=( $(use X && use opengl && echo glx) $(use egl && echo egl) )
+		local gl_winsys=(
+			$(use X && echo x11)
+			$(use wayland && echo wayland)
+			$(use egl && echo egl)
+			$(use gbm && echo gbm)
+		)
+
+		emesonargs+=(
+			-Dgl=enabled
+			-Dgl-graphene=enabled
+			-Dgl_api=$(IFS=, ; echo "${gl_api[*]}")
+			-Dgl_platform=$(IFS=, ; echo "${gl_platform[*]}")
+			-Dgl_winsys=$(IFS=, ; echo "${gl_winsys[*]}")
+		)
+	else
+		emesonargs+=(
+			-Dgl=disabled
+			-Dgl_api=
+			-Dgl_platform=
+			-Dgl_winsys=
+		)
+	fi
+
+	# Workaround EGL/eglplatform.h being built with X11 present
+	use X || export CFLAGS="${CFLAGS} -DEGL_NO_X11"
+
+	gstreamer_multilib_src_configure
+}