gentoo auto-resync : 09:11:2024 - 03:03:12HEADmaster

2 files changed, 172 insertions, 0 deletions

diff --git a/media-libs/gegl/Manifest b/media-libs/gegl/Manifest
index 8373a80f97e4..b711f0425557 100644
--- a/media-libs/gegl/Manifest
+++ b/media-libs/gegl/Manifest
@@ -1,6 +1,8 @@
 DIST gegl-0.4.46.tar.xz 5799248 BLAKE2B 2fc9ccd0c711cc901abd50740a24d0f75b162cbb196bdd62ab8430882da3b9ea72c08dd587ecfecaf5e4ba9aca4df51bcd7d98ec197325375b1d954c2995029e SHA512 cd733208da7dc1ec77ca023f03f47e578350e156ad07ece701b39f517a292e9f9c081b3a8a2db846813483b4ddb21f32f9fc8b9c70fea8a6ba27bb97ef8bb847
 DIST gegl-0.4.48.tar.xz 5805488 BLAKE2B 3a800004f166fdbfbd563688bb71c4579bba132380f5f45496e8fb813943333b89781320230adf6e0ee49b9bde7db37d81929a8fd42e19e62281e7f8d1ea3bfb SHA512 8f47e6445062894c16d54eeeec4a55cccc32fc49c9fb9be3428a591daaeb21b1a5b8529a68d82613fd75f107bb8c0418c9e5337346bd94da3226e545189c226b
+DIST gegl-0.4.50.tar.xz 5987700 BLAKE2B 08d59ec417194b17819c8996efcb4e10cd86e3626bbe2690ca6f22e095a8bc346fac83460896019044978f5577b7ccdf02265487b3d3dfe8e28a7390741d38d7 SHA512 6ba7cc6a1feca518857a6f474fffec4d3ddce81104541d9d8c9d6a6d7464a00ec0d4fce63194ba2d457d606fea3049fbd365b20b70fdbdf275dac61bc35f8205
 EBUILD gegl-0.4.46.ebuild 4962 BLAKE2B 3220ef54e9792687d01d7c8cb6bcd84b8ed003fad20c94ae6464a254636d49cce2633e1d7e1a25f08fad242cea00d83d9247faf8df481749608b82e0530d4775 SHA512 3d1debd2428143be83ae4bb15cb8f2ec7933ec55541313d87f9f6ad38755317b7334ab58abbda01db16cd8d1d661a9db3b6ef65faaafb91b767dd9f6ce1c2e0c
 EBUILD gegl-0.4.48.ebuild 4964 BLAKE2B ae8a66c5dce49691b97ac9d93b02b7ab8ffd468ae62df137b91ba2841b3de5c0eb8961766a06c3b55ddaa2c37e0f8ef65df7f43e4362dce1f0dde011e6f988f7 SHA512 22f30aefb0816f3af5329431c29ea58b861214a8890912b8a4b6a407b2452406d9cbef32db557d8598cc41a7723c9b1fbcb3c856012e791c5eb71e18f67403ec
+EBUILD gegl-0.4.50.ebuild 5136 BLAKE2B e9c4600629e0fd705610af0793aa583868ac7b0cd4d2d8371611e2b78ab438914a572bfa0ab167de77cd5311d48ba8c9742118a5cb516300cf037fb54e40f9ba SHA512 377b8dcff7d204c45cdec429e88baee333c3ff133a64539ca5bf6f95a7e40e06829de68d6b0207fa96e2ecb8fff504131e2965bd41027f9a9a1651c66f01bf68
 EBUILD gegl-9999.ebuild 4745 BLAKE2B 664ec99ae4b444277accf25895c5552d5a0d3860a4f29df4a2ed9685e59f68e83deb066a87fd9253507b1619813e9d860ba82c05335a08f8fcba555cbceb63d8 SHA512 87e7c424619ffba6bec190270b281e4945f71f72b0fd1341231e62401669e66a9500daeaf3ead51cee9fe977669b6757537f748fe4f00c0ea3e81447c5ae8d4a
 MISC metadata.xml 761 BLAKE2B fa74f6ff5ae13c05793505d0a27b7bc8587748ad356fa4f3ec5b48bd2919c6197788ab02bdc02fbdbdfe2f376d93222b600e30915e50f4ee4643e973ce054d86 SHA512 8cf93e9c5130a017bb864144e88cd2a4f2eff17b5543514a3ca84066b90e394dda6ee64a5e49d8db3b48eb905df5eef815f3b2689bc2be9772a01dcd2cecad30
