gentoo auto-resync : 30:11:2023 - 04:55:37

2 files changed, 204 insertions, 0 deletions

diff --git a/media-gfx/inkscape/Manifest b/media-gfx/inkscape/Manifest
index 9d675e1d652c..36da5c9c9b09 100644
--- a/media-gfx/inkscape/Manifest
+++ b/media-gfx/inkscape/Manifest
@@ -1,8 +1,10 @@
 AUX inkscape-1.2.2-fix-compile.patch 1948 BLAKE2B 4482e3f021f9cdee4a26e0d179e5e18e21d2a0649d1801979ee08b2428a1b9ae8850a09cacaa2121a25069d763758123f0c550e1e7dac2a91c04198eb6bc960f SHA512 ccc4a593c903ce467e0076a8b036aac421a3f5a943815d6d7cf91c48acb07d49c76fb73b58ad01fc3a3f45af2c6e4bc78d6a13848ed3f91de42c3a074b1aeb17
 DIST inkscape-1.2.2.tar.xz 39392040 BLAKE2B 7a4f0e42d1d8b67f42b924c760be484156e210e5661dc48408c992cbef5e0ac997a468cf1263e5c14cd5c0c0a83345e77055ff59fd7fb2d01b2d196f42a9e858 SHA512 b3e95f7d45612140b38c95fd758b051c27b0ed55bac7e7980c0491d3ba94c62edd7f0b27034314388bf74faf2046d829f36d2f6745cb4a54fb43b8b684df235f
+DIST inkscape-1.3.2.tar.xz 44720944 BLAKE2B 24120f8c671e1fb54bb6626cab95e7086e3c60fbc117bbe8017d081c799bc26812b1286e670771e7ffe88720ba25f237146c452afaf65c1ee2ee554fb07f79a2 SHA512 a6da4b676ba3e7f954f95e3916ce78ce358b49c8052795a52d478064ef02eeae0337b0a94e89b9752ea6824a5758d28072c2bbf83f1e9ee28daebd3b0ef87343
 DIST inkscape-1.3.tar.xz 85764028 BLAKE2B 798ba301fa649c12c4fd14ec32ab5361ec83a15d5049e493cb27666a7322a65a5f168f8510d525f58abcba8cf32bd2de772de3ae11e86d40556f0255fe768c90 SHA512 1eb488105586bf98a51c7109ab2e23292f039e5f0e66de4d3684a73f0ab408d89ee55560517d3185370ad3f32b31cf03d149df02ba5c895fe386dd1581fcb2e8
 EBUILD inkscape-1.2.2-r4.ebuild 5311 BLAKE2B edcf8affb0c5538b0aa6aae407966cd7ca9ca099be76ed1680d7764fc19b2e8012d3f3f14a1091dd32c09e59ecf6ea32e0ed2bcae20918fce78074c3cf1a2c8f SHA512 362e9879420f9ab450affc624a984d3f3c88a82b164cfc85ed4f4058673f471ac29f9cec7cf8806a322fe1feb1ec3d281639713f47781346b040c85217104434
 EBUILD inkscape-1.2.2.ebuild 5254 BLAKE2B 164f9d0482e89aaceacd35e68634c92160e015b495234592194ebaae5d0c80423af2cb650eb1d5d63b2a5d02dd9cf31b2ed40e4348477120f3465df9615f1494 SHA512 b5c88d5aa0fbd1b81f3807409ccdee0f9acbe140d5c46f2e56d2b298a639f0b1c95b2f5078498e329c384618e12f3871c38ae4dd3e491c2d86eecabf7b063afb
