gentoo auto-resync : 16:07:2022 - 19:46:10

3 files changed, 309 insertions, 29 deletions

diff --git a/media-gfx/imagemagick/Manifest b/media-gfx/imagemagick/Manifest
index f4affd575c26..f1bf7b9f9ee6 100644
--- a/media-gfx/imagemagick/Manifest
+++ b/media-gfx/imagemagick/Manifest
@@ -5,9 +5,11 @@ DIST ImageMagick-6.9.12-28.tar.xz 9181044 BLAKE2B 2efc03da9e4c53b82479badfcc9a25
 DIST ImageMagick-6.9.12-35.tar.xz 9178620 BLAKE2B 8bcf8bcc8bee8fe3d996a3b9388fdc20a6bbd45dda35121a9fb84804277286cb17c3b6cf2e6096765aefe20a31f819f8bcf094b0b3b1c68b683b50ddc415b398 SHA512 ba1f49570d1f890bc313d4e58c53c2b7388108c64cd2c5ef7586a7568f72d5655fced1a22085e27858cffcf86b7548376970fc6947fccb36f4cfba48327089e6
 DIST ImageMagick-7.1.0-13.tar.xz 10311564 BLAKE2B 7cb3e58f548cbe0b9e1239df47ff4f42af2cd0b6ff4c417a62515ff9bd434ecabed2cc7f7cb7cf8880f20af3f6d7de33d7368f146b9ac7668149959966a463d8 SHA512 dac1fc229599a63703fc3aa1378de313dc94dfbfa71913dc408ef65c88ef33820b5ddab4c9a064a86cc35c0abb0136f0adb626bff9e227b52ed0d90993688044
 DIST ImageMagick-7.1.0-20.tar.xz 10339572 BLAKE2B 7e99a8b36089b1258f537dbdf8c674be17677da5450854e0dfe0ed3bd3722ec826099f7c22d615daece6d647e6c22f4d9aa7293fed9b4bebb77c163e3ac54bc3 SHA512 e07d8f8ede8f713f1c0bd571b6042062b154b95ab06b0479ec4162d242beba982bfa88438ac67985d4da6d18074bda4b0ac25a7c2ced44f19b54c21120441991
+DIST ImageMagick-7.1.0-37.tar.xz 10345216 BLAKE2B e07179d55527537c36dd1655d44f93df4ad39cb66667857581e0cae8efc03ec45dc65b0d5b0a2b78fd24ed5371f8ebea6c4965168b328bac7041466f45f40469 SHA512 43f116a3a6bb9794b8c8440c57a537eab29b0dac7b8ace574e3cc1e6d484054557c9e44235eb799b843ef761c6f22d29ef959f6de6b80a45a3898bee4d2f16da
 EBUILD imagemagick-6.9.12.28.ebuild 7271 BLAKE2B 10af3bac2a382aefdb2d731fe40c2e59d9a61ea7801bae918eeff8f41f39123714ee75006aae03b18d413de740599dcf9ac12dbbf061c5e774947f90edacfb5d SHA512 f7eb66bad1739b447c462d23e2f391a268a62291b3b3642cd3404379fcce9e229e8a2386b90985bbdb98f884021b4202bfa78e2ea26903404aaa03f8824c861f
 EBUILD imagemagick-6.9.12.35-r1.ebuild 7328 BLAKE2B 440bba84bf2fd9df190f2954ca6ad290af88841fa94085e9e4cea26ed5419b82f3b667429f0d596d96b78f6714037f106a31a3aa7ab38253b4348498d0ef1c25 SHA512 556e1b05a49bd60d0750f80746cccdfb7a39428b63f2e8860772a1a58d5a16675fe6b66cbe6bb29a9ab388ff43b621f69264318a119fd4466876c1731252595f
 EBUILD imagemagick-7.1.0.13.ebuild 7485 BLAKE2B 896feef5fe189b78077bf00f94a6c97dcdadc41173ccbc1496892b2f226ad8e1acea5098cb4db713fb16580fe1283b0abb87d2d391a7924a8e8b46cccaea1bbf SHA512 faf93e670caf340354f5ecf2fc4e7321b6759aff9913b4a7c341c8664ac800ea113e66faadf16c080053bc0f706977298de923708b3e7ede2e136c955d6efb7c
 EBUILD imagemagick-7.1.0.20-r1.ebuild 7555 BLAKE2B e4db7228ea2ae637eef9b189faf54b5580892f10ef93509f976929138338a5dd17eaf7630a411749549076f283de5ef00227d581ed9ff5b7c00c2a9fcc43b697 SHA512 39204411775a0e8b13633727304e585a2eb8d5be426242f735896c71275e1a2c467cf220f5451f60082f77e26f36c345fd20da3f733f52b0e58a665aa51c08dd
