gentoo auto-resync : 01:09:2022 - 19:24:10

4 files changed, 171 insertions, 8 deletions

diff --git a/media-libs/gegl/Manifest b/media-libs/gegl/Manifest
index fac89bdb0563..efa2f1d33cf6 100644
--- a/media-libs/gegl/Manifest
+++ b/media-libs/gegl/Manifest
@@ -1,4 +1,6 @@
 DIST gegl-0.4.36.tar.xz 5680876 BLAKE2B e2051d21eadfd6ff5c4547d337e749ebb9526be0b45bf80116cfdd1bb98b0fd3b4cced83b4700ecb04c003f83074928ac0c7b4bc8929134c57950a1ac957d50b SHA512 4d681091b15e7911229f86bf22381d62268451da57bba072bcb8ee3f4db79e2719dd7e70ab208c2c021e5353f42a9f88c18f62132512b18fe78ed6ad279660f8
+DIST gegl-0.4.38.tar.xz 5722188 BLAKE2B 8079326f50b18b4698e83f90a4fa8fd26722a3b6fd8d81a9cc1a735e765591e1b76a3dbbef37e7a793231becf265b28bd0bd235076e43ae00c4071d8986a2edf SHA512 367aa67019557b10a19536c56dfbf6687ade183585eeefec65ce12d3c72f5d78330e02ae0ff403609bb7579dc25340a7132b81d36bbf84327c658a96a2d04d4c
 EBUILD gegl-0.4.36-r1.ebuild 4588 BLAKE2B dc35ccabe00e2e53c759964de5556939ccb5047ccb2c70fe0039a52f410afb21696f501c1e51da20138920ba54c66781ee8c1cd0099677a866b7d68df9de01c7 SHA512 65ed7c2a49db5444b2ec2032658130dfd331fe1b1ba179f7d7a26ad81aed3236538ebc947f4991fd396b1370679566941cc9360ebf2ff4a334096659ec3902c0
