gentoo resync : 10.09.2021

3 files changed, 162 insertions, 3 deletions

diff --git a/media-libs/gegl/Manifest b/media-libs/gegl/Manifest
index 8f8508b86f44..7c8e0b87ffda 100644
--- a/media-libs/gegl/Manifest
+++ b/media-libs/gegl/Manifest
@@ -5,8 +5,10 @@ AUX gegl-0.4.30-fix-build-openexr-3.patch 694 BLAKE2B 45bfdc9ebb8bb651e84a5e7038
 DIST gegl-0.4.26.tar.xz 4942492 BLAKE2B 656a9c0d339d136f3f2efbb1484fbfea27deab241821503b31d74b015fe8766ee8d931ea0bf1a354200581bc54fea307a2cfb9b469e73a211a77d109d33707f3 SHA512 634778df0060ffe630121c24044a6ddcc7f2de0ff61b02be24db4054c6f3def24373b28dd1152d62882d58383a3aa7a1f74cd5b743a299fd0719a2a2ff992d24
 DIST gegl-0.4.28.tar.xz 4966580 BLAKE2B fcf4fb0e4fac0357d25987348c6abe2434db17bd974ab39f15c3e11a6a6ee8630469d0b53fe2cc76a3af90c9b3a6ba88972301d6fac8df693f5fa12919e0bfa0 SHA512 ad02dc4e4ff7c5beddb3cc8e1c05b6f858e7164dfd239bada70cc138a541a36f82c0e415c6fb81d4799ae8acdcb95ddb607c6b24481a73c5ae0d6e87c73fdbb7
 DIST gegl-0.4.30.tar.xz 5398052 BLAKE2B c57b34ed64d3b9305d3e639b872c283bd4c9c798d13f7bde49b991044139bb4e433a3adb0a9e991b78b2905985496ca3bf4ed116333ceaaccc043b8a66426131 SHA512 73db2d18260ba061fbbc2adb3256ea9d5b822b57f5654cc3aefb59e7afeeb2e4f0fd7e95ac14603c0a549935df04d5744001089efb378511c914c68664dbd378
+DIST gegl-0.4.32.tar.xz 5633796 BLAKE2B a4ba5d19291a61c6903dcc368e6cc3e1934e8d89b555e81afd22709504fbb8a7ed104890af5f1e7bfbdd5664caef8f5e015341c7882f2171ecb518afe32a65ef SHA512 68da02b8df0a1d234063958896f3678ead62772e611bddb39a6f21ec58cc744599d0a691224c057f2da4d04f2ccfb155a545deea92e77c728dbaeeb90e68cad6
 EBUILD gegl-0.4.26-r1.ebuild 5022 BLAKE2B d76955b962ac995d1648152318607f4ebc4f74680e95e357eaf2ff0391800212c9cf0ba2bb7445ce89031ff0d0fc1c5c14046903de32bb4e49a6adc3267fb49e SHA512 14bf294c9c1b073d7c3dce07b61b0b02d298ed3fe9d53825c91c4ed6b10d28fdfebc73dcb63fff9dbd272d0278b688a64236ca0ddce5ca15722af2b17d009912
 EBUILD gegl-0.4.28.ebuild 5034 BLAKE2B aa7b52183ed7cf1047dc19be3343fd06efda464eb03aecd93959bbecde260a4d7aaf172bb91194d672fa8ae2512ef698e0b77492a8bc6307eda9c4f093271f73 SHA512 bb2ab17cfbab58b420bad3b957a2b84563d7294631a7b188fef6a5dc530b742da96b6dee5d0fc8103ee419e9ef2b587ee1011e02cb96bac372df7f68404fab8d
 EBUILD gegl-0.4.30.ebuild 4830 BLAKE2B fa94364b30d66a79315ea3590fadf06467c8b24ae4ed83b7d4e27435b4e0b54f48a7252e009165d1aacbd0db72673c9ed3d32cd593c0ab652e74aec635f2aeae SHA512 65935c4762ab9e6aae27e23fc0ea4498db7d4ce7cc3479c694b9fd665a1dbe90aed34c467fa7dfc72955ee522a955dbfa9944f8d665e4e06bd7c9039a6d9de69
