gentoo auto-resync : 18:09:2023 - 11:05:42

6 files changed, 232 insertions, 23 deletions

diff --git a/media-gfx/inkscape/Manifest b/media-gfx/inkscape/Manifest
index ed995e7af9e0..9d675e1d652c 100644
--- a/media-gfx/inkscape/Manifest
+++ b/media-gfx/inkscape/Manifest
@@ -1,6 +1,8 @@
 AUX inkscape-1.2.2-fix-compile.patch 1948 BLAKE2B 4482e3f021f9cdee4a26e0d179e5e18e21d2a0649d1801979ee08b2428a1b9ae8850a09cacaa2121a25069d763758123f0c550e1e7dac2a91c04198eb6bc960f SHA512 ccc4a593c903ce467e0076a8b036aac421a3f5a943815d6d7cf91c48acb07d49c76fb73b58ad01fc3a3f45af2c6e4bc78d6a13848ed3f91de42c3a074b1aeb17
 DIST inkscape-1.2.2.tar.xz 39392040 BLAKE2B 7a4f0e42d1d8b67f42b924c760be484156e210e5661dc48408c992cbef5e0ac997a468cf1263e5c14cd5c0c0a83345e77055ff59fd7fb2d01b2d196f42a9e858 SHA512 b3e95f7d45612140b38c95fd758b051c27b0ed55bac7e7980c0491d3ba94c62edd7f0b27034314388bf74faf2046d829f36d2f6745cb4a54fb43b8b684df235f
-EBUILD inkscape-1.2.2-r4.ebuild 5246 BLAKE2B 8e28f632c05ad84ddf7c54eeacbb44157eeee885255672e4792edb5f2851c1f5f7e25ed71f52f82bc4a4f36f65997cbdefa26a2e06d5441387bffed31144623c SHA512 538ab62136f0e6dad3437086ea48d2d5646b5884130ff0cd25066976a273bda1e149505caeea2f635a6f11f3501227a739b36a17d81ac061779b19a9f59de1ff
-EBUILD inkscape-1.2.2.ebuild 5189 BLAKE2B 62a14c92e245ec737176aa3015bd508068fe0c12436f1487f5140bd0f6bf50f4ffed82abd67cb35b2b2814ea0fad9eea3c2b5f634784be5a1c64f8040d48ad55 SHA512 0aaf8dc62bc796b78ec7076fa9d6b6f2c75e767b98e251345e5b7727d65827a23dd55d3ee08fbff7650ef3533f7bf7692a2ab294299bfd36c8d01be3b63f9560
-EBUILD inkscape-9999.ebuild 5109 BLAKE2B 072db9c614f1b307df080b0541016db844eb5a5dc060146ee6b762a7655daeb35f6c9fd6b64b345eba4b2e4b9b037623f4658dd3c6d86b6f278c3a970a931d4e SHA512 2bf56ca70b41768db67029bb61a6fc4f98e3ada53dbbbe02437f42a38fb5e1fe5d0e489ef42c1e836f79eb429513f48439a077839776eb9b05b8600f51faa9e3
-MISC metadata.xml 876 BLAKE2B e8998be1909e5848fd13fa4a8c4e2d9a424c818c3a41ebdd0a5807f572f9d0037900ac2516d107b9ab016410c25bc4ca3225e832ef17bd6b345d6471d5b5f0bc SHA512 f9a8581f7f401a40b100f61e67adb032859b2c70bd49eaa60b13a18cf24cc24e3a2704e227cba5590aad4bbaf705f3a4bf8c6ffda75f473c39bb8177af4aca6b
+DIST inkscape-1.3.tar.xz 85764028 BLAKE2B 798ba301fa649c12c4fd14ec32ab5361ec83a15d5049e493cb27666a7322a65a5f168f8510d525f58abcba8cf32bd2de772de3ae11e86d40556f0255fe768c90 SHA512 1eb488105586bf98a51c7109ab2e23292f039e5f0e66de4d3684a73f0ab408d89ee55560517d3185370ad3f32b31cf03d149df02ba5c895fe386dd1581fcb2e8
+EBUILD inkscape-1.2.2-r4.ebuild 5311 BLAKE2B edcf8affb0c5538b0aa6aae407966cd7ca9ca099be76ed1680d7764fc19b2e8012d3f3f14a1091dd32c09e59ecf6ea32e0ed2bcae20918fce78074c3cf1a2c8f SHA512 362e9879420f9ab450affc624a984d3f3c88a82b164cfc85ed4f4058673f471ac29f9cec7cf8806a322fe1feb1ec3d281639713f47781346b040c85217104434
+EBUILD inkscape-1.2.2.ebuild 5254 BLAKE2B 164f9d0482e89aaceacd35e68634c92160e015b495234592194ebaae5d0c80423af2cb650eb1d5d63b2a5d02dd9cf31b2ed40e4348477120f3465df9615f1494 SHA512 b5c88d5aa0fbd1b81f3807409ccdee0f9acbe140d5c46f2e56d2b298a639f0b1c95b2f5078498e329c384618e12f3871c38ae4dd3e491c2d86eecabf7b063afb
+EBUILD inkscape-1.3.ebuild 5376 BLAKE2B e2853a4667bbe86e127ec8ab8778b1e1a56f825f4b3059859ecf066afe084877c3dfd6dfc643a5e98376ac4e05a0e72adf48bc95165d53d21601b12e068021fb SHA512 623f61bbde4330519ec658afd6668b3e26ebbcf9db560cd7fe086c333c641c02ba4837b73a038caea0eeacf29745f82174220f6319f56ee755ac950f4a8cb493
+EBUILD inkscape-9999.ebuild 5376 BLAKE2B e2853a4667bbe86e127ec8ab8778b1e1a56f825f4b3059859ecf066afe084877c3dfd6dfc643a5e98376ac4e05a0e72adf48bc95165d53d21601b12e068021fb SHA512 623f61bbde4330519ec658afd6668b3e26ebbcf9db560cd7fe086c333c641c02ba4837b73a038caea0eeacf29745f82174220f6319f56ee755ac950f4a8cb493
+MISC metadata.xml 982 BLAKE2B f44f534865614c8dd7bf71e92ce69cff708fc08e3eb701765bf93144b433ec52df52a506b69cc98969909c695015881b60592cccdf27613c6fe82812fc50727b SHA512 2963a9b473f139d06cefd1c3231ef148045c005adb4688850522c183f39ba15a36331b7eae7752e9bf15a26e6370f2af14ec02e59735f1753246c45821c0cdbc
diff --git a/media-gfx/inkscape/inkscape-1.2.2-r4.ebuild b/media-gfx/inkscape/inkscape-1.2.2-r4.ebuild
index d1745d96109b..dad95b005747 100644
--- a/media-gfx/inkscape/inkscape-1.2.2-r4.ebuild
+++ b/media-gfx/inkscape/inkscape-1.2.2-r4.ebuild
@@ -21,10 +21,10 @@ HOMEPAGE="https://inkscape.org/ https://gitlab.com/inkscape/inkscape/"
 
 LICENSE="GPL-2 LGPL-2.1"
 SLOT="0"
-IUSE="cdr dia exif graphicsmagick imagemagick inkjar jemalloc jpeg
-openmp postscript readline spell svg2 test visio wpg X"
-
+IUSE="cdr dia exif graphicsmagick imagemagick inkjar jemalloc jpeg openmp postscript readline spell svg2 test visio wpg X"
 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+# Lots of test failures which need investigating, bug #871621
+RESTRICT="!test? ( test ) test"
 
 BDEPEND="
 	dev-util/glib-utils
@@ -103,8 +103,6 @@ DEPEND="${COMMON_DEPEND}
 	test? ( dev-cpp/gtest )
 "
 
-RESTRICT="!test? ( test )"
-
 S="${WORKDIR}/${MY_P}"
 
 PATCHES=(
diff --git a/media-gfx/inkscape/inkscape-1.2.2.ebuild b/media-gfx/inkscape/inkscape-1.2.2.ebuild
index a5abc5d13f0a..1d5d7d1ddda9 100644
--- a/media-gfx/inkscape/inkscape-1.2.2.ebuild
+++ b/media-gfx/inkscape/inkscape-1.2.2.ebuild
@@ -21,10 +21,10 @@ HOMEPAGE="https://inkscape.org/ https://gitlab.com/inkscape/inkscape/"
 
 LICENSE="GPL-2 LGPL-2.1"
 SLOT="0"
-IUSE="cdr dia exif graphicsmagick imagemagick inkjar jemalloc jpeg
-openmp postscript readline spell svg2 test visio wpg X"
-
+IUSE="cdr dia exif graphicsmagick imagemagick inkjar jemalloc jpeg openmp postscript readline spell svg2 test visio wpg X"
 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+# Lots of test failures which need investigating, bug #871621
+RESTRICT="!test? ( test ) test"
 
 BDEPEND="
 	dev-util/glib-utils
@@ -104,8 +104,6 @@ DEPEND="${COMMON_DEPEND}
 	test? ( dev-cpp/gtest )
 "
 
-RESTRICT="!test? ( test )"
-
 S="${WORKDIR}/${MY_P}"
 
 pkg_pretend() {
diff --git a/media-gfx/inkscape/inkscape-1.3.ebuild b/media-gfx/inkscape/inkscape-1.3.ebuild
new file mode 100644
index 000000000000..0f162519d9ab
--- /dev/null
+++ b/media-gfx/inkscape/inkscape-1.3.ebuild
@@ -0,0 +1,201 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..11} )
+PYTHON_REQ_USE="xml(+)"
+MY_P="${P/_/}"
+inherit cmake flag-o-matic xdg toolchain-funcs python-single-r1
+
+if [[ ${PV} = 9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://gitlab.com/inkscape/inkscape.git"
+else
+	SRC_URI="https://media.inkscape.org/dl/resources/file/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+fi
+
+DESCRIPTION="SVG based generic vector-drawing program"
+HOMEPAGE="https://inkscape.org/ https://gitlab.com/inkscape/inkscape/"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0"
+IUSE="cdr dia exif graphicsmagick imagemagick inkjar jpeg openmp postscript readline sourceview spell svg2 test visio wpg X"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+# Lots of test failures which need investigating, bug #871621
+RESTRICT="!test? ( test ) test"
+
+BDEPEND="
+	dev-util/glib-utils
+	>=sys-devel/gettext-0.17
+	virtual/pkgconfig
+	test? ( virtual/imagemagick-tools )
+"
+COMMON_DEPEND="${PYTHON_DEPS}
+	>=app-text/poppler-0.57.0:=[cairo]
+	>=dev-cpp/cairomm-1.12:0
+	>=dev-cpp/glibmm-2.54.1:2
+	dev-cpp/gtkmm:3.0
+	>=dev-cpp/pangomm-2.40:1.4
+	>=dev-libs/boehm-gc-7.1:=
+	dev-libs/boost:=[stacktrace(-)]
+	dev-libs/double-conversion:=
+	>=dev-libs/glib-2.41
+	>=dev-libs/libsigc++-2.8:2
+	>=dev-libs/libxml2-2.7.4
+	>=dev-libs/libxslt-1.1.25
+	dev-libs/popt
+	media-gfx/potrace
+	media-libs/libepoxy
+	media-libs/fontconfig
+	media-libs/freetype:2
+	media-libs/lcms:2
+	media-libs/libpng:0=
+	net-libs/libsoup:2.4
+	sci-libs/gsl:=
+	>=x11-libs/pango-1.44
+	x11-libs/gtk+:3[X?]
+	X? ( x11-libs/libX11 )
+	$(python_gen_cond_dep '
+		dev-python/appdirs[${PYTHON_USEDEP}]
+		dev-python/cachecontrol[${PYTHON_USEDEP}]
+		dev-python/cssselect[${PYTHON_USEDEP}]
+		dev-python/lockfile[${PYTHON_USEDEP}]
+		dev-python/lxml[${PYTHON_USEDEP}]
+		media-gfx/scour[${PYTHON_USEDEP}]
+	')
+	cdr? (
+		app-text/libwpg:0.3
+		dev-libs/librevenge
+		media-libs/libcdr
+	)
+	exif? ( media-libs/libexif )
+	imagemagick? (
+		!graphicsmagick? ( media-gfx/imagemagick:=[cxx] )
+		graphicsmagick? ( media-gfx/graphicsmagick:=[cxx] )
+	)
+	jpeg? ( media-libs/libjpeg-turbo:= )
+	readline? ( sys-libs/readline:= )
+	sourceview? ( x11-libs/gtksourceview:4 )
+	spell? ( app-text/gspell )
+	visio? (
+		app-text/libwpg:0.3
+		dev-libs/librevenge
+		media-libs/libvisio
+	)
+	wpg? (
+		app-text/libwpg:0.3
+		dev-libs/librevenge
+	)
+"
+# These only use executables provided by these packages
+# See share/extensions for more details. inkscape can tell you to
+# install these so we could of course just not depend on those and rely
+# on that.
+RDEPEND="${COMMON_DEPEND}
+	$(python_gen_cond_dep '
+		dev-python/numpy[${PYTHON_USEDEP}]
+	')
+	dia? ( app-office/dia )
+	postscript? ( app-text/ghostscript-gpl )
+"
+DEPEND="${COMMON_DEPEND}
+	test? ( dev-cpp/gtest )
+"
+
+S="${WORKDIR}/${MY_P}"
+
+pkg_pretend() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+	python-single-r1_pkg_setup
+}
+
+src_unpack() {
+	if [[ ${PV} = 9999* ]]; then
+		git-r3_src_unpack
+	else
+		default
+	fi
+	[[ -d "${S}" ]] || mv -v "${WORKDIR}/${P}_202"?-??-* "${S}" || die
+}
+
+src_prepare() {
+	cmake_src_prepare
+	sed -i "/install.*COPYING/d" CMakeScripts/ConfigCPack.cmake || die
+}
+
+src_configure() {
+	# aliasing unsafe wrt #310393
+	append-flags -fno-strict-aliasing
+
+	local mycmakeargs=(
+		# -DWITH_LPETOOL   # Compile with LPE Tool and experimental LPEs enabled
+		-DWITH_NLS=ON
+		-DENABLE_POPPLER=ON
+		-DENABLE_POPPLER_CAIRO=ON
+		-DWITH_PROFILING=OFF
+		-DWITH_INTERNAL_2GEOM=ON
+		-DBUILD_TESTING=$(usex test)
+		-DWITH_LIBCDR=$(usex cdr)
+		-DWITH_IMAGE_MAGICK=$(usex imagemagick $(usex !graphicsmagick)) # requires ImageMagick 6, only IM must be enabled
+		-DWITH_GRAPHICS_MAGICK=$(usex graphicsmagick $(usex imagemagick)) # both must be enabled to use GraphicsMagick
+		-DWITH_GNU_READLINE=$(usex readline)
+		-DWITH_GSPELL=$(usex spell)
+		-DWITH_JEMALLOC=OFF
+		-DENABLE_LCMS=ON
+		-DWITH_OPENMP=$(usex openmp)
+		-DBUILD_SHARED_LIBS=ON
+		-DWITH_GSOURCEVIEW=$(usex sourceview)
+		-DWITH_SVG2=$(usex svg2)
+		-DWITH_LIBVISIO=$(usex visio)
+		-DWITH_LIBWPG=$(usex wpg)
+		-DWITH_X11=$(usex X)
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	CMAKE_SKIP_TESTS=(
+		# render_text*: needs patched Cairo / maybe upstream changes
+		# not yet in a release.
+		# test_lpe/test_lpe64: precision differences b/c of new GCC?
+		# cli_export-png-color-mode-gray-8_png_check_output: ditto?
+		render_test-use
+		render_test-glyph-y-pos
+		render_text-glyphs-combining
+		render_text-glyphs-vertical
+		render_test-rtl-vertical
+		test_lpe
+		test_lpe64
+		cli_export-png-color-mode-gray-8_png_check_output
+	)
+
+	# bug #871621
+	cmake_src_compile tests
+	cmake_src_test -j1
+}
+
+src_install() {
+	cmake_src_install
+
+	find "${ED}" -type f -name "*.la" -delete || die
+
+	find "${ED}"/usr/share/man -type f -maxdepth 3 -name '*.bz2' -exec bzip2 -d {} \; || die
+
+	find "${ED}"/usr/share/man -type f -maxdepth 3 -name '*.gz' -exec gzip -d {} \; || die
+
+	local extdir="${ED}"/usr/share/${PN}/extensions
+
+	if [[ -e "${extdir}" ]] && [[ -n $(find "${extdir}" -mindepth 1) ]]; then
+		python_optimize "${ED}"/usr/share/${PN}/extensions
+	fi
+
+	# Empty directory causes sandbox issues, see bug #761915
+	rm -r "${ED}/usr/share/inkscape/fonts" || die "Failed to remove fonts directory."
+}
diff --git a/media-gfx/inkscape/inkscape-9999.ebuild b/media-gfx/inkscape/inkscape-9999.ebuild
index 176dc00840be..0f162519d9ab 100644
--- a/media-gfx/inkscape/inkscape-9999.ebuild
+++ b/media-gfx/inkscape/inkscape-9999.ebuild
@@ -3,7 +3,7 @@
 
 EAPI=8
 
-PYTHON_COMPAT=( python3_{9..11} )
+PYTHON_COMPAT=( python3_{10..11} )
 PYTHON_REQ_USE="xml(+)"
 MY_P="${P/_/}"
 inherit cmake flag-o-matic xdg toolchain-funcs python-single-r1
@@ -13,7 +13,7 @@ if [[ ${PV} = 9999* ]]; then
 	EGIT_REPO_URI="https://gitlab.com/inkscape/inkscape.git"
 else
 	SRC_URI="https://media.inkscape.org/dl/resources/file/${P}.tar.xz"
-	KEYWORDS="~alpha ~amd64"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
 fi
 
 DESCRIPTION="SVG based generic vector-drawing program"
@@ -21,10 +21,10 @@ HOMEPAGE="https://inkscape.org/ https://gitlab.com/inkscape/inkscape/"
 
 LICENSE="GPL-2 LGPL-2.1"
 SLOT="0"
-IUSE="cdr dia exif graphicsmagick imagemagick inkjar jpeg
-openmp postscript readline spell svg2 test visio wpg X"
-
+IUSE="cdr dia exif graphicsmagick imagemagick inkjar jpeg openmp postscript readline sourceview spell svg2 test visio wpg X"
 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+# Lots of test failures which need investigating, bug #871621
+RESTRICT="!test? ( test ) test"
 
 BDEPEND="
 	dev-util/glib-utils
@@ -77,6 +77,7 @@ COMMON_DEPEND="${PYTHON_DEPS}
 	)
 	jpeg? ( media-libs/libjpeg-turbo:= )
 	readline? ( sys-libs/readline:= )
+	sourceview? ( x11-libs/gtksourceview:4 )
 	spell? ( app-text/gspell )
 	visio? (
 		app-text/libwpg:0.3
@@ -103,8 +104,6 @@ DEPEND="${COMMON_DEPEND}
 	test? ( dev-cpp/gtest )
 "
 
-RESTRICT="!test? ( test )"
-
 S="${WORKDIR}/${MY_P}"
 
 pkg_pretend() {
@@ -151,6 +150,7 @@ src_configure() {
 		-DENABLE_LCMS=ON
 		-DWITH_OPENMP=$(usex openmp)
 		-DBUILD_SHARED_LIBS=ON
+		-DWITH_GSOURCEVIEW=$(usex sourceview)
 		-DWITH_SVG2=$(usex svg2)
 		-DWITH_LIBVISIO=$(usex visio)
 		-DWITH_LIBWPG=$(usex wpg)
@@ -161,14 +161,23 @@ src_configure() {
 }
 
 src_test() {
-	local myctestargs=(
+	CMAKE_SKIP_TESTS=(
 		# render_text*: needs patched Cairo / maybe upstream changes
 		# not yet in a release.
 		# test_lpe/test_lpe64: precision differences b/c of new GCC?
 		# cli_export-png-color-mode-gray-8_png_check_output: ditto?
-		-E "(render_test-use|render_test-glyph-y-pos|render_text-glyphs-combining|render_text-glyphs-vertical|render_test-rtl-vertical|test_lpe|test_lpe64|cli_export-png-color-mode-gray-8_png_check_output)"
+		render_test-use
+		render_test-glyph-y-pos
+		render_text-glyphs-combining
+		render_text-glyphs-vertical
+		render_test-rtl-vertical
+		test_lpe
+		test_lpe64
+		cli_export-png-color-mode-gray-8_png_check_output
 	)
 
+	# bug #871621
+	cmake_src_compile tests
 	cmake_src_test -j1
 }
 
diff --git a/media-gfx/inkscape/metadata.xml b/media-gfx/inkscape/metadata.xml
index f5a32443fc24..ec2121f26229 100644
--- a/media-gfx/inkscape/metadata.xml
+++ b/media-gfx/inkscape/metadata.xml
@@ -9,6 +9,7 @@
 		<flag name="cdr">Enable support for CorelDRAW files via <pkg>media-libs/libcdr</pkg></flag>
 		<flag name="dia">Enable DIA flow chart import via <pkg>app-office/dia</pkg></flag>
 		<flag name="inkjar">Enable support for OpenOffice.org SVG jar files</flag>
+		<flag name="sourceview">Enable syntax highlighting support via <pkg>x11-libs/gtksourceview</pkg></flag>
 		<flag name="svg2">Enable support for new SVG2 features</flag>
 		<flag name="visio">Enable support for Microsoft Visio diagrams via <pkg>media-libs/libvisio</pkg></flag>
 		<flag name="wpg">Enable support for WordPerfect graphics via <pkg>app-text/libwpg</pkg></flag>