-EBUILD gegl-9999.ebuild 4378 BLAKE2B 84ff73cd6821e16038c52a87daaa404d7b4c09b701c0251bd2744bdd57a546f90f636efce4e6dd838c99131e251bd6c710fbb0190449bb51e412c3a357df7416 SHA512 5aa398283404313498eb5638f0a0c9c31b0f8db59acde5d5fb244558cb8148510463217c850196d972e9eb8a5148401ed03604580dbaf3e0248ccaeb743921dd
-MISC metadata.xml 581 BLAKE2B 180d0731a2d488b8772fc6aa8411871cb892a886ff93368a39a32b284702b7daeedfe32fdf19c0f11101304231ed1338cd8462d7788a08df1bc7ae1b8ac16a66 SHA512 bc5907cd42cbba848b57266cf1023a402296ed96f6ea53ede2501fb49923c23d636622ec569463df402dbb5db3c970353b92b110962945806222ec92257a12d9
+EBUILD gegl-0.4.38.ebuild 4697 BLAKE2B d9746761982eb13b9a01929ea87a92c8c3cc305265253e227e7a3f23f151cd70d1965cacd9941fbb93735ea65b6b31284bad8516dcecac31ea6ab3e7f7797bf1 SHA512 828b4f007b4e6f1123f6da8d5cc53ae3202ce02029b143f4e45c2bcbb1df82048902ee13fcb1e9aa5a953f1df73a25c862d3423edc5a1fff71b694f0fb16d4d0
+EBUILD gegl-9999.ebuild 4483 BLAKE2B 18ae15481a8fef93605238456bb5e03734d58aec6e33d91e72bfd9a8a4e9b3628efd2a0d2360b7bf1b5006175233a1c442121d7e4ef2ba8b24f1b320fa7e8f5c SHA512 39d9a36b5fc7be68ad7bba03248a3e1e6f2fbd93be044d482d3b14ad3569fc0a76a42fe3a1f4783b36897d1b6d82c68391bda6d95c8bbdf9ba3e6627ad6506a8
+MISC metadata.xml 680 BLAKE2B 6785a153412860b02b1ca6daa7c6e62f5f178c0a01346bd42dac8da5254ec9ada1c4aaab96944072216b414e5bdc5d8999fbb16dbe6c5127f8988873b07817e7 SHA512 c75bc64503925b586e6aaee3a38fceb793e0d9b3f17bb487fd72a32615ac24eb509e4efb7243d9606572507f41f98ba6b5fe8ac12ea23a87f012d69d24e92d5e
diff --git a/media-libs/gegl/gegl-0.4.38.ebuild b/media-libs/gegl/gegl-0.4.38.ebuild
new file mode 100644
index 000000000000..79681b0950fe
--- /dev/null
+++ b/media-libs/gegl/gegl-0.4.38.ebuild
@@ -0,0 +1,156 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..11} )
+# vala and introspection support is broken, bug #468208
+VALA_USE_DEPEND=vapigen
+
+inherit flag-o-matic meson optfeature python-any-r1 vala
+
+if [[ ${PV} == *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://gitlab.gnome.org/GNOME/gegl.git"
+	SRC_URI=""
+else
+	SRC_URI="https://download.gimp.org/pub/${PN}/${PV:0:3}/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~x86 ~amd64-linux ~x86-linux"
+fi
+
+DESCRIPTION="A graph based image processing framework"
+HOMEPAGE="https://gegl.org/"
+
+LICENSE="|| ( GPL-3+ LGPL-3 )"
+SLOT="0.4"
+
+IUSE="cairo debug ffmpeg introspection lcms lensfun openexr pdf raw sdl sdl2 svg test tiff umfpack vala v4l webp"
+REQUIRED_USE="
+	svg? ( cairo )
+	test? ( introspection )
+	vala? ( introspection )
+"
+
+RESTRICT="!test? ( test )"
+
+# NOTE: Even current libav 11.4 does not have AV_CODEC_CAP_VARIABLE_FRAME_SIZE
+#       so there is no chance to support libav right now (Gentoo bug #567638)
+#       If it returns, please check prior GEGL ebuilds for how libav was integrated.  Thanks!
+RDEPEND="
+	>=dev-libs/glib-2.68.2:2
+	>=dev-libs/json-glib-1.2.6
+	>=media-libs/babl-0.1.96[introspection?,lcms?,vala?]
+	media-libs/libjpeg-turbo
+	media-libs/libnsgif
+	>=media-libs/libpng-1.6.0:0=
+	>=sys-libs/zlib-1.2.0
+	>=x11-libs/gdk-pixbuf-2.32:2
+	>=x11-libs/pango-1.38.0
+	cairo? ( >=x11-libs/cairo-1.12.2 )
+	ffmpeg? ( media-video/ffmpeg:0= )
+	introspection? ( >=dev-libs/gobject-introspection-1.32:= )
+	lcms? ( >=media-libs/lcms-2.8:2 )
+	lensfun? ( >=media-libs/lensfun-0.2.5 )
+	openexr? ( >=media-libs/openexr-1.6.1:= )
+	pdf? ( >=app-text/poppler-0.71.0[cairo] )
+	raw? ( >=media-libs/libraw-0.15.4:0= )
+	sdl? ( >=media-libs/libsdl-1.2.0 )
+	sdl2? ( >=media-libs/libsdl2-2.0.20 )
+	svg? ( >=gnome-base/librsvg-2.40.6:2 )
+	tiff? ( >=media-libs/tiff-4:0 )
+	umfpack? ( sci-libs/umfpack )
+	v4l? ( >=media-libs/libv4l-1.0.1 )
+	webp? ( >=media-libs/libwebp-0.5.0:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-lang/perl
+	>=dev-util/gtk-doc-am-1
+	>=sys-devel/gettext-0.19.8
+	>=sys-devel/libtool-2.2
+	virtual/pkgconfig
+	test? ( $(python_gen_any_dep '>=dev-python/pygobject-3.2:3[${PYTHON_USEDEP}]') )
+	vala? ( $(vala_depend) )
+"
+
+DOCS=( AUTHORS docs/ChangeLog docs/NEWS.adoc )
+
+python_check_deps() {
+	use test || return 0
+	has_version -b ">=dev-python/pygobject-3.2:3[${PYTHON_USEDEP}]"
+}
+
+src_prepare() {
+	default
+	# patch executables suffix
+	sed -i -e "s/'gegl'/'gegl-0.4'/" bin/meson.build || die
+	sed -i -e "s/'gegl-imgcmp'/'gegl-imgcmp-0.4'/" tools/meson.build || die
+	sed -i -e "s/gegl-imgcmp/gegl-imgcmp-0.4/" tests/simple/test-exp-combine.sh || die
+	# skip UNEXPECTED PASSED 'matting-levin' test
+	sed -i -e "s/composition_tests += 'matting-levin'//" \
+		-e "s/composition_tests_fail += 'matting-levin'//" tests/compositions/meson.build || die
+
+	# don't require Apple's OpenCL on versions of OSX that don't have it
+	if [[ ${CHOST} == *-darwin* && ${CHOST#*-darwin} -le 9 ]] ; then
+		sed -i -e 's/#ifdef __APPLE__/#if 0/' gegl/opencl/* || die
+	fi
+
+	# fix 'build'headers from *.cl on gentoo-hardened, bug 739816
+	pushd "${S}/opencl/" || die
+	for file in *.cl; do
+		if [[ -f ${file} ]]; then
+			"${EPYTHON}" cltostring.py "${file}" || die
+		fi
+	done
+	popd || die
+}
+
+src_configure() {
+	# Bug #859901
+	filter-lto
+
+	use vala && vala_setup
+
+	local emesonargs=(
+		#  - Disable documentation as the generating is bit automagic
+		#    if anyone wants to work on it just create bug with patch
+		-Ddocs=false
+		-Dexiv2=disabled
+		-Dgdk-pixbuf=enabled
+		-Djasper=disabled
+		#  - libspiro: not in portage main tree
+		-Dlibspiro=disabled
+		-Dlua=disabled
+		-Dmrg=disabled
+		-Dpango=enabled
+		#  - Parameter -Dworkshop=false disables any use of Lua, effectivly
+		-Dworkshop=false
+		$(meson_feature cairo)
+		$(meson_feature cairo pangocairo)
+		$(meson_feature ffmpeg libav)
+		$(meson_feature lcms)
+		$(meson_feature lensfun)
+		$(meson_feature openexr)
+		$(meson_feature pdf poppler)
+		$(meson_feature raw libraw)
+		$(meson_feature sdl sdl1)
+		$(meson_feature sdl2 sdl2)
+		$(meson_feature svg librsvg)
+		$(meson_feature test pygobject)
+		$(meson_feature tiff libtiff)
+		$(meson_feature umfpack)
+		#  - v4l support does not work with our media-libs/libv4l-0.8.9,
+		#    upstream bug at https://bugzilla.gnome.org/show_bug.cgi?id=654675
+		$(meson_feature v4l libv4l)
+		$(meson_feature v4l libv4l2)
+		$(meson_feature vala vapigen)
+		$(meson_feature webp)
+		$(meson_use introspection)
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	optfeature "'Show Image Graph' under GIMP[debug] menu 'File - Debug'" media-gfx/graphviz
+}
diff --git a/media-libs/gegl/gegl-9999.ebuild b/media-libs/gegl/gegl-9999.ebuild
index bd02e5d34adf..0039c8802478 100644
--- a/media-libs/gegl/gegl-9999.ebuild
+++ b/media-libs/gegl/gegl-9999.ebuild
@@ -3,11 +3,11 @@
 
 EAPI=8
 
-PYTHON_COMPAT=( python3_{8..10} )
+PYTHON_COMPAT=( python3_{8..11} )
 # vala and introspection support is broken, bug #468208
 VALA_USE_DEPEND=vapigen
 
-inherit meson optfeature python-any-r1 vala
+inherit flag-o-matic meson optfeature python-any-r1 vala
 
 if [[ ${PV} == *9999* ]]; then
 	inherit git-r3
@@ -24,7 +24,7 @@ HOMEPAGE="https://gegl.org/"
 LICENSE="|| ( GPL-3+ LGPL-3 )"
 SLOT="0.4"
 
-IUSE="cairo debug ffmpeg introspection lcms lensfun openexr pdf raw sdl svg test tiff umfpack vala v4l webp"
+IUSE="cairo debug ffmpeg introspection lcms lensfun openexr pdf raw sdl sdl2 svg test tiff umfpack vala v4l webp"
 REQUIRED_USE="
 	svg? ( cairo )
 	test? ( introspection )
@@ -39,11 +39,11 @@ RESTRICT="!test? ( test )"
 RDEPEND="
 	>=dev-libs/glib-2.68.2:2
 	>=dev-libs/json-glib-1.2.6
-	>=media-libs/babl-0.1.90[introspection?,lcms?,vala?]
+	>=media-libs/babl-0.1.96[introspection?,lcms?,vala?]
+	media-libs/libjpeg-turbo
 	media-libs/libnsgif
 	>=media-libs/libpng-1.6.0:0=
 	>=sys-libs/zlib-1.2.0
-	virtual/jpeg:0=
 	>=x11-libs/gdk-pixbuf-2.32:2
 	>=x11-libs/pango-1.38.0
 	cairo? ( >=x11-libs/cairo-1.12.2 )
@@ -55,6 +55,7 @@ RDEPEND="
 	pdf? ( >=app-text/poppler-0.71.0[cairo] )
 	raw? ( >=media-libs/libraw-0.15.4:0= )
 	sdl? ( >=media-libs/libsdl-1.2.0 )
+	sdl2? ( >=media-libs/libsdl2-2.0.20 )
 	svg? ( >=gnome-base/librsvg-2.40.6:2 )
 	tiff? ( >=media-libs/tiff-4:0 )
 	umfpack? ( sci-libs/umfpack )
@@ -97,6 +98,9 @@ src_prepare() {
 }
 
 src_configure() {
+	# Bug #859901
+	filter-lto
+
 	use vala && vala_setup
 
 	local emesonargs=(
@@ -111,7 +115,6 @@ src_configure() {
 		-Dlua=disabled
 		-Dmrg=disabled
 		-Dpango=enabled
-		-Dsdl2=disabled
 		#  - Parameter -Dworkshop=false disables any use of Lua, effectivly
 		-Dworkshop=false
 		$(meson_feature cairo)
@@ -123,6 +126,7 @@ src_configure() {
 		$(meson_feature pdf poppler)
 		$(meson_feature raw libraw)
 		$(meson_feature sdl sdl1)
+		$(meson_feature sdl2 sdl2)
 		$(meson_feature svg librsvg)
 		$(meson_feature test pygobject)
 		$(meson_feature tiff libtiff)
diff --git a/media-libs/gegl/metadata.xml b/media-libs/gegl/metadata.xml
index 6c5403ce1547..3a7a19add4b2 100644
--- a/media-libs/gegl/metadata.xml
+++ b/media-libs/gegl/metadata.xml
@@ -11,6 +11,7 @@
 	</maintainer>
 	<use>
 		<flag name="lensfun">Enable support for <pkg>media-libs/lensfun</pkg>.</flag>
+		<flag name="sdl2">Add support for Simple Direct Layer 2.0 (<pkg>media-libs/libsdl2</pkg>)</flag>
 		<flag name="umfpack">Enable sparse solving via <pkg>sci-libs/umfpack</pkg>.</flag>
 	</use>
 </pkgmetadata>