gentoo auto-resync : 28:06:2023 - 13:37:56

3 files changed, 171 insertions, 2 deletions

diff --git a/media-libs/gegl/Manifest b/media-libs/gegl/Manifest
index 7db896a8eabb..8f6ebf0d1094 100644
--- a/media-libs/gegl/Manifest
+++ b/media-libs/gegl/Manifest
@@ -3,8 +3,10 @@ AUX gegl-0.4.40-strict-prototypes.patch 2555 BLAKE2B a377756270ea1cae19a5d890305
 DIST gegl-0.4.40.tar.xz 5784744 BLAKE2B c4466a76ec4f7939161e9ead6980b8a701f3fc459c40c3de3e09caa688aae12fb1f4a9979ca82e95011437f229532ba07012590d00aeb97b610b69968faa454f SHA512 99ace5f1b916e56f31483b60a38f885d0e09652c834122390bba4439d9bb1a137d84770e1518187330c44f3491e53393cfb8802ba9ede20658e1c8122e798888
 DIST gegl-0.4.42.tar.xz 5787100 BLAKE2B 6ae3ec98e72b1057b9d84551f56b675edb511994a73979bfccf559e24d3d636ba915aab10d3b3a1b38989d69c63692d3f312c621819700332c8cc1a4b3e86875 SHA512 29ccd93faa6127b6a9b1180eeba47f1b6f9bc06da8a5c9d68315d7474b77ff19d1084a6f4e7b218666b355329b17bc562f5906a334aa2baf93840d7caa0adf57
 DIST gegl-0.4.44.tar.xz 5791844 BLAKE2B dbbdca0ff9985025f528fe298df32672069c09dd87e22ab70330f078ca7fc7efb8b78f8f9077bb559eb61c790c5ab50c53853a1032fe00fbea7080d140baa28c SHA512 4dd3fad0c5e391fc1ac3784d4365ffdc483d37b90a24a29eaa632dd337971674999b2e0f8facf255d86852a3899cc51f4d27f9875ab5849f8b38d9ed5bb7413a
+DIST gegl-0.4.46.tar.xz 5799248 BLAKE2B 2fc9ccd0c711cc901abd50740a24d0f75b162cbb196bdd62ab8430882da3b9ea72c08dd587ecfecaf5e4ba9aca4df51bcd7d98ec197325375b1d954c2995029e SHA512 cd733208da7dc1ec77ca023f03f47e578350e156ad07ece701b39f517a292e9f9c081b3a8a2db846813483b4ddb21f32f9fc8b9c70fea8a6ba27bb97ef8bb847
 EBUILD gegl-0.4.40-r1.ebuild 5056 BLAKE2B 70db81c565564ce7330f36d1435b7abd2c368ac5e967cdb684784537e1752cc2f95453826fdb30d01d93bec5f5a5a94a1fe78cf8e1c57579aef56326d20d0f2d SHA512 3ce0f2aac7baaa4d654d7eaef917ff6c94fa2a4eca16ace26be6423c23facefce5de1e14e82496b9b32c20d12574aab62a3093d328b04308746117b6832b3fcf
 EBUILD gegl-0.4.42-r1.ebuild 5035 BLAKE2B a2140fa970486877e094de08d320f3efafbcb056d60832243744164b4fd2940ed7818c636d9e28249df40437cd2ad4a9a7c6b1351def2f9a8a3de3f8f6f6703a SHA512 49dfa07c3075c5cea33b36df23dcfd5063b5b912072e5ec3034ac44178305ad9ae42767e106b162c7fc0dc23d610abc2ff8ac6bdea49452cfa4e3c3f3b528fba
 EBUILD gegl-0.4.44.ebuild 4966 BLAKE2B 169d2b55625c4fdd9da3c8cf6bca5c29ab30b97b26e811ab5d578559e7db6bf88abb46e658818ffeb1363395f6d1bac7ab9f34e4e2bf6fc9b87707984d1ac2d9 SHA512 a149632eac40fb13edd0aa59bcf523dfedef408cbf2e09199d642735e42707d2d416272de46dcaf7c97978dfbc202e6d69e8ce810f75c9eb8faa4cfb4e7d5023
