gentoo resync : 20.03.2022

1 files changed, 42 insertions, 0 deletions

diff --git a/media-libs/Field3D/Field3D-1.7.2-r3.ebuild b/media-libs/Field3D/Field3D-1.7.2-r3.ebuild
new file mode 100644
index 000000000000..834067f5713b
--- /dev/null
+++ b/media-libs/Field3D/Field3D-1.7.2-r3.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake flag-o-matic
+
+DESCRIPTION="A library for storing voxel data"
+HOMEPAGE="http://opensource.imageworks.com/?p=field3d"
+SRC_URI="https://github.com/imageworks/Field3D/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="amd64 ~arm ~arm64 x86"
+IUSE="mpi"
+
+RDEPEND="
+	>=dev-libs/boost-1.62:=
+	>=dev-libs/imath-3.1.4-r2:=
+	>=media-libs/openexr-3:0=
+	sci-libs/hdf5:=
+	mpi? ( virtual/mpi )
+"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.7.2-openexr-3-imath.patch
+)
+
+src_configure() {
+	# Needed for now ("fix" compatibility with >=sci-libs/hdf5-1.12)
+	# bug #808731
+	append-cppflags -DH5_USE_110_API
+
+	local mycmakeargs=(
+		-DINSTALL_DOCS=OFF # Docs are not finished yet.
+		-DCMAKE_DISABLE_FIND_PACKAGE_Doxygen=ON
+		$(cmake_use_find_package mpi MPI)
+	)
+
+	cmake_src_configure
+}