gentoo resync : 01.10.2020

3 files changed, 527 insertions, 0 deletions

diff --git a/media-gfx/imagemagick/Manifest b/media-gfx/imagemagick/Manifest
index a0f69dee82af..4aa8e8675d83 100644
--- a/media-gfx/imagemagick/Manifest
+++ b/media-gfx/imagemagick/Manifest
@@ -1,8 +1,12 @@
 AUX policy-hardening.snippet 442 BLAKE2B d79fdbddab418fc9d8391e78992e3dda844e096052115113ff6f759c1a54541bcd7d7793547bc7140776659c98379a9e9f004aa46f757300a33f445d396fbf14 SHA512 e9e723c40d5b8c52bbc2f2b9a3ad7c7e2aee493bc37b6c3940e8486b92a1c6659e47b1e12ee2fb11c8a8b6ee48a7fc10354617ae12c36181a58e9e73b239368d
 AUX policy.test.xml 746 BLAKE2B 6bfa073606469b81cf517d9b069e48794cbda9272d12c3abb8ae3456aaf30cd1923510baddb7d813aa8ccde84e161de0b29314cef7b1a37730c7ad5236d1f5dc SHA512 22f66004324e3777393446a3df738ecd2aa405df088d39137008514cd86b436765b48ccd4355d670a42061ce4e5a7b2fd8e4be5852cd914f62ff0250a4a7ae57
 DIST ImageMagick-6.9.11-28.tar.xz 9315628 BLAKE2B 8ece7dae4d8c7de695e85b832e5c15c1474e00c9027aeb251a279dc9b51a02f5fd1e96f48987377cd6d937a126e5750e9aef9a11caf64603267b81e6a874f205 SHA512 e2954d1a55a37fa339dd0cbc0ca753e4f783cd77858277e287c033a53ac5f2e96bc5329d069016fc3841d07dc9e8f5b1bb08ecf9ed0224bbc675843132749fdd
+DIST ImageMagick-6.9.11-31.tar.xz 9225744 BLAKE2B 0a540862ac6cf3504e0ad081748c5e6a99b8858ed52e145b8be142a3294a5e354ee8453987c9783deb924a69fe2dbf340d88e9bc7bcdb14b98f33a6bf18e3039 SHA512 11a33d75c2e9ff35ff5e8d0c40a470874dcbe39350f84f7816c536798af0be5da78cd28416ce74e6f045a4cfdb0f70e1f7fb58dd7bf88465a744fb587c098ee4
 DIST ImageMagick-7.0.10-28.tar.xz 9705324 BLAKE2B 0fe890a23b9fc97ceb5253e24ab8236135f4a4f48c1480ad5577c6a2535bf350fcea062b8897fc5e7993ab86716b1e280fabcf664442e3fe9d209e8c2806ea2d SHA512 fcfdacec893bb0a39c4a3caae1ade5ea7d3f6b8909cc73f218260f9f9b354ebe77aecedb2be2e2a64011eceb895c1ecb2fa0f349361387d56fb0f3cde657e158
+DIST ImageMagick-7.0.10-31.tar.xz 9653808 BLAKE2B 14c02ed0be35d817ebc2ccb0fcd436e34a7350dbe459ec3acd1a6ed94e46b181b5f713c9e8b5260e08287d5feb34c7a23b4e57bda0752a8206352c10b5379825 SHA512 0f6a2e098706186e43be3b91f10ac243aef4d96ce8943e88709243f9673205ec2261502c623f10af4f8fa126d8b4d5e3f636c9820790e5d730e54c5e634a61b3
 EBUILD imagemagick-6.9.11.28.ebuild 7049 BLAKE2B a55cac8280b047983a972159734711175d78840a6d29c75ed38366fc07aa4be312c75f523ef4185318f9734df496373e36b0c3170cd89e0859d282935ef3b566 SHA512 524f10eb990b5a5df4af8d0c39e6cf00d30f6d3bda40c0f609a16825d23b2b1b18d5ea10413df97aca1c6a26b0ac05d06c7c902f8a7c0ded4c33106b05566d2b