-EBUILD gegl-9999.ebuild 4749 BLAKE2B f9c275c0ce0223df7af16be825474e687a6447dc78d19342a3cc90504a76aa3c98d65cf9609e6628e7d9fd650c99251be19c283c2f1fbe7be84571420a7096b6 SHA512 a7f6d89d928ce2e7850bbac75bc4af7d7c7d9e2a06724477c83281a4310418782ea340ec1caf9b7d904bc4dbbc3cae8e759a1031344cf7e5c1ec64801c7e69b8
+EBUILD gegl-0.4.46.ebuild 4971 BLAKE2B 6ee186ec15252273ce21003bf4c99ef6f3a7c2d89d18ddce530604195ec712c5178ce9afd848ecdb89969c74a6a81705541dc114c03bf4e684be34cca0fcdc58 SHA512 8bf40d35582cea05f677376c6fc14bbd3c0c18d1059148b74107ca0553f775ef6749ddda99ecb596abdcefcd59246b175dcfe6a9ae9c382deb233e13f31df2ee
+EBUILD gegl-9999.ebuild 4750 BLAKE2B 731f5df46b7bb85f67955308cca358efd4e19da0d1cba2d8ac71bf5cb6927b0d8dfb79bc987370b39d347befd9b1c3a18c7d274cf127b8a3fd1ceba94c04d084 SHA512 825d5201ab3bb13df91d8f09c972b34033b5e965fe7f9e271c4e29eff2a41ce352f2946ca1ea491e5f9e174dd9b6ea90039881c01b93c090d2ec1aa1da60eabc
 MISC metadata.xml 761 BLAKE2B fa74f6ff5ae13c05793505d0a27b7bc8587748ad356fa4f3ec5b48bd2919c6197788ab02bdc02fbdbdfe2f376d93222b600e30915e50f4ee4643e973ce054d86 SHA512 8cf93e9c5130a017bb864144e88cd2a4f2eff17b5543514a3ca84066b90e394dda6ee64a5e49d8db3b48eb905df5eef815f3b2689bc2be9772a01dcd2cecad30