-EBUILD imagemagick-9999.ebuild 7548 BLAKE2B 5ee411dfe66206ca1065a1acd6f3966d88e3f9b18a1e8dec9e108c4c6f8c76fe45c1810ab8dfa77439b7e8b3100a95a16676e930cd1bdbafc88e97449905ae58 SHA512 003ebd2be2fa54d713ecdf597db76d23d32b40127c92a1992b2fc0f6de230d9eedae61d80422a0dd2d6103099e5b2fb65dad3ecf8d7206f221dd4fa8a3c398a1
+EBUILD imagemagick-7.1.0.37.ebuild 7583 BLAKE2B 1a81e066c744d9a13e0d877d8c0ed8b13f754849409bd18f56cfe47418b37e7f1dae97e4f225743751577024442b0eb25b5bba2e300a441048c36fb45bb9b7af SHA512 4eef7d19c52ab9f5b424bd458308ba88fea6f7f30bc8ebfbba795da82cf2e1354f65549d633c533cc80a19b306a264c19fcb18b1c562420cf86efecdedb3f7e5
+EBUILD imagemagick-9999.ebuild 7583 BLAKE2B 1a81e066c744d9a13e0d877d8c0ed8b13f754849409bd18f56cfe47418b37e7f1dae97e4f225743751577024442b0eb25b5bba2e300a441048c36fb45bb9b7af SHA512 4eef7d19c52ab9f5b424bd458308ba88fea6f7f30bc8ebfbba795da82cf2e1354f65549d633c533cc80a19b306a264c19fcb18b1c562420cf86efecdedb3f7e5
 MISC metadata.xml 1227 BLAKE2B de893eae7e8f8e299ae10df13d202819b60df3b85858eacbe3455c4f27627689e7790a6fdded32d11d3157c35b5a2e08cab958e84b8f5799bb298deca15a1d4c SHA512 726e0c2cea973806fef1a3f51da11fb525b6a2e75bf2221a0939adbe50d2d8e267c5e627eca571e39769e4c14b134d2b9be3792047523540620c2eac149dd066