+EBUILD imagemagick-6.9.11.31.ebuild 7056 BLAKE2B 31393b291f0d6bec7dc70d794b1a84039d54c1a12b7b4417caacea9bb2dc693a91d00273243a6450c1e7b7044e6b4c66a5fa8ccf28d1634d610a767775dd566a SHA512 72e95675a0102e46604bc1161c687465d2b2acf58a7096dd0637e2b9bdbc4a53ce2fb3490e6d32fd00ce5767540abe39b03a93c187f33b0c6c21f5c96a897d49
 EBUILD imagemagick-7.0.10.28.ebuild 7338 BLAKE2B c5bd8fa410de6a1fec8a11c9f11d4bc527acf4502ef3d02dfd2f845ee0db2831de6a1734c860aacf224df0e13895aed104d238420b5021b947ba35b91b60149c SHA512 2ff4dc18a4fe408c0aead424af26225f8590607a48a60ac11906603f0cd808e23c0b6b50813f3463f570d3e5c3a9675fb60edc67b2bd8428d073c7ebe0778a17
+EBUILD imagemagick-7.0.10.31.ebuild 7346 BLAKE2B 6b3c2522969859e905afddcb92679bed0944d991831822d5bf6e967e0faafed369380f793aa337ac87b3a1af7a1b7290dc0f71094cf6346fdd63d57d49823d97 SHA512 a21b1d1bd706370b2c044c7cd55c290dd7a9ffac55c0c92b86c8f4ac969a14d2d3eca6b9e97decc61099d3f0842e9029f145e0adc4366c1ae153a0333869da74
 EBUILD imagemagick-9999.ebuild 7220 BLAKE2B 12b0db73d15e5d9b5af68912ae1b2907919cc875d73536c261477534fa17363fb8f75b2d63501ab6f844eb9e976893107513968d9e89ccce9d3490cfe93389db SHA512 19ce4536488e465e744a5da210566112de83a6d2df48a1cf9cc44c32a2e9d4ab3a65909ce17ac47e0dc29ccb734a5b52e81f6585dc015a3ad89faa3d72667747
 MISC metadata.xml 1106 BLAKE2B e77cabff89df6b98687290ef0ee06d85111a7ddca6f5e1e31f820e6d186a6510c2afd0b85ba31004f102fd7f7b88f46af101f4ba45011aac75afa40b0a714857 SHA512 68a5f9a80b1e3f2e3004252703f9b3176d7c59880a2724ae431fdfd97e8f2adcd7ff7ad2cd8ea8bd35645a3b559052f2c38713647ce7ae889ff1a6061e6b2d92