diff --git a/media-libs/gegl/gegl-0.4.46.ebuild b/media-libs/gegl/gegl-0.4.46.ebuild
new file mode 100644
index 000000000000..279651055071
--- /dev/null
+++ b/media-libs/gegl/gegl-0.4.46.ebuild
@@ -0,0 +1,167 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..11} )
+# vala and introspection support is broken, bug #468208
+VALA_USE_DEPEND=vapigen
+
+inherit flag-o-matic meson optfeature python-any-r1 toolchain-funcs vala
+
+if [[ ${PV} == *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://gitlab.gnome.org/GNOME/gegl.git"
+	SRC_URI=""
+else
+	SRC_URI="https://download.gimp.org/pub/${PN}/${PV:0:3}/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~x86 ~amd64-linux ~x86-linux"
+fi
+
+DESCRIPTION="A graph based image processing framework"
+HOMEPAGE="https://gegl.org/"
+
+LICENSE="|| ( GPL-3+ LGPL-3 )"
+SLOT="0.4"
+
+IUSE="cairo debug ffmpeg introspection lcms lensfun openexr openmp pdf raw sdl sdl2 svg test tiff umfpack vala v4l webp"
+REQUIRED_USE="
+	svg? ( cairo )
+	test? ( introspection )
+	vala? ( introspection )
+"
+
+RESTRICT="!test? ( test )"
+
+# NOTE: Even current libav 11.4 does not have AV_CODEC_CAP_VARIABLE_FRAME_SIZE
+#       so there is no chance to support libav right now (Gentoo bug #567638)
+#       If it returns, please check prior GEGL ebuilds for how libav was integrated.  Thanks!
+RDEPEND="
+	>=dev-libs/glib-2.68.2:2
+	>=dev-libs/json-glib-1.2.6
+	>=media-libs/babl-0.1.98[introspection?,lcms?,vala?]
+	media-libs/libjpeg-turbo
+	media-libs/libnsgif
+	>=media-libs/libpng-1.6.0:0=
+	>=sys-libs/zlib-1.2.0
+	>=x11-libs/gdk-pixbuf-2.32:2
+	>=x11-libs/pango-1.38.0
+	cairo? ( >=x11-libs/cairo-1.12.2 )
+	ffmpeg? ( media-video/ffmpeg:0= )
+	introspection? ( >=dev-libs/gobject-introspection-1.32:= )
+	lcms? ( >=media-libs/lcms-2.8:2 )
+	lensfun? ( >=media-libs/lensfun-0.2.5 )
+	openexr? ( >=media-libs/openexr-1.6.1:= )
+	pdf? ( >=app-text/poppler-0.71.0[cairo] )
+	raw? ( >=media-libs/libraw-0.15.4:0= )
+	sdl? ( >=media-libs/libsdl-1.2.0 )
+	sdl2? ( >=media-libs/libsdl2-2.0.20 )
+	svg? ( >=gnome-base/librsvg-2.40.6:2 )
+	tiff? ( >=media-libs/tiff-4:= )
+	umfpack? ( sci-libs/umfpack )
+	v4l? ( >=media-libs/libv4l-1.0.1 )
+	webp? ( >=media-libs/libwebp-0.5.0:= )
+"
+DEPEND="${RDEPEND}
+	x11-base/xorg-proto"
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-lang/perl
+	>=dev-util/gtk-doc-am-1
+	>=sys-devel/gettext-0.19.8
+	>=sys-devel/libtool-2.2
+	virtual/pkgconfig
+	test? ( $(python_gen_any_dep '>=dev-python/pygobject-3.2:3[${PYTHON_USEDEP}]') )
+	vala? ( $(vala_depend) )
+"
+
+DOCS=( AUTHORS docs/ChangeLog docs/NEWS.adoc )
+
+pkg_pretend() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+	python-any-r1_pkg_setup
+}
+
+python_check_deps() {
+	use test || return 0
+	python_has_version -b ">=dev-python/pygobject-3.2:3[${PYTHON_USEDEP}]"
+}
+
+src_prepare() {
+	default
+	# patch executables suffix
+	sed -i -e "s/'gegl'/'gegl-0.4'/" bin/meson.build || die
+	sed -i -e "s/'gegl-imgcmp'/'gegl-imgcmp-0.4'/" tools/meson.build || die
+	sed -i -e "s/gegl-imgcmp/gegl-imgcmp-0.4/" tests/simple/test-exp-combine.sh || die
+	# skip UNEXPECTED PASSED 'matting-levin' test
+	sed -i -e "s/composition_tests += 'matting-levin'//" \
+		-e "s/composition_tests_fail += 'matting-levin'//" tests/compositions/meson.build || die
+
+	# don't require Apple's OpenCL on versions of OSX that don't have it
+	if [[ ${CHOST} == *-darwin* && ${CHOST#*-darwin} -le 9 ]] ; then
+		sed -i -e 's/#ifdef __APPLE__/#if 0/' gegl/opencl/* || die
+	fi
+
+	# fix 'build'headers from *.cl on gentoo-hardened, bug 739816
+	pushd "${S}/opencl/" || die
+	for file in *.cl; do
+		if [[ -f ${file} ]]; then
+			"${EPYTHON}" cltostring.py "${file}" || die
+		fi
+	done
+	popd || die
+}
+
+src_configure() {
+	# Bug #859901
+	filter-lto
+
+	use vala && vala_setup
+
+	local emesonargs=(
+		#  - Disable documentation as the generating is bit automagic
+		#    if anyone wants to work on it just create bug with patch
+		-Ddocs=false
+		-Dexiv2=disabled
+		-Dgdk-pixbuf=enabled
+		-Djasper=disabled
+		#  - libspiro: not in portage main tree
+		-Dlibspiro=disabled
+		-Dlua=disabled
+		-Dmrg=disabled
+		-Dpango=enabled
+		#  - Parameter -Dworkshop=false disables any use of Lua, effectivly
+		-Dworkshop=false
+		$(meson_feature cairo)
+		$(meson_feature cairo pangocairo)
+		$(meson_feature ffmpeg libav)
+		$(meson_feature lcms)
+		$(meson_feature lensfun)
+		$(meson_feature openexr)
+		$(meson_feature openmp)
+		$(meson_feature pdf poppler)
+		$(meson_feature raw libraw)
+		$(meson_feature sdl sdl1)
+		$(meson_feature sdl2 sdl2)
+		$(meson_feature svg librsvg)
+		$(meson_feature test pygobject)
+		$(meson_feature tiff libtiff)
+		$(meson_feature umfpack)
+		#  - v4l support does not work with our media-libs/libv4l-0.8.9,
+		#    upstream bug at https://bugzilla.gnome.org/show_bug.cgi?id=654675
+		$(meson_feature v4l libv4l)
+		$(meson_feature v4l libv4l2)
+		$(meson_feature vala vapigen)
+		$(meson_feature webp)
+		$(meson_use introspection)
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	optfeature "'Show Image Graph' under GIMP[debug] menu 'File - Debug'" media-gfx/graphviz
+}
diff --git a/media-libs/gegl/gegl-9999.ebuild b/media-libs/gegl/gegl-9999.ebuild
index e0cc3086c9da..0c0abf046ae3 100644
--- a/media-libs/gegl/gegl-9999.ebuild
+++ b/media-libs/gegl/gegl-9999.ebuild
@@ -3,7 +3,7 @@
 
 EAPI=8
 
-PYTHON_COMPAT=( python3_{9..11} )
+PYTHON_COMPAT=( python3_{10..11} )
 # vala and introspection support is broken, bug #468208
 VALA_USE_DEPEND=vapigen