reinit the tree, so we can have metadata

1 files changed, 48 insertions, 0 deletions

diff --git a/media-libs/ffmpegsource/ffmpegsource-9999.ebuild b/media-libs/ffmpegsource/ffmpegsource-9999.ebuild
new file mode 100644
index 000000000000..7f457d85c064
--- /dev/null
+++ b/media-libs/ffmpegsource/ffmpegsource-9999.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit autotools eutils flag-o-matic git-r3
+
+DESCRIPTION="A libav/ffmpeg based source library for easy frame accurate access"
+HOMEPAGE="https://github.com/FFMS/ffms2"
+EGIT_REPO_URI="https://github.com/FFMS/ffms2.git"
+
+LICENSE="MIT"
+SLOT="0/4"
+KEYWORDS=""
+IUSE="libav"
+
+RDEPEND="
+	sys-libs/zlib
+	!libav? ( >=media-video/ffmpeg-2.4:0= )
+	libav? ( >=media-video/libav-9:0= )
+"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+"
+
+ffms_check_compiler() {
+	if [[ ${MERGE_TYPE} != "binary" ]] && ! test-flag-CXX -std=c++11; then
+		die "Your compiler lacks C++11 support. Use GCC>=4.7.0 or Clang>=3.3."
+	fi
+}
+
+pkg_pretend() {
+	ffms_check_compiler
+}
+
+pkg_setup() {
+	ffms_check_compiler
+}
+
+src_prepare() {
+	default_src_prepare
+	eautoreconf
+}
+
+src_install() {
+	default_src_install
+	prune_libtool_files
+}