diff --git a/media-gfx/imagemagick/imagemagick-7.1.0.37.ebuild b/media-gfx/imagemagick/imagemagick-7.1.0.37.ebuild
new file mode 100644
index 000000000000..c8d5c41b6f15
--- /dev/null
+++ b/media-gfx/imagemagick/imagemagick-7.1.0.37.ebuild
@@ -0,0 +1,278 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+QA_PKGCONFIG_VERSION=$(ver_cut 1-3)
+inherit autotools flag-o-matic perl-functions toolchain-funcs
+
+if [[ ${PV} == 9999 ]] ; then
+	EGIT_REPO_URI="https://github.com/ImageMagick/ImageMagick.git"
+	inherit git-r3
+	MY_P="imagemagick-9999"
+else
+	MY_PV="$(ver_rs 3 '-')"
+	MY_P="ImageMagick-${MY_PV}"
+	SRC_URI="mirror://imagemagick/${MY_P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+fi
+
+S="${WORKDIR}/${MY_P}"
+
+DESCRIPTION="A collection of tools and libraries for many image formats"
+HOMEPAGE="https://www.imagemagick.org/"
+
+LICENSE="imagemagick"
+SLOT="0/7.1.0-37"
+IUSE="bzip2 corefonts +cxx djvu fftw fontconfig fpx graphviz hdri heif jbig jpeg jpeg2k lcms lqr lzma opencl openexr openmp pango perl +png postscript q32 q8 raw static-libs svg test tiff truetype webp wmf X xml zip zlib"
+
+REQUIRED_USE="corefonts? ( truetype )
+	svg? ( xml )
+	test? ( corefonts )"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	!media-gfx/graphicsmagick[imagemagick]
+	dev-libs/libltdl
+	bzip2? ( app-arch/bzip2 )
+	corefonts? ( media-fonts/corefonts )
+	djvu? ( app-text/djvu )
+	fftw? ( sci-libs/fftw:3.0 )
+	fontconfig? ( media-libs/fontconfig )
+	fpx? ( >=media-libs/libfpx-1.3.0-r1 )
+	graphviz? ( media-gfx/graphviz )
+	heif? ( media-libs/libheif:=[x265] )
+	jbig? ( >=media-libs/jbigkit-2:= )
+	jpeg? ( media-libs/libjpeg-turbo:= )
+	jpeg2k? ( >=media-libs/openjpeg-2.1.0:2 )
+	lcms? ( media-libs/lcms:2= )
+	lqr? ( media-libs/liblqr )
+	opencl? ( virtual/opencl )
+	openexr? ( media-libs/openexr:0= )
+	pango? ( x11-libs/pango )
+	perl? ( >=dev-lang/perl-5.8.8:= )
+	png? ( media-libs/libpng:= )
+	postscript? ( app-text/ghostscript-gpl )
+	raw? ( media-libs/libraw:= )
+	svg? (
+		gnome-base/librsvg
+		media-gfx/potrace
+	)
+	tiff? ( media-libs/tiff:= )
+	truetype? (
+		media-fonts/urw-fonts
+		>=media-libs/freetype-2
+	)
+	webp? ( media-libs/libwebp:= )
+	wmf? ( media-libs/libwmf )
+	X? (
+		x11-libs/libICE
+		x11-libs/libSM
+		x11-libs/libXext
+		x11-libs/libXt
+	)
+	xml? ( dev-libs/libxml2 )
+	lzma? ( app-arch/xz-utils )
+	zip? ( dev-libs/libzip:= )
+	zlib? ( sys-libs/zlib:= )"
+DEPEND="${RDEPEND}
+	X? ( x11-base/xorg-proto )"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-9999-nocputuning.patch"
+)
+
+pkg_pretend() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+src_prepare() {
+	default
+
+	#elibtoolize # for Darwin modules
+	eautoreconf
+
+	# Apply hardening, bug #664236
+	cp "${FILESDIR}"/policy-hardening.snippet "${S}" || die
+	sed -i -e '/^<policymap>$/ {
+			r policy-hardening.snippet
+			d
+		}' \
+		config/policy.xml || \
+		die "Failed to apply hardening of policy.xml"
+	einfo "policy.xml hardened"
+
+	# For testsuite, see https://bugs.gentoo.org/show_bug.cgi?id=500580#c3
+	local ati_cards mesa_cards nvidia_cards render_cards
+	shopt -s nullglob
+	ati_cards=$(echo -n /dev/ati/card* | sed 's/ /:/g')
+	if test -n "${ati_cards}"; then
+		addpredict "${ati_cards}"
+	fi
+	mesa_cards=$(echo -n /dev/dri/card* | sed 's/ /:/g')
+	if test -n "${mesa_cards}"; then
+		addpredict "${mesa_cards}"
+	fi
+	nvidia_cards=$(echo -n /dev/nvidia* | sed 's/ /:/g')
+	if test -n "${nvidia_cards}"; then
+		addpredict "${nvidia_cards}"
+	fi
+	render_cards=$(echo -n /dev/dri/renderD128* | sed 's/ /:/g')
+	if test -n "${render_cards}"; then
+		addpredict "${render_cards}"
+	fi
+	shopt -u nullglob
+	addpredict /dev/nvidiactl
+}
+
+src_configure() {
+	local depth=16
+	use q8 && depth=8
+	use q32 && depth=32
+
+	use perl && perl_check_env
+
+	[[ ${CHOST} == *-solaris* ]] && append-ldflags -lnsl -lsocket
+
+	local myeconfargs=(
+		$(use_enable static-libs static)
+		$(use_enable hdri)
+		$(use_enable opencl)
+		$(use_enable openmp)
+		--with-threads
+		--with-modules
+		--with-quantum-depth=${depth}
+		$(use_with cxx magick-plus-plus)
+		$(use_with perl)
+		--with-perl-options='INSTALLDIRS=vendor'
+		--with-gs-font-dir="${EPREFIX}"/usr/share/fonts/urw-fonts
+		$(use_with bzip2 bzlib)
+		$(use_with X x)
+		$(use_with zip)
+		$(use_with zlib)
+		--without-autotrace
+		$(use_with postscript dps)
+		$(use_with djvu)
+		--with-dejavu-font-dir="${EPREFIX}"/usr/share/fonts/dejavu
+		$(use_with fftw)
+		$(use_with fpx)
+		$(use_with fontconfig)
+		$(use_with truetype freetype)
+		$(use_with postscript gslib)
+		$(use_with graphviz gvc)
+		$(use_with heif heic)
+		$(use_with jbig)
+		$(use_with jpeg)
+		$(use_with jpeg2k openjp2)
+		--without-jxl
+		$(use_with lcms)
+		$(use_with lqr)
+		$(use_with lzma)
+		$(use_with openexr)
+		$(use_with pango)
+		$(use_with png)
+		$(use_with raw)
+		$(use_with svg rsvg)
+		$(use_with tiff)
+		$(use_with webp)
+		$(use_with corefonts windows-font-dir "${EPREFIX}"/usr/share/fonts/corefonts)
+		$(use_with wmf)
+		$(use_with xml)
+	)
+
+	CONFIG_SHELL="${BROOT}"/bin/bash econf "${myeconfargs[@]}"
+}
+
+src_test() {
+	# Install default (unrestricted) policy in $HOME for test suite, bug #664238
+	local _im_local_config_home="${HOME}/.config/ImageMagick"
+	mkdir -p "${_im_local_config_home}" || \
+		die "Failed to create IM config dir in '${_im_local_config_home}'"
+	cp "${FILESDIR}"/policy.test.xml "${_im_local_config_home}/policy.xml" || \
+		die "Failed to install default blank policy.xml in '${_im_local_config_home}'"
+
+	local im_command= IM_COMMANDS=()
+	if [[ ${PV} == 9999 ]] ; then
+		IM_COMMANDS+=( "magick -version" ) # Show version we are using -- cannot verify because of live ebuild
+	else
+		IM_COMMANDS+=( "magick -version | grep -q -- \"${MY_PV}\"" ) # Verify that we are using version we just built
+	fi
+	IM_COMMANDS+=( "magick -list policy" ) # Verify that policy.xml is used
+	IM_COMMANDS+=( "emake check" ) # Run tests
+
+	for im_command in "${IM_COMMANDS[@]}"; do
+		eval "${S}"/magick.sh \
+			${im_command} || \
+			die "Failed to run \"${im_command}\""
+	done
+}
+
+src_install() {
+	# Ensure documentation installation files and paths with each release!
+	emake \
+		DESTDIR="${D}" \
+		DOCUMENTATION_PATH="${EPREFIX}"/usr/share/doc/${PF}/html \
+		install
+
+	rm -f "${ED}"/usr/share/doc/${PF}/html/{ChangeLog,LICENSE,NEWS.txt}
+	dodoc {AUTHORS,README}.txt
+
+	if use perl; then
+		find "${ED}" -type f -name perllocal.pod -exec rm -f {} +
+		find "${ED}" -depth -mindepth 1 -type d -empty -exec rm -rf {} +
+	fi
+
+	find "${ED}" -name '*.la' -exec sed -i -e "/^dependency_libs/s:=.*:='':" {} +
+	# .la files in parent are not needed, keep plugin .la files
+	find "${ED}"/usr/$(get_libdir)/ -maxdepth 1 -name "*.la" -delete || die
+
+	if use opencl; then
+		cat <<-EOF > "${T}"/99${PN}
+		SANDBOX_PREDICT="/dev/nvidiactl:/dev/nvidia-uvm:/dev/ati/card:/dev/dri/card:/dev/dri/card0:/dev/dri/renderD128"
+		EOF
+
+		insinto /etc/sandbox.d
+		doins "${T}"/99${PN} #472766
+	fi
+
+	insinto /usr/share/${PN}
+	doins config/*icm
+}
+
+pkg_postinst() {
+	local _show_policy_xml_notice=
+
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		# This is a new installation
+		_show_policy_xml_notice=yes
+	else
+		local v
+		for v in ${REPLACING_VERSIONS}; do
+			if ! ver_test "${v}" -gt "7.0.8.10-r2"; then
+				# This is an upgrade
+				_show_policy_xml_notice=yes
+
+				# Show this elog only once
+				break
+			fi
+		done
+	fi
+
+	if [[ -n "${_show_policy_xml_notice}" ]]; then
+		elog "For security reasons, a policy.xml file was installed in /etc/ImageMagick-7"
+		elog "which will prevent the usage of the following coders by default:"
+		elog ""
+		elog "  - PS"
+		elog "  - PS2"
+		elog "  - PS3"
+		elog "  - EPS"
+		elog "  - PDF"
+		elog "  - XPS"
+	fi
+}
diff --git a/media-gfx/imagemagick/imagemagick-9999.ebuild b/media-gfx/imagemagick/imagemagick-9999.ebuild
index 0b6122942f86..c8d5c41b6f15 100644
--- a/media-gfx/imagemagick/imagemagick-9999.ebuild
+++ b/media-gfx/imagemagick/imagemagick-9999.ebuild
@@ -1,11 +1,12 @@
 # Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI="8"
+EAPI=8
 
-inherit autotools flag-o-matic libtool perl-functions toolchain-funcs
+QA_PKGCONFIG_VERSION=$(ver_cut 1-3)
+inherit autotools flag-o-matic perl-functions toolchain-funcs
 
-if [[ ${PV} == "9999" ]] ; then
+if [[ ${PV} == 9999 ]] ; then
 	EGIT_REPO_URI="https://github.com/ImageMagick/ImageMagick.git"
 	inherit git-r3
 	MY_P="imagemagick-9999"
@@ -13,14 +14,16 @@ else
 	MY_PV="$(ver_rs 3 '-')"
 	MY_P="ImageMagick-${MY_PV}"
 	SRC_URI="mirror://imagemagick/${MY_P}.tar.xz"
-	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
 fi
 
+S="${WORKDIR}/${MY_P}"
+
 DESCRIPTION="A collection of tools and libraries for many image formats"
 HOMEPAGE="https://www.imagemagick.org/"
 
 LICENSE="imagemagick"
-SLOT="0/7.1.0-0"
+SLOT="0/7.1.0-37"
 IUSE="bzip2 corefonts +cxx djvu fftw fontconfig fpx graphviz hdri heif jbig jpeg jpeg2k lcms lqr lzma opencl openexr openmp pango perl +png postscript q32 q8 raw static-libs svg test tiff truetype webp wmf X xml zip zlib"
 
 REQUIRED_USE="corefonts? ( truetype )
@@ -29,10 +32,9 @@ REQUIRED_USE="corefonts? ( truetype )
 
 RESTRICT="!test? ( test )"
 
-BDEPEND="virtual/pkgconfig"
-
 RDEPEND="
-	dev-libs/libltdl:0
+	!media-gfx/graphicsmagick[imagemagick]
+	dev-libs/libltdl
 	bzip2? ( app-arch/bzip2 )
 	corefonts? ( media-fonts/corefonts )
 	djvu? ( app-text/djvu )
@@ -42,49 +44,46 @@ RDEPEND="
 	graphviz? ( media-gfx/graphviz )
 	heif? ( media-libs/libheif:=[x265] )
 	jbig? ( >=media-libs/jbigkit-2:= )
-	jpeg? ( virtual/jpeg:0 )
+	jpeg? ( media-libs/libjpeg-turbo:= )
 	jpeg2k? ( >=media-libs/openjpeg-2.1.0:2 )
 	lcms? ( media-libs/lcms:2= )
 	lqr? ( media-libs/liblqr )
 	opencl? ( virtual/opencl )
 	openexr? ( media-libs/openexr:0= )
 	pango? ( x11-libs/pango )
-	perl? ( >=dev-lang/perl-5.8.8:0= )
-	png? ( media-libs/libpng:0= )
+	perl? ( >=dev-lang/perl-5.8.8:= )
+	png? ( media-libs/libpng:= )
 	postscript? ( app-text/ghostscript-gpl )
 	raw? ( media-libs/libraw:= )
 	svg? (
 		gnome-base/librsvg
 		media-gfx/potrace
-		)
-	tiff? ( media-libs/tiff:0= )
+	)
+	tiff? ( media-libs/tiff:= )
 	truetype? (
 		media-fonts/urw-fonts
 		>=media-libs/freetype-2
-		)
-	webp? ( media-libs/libwebp:0= )
+	)
+	webp? ( media-libs/libwebp:= )
 	wmf? ( media-libs/libwmf )
 	X? (
 		x11-libs/libICE
 		x11-libs/libSM
 		x11-libs/libXext
 		x11-libs/libXt
-		)
-	xml? ( dev-libs/libxml2:= )
+	)
+	xml? ( dev-libs/libxml2 )
 	lzma? ( app-arch/xz-utils )
 	zip? ( dev-libs/libzip:= )
 	zlib? ( sys-libs/zlib:= )"
-
 DEPEND="${RDEPEND}
-	!media-gfx/graphicsmagick[imagemagick]
 	X? ( x11-base/xorg-proto )"
+BDEPEND="virtual/pkgconfig"
 
 PATCHES=(
 	"${FILESDIR}/${PN}-9999-nocputuning.patch"
 )
 
-S="${WORKDIR}/${MY_P}"
-
 pkg_pretend() {
 	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
 }
@@ -95,9 +94,11 @@ pkg_setup() {
 
 src_prepare() {
 	default
+
+	#elibtoolize # for Darwin modules
 	eautoreconf
 
-	# Apply hardening #664236
+	# Apply hardening, bug #664236
 	cp "${FILESDIR}"/policy-hardening.snippet "${S}" || die
 	sed -i -e '/^<policymap>$/ {
 			r policy-hardening.snippet
@@ -107,8 +108,6 @@ src_prepare() {
 		die "Failed to apply hardening of policy.xml"
 	einfo "policy.xml hardened"
 
-	elibtoolize # for Darwin modules
-
 	# For testsuite, see https://bugs.gentoo.org/show_bug.cgi?id=500580#c3
 	local ati_cards mesa_cards nvidia_cards render_cards
 	shopt -s nullglob
@@ -186,11 +185,12 @@ src_configure() {
 		$(use_with wmf)
 		$(use_with xml)
 	)
-	CONFIG_SHELL=$(type -P bash) econf "${myeconfargs[@]}"
+
+	CONFIG_SHELL="${BROOT}"/bin/bash econf "${myeconfargs[@]}"
 }
 
 src_test() {
-	# Install default (unrestricted) policy in $HOME for test suite #664238
+	# Install default (unrestricted) policy in $HOME for test suite, bug #664238
 	local _im_local_config_home="${HOME}/.config/ImageMagick"
 	mkdir -p "${_im_local_config_home}" || \
 		die "Failed to create IM config dir in '${_im_local_config_home}'"
@@ -198,7 +198,7 @@ src_test() {
 		die "Failed to install default blank policy.xml in '${_im_local_config_home}'"
 
 	local im_command= IM_COMMANDS=()
-	if [[ ${PV} == "9999" ]] ; then
+	if [[ ${PV} == 9999 ]] ; then
 		IM_COMMANDS+=( "magick -version" ) # Show version we are using -- cannot verify because of live ebuild
 	else
 		IM_COMMANDS+=( "magick -version | grep -q -- \"${MY_PV}\"" ) # Verify that we are using version we just built
@@ -221,7 +221,7 @@ src_install() {
 		install
 
 	rm -f "${ED}"/usr/share/doc/${PF}/html/{ChangeLog,LICENSE,NEWS.txt}
-	dodoc {AUTHORS,README}.txt ChangeLog
+	dodoc {AUTHORS,README}.txt
 
 	if use perl; then
 		find "${ED}" -type f -name perllocal.pod -exec rm -f {} +