+EBUILD inkscape-1.3.2.ebuild 5404 BLAKE2B 37d1926e760a08bb57e55497ac3c7fee95184251b5e1fd4048e6c7064b01eb527e30cf755c61457e60d5d2ad85363ab48c4dfd455181f02177c69962753dc8eb SHA512 5b3fb4f0b542a122606ae582097cc9588851de39313704698058572d4c401973efad7771e1a926aa73d9dd3d43f0c32e585aa21dff9be2361b65d338cd32ccef
 EBUILD inkscape-1.3.ebuild 5376 BLAKE2B e2853a4667bbe86e127ec8ab8778b1e1a56f825f4b3059859ecf066afe084877c3dfd6dfc643a5e98376ac4e05a0e72adf48bc95165d53d21601b12e068021fb SHA512 623f61bbde4330519ec658afd6668b3e26ebbcf9db560cd7fe086c333c641c02ba4837b73a038caea0eeacf29745f82174220f6319f56ee755ac950f4a8cb493
 EBUILD inkscape-9999.ebuild 5376 BLAKE2B e2853a4667bbe86e127ec8ab8778b1e1a56f825f4b3059859ecf066afe084877c3dfd6dfc643a5e98376ac4e05a0e72adf48bc95165d53d21601b12e068021fb SHA512 623f61bbde4330519ec658afd6668b3e26ebbcf9db560cd7fe086c333c641c02ba4837b73a038caea0eeacf29745f82174220f6319f56ee755ac950f4a8cb493
 MISC metadata.xml 982 BLAKE2B f44f534865614c8dd7bf71e92ce69cff708fc08e3eb701765bf93144b433ec52df52a506b69cc98969909c695015881b60592cccdf27613c6fe82812fc50727b SHA512 2963a9b473f139d06cefd1c3231ef148045c005adb4688850522c183f39ba15a36331b7eae7752e9bf15a26e6370f2af14ec02e59735f1753246c45821c0cdbc
diff --git a/media-gfx/inkscape/inkscape-1.3.2.ebuild b/media-gfx/inkscape/inkscape-1.3.2.ebuild
new file mode 100644
index 000000000000..ca758524da42
--- /dev/null
+++ b/media-gfx/inkscape/inkscape-1.3.2.ebuild
@@ -0,0 +1,202 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..11} )
+PYTHON_REQ_USE="xml(+)"
+MY_P="${P/_/}"
+inherit cmake flag-o-matic xdg toolchain-funcs python-single-r1
+
+if [[ ${PV} = 9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://gitlab.com/inkscape/inkscape.git"
+else
+	SRC_URI="https://media.inkscape.org/dl/resources/file/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+fi
+
+DESCRIPTION="SVG based generic vector-drawing program"
+HOMEPAGE="https://inkscape.org/ https://gitlab.com/inkscape/inkscape/"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0"
+IUSE="cdr dia exif graphicsmagick imagemagick inkjar jpeg openmp postscript readline sourceview spell svg2 test visio wpg X"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+# Lots of test failures which need investigating, bug #871621
+RESTRICT="!test? ( test ) test"
+
+BDEPEND="
+	dev-util/glib-utils
+	>=sys-devel/gettext-0.17
+	virtual/pkgconfig
+	test? ( virtual/imagemagick-tools )
+"
+COMMON_DEPEND="${PYTHON_DEPS}
+	>=app-text/poppler-0.57.0:=[cairo]
+	>=dev-cpp/cairomm-1.12:0
+	>=dev-cpp/glibmm-2.54.1:2
+	dev-cpp/gtkmm:3.0
+	>=dev-cpp/pangomm-2.40:1.4
+	>=dev-libs/boehm-gc-7.1:=
+	dev-libs/boost:=[stacktrace(-)]
+	dev-libs/double-conversion:=
+	>=dev-libs/glib-2.41
+	>=dev-libs/libsigc++-2.8:2
+	>=dev-libs/libxml2-2.7.4
+	>=dev-libs/libxslt-1.1.25
+	dev-libs/popt
+	media-gfx/potrace
+	media-libs/libepoxy
+	media-libs/fontconfig
+	media-libs/freetype:2
+	media-libs/lcms:2
+	media-libs/libpng:0=
+	net-libs/libsoup:2.4
+	sci-libs/gsl:=
+	>=x11-libs/pango-1.44
+	x11-libs/gtk+:3[X?]
+	X? ( x11-libs/libX11 )
+	$(python_gen_cond_dep '
+		dev-python/appdirs[${PYTHON_USEDEP}]
+		dev-python/cachecontrol[${PYTHON_USEDEP}]
+		dev-python/cssselect[${PYTHON_USEDEP}]
+		dev-python/lockfile[${PYTHON_USEDEP}]
+		dev-python/lxml[${PYTHON_USEDEP}]
+		media-gfx/scour[${PYTHON_USEDEP}]
+	')
+	cdr? (
+		app-text/libwpg:0.3
+		dev-libs/librevenge
+		media-libs/libcdr
+	)
+	exif? ( media-libs/libexif )
+	imagemagick? (
+		!graphicsmagick? ( media-gfx/imagemagick:=[cxx] )
+		graphicsmagick? ( media-gfx/graphicsmagick:=[cxx] )
+	)
+	jpeg? ( media-libs/libjpeg-turbo:= )
+	readline? ( sys-libs/readline:= )
+	sourceview? ( x11-libs/gtksourceview:4 )
+	spell? ( app-text/gspell )
+	visio? (
+		app-text/libwpg:0.3
+		dev-libs/librevenge
+		media-libs/libvisio
+	)
+	wpg? (
+		app-text/libwpg:0.3
+		dev-libs/librevenge
+	)
+"
+# These only use executables provided by these packages
+# See share/extensions for more details. inkscape can tell you to
+# install these so we could of course just not depend on those and rely
+# on that.
+RDEPEND="${COMMON_DEPEND}
+	$(python_gen_cond_dep '
+		dev-python/numpy[${PYTHON_USEDEP}]
+	')
+	dia? ( app-office/dia )
+	postscript? ( app-text/ghostscript-gpl )
+"
+DEPEND="${COMMON_DEPEND}
+	test? ( dev-cpp/gtest )
+"
+
+S="${WORKDIR}/${MY_P}"
+
+pkg_pretend() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+	python-single-r1_pkg_setup
+}
+
+src_unpack() {
+	if [[ ${PV} = 9999* ]]; then
+		git-r3_src_unpack
+	else
+		default
+	fi
+	[[ -d "${S}" ]] || mv -v "${WORKDIR}/${P}_202"?-??-* "${S}" || die
+}
+
+src_prepare() {
+	cmake_src_prepare
+	sed -i "/install.*COPYING/d" CMakeScripts/ConfigCPack.cmake || die
+}
+
+src_configure() {
+	# aliasing unsafe wrt #310393
+	append-flags -fno-strict-aliasing
+
+	local mycmakeargs=(
+		# -DWITH_LPETOOL   # Compile with LPE Tool and experimental LPEs enabled
+		-DWITH_NLS=ON
+		-DENABLE_POPPLER=ON
+		-DENABLE_POPPLER_CAIRO=ON
+		-DWITH_PROFILING=OFF
+		-DWITH_INTERNAL_CAIRO=OFF
+		-DWITH_INTERNAL_2GEOM=ON
+		-DBUILD_TESTING=$(usex test)
+		-DWITH_LIBCDR=$(usex cdr)
+		-DWITH_IMAGE_MAGICK=$(usex imagemagick $(usex !graphicsmagick)) # requires ImageMagick 6, only IM must be enabled
+		-DWITH_GRAPHICS_MAGICK=$(usex graphicsmagick $(usex imagemagick)) # both must be enabled to use GraphicsMagick
+		-DWITH_GNU_READLINE=$(usex readline)
+		-DWITH_GSPELL=$(usex spell)
+		-DWITH_JEMALLOC=OFF
+		-DENABLE_LCMS=ON
+		-DWITH_OPENMP=$(usex openmp)
+		-DBUILD_SHARED_LIBS=ON
+		-DWITH_GSOURCEVIEW=$(usex sourceview)
+		-DWITH_SVG2=$(usex svg2)
+		-DWITH_LIBVISIO=$(usex visio)
+		-DWITH_LIBWPG=$(usex wpg)
+		-DWITH_X11=$(usex X)
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	CMAKE_SKIP_TESTS=(
+		# render_text*: needs patched Cairo / maybe upstream changes
+		# not yet in a release.
+		# test_lpe/test_lpe64: precision differences b/c of new GCC?
+		# cli_export-png-color-mode-gray-8_png_check_output: ditto?
+		render_test-use
+		render_test-glyph-y-pos
+		render_text-glyphs-combining
+		render_text-glyphs-vertical
+		render_test-rtl-vertical
+		test_lpe
+		test_lpe64
+		cli_export-png-color-mode-gray-8_png_check_output
+	)
+
+	# bug #871621
+	cmake_src_compile tests
+	cmake_src_test -j1
+}
+
+src_install() {
+	cmake_src_install
+
+	find "${ED}" -type f -name "*.la" -delete || die
+
+	find "${ED}"/usr/share/man -type f -maxdepth 3 -name '*.bz2' -exec bzip2 -d {} \; || die
+
+	find "${ED}"/usr/share/man -type f -maxdepth 3 -name '*.gz' -exec gzip -d {} \; || die
+
+	local extdir="${ED}"/usr/share/${PN}/extensions
+
+	if [[ -e "${extdir}" ]] && [[ -n $(find "${extdir}" -mindepth 1) ]]; then
+		python_optimize "${ED}"/usr/share/${PN}/extensions
+	fi
+
+	# Empty directory causes sandbox issues, see bug #761915
+	rm -r "${ED}/usr/share/inkscape/fonts" || die "Failed to remove fonts directory."
+}