diff --git a/media-libs/gegl/gegl-0.4.50.ebuild b/media-libs/gegl/gegl-0.4.50.ebuild
new file mode 100644
index 000000000000..878b5ac31d73
--- /dev/null
+++ b/media-libs/gegl/gegl-0.4.50.ebuild
@@ -0,0 +1,170 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+# vala and introspection support is broken, bug #468208
+VALA_USE_DEPEND=vapigen
+
+inherit flag-o-matic meson optfeature python-any-r1 toolchain-funcs vala
+
+if [[ ${PV} == *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://gitlab.gnome.org/GNOME/gegl.git"
+	SRC_URI=""
+else
+	SRC_URI="https://download.gimp.org/pub/${PN}/${PV:0:3}/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~x86 ~amd64-linux ~x86-linux"
+fi
+
+DESCRIPTION="A graph based image processing framework"
+HOMEPAGE="https://gegl.org/"
+
+LICENSE="|| ( GPL-3+ LGPL-3 )"
+SLOT="0.4"
+
+IUSE="cairo debug ffmpeg introspection lcms lensfun openexr openmp pdf raw sdl sdl2 svg test tiff umfpack vala v4l webp"
+REQUIRED_USE="
+	svg? ( cairo )
+	test? ( introspection )
+	vala? ( introspection )
+"
+
+RESTRICT="!test? ( test )"
+
+# NOTE: Even current libav 11.4 does not have AV_CODEC_CAP_VARIABLE_FRAME_SIZE
+#       so there is no chance to support libav right now (Gentoo bug #567638)
+#       If it returns, please check prior GEGL ebuilds for how libav was integrated.  Thanks!
+RDEPEND="
+	>=dev-libs/glib-2.68.2:2
+	>=dev-libs/json-glib-1.2.6
+	>=media-libs/babl-0.1.110[introspection?,lcms?,vala?]
+	media-libs/libjpeg-turbo
+	media-libs/libnsgif
+	>=media-libs/libpng-1.6.0:0=
+	>=sys-libs/zlib-1.2.0
+	>=x11-libs/gdk-pixbuf-2.32:2
+	>=x11-libs/pango-1.38.0
+	cairo? ( >=x11-libs/cairo-1.12.2 )
+	ffmpeg? ( media-video/ffmpeg:0= )
+	introspection? ( >=dev-libs/gobject-introspection-1.32:= )
+	lcms? ( >=media-libs/lcms-2.8:2 )
+	lensfun? ( >=media-libs/lensfun-0.2.5 )
+	openexr? ( >=media-libs/openexr-1.6.1:= )
+	pdf? ( >=app-text/poppler-0.71.0[cairo] )
+	raw? ( >=media-libs/libraw-0.15.4:0= )
+	sdl? ( >=media-libs/libsdl-1.2.0 )
+	sdl2? ( >=media-libs/libsdl2-2.0.20 )
+	svg? ( >=gnome-base/librsvg-2.40.6:2 )
+	tiff? ( >=media-libs/tiff-4:= )
+	umfpack? ( sci-libs/umfpack )
+	v4l? ( >=media-libs/libv4l-1.0.1 )
+	webp? ( >=media-libs/libwebp-0.5.0:= )
+"
+DEPEND="${RDEPEND}
+	x11-base/xorg-proto"
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-lang/perl
+	>=dev-build/gtk-doc-am-1
+	>=sys-devel/gettext-0.19.8
+	>=dev-build/libtool-2.2
+	virtual/pkgconfig
+	test? ( $(python_gen_any_dep '>=dev-python/pygobject-3.2:3[${PYTHON_USEDEP}]') )
+	vala? ( $(vala_depend) )
+"
+
+DOCS=( AUTHORS docs/ChangeLog docs/NEWS.adoc )
+
+pkg_pretend() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+	python-any-r1_pkg_setup
+}
+
+python_check_deps() {
+	use test || return 0
+	python_has_version -b ">=dev-python/pygobject-3.2:3[${PYTHON_USEDEP}]"
+}
+
+src_prepare() {
+	default
+	# patch executables suffix
+	sed -i -e "s/'gegl'/'gegl-0.4'/" bin/meson.build || die
+	sed -i -e "s/'gegl-imgcmp'/'gegl-imgcmp-0.4'/" tools/meson.build || die
+	sed -i -e "s/gegl-imgcmp/gegl-imgcmp-0.4/" tests/simple/test-exp-combine.sh || die
+	# skip UNEXPECTED PASSED 'matting-levin' test
+	sed -i -e "s/composition_tests += 'matting-levin'//" \
+		-e "s/composition_tests_fail += 'matting-levin'//" tests/compositions/meson.build || die
+
+	# don't require Apple's OpenCL on versions of OSX that don't have it
+	if [[ ${CHOST} == *-darwin* && ${CHOST#*-darwin} -le 9 ]] ; then
+		sed -i -e 's/#ifdef __APPLE__/#if 0/' gegl/opencl/* || die
+	fi
+
+	# fix 'build'headers from *.cl on gentoo-hardened, bug 739816
+	pushd "${S}/opencl/" || die
+	for file in *.cl; do
+		if [[ -f ${file} ]]; then
+			"${EPYTHON}" cltostring.py "${file}" || die
+		fi
+	done
+	popd || die
+
+	# Fix QA warning, install docs into /usr/share/gtk-doc/gegl-0.4 instead of /usr/share/doc/gegl-0.4
+	sed -i -e   "s/'doc'/'gtk-doc'/" docs/reference/meson.build || die
+}
+
+src_configure() {
+	# Bug #859901
+	filter-lto
+
+	use vala && vala_setup
+
+	local emesonargs=(
+		#  - Disable documentation as the generating is bit automagic
+		#    if anyone wants to work on it just create bug with patch
+		-Ddocs=false
+		-Dexiv2=disabled
+		-Dgdk-pixbuf=enabled
+		-Djasper=disabled
+		#  - libspiro: not in portage main tree
+		-Dlibspiro=disabled
+		-Dlua=disabled
+		-Dmrg=disabled
+		-Dpango=enabled
+		#  - Parameter -Dworkshop=false disables any use of Lua, effectivly
+		-Dworkshop=false
+		$(meson_feature cairo)
+		$(meson_feature cairo pangocairo)
+		$(meson_feature ffmpeg libav)
+		$(meson_feature lcms)
+		$(meson_feature lensfun)
+		$(meson_feature openexr)
+		$(meson_feature openmp)
+		$(meson_feature pdf poppler)
+		$(meson_feature raw libraw)
+		$(meson_feature sdl sdl1)
+		$(meson_feature sdl2 sdl2)
+		$(meson_feature svg librsvg)
+		$(meson_feature test pygobject)
+		$(meson_feature tiff libtiff)
+		$(meson_feature umfpack)
+		#  - v4l support does not work with our media-libs/libv4l-0.8.9,
+		#    upstream bug at https://bugzilla.gnome.org/show_bug.cgi?id=654675
+		$(meson_feature v4l libv4l)
+		$(meson_feature v4l libv4l2)
+		$(meson_feature vala vapigen)
+		$(meson_feature webp)
+		$(meson_use introspection)
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	optfeature "'Show Image Graph' under GIMP[debug] menu 'File - Debug'" media-gfx/graphviz
+}