-EBUILD gegl-9999.ebuild 4500 BLAKE2B 275eff93d21c7f810325e111597a74faead0fc7065dabca1eeb9d98ab7d632ac663c0d88e647b817ccaf0caaec518378c17571b466563875b32db17c0173106a SHA512 c6b2342384bb704cb5ea8870e12aa4598ff1d78d14b45ed31a51c5819aab8dbad0fdd4a6f31400de248a30d646f3860c7353d69315796b0b5bbbf250a25a1315
+EBUILD gegl-0.4.32.ebuild 4772 BLAKE2B f836d4e8dec2fcc1e980b7f4f455558d92878939fc5cf5ebefef9eccad28f7559bd5e799834a340a324b515a6d360e257b01414b08ae410410a1f28332841534 SHA512 f59ca98ae2590ac71a9cbf1698f91bb1c5db9fbddd0e5fb675bce3f99f589356779c0c5279aa6558dceab5ac4573f9e5586318ff99773b856e282fd86ec23d69
+EBUILD gegl-9999.ebuild 4502 BLAKE2B 9d432a8647e2d5b2e2f77025a602b92ceecca6080b1945e6a5e3971619ff00e918f277a10ca5accc9c0feb5aa7786d33d76fddc530aa9b4f56b740f5d5a0f7e1 SHA512 a9c920fdf717898e9722d11b59a1c78d7c0a7686494b904df2de29216a921a049e2687bc61457fd1cc9f347079990fc7200a6afd6f0bb1bda96e591ea74d7794
 MISC metadata.xml 580 BLAKE2B 604088ef1ce307cb04f44e6c204355569136168f6f574a3b58a5ce374b9e9d4e41476107f11cd5990d0ae39ace5db5420e372c7c88d409b38930cc8b6030b3c0 SHA512 a59cd50a65117f265616e2b595ec3cc95a59f9caac46218fb137af2f62067c5563a4dc53930188b6adf13b0548f02b637bb8312863ee1976ace90ec509e4a2f1
diff --git a/media-libs/gegl/gegl-0.4.32.ebuild b/media-libs/gegl/gegl-0.4.32.ebuild
new file mode 100644
index 000000000000..95d000ce76ab
--- /dev/null
+++ b/media-libs/gegl/gegl-0.4.32.ebuild
@@ -0,0 +1,157 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+# vala and introspection support is broken, bug #468208
+VALA_USE_DEPEND=vapigen
+
+inherit meson optfeature python-any-r1 vala
+
+if [[ ${PV} == *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://gitlab.gnome.org/GNOME/gegl.git"
+	SRC_URI=""
+else
+	SRC_URI="https://download.gimp.org/pub/${PN}/${PV:0:3}/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~x86 ~amd64-linux ~x86-linux"
+fi
+
+DESCRIPTION="A graph based image processing framework"
+HOMEPAGE="https://gegl.org/"
+
+LICENSE="|| ( GPL-3+ LGPL-3 )"
+SLOT="0.4"
+
+IUSE="cairo debug ffmpeg introspection lcms lensfun openexr pdf raw sdl svg test tiff umfpack vala v4l webp"
+REQUIRED_USE="
+	svg? ( cairo )
+	test? ( introspection )
+	vala? ( introspection )
+"
+
+RESTRICT="!test? ( test )"
+
+# NOTE: Even current libav 11.4 does not have AV_CODEC_CAP_VARIABLE_FRAME_SIZE
+#       so there is no chance to support libav right now (Gentoo bug #567638)
+#       If it returns, please check prior GEGL ebuilds for how libav was integrated.  Thanks!
+RDEPEND="
+	>=dev-libs/glib-2.68.2:2
+	>=dev-libs/json-glib-1.2.6
+	>=media-libs/babl-0.1.88[introspection?,lcms?,vala?]
+	media-libs/libnsgif
+	>=media-libs/libpng-1.6.0:0=
+	>=sys-libs/zlib-1.2.0
+	virtual/jpeg:0=
+	>=x11-libs/gdk-pixbuf-2.32:2
+	>=x11-libs/pango-1.38.0
+	cairo? ( >=x11-libs/cairo-1.12.2 )
+	ffmpeg? ( media-video/ffmpeg:0= )
+	introspection? ( >=dev-libs/gobject-introspection-1.32:= )
+	lcms? ( >=media-libs/lcms-2.8:2 )
+	lensfun? ( >=media-libs/lensfun-0.2.5 )
+	openexr? ( >=media-libs/openexr-1.6.1:= )
+	pdf? ( >=app-text/poppler-0.71.0[cairo] )
+	raw? ( >=media-libs/libraw-0.15.4:0= )
+	sdl? ( >=media-libs/libsdl-1.2.0 )
+	svg? ( >=gnome-base/librsvg-2.40.6:2 )
+	tiff? ( >=media-libs/tiff-4:0 )
+	umfpack? ( sci-libs/umfpack )
+	v4l? ( >=media-libs/libv4l-1.0.1 )
+	webp? ( >=media-libs/libwebp-0.5.0:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-lang/perl
+	>=dev-util/gtk-doc-am-1
+	>=sys-devel/gettext-0.19.8
+	>=sys-devel/libtool-2.2
+	virtual/pkgconfig
+	test? ( $(python_gen_any_dep '>=dev-python/pygobject-3.2:3[${PYTHON_USEDEP}]') )
+	vala? ( $(vala_depend) )
+"
+
+DOCS=( AUTHORS docs/ChangeLog docs/NEWS.adoc )
+
+python_check_deps() {
+	use test || return 0
+	has_version -b ">=dev-python/pygobject-3.2:3[${PYTHON_USEDEP}]"
+}
+
+src_prepare() {
+	default
+	# patch executables suffix
+	sed -i -e "s/'gegl'/'gegl-0.4'/" bin/meson.build || die
+	sed -i -e "s/'gegl-imgcmp'/'gegl-imgcmp-0.4'/" tools/meson.build || die
+	sed -i -e "s/gegl-imgcmp/gegl-imgcmp-0.4/" tests/simple/test-exp-combine.sh || die
+	# skip UNEXPECTED PASSED 'matting-levin' test
+	sed -i -e "s/composition_tests += 'matting-levin'//" \
+		-e "s/composition_tests_fail += 'matting-levin'//" tests/compositions/meson.build || die
+
+	# don't require Apple's OpenCL on versions of OSX that don't have it
+	if [[ ${CHOST} == *-darwin* && ${CHOST#*-darwin} -le 9 ]] ; then
+		sed -i -e 's/#ifdef __APPLE__/#if 0/' gegl/opencl/* || die
+	fi
+
+	# commit 7c78497b : tests that use gegl.png are broken on non-amd64
+	sed -e '/clones.xml/d' \
+		-e '/composite-transform.xml/d' \
+		-i tests/compositions/meson.build || die
+
+	# fix 'build'headers from *.cl on gentoo-hardened, bug 739816
+	pushd "${S}/opencl/" || die
+	for file in *.cl; do
+		if [[ -f ${file} ]]; then
+			"${EPYTHON}" cltostring.py "${file}" || die
+		fi
+	done
+	popd || die
+
+	use vala && vala_src_prepare
+}
+
+src_configure() {
+	local emesonargs=(
+		#  - Disable documentation as the generating is bit automagic
+		#    if anyone wants to work on it just create bug with patch
+		-Ddocs=false
+		-Dexiv2=disabled
+		-Dgdk-pixbuf=enabled
+		-Djasper=disabled
+		#  - libspiro: not in portage main tree
+		-Dlibspiro=disabled
+		-Dlua=disabled
+		-Dmrg=disabled
+		-Dpango=enabled
+		-Dsdl2=disabled
+		#  - Parameter -Dworkshop=false disables any use of Lua, effectivly
+		-Dworkshop=false
+		$(meson_feature cairo)
+		$(meson_feature cairo pangocairo)
+		$(meson_feature ffmpeg libav)
+		$(meson_feature lcms)
+		$(meson_feature lensfun)
+		$(meson_feature openexr)
+		$(meson_feature pdf poppler)
+		$(meson_feature raw libraw)
+		$(meson_feature sdl sdl1)
+		$(meson_feature svg librsvg)
+		$(meson_feature test pygobject)
+		$(meson_feature tiff libtiff)
+		$(meson_feature umfpack)
+		#  - v4l support does not work with our media-libs/libv4l-0.8.9,
+		#    upstream bug at https://bugzilla.gnome.org/show_bug.cgi?id=654675
+		$(meson_feature v4l libv4l)
+		$(meson_feature v4l libv4l2)
+		$(meson_feature vala vapigen)
+		$(meson_feature webp)
+		$(meson_use introspection)
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	optfeature "'Show Image Graph' under GIMP[debug] menu 'File - Debug'" media-gfx/graphviz
+}
diff --git a/media-libs/gegl/gegl-9999.ebuild b/media-libs/gegl/gegl-9999.ebuild
index 489b8bd6e250..241f4ce6cfa1 100644
--- a/media-libs/gegl/gegl-9999.ebuild
+++ b/media-libs/gegl/gegl-9999.ebuild
@@ -36,9 +36,9 @@ RESTRICT="!test? ( test )"
 #       so there is no chance to support libav right now (Gentoo bug #567638)
 #       If it returns, please check prior GEGL ebuilds for how libav was integrated.  Thanks!
 RDEPEND="
-	>=dev-libs/glib-2.44:2
+	>=dev-libs/glib-2.68.2:2
 	>=dev-libs/json-glib-1.2.6
-	>=media-libs/babl-0.1.84[introspection?,lcms?,vala?]
+	>=media-libs/babl-0.1.88[introspection?,lcms?,vala?]
 	media-libs/libnsgif
 	>=media-libs/libpng-1.6.0:0=
 	>=sys-libs/zlib-1.2.0