diff --git a/media-gfx/imagemagick/imagemagick-6.9.11.31.ebuild b/media-gfx/imagemagick/imagemagick-6.9.11.31.ebuild
new file mode 100644
index 000000000000..02b0c9655fe7
--- /dev/null
+++ b/media-gfx/imagemagick/imagemagick-6.9.11.31.ebuild
@@ -0,0 +1,255 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+inherit eapi7-ver eutils flag-o-matic libtool perl-functions toolchain-funcs multilib
+
+MY_PV="$(ver_rs 3 '-')"
+MY_P="ImageMagick-${MY_PV}"
+
+DESCRIPTION="A collection of tools and libraries for many image formats"
+HOMEPAGE="https://www.imagemagick.org/"
+SRC_URI="mirror://imagemagick/${MY_P}.tar.xz"
+
+LICENSE="imagemagick"
+SLOT="0/6.9.11"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~ppc-aix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="bzip2 corefonts +cxx djvu fftw fontconfig fpx graphviz hdri heif jbig jpeg jpeg2k lcms lqr lzma opencl openexr openmp pango perl png postscript q32 q8 raw static-libs svg test tiff truetype webp wmf X xml zlib"
+
+REQUIRED_USE="corefonts? ( truetype )
+	test? ( corefonts )"
+
+RESTRICT="perl? ( userpriv )
+	!test? ( test )"
+
+RDEPEND="
+	dev-libs/libltdl:0
+	bzip2? ( app-arch/bzip2 )
+	corefonts? ( media-fonts/corefonts )
+	djvu? ( app-text/djvu )
+	fftw? ( sci-libs/fftw:3.0 )
+	fontconfig? ( media-libs/fontconfig )
+	fpx? ( >=media-libs/libfpx-1.3.0-r1 )
+	graphviz? ( media-gfx/graphviz )
+	heif? ( media-libs/libheif:= )
+	jbig? ( >=media-libs/jbigkit-2:= )
+	jpeg? ( virtual/jpeg:0 )
+	jpeg2k? ( >=media-libs/openjpeg-2.1.0:2 )
+	lcms? ( media-libs/lcms:2= )
+	lqr? ( media-libs/liblqr )
+	opencl? ( virtual/opencl )
+	openexr? ( media-libs/openexr:0= )
+	pango? ( x11-libs/pango )
+	perl? ( >=dev-lang/perl-5.8.8:0= )
+	png? ( media-libs/libpng:0= )
+	postscript? ( app-text/ghostscript-gpl )
+	raw? ( media-libs/libraw:= )
+	svg? (
+		gnome-base/librsvg
+		media-gfx/potrace
+		)
+	tiff? ( media-libs/tiff:0= )
+	truetype? (
+		media-fonts/urw-fonts
+		>=media-libs/freetype-2
+		)
+	webp? ( media-libs/libwebp:0= )
+	wmf? ( media-libs/libwmf )
+	X? (
+		x11-libs/libICE
+		x11-libs/libSM
+		x11-libs/libXext
+		x11-libs/libXt
+		)
+	xml? ( dev-libs/libxml2:= )
+	lzma? ( app-arch/xz-utils )
+	zlib? ( sys-libs/zlib:= )"
+DEPEND="${RDEPEND}
+	!media-gfx/graphicsmagick[imagemagick]
+	virtual/pkgconfig
+	X? ( x11-base/xorg-proto )"
+
+S="${WORKDIR}/${MY_P}"
+#S="${WORKDIR}/ImageMagick6-${MY_PV}"
+
+src_prepare() {
+	default
+
+	# Apply hardening #664236
+	cp "${FILESDIR}"/policy-hardening.snippet "${S}" || die
+	sed -i -e '/^<policymap>$/ {
+			r policy-hardening.snippet
+			d
+		}' \
+		config/policy.xml || \
+		die "Failed to apply hardening of policy.xml"
+	einfo "policy.xml hardened"
+
+	elibtoolize # for Darwin modules
+
+	# For testsuite, see https://bugs.gentoo.org/show_bug.cgi?id=500580#c3
+	local mesa_cards ati_cards nvidia_cards render_cards
+	shopt -s nullglob
+	ati_cards=$(echo -n /dev/ati/card* | sed 's/ /:/g')
+	if test -n "${ati_cards}"; then
+		addpredict "${ati_cards}"
+	fi
+	mesa_cards=$(echo -n /dev/dri/card* | sed 's/ /:/g')
+	if test -n "${mesa_cards}"; then
+		addpredict "${mesa_cards}"
+	fi
+	nvidia_cards=$(echo -n /dev/nvidia** | sed 's/ /:/g')
+	if test -n "${nvidia_cards}"; then
+		addpredict "${nvidia_cards}"
+	fi
+	render_cards=$(echo -n /dev/dri/renderD128* | sed 's/ /:/g')
+	if test -n "${render_cards}"; then
+		addpredict "${render_cards}"
+	fi
+	shopt -u nullglob
+	addpredict /dev/nvidiactl
+}
+
+src_configure() {
+	local depth=16
+	use q8 && depth=8
+	use q32 && depth=32
+
+	local openmp=disable
+	use openmp && { tc-has-openmp && openmp=enable; }
+
+	use perl && perl_check_env
+
+	[[ ${CHOST} == *-solaris* ]] && append-ldflags -lnsl -lsocket
+
+	local myeconfargs=(
+		$(use_enable static-libs static)
+		$(use_enable hdri)
+		$(use_enable opencl)
+		--with-threads
+		--with-modules
+		--with-quantum-depth=${depth}
+		$(use_with cxx magick-plus-plus)
+		$(use_with perl)
+		--with-perl-options='INSTALLDIRS=vendor'
+		--with-gs-font-dir="${EPREFIX}"/usr/share/fonts/urw-fonts
+		$(use_with bzip2 bzlib)
+		$(use_with X x)
+		$(use_with zlib)
+		--without-autotrace
+		$(use_with postscript dps)
+		$(use_with djvu)
+		--with-dejavu-font-dir="${EPREFIX}"/usr/share/fonts/dejavu
+		$(use_with fftw)
+		$(use_with fpx)
+		$(use_with fontconfig)
+		$(use_with truetype freetype)
+		$(use_with postscript gslib)
+		$(use_with graphviz gvc)
+		$(use_with heif heic)
+		$(use_with jbig)
+		$(use_with jpeg)
+		$(use_with jpeg2k openjp2)
+		$(use_with lcms)
+		$(use_with lqr)
+		$(use_with lzma)
+		$(use_with openexr)
+		$(use_with pango)
+		$(use_with png)
+		$(use_with raw)
+		$(use_with svg rsvg)
+		$(use_with tiff)
+		$(use_with webp)
+		$(use_with corefonts windows-font-dir "${EPREFIX}"/usr/share/fonts/corefonts)
+		$(use_with wmf)
+		$(use_with xml)
+		--${openmp}-openmp
+		--with-gcc-arch=no-automagic
+	)
+	CONFIG_SHELL=$(type -P bash) econf "${myeconfargs[@]}"
+}
+
+src_test() {
+	# Install default (unrestricted) policy in $HOME for test suite #664238
+	local _im_local_config_home="${HOME}/.config/ImageMagick"
+	mkdir -p "${_im_local_config_home}" || \
+		die "Failed to create IM config dir in '${_im_local_config_home}'"
+	cp "${FILESDIR}"/policy.test.xml "${_im_local_config_home}/policy.xml" || \
+		die "Failed to install default blank policy.xml in '${_im_local_config_home}'"
+
+	local im_command= IM_COMMANDS=()
+	IM_COMMANDS+=( "identify -version | grep -q -- \"${MY_PV}\"" ) # Verify that we are using version we just built
+	IM_COMMANDS+=( "identify -list policy" ) # Verify that policy.xml is used
+	IM_COMMANDS+=( "emake check" ) # Run tests
+
+	for im_command in "${IM_COMMANDS[@]}"; do
+		eval "${S}"/magick.sh \
+			${im_command} || \
+			die "Failed to run \"${im_command}\""
+	done
+}
+
+src_install() {
+	# Ensure documentation installation files and paths with each release!
+	emake \
+		DESTDIR="${D}" \
+		DOCUMENTATION_PATH="${EPREFIX}"/usr/share/doc/${PF}/html \
+		install
+
+	rm -f "${ED%/}"/usr/share/doc/${PF}/html/{ChangeLog,LICENSE,NEWS.txt}
+	dodoc {AUTHORS,README}.txt ChangeLog
+
+	if use perl; then
+		find "${ED}" -type f -name perllocal.pod -exec rm -f {} +
+		find "${ED}" -depth -mindepth 1 -type d -empty -exec rm -rf {} +
+	fi
+
+	find "${ED}" -name '*.la' -exec sed -i -e "/^dependency_libs/s:=.*:='':" {} +
+	# .la files in parent are not needed, keep plugin .la files
+	rm "${ED}"/usr/$(get_libdir)/*.la || die
+
+	if use opencl; then
+		cat <<-EOF > "${T}"/99${PN}
+		SANDBOX_PREDICT="/dev/nvidiactl:/dev/nvidia-uvm:/dev/ati/card:/dev/dri/card:/dev/dri/renderD128"
+		EOF
+
+		insinto /etc/sandbox.d
+		doins "${T}"/99${PN} #472766
+	fi
+
+	insinto /usr/share/${PN}
+	doins config/*icm
+}
+
+pkg_postinst() {
+	local _show_policy_xml_notice=
+
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		# This is a new installation
+		_show_policy_xml_notice=yes
+	else
+		local v
+		for v in ${REPLACING_VERSIONS}; do
+			if ! ver_test "${v}" -gt "6.9.10.10-r2"; then
+				# This is an upgrade
+				_show_policy_xml_notice=yes
+
+				# Show this elog only once
+				break
+			fi
+		done
+	fi
+
+	if [[ -n "${_show_policy_xml_notice}" ]]; then
+		elog "For security reasons, a policy.xml file was installed in /etc/ImageMagick-6"
+		elog "which will prevent the usage of the following coders by default:"
+		elog ""
+		elog "  - PS"
+		elog "  - PS2"
+		elog "  - PS3"
+		elog "  - EPS"
+		elog "  - PDF"
+		elog "  - XPS"
+	fi
+}
diff --git a/media-gfx/imagemagick/imagemagick-7.0.10.31.ebuild b/media-gfx/imagemagick/imagemagick-7.0.10.31.ebuild
new file mode 100644
index 000000000000..ac9609f64eff
--- /dev/null
+++ b/media-gfx/imagemagick/imagemagick-7.0.10.31.ebuild
@@ -0,0 +1,268 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+inherit flag-o-matic libtool perl-functions toolchain-funcs multilib
+
+if [[ ${PV} == "9999" ]] ; then
+	EGIT_REPO_URI="https://github.com/ImageMagick/ImageMagick.git"
+	inherit git-r3
+	MY_P="imagemagick-9999"
+else
+	MY_PV="$(ver_rs 3 '-')"
+	MY_P="ImageMagick-${MY_PV}"
+	SRC_URI="mirror://imagemagick/${MY_P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~ppc-aix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+fi
+
+DESCRIPTION="A collection of tools and libraries for many image formats"
+HOMEPAGE="https://www.imagemagick.org/"
+
+LICENSE="imagemagick"
+SLOT="0/7.0.10"
+IUSE="bzip2 corefonts +cxx djvu fftw fontconfig fpx graphviz hdri heif jbig jpeg jpeg2k lcms lqr lzma opencl openexr openmp pango perl png postscript q32 q8 raw static-libs svg test tiff truetype webp wmf X xml zlib"
+RESTRICT="!test? ( test )"
+
+REQUIRED_USE="corefonts? ( truetype )
+	svg? ( xml )
+	test? ( corefonts )"
+
+RESTRICT="!test? ( test )"
+
+BDEPEND="virtual/pkgconfig"
+
+RDEPEND="
+	dev-libs/libltdl:0
+	bzip2? ( app-arch/bzip2 )
+	corefonts? ( media-fonts/corefonts )
+	djvu? ( app-text/djvu )
+	fftw? ( sci-libs/fftw:3.0 )
+	fontconfig? ( media-libs/fontconfig )
+	fpx? ( >=media-libs/libfpx-1.3.0-r1 )
+	graphviz? ( media-gfx/graphviz )
+	heif? ( media-libs/libheif:= )
+	jbig? ( >=media-libs/jbigkit-2:= )
+	jpeg? ( virtual/jpeg:0 )
+	jpeg2k? ( >=media-libs/openjpeg-2.1.0:2 )
+	lcms? ( media-libs/lcms:2= )
+	lqr? ( media-libs/liblqr )
+	opencl? ( virtual/opencl )
+	openexr? ( media-libs/openexr:0= )
+	pango? ( x11-libs/pango )
+	perl? ( >=dev-lang/perl-5.8.8:0= )
+	png? ( media-libs/libpng:0= )
+	postscript? ( app-text/ghostscript-gpl )
+	raw? ( media-libs/libraw:= )
+	svg? (
+		gnome-base/librsvg
+		media-gfx/potrace
+		)
+	tiff? ( media-libs/tiff:0= )
+	truetype? (
+		media-fonts/urw-fonts
+		>=media-libs/freetype-2
+		)
+	webp? ( media-libs/libwebp:0= )
+	wmf? ( media-libs/libwmf )
+	X? (
+		x11-libs/libICE
+		x11-libs/libSM
+		x11-libs/libXext
+		x11-libs/libXt
+		)
+	xml? ( dev-libs/libxml2:= )
+	lzma? ( app-arch/xz-utils )
+	zlib? ( sys-libs/zlib:= )"
+
+DEPEND="${RDEPEND}
+	!media-gfx/graphicsmagick[imagemagick]
+	X? ( x11-base/xorg-proto )"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	default
+
+	# Apply hardening #664236
+	cp "${FILESDIR}"/policy-hardening.snippet "${S}" || die
+	sed -i -e '/^<policymap>$/ {
+			r policy-hardening.snippet
+			d
+		}' \
+		config/policy.xml || \
+		die "Failed to apply hardening of policy.xml"
+	einfo "policy.xml hardened"
+
+	elibtoolize # for Darwin modules
+
+	# For testsuite, see https://bugs.gentoo.org/show_bug.cgi?id=500580#c3
+	local ati_cards mesa_cards nvidia_cards render_cards
+	shopt -s nullglob
+	ati_cards=$(echo -n /dev/ati/card* | sed 's/ /:/g')
+	if test -n "${ati_cards}"; then
+		addpredict "${ati_cards}"
+	fi
+	mesa_cards=$(echo -n /dev/dri/card* | sed 's/ /:/g')
+	if test -n "${mesa_cards}"; then
+		addpredict "${mesa_cards}"
+	fi
+	nvidia_cards=$(echo -n /dev/nvidia* | sed 's/ /:/g')
+	if test -n "${nvidia_cards}"; then
+		addpredict "${nvidia_cards}"
+	fi
+	render_cards=$(echo -n /dev/dri/renderD128* | sed 's/ /:/g')
+	if test -n "${render_cards}"; then
+		addpredict "${render_cards}"
+	fi
+	shopt -u nullglob
+	addpredict /dev/nvidiactl
+}
+
+src_configure() {
+	local depth=16
+	use q8 && depth=8
+	use q32 && depth=32
+
+	local openmp=disable
+	use openmp && { tc-has-openmp && openmp=enable; }
+
+	use perl && perl_check_env
+
+	[[ ${CHOST} == *-solaris* ]] && append-ldflags -lnsl -lsocket
+
+	local myeconfargs=(
+		$(use_enable static-libs static)
+		$(use_enable hdri)
+		$(use_enable opencl)
+		--with-threads
+		--with-modules
+		--with-quantum-depth=${depth}
+		$(use_with cxx magick-plus-plus)
+		$(use_with perl)
+		--with-perl-options='INSTALLDIRS=vendor'
+		--with-gs-font-dir="${EPREFIX}"/usr/share/fonts/urw-fonts
+		$(use_with bzip2 bzlib)
+		$(use_with X x)
+		$(use_with zlib)
+		--without-autotrace
+		$(use_with postscript dps)
+		$(use_with djvu)
+		--with-dejavu-font-dir="${EPREFIX}"/usr/share/fonts/dejavu
+		$(use_with fftw)
+		$(use_with fpx)
+		$(use_with fontconfig)
+		$(use_with truetype freetype)
+		$(use_with postscript gslib)
+		$(use_with graphviz gvc)
+		$(use_with heif heic)
+		$(use_with jbig)
+		$(use_with jpeg)
+		$(use_with jpeg2k openjp2)
+		--without-jxl
+		$(use_with lcms)
+		$(use_with lqr)
+		$(use_with lzma)
+		$(use_with openexr)
+		$(use_with pango)
+		$(use_with png)
+		$(use_with raw)
+		$(use_with svg rsvg)
+		$(use_with tiff)
+		$(use_with webp)
+		$(use_with corefonts windows-font-dir "${EPREFIX}"/usr/share/fonts/corefonts)
+		$(use_with wmf)
+		$(use_with xml)
+		--${openmp}-openmp
+		--with-gcc-arch=no-automagic
+	)
+	CONFIG_SHELL=$(type -P bash) econf "${myeconfargs[@]}"
+}
+
+src_test() {
+	# Install default (unrestricted) policy in $HOME for test suite #664238
+	local _im_local_config_home="${HOME}/.config/ImageMagick"
+	mkdir -p "${_im_local_config_home}" || \
+		die "Failed to create IM config dir in '${_im_local_config_home}'"
+	cp "${FILESDIR}"/policy.test.xml "${_im_local_config_home}/policy.xml" || \
+		die "Failed to install default blank policy.xml in '${_im_local_config_home}'"
+
+	local im_command= IM_COMMANDS=()
+	if [[ ${PV} == "9999" ]] ; then
+		IM_COMMANDS+=( "magick -version" ) # Show version we are using -- cannot verify because of live ebuild
+	else
+		IM_COMMANDS+=( "magick -version | grep -q -- \"${MY_PV}\"" ) # Verify that we are using version we just built
+	fi
+	IM_COMMANDS+=( "magick -list policy" ) # Verify that policy.xml is used
+	IM_COMMANDS+=( "emake check" ) # Run tests
+
+	for im_command in "${IM_COMMANDS[@]}"; do
+		eval "${S}"/magick.sh \
+			${im_command} || \
+			die "Failed to run \"${im_command}\""
+	done
+}
+
+src_install() {
+	# Ensure documentation installation files and paths with each release!
+	emake \
+		DESTDIR="${D}" \
+		DOCUMENTATION_PATH="${EPREFIX}"/usr/share/doc/${PF}/html \
+		install
+
+	rm -f "${ED}"/usr/share/doc/${PF}/html/{ChangeLog,LICENSE,NEWS.txt}
+	dodoc {AUTHORS,README}.txt ChangeLog
+
+	if use perl; then
+		find "${ED}" -type f -name perllocal.pod -exec rm -f {} +
+		find "${ED}" -depth -mindepth 1 -type d -empty -exec rm -rf {} +
+	fi
+
+	find "${ED}" -name '*.la' -exec sed -i -e "/^dependency_libs/s:=.*:='':" {} +
+	# .la files in parent are not needed, keep plugin .la files
+	rm "${ED}"/usr/$(get_libdir)/*.la || die
+
+	if use opencl; then
+		cat <<-EOF > "${T}"/99${PN}
+		SANDBOX_PREDICT="/dev/nvidiactl:/dev/nvidia-uvm:/dev/ati/card:/dev/dri/card:/dev/dri/renderD128"
+		EOF
+
+		insinto /etc/sandbox.d
+		doins "${T}"/99${PN} #472766
+	fi
+
+	insinto /usr/share/${PN}
+	doins config/*icm
+}
+
+pkg_postinst() {
+	local _show_policy_xml_notice=
+
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		# This is a new installation
+		_show_policy_xml_notice=yes
+	else
+		local v
+		for v in ${REPLACING_VERSIONS}; do
+			if ! ver_test "${v}" -gt "7.0.8.10-r2"; then
+				# This is an upgrade
+				_show_policy_xml_notice=yes
+
+				# Show this elog only once
+				break
+			fi
+		done
+	fi
+
+	if [[ -n "${_show_policy_xml_notice}" ]]; then
+		elog "For security reasons, a policy.xml file was installed in /etc/ImageMagick-7"
+		elog "which will prevent the usage of the following coders by default:"
+		elog ""
+		elog "  - PS"
+		elog "  - PS2"
+		elog "  - PS3"
+		elog "  - EPS"
+		elog "  - PDF"
+		elog "  - XPS"
+	fi
+}