gentoo resync : 06.04.2022

4 files changed, 197 insertions, 17 deletions

diff --git a/media-gfx/graphicsmagick/Manifest b/media-gfx/graphicsmagick/Manifest
index f852c8057966..14b08e6ecd55 100644
--- a/media-gfx/graphicsmagick/Manifest
+++ b/media-gfx/graphicsmagick/Manifest
@@ -1,6 +1,9 @@
 AUX graphicsmagick-1.3.19-perl.patch 491 BLAKE2B 6a6465162d9a4d7d09b1edb425cc7114cd4e0fc65e48f15c8c2a854fe835fd1fe94c56611c6d2744d9e26884c57b1f67353bfd32abe2f25a145dd7abbf5479f0 SHA512 da114b891ec923253048d90ee14f136742072bcb70e512e8d2838bbcac57b5fe6ea580cdccfd1bba5156777623c43e946ce2a8661f88612d4c24849bef0fb865
 AUX graphicsmagick-1.3.36-flags.patch 2009 BLAKE2B 1d58f03cfeac9be92e2e85a2b6274ec22e3cb2c65d62e3095f2bb3da8f817ae52fdd6fe70e5da30bb8110202ec8c8268ffef7069c34d55ef7f7ccc3e53785418 SHA512 205694ea04e7b65c5519c564bbfa1ebd33ef4fa7800aec1a91439ed90794629dd54ab42c1c7f4f2f5ce3b7b078b3fffe76ce37c61643087f5cca244931b5bd3a
 DIST GraphicsMagick-1.3.37.tar.xz 5623688 BLAKE2B d6d5c8a07ec2aa2e60399887fa788751104c6917af295bb5a7bb1281d4a547462dd76cdde98f09cc00322bc3d7c89258dcd9d50506cfcec47a606efd90163b2a SHA512 971e05480a65eb99ff3c0d874675bcbffc24eafec1cacd03f5ef410ae014f82329f3590393100927f753feb183be1105fe0cfc5b0f775a30b0e6dc0c6b8a77af
+DIST GraphicsMagick-1.3.38.tar.xz 5958352 BLAKE2B 132c8b2303690dbe84b0e9ab33db0c0861845ef0260915e33197912dbcae02ae70c27bce634cfe0ab6b739ef6f3e828cbea9043fc90be993fb2c4a5e33e20ee9 SHA512 478f9e2907d4cb1099b0cbd1a73e4ab58aef94edf6cb1636ce48a378084ec1671599fd4f369455e5af898e94d1386f7149f6933b7c668027a6f6952bc763ec3a
+DIST GraphicsMagick-1.3.38.tar.xz.sig 119 BLAKE2B 166b7bb6de30af22d1f2317812f76dee43dd69c5557613deea35de3767624466c07001fe029ec9d33d0c61ed2fe5ca3f48bf435853374c722963a1293bfaa7a1 SHA512 c6dfee7e4b63b646460f9045ca5c8f3105d1a761ec3cd3471b53293178ed9a963884539c8026d934ce1915654d517a9b30232d7260a13f6d7dbeb5a592485b09
 EBUILD graphicsmagick-1.3.37.ebuild 3200 BLAKE2B dcc9f75b410f671a4aaa8da96bd40672e005cacc0f0138e42a7d20924738ae514845548d612d404a76069e2b604e7aacea0957b70d893e7eb07550886204bf5a SHA512 fcadc6d72188e1106b0374ecdbf6ea5c37b3fb8e24ef4e453e291c080ee95f51440360938872c86ca011a17f4945d97065836c3b06c6aabcb4f5c9b7ae7c762c
-EBUILD graphicsmagick-9999.ebuild 3202 BLAKE2B 00c9664a42a33974782006a2d27043d7cce406ac6558b50af40eae04f6cabed858474223b7221ddafcb7a3b37ecbea45eedd64157a3134cbe9e85b16f88fc36d SHA512 6de55d703f28e0b87cfa6c16d952cc6cf56ad7ff967ac65ec9cb8c81fe696abbca2d62158467da7ce5d5aea96f0a10f27ef7c920ec7c1c4be4a522b29c896667
-MISC metadata.xml 1277 BLAKE2B 2dc552ca54b8776bbcf08f6939a7cd10fbae14a1b6062ffc3f4480b079d39caad022b1eac1eda95d03aaa30da01fd26da4fb59c5cf117300d446105f29b50a9c SHA512 8fa1382b7effbb5d8a56b3fbbb063abe5f60bcc85a57a834969878510be81fa255c1f09f8b5d839729e860c48b57d44a6666f3e89f4fba852b457df2940dcde0
+EBUILD graphicsmagick-1.3.38.ebuild 3702 BLAKE2B ad030ead93c82ee5c4b24e514ae924ceadf0025e9bb379faec36d53c3c2c0fe3f294a54f0f6a07b020389597fa178fa0315731ef5421a3c9567814c720238d97 SHA512 80dfc7c235ec29ce90d0624346e55c9e87a151549542370b2f3f7b760bbe7aebfe96870c50f4348c010a1881b777cb35ea0e26075634850be4c10f0bbf679059
+EBUILD graphicsmagick-9999.ebuild 3746 BLAKE2B 126886c157531dcf84278813df6c365a94992c753c865ad09cf897eee7f5e0b93458cde1676999539c99ff33cc7b2fafe8b830cb2ccfc4379f6479bcdddb8847 SHA512 118d0b3fe97b2dcfaea78c59b367986292b773165ba50a10e1c5ae3c1bf78e7704cc92b9c17e06d0b8b8fa2ad23c26c50f76e6279d0f8e6eeda6b5c8ca431507
+MISC metadata.xml 1405 BLAKE2B 450ce6e18c6debd66f923847912746cc3f522f923b2290e7815326cc9a8e4dfa9f57e0ed0d66ade4b09d71f6ecb2da810665530ae4876abcfd77dbbf0696829c SHA512 88d109fb876d4fef9dc7b9270c6418e8cc9820d6a085b0faabe647225ae4e5fa731335d7b45bb022a531eaf0ab4c9302be5a802603dd8ecc8ef484ba3bbf74ba
diff --git a/media-gfx/graphicsmagick/graphicsmagick-1.3.38.ebuild b/media-gfx/graphicsmagick/graphicsmagick-1.3.38.ebuild
new file mode 100644
index 000000000000..42ffd6c74653
--- /dev/null
+++ b/media-gfx/graphicsmagick/graphicsmagick-1.3.38.ebuild
@@ -0,0 +1,156 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools toolchain-funcs
+
+MY_P=${P/graphicsm/GraphicsM}
+DESCRIPTION="Collection of tools and libraries for many image formats"
+HOMEPAGE="http://www.graphicsmagick.org/ http://hg.code.sf.net/p/graphicsmagick/code/"
+
+if [[ ${PV} == 9999 ]] ; then
+	inherit mercurial
+	EHG_REPO_URI="http://hg.code.sf.net/p/${PN}/code"
+else
+	VERIFY_SIG_OPENPGP_KEY_PATH="${BROOT}"/usr/share/openpgp-keys/bobfriesenhahn.asc
+	inherit verify-sig
+	SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.xz"
+	SRC_URI+=" verify-sig? ( mirror://sourceforge/${PN}/${MY_P}.tar.xz.sig )"
+	S="${WORKDIR}/${MY_P}"
+
+	KEYWORDS="~alpha ~amd64 ~hppa ~m68k ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
+
+	BDEPEND="verify-sig? ( sec-keys/openpgp-keys-bobfriesenhahn )"
+fi
+
+LICENSE="MIT"
+SLOT="0/${PV%.*}"
+
+IUSE="bzip2 +cxx debug dynamic-loading fpx heif imagemagick jbig jpeg jpegxl lcms lzma"
+IUSE+=" openmp perl png postscript q16 q32 static-libs svg threads tiff truetype"
+IUSE+=" webp wmf X zlib"
+
+RDEPEND="dev-libs/libltdl
+	bzip2? ( app-arch/bzip2 )
+	fpx? ( media-libs/libfpx )
+	heif? ( media-libs/libheif:= )
+	imagemagick? ( !media-gfx/imagemagick )
+	jbig? ( media-libs/jbigkit )
+	jpeg? ( virtual/jpeg )
+	jpegxl? ( media-libs/libjxl:= )
+	lcms? ( media-libs/lcms:2 )
+	lzma? ( app-arch/xz-utils )
+	perl? ( dev-lang/perl:= )
+	png? ( media-libs/libpng:= )
+	postscript? ( app-text/ghostscript-gpl )
+	svg? ( dev-libs/libxml2 )
+	tiff? ( media-libs/tiff )
+	truetype? (
+		media-fonts/urw-fonts
+		>=media-libs/freetype-2
+	)
+	webp? ( media-libs/libwebp:= )
+	wmf? ( media-libs/libwmf )
+	X? (
+		x11-libs/libSM
+		x11-libs/libXext
+	)
+	zlib? ( sys-libs/zlib )"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.3.36-flags.patch
+	"${FILESDIR}"/${PN}-1.3.19-perl.patch
+)
+
+pkg_pretend() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+src_prepare() {
+	default
+
+	eautoreconf
+}
+
+src_configure() {
+	local depth=8
+
+	use q16 && depth=16
+	use q32 && depth=32
+
+	local myeconfargs=(
+		--enable-largefile
+		--enable-shared
+		$(use_enable static-libs static)
+		$(use_enable debug prof)
+		$(use_enable debug gcov)
+		$(use_enable imagemagick magick-compat)
+		$(use_with threads)
+		$(use_with dynamic-loading modules)
+		--with-quantum-depth=${depth}
+		--without-frozenpaths
+		$(use_with cxx magick-plus-plus)
+		$(use_with heif)
+		$(use_with jpegxl jxl)
+		$(use_with perl)
+		--with-perl-options=INSTALLDIRS=vendor
+		$(use_with bzip2 bzlib)
+		$(use_with postscript dps)
+		$(use_with fpx)
+		$(use_with jbig)
+		$(use_with webp)
+		$(use_with jpeg)
+		--without-jp2
+		$(use_with lcms lcms2)
+		$(use_with lzma)
+		$(use_with png)
+		$(use_with tiff)
+		$(use_with truetype ttf)
+		$(use_with wmf)
+		--with-fontpath="${EPREFIX}"/usr/share/fonts
+		--with-gs-font-dir="${EPREFIX}"/usr/share/fonts/urw-fonts
+		--with-windows-font-dir="${EPREFIX}"/usr/share/fonts/corefonts
+		$(use_with svg xml)
+		$(use_with zlib)
+		$(use_with X x)
+	)
+
+	if use openmp && tc-has-openmp ; then
+		myeconfargs+=( --enable-openmp )
+	else
+		myeconfargs+=( --disable-openmp )
+	fi
+
+	econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+	default
+
+	use perl && emake perl-build
+}
+
+src_test() {
+	unset DISPLAY # some perl tests fail when DISPLAY is set
+
+	default
+}
+
+src_install() {
+	default
+
+	if use perl ; then
+		emake -C PerlMagick DESTDIR="${D}" install
+
+		find "${ED}" -type f -name perllocal.pod -exec rm -f {} + || die
+		find "${ED}" -depth -mindepth 1 -type d -empty -exec rm -rf {} + || die
+	fi
+
+	find "${ED}" -name '*.la' -exec sed -i -e "/^dependency_libs/s:=.*:='':" {} + || die
+}
diff --git a/media-gfx/graphicsmagick/graphicsmagick-9999.ebuild b/media-gfx/graphicsmagick/graphicsmagick-9999.ebuild
index 903411326261..c640b1b4cc74 100644
--- a/media-gfx/graphicsmagick/graphicsmagick-9999.ebuild
+++ b/media-gfx/graphicsmagick/graphicsmagick-9999.ebuild
@@ -1,7 +1,7 @@
-# Copyright 1999-2021 Gentoo Authors
+# Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=7
+EAPI=8
 
 inherit autotools toolchain-funcs
 
@@ -9,36 +9,43 @@ MY_P=${P/graphicsm/GraphicsM}
 DESCRIPTION="Collection of tools and libraries for many image formats"
 HOMEPAGE="http://www.graphicsmagick.org/ http://hg.code.sf.net/p/graphicsmagick/code/"
 
-if [[ ${PV} == "9999" ]] ; then
+if [[ ${PV} == 9999 ]] ; then
 	inherit mercurial
 	EHG_REPO_URI="http://hg.code.sf.net/p/${PN}/code"
 else
+	VERIFY_SIG_OPENPGP_KEY_PATH="${BROOT}"/usr/share/openpgp-keys/bobfriesenhahn.asc
+	inherit verify-sig
 	SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.xz"
+	SRC_URI+=" verify-sig? ( mirror://sourceforge/${PN}/${MY_P}.tar.xz.sig )"
 	S="${WORKDIR}/${MY_P}"
 
-	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
+
+	BDEPEND="verify-sig? ( sec-keys/openpgp-keys-bobfriesenhahn )"
 fi
 
 LICENSE="MIT"
 SLOT="0/${PV%.*}"
 
-IUSE="bzip2 +cxx debug dynamic-loading fpx imagemagick jbig jpeg lcms lzma"
+IUSE="bzip2 +cxx debug dynamic-loading fpx heif imagemagick jbig jpeg jpegxl lcms lzma"
 IUSE+=" openmp perl png postscript q16 q32 static-libs svg threads tiff truetype"
 IUSE+=" webp wmf X zlib"
 
-RDEPEND="dev-libs/libltdl:0
+RDEPEND="dev-libs/libltdl
 	bzip2? ( app-arch/bzip2 )
 	fpx? ( media-libs/libfpx )
+	heif? ( media-libs/libheif:= )
 	imagemagick? ( !media-gfx/imagemagick )
 	jbig? ( media-libs/jbigkit )
-	jpeg? ( virtual/jpeg:0 )
+	jpeg? ( virtual/jpeg )
+	jpegxl? ( media-libs/libjxl:= )
 	lcms? ( media-libs/lcms:2 )
 	lzma? ( app-arch/xz-utils )
 	perl? ( dev-lang/perl:= )
-	png? ( media-libs/libpng:0= )
+	png? ( media-libs/libpng:= )
 	postscript? ( app-text/ghostscript-gpl )
 	svg? ( dev-libs/libxml2 )
-	tiff? ( media-libs/tiff:0 )
+	tiff? ( media-libs/tiff )
 	truetype? (
 		media-fonts/urw-fonts
 		>=media-libs/freetype-2
@@ -57,6 +64,14 @@ PATCHES=(
 	"${FILESDIR}"/${PN}-1.3.19-perl.patch
 )
 
+pkg_pretend() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
 src_prepare() {
 	default
 
@@ -65,16 +80,11 @@ src_prepare() {
 
 src_configure() {
 	local depth=8
+
 	use q16 && depth=16
 	use q32 && depth=32
 
-	local openmp=disable
-	if use openmp && tc-has-openmp ; then
-		openmp=enable
-	fi
-
 	local myeconfargs=(
-		--${openmp}-openmp
 		--enable-largefile
 		--enable-shared
 		$(use_enable static-libs static)
@@ -86,6 +96,8 @@ src_configure() {
 		--with-quantum-depth=${depth}
 		--without-frozenpaths
 		$(use_with cxx magick-plus-plus)
+		$(use_with heif)
+		$(use_with jpegxl jxl)
 		$(use_with perl)
 		--with-perl-options=INSTALLDIRS=vendor
 		$(use_with bzip2 bzlib)
@@ -109,6 +121,12 @@ src_configure() {
 		$(use_with X x)
 	)
 
+	if use openmp && tc-has-openmp ; then
+		myeconfargs+=( --enable-openmp )
+	else
+		myeconfargs+=( --disable-openmp )
+	fi
+
 	econf "${myeconfargs[@]}"
 }
 
@@ -129,6 +147,7 @@ src_install() {
 
 	if use perl ; then
 		emake -C PerlMagick DESTDIR="${D}" install
+
 		find "${ED}" -type f -name perllocal.pod -exec rm -f {} + || die
 		find "${ED}" -depth -mindepth 1 -type d -empty -exec rm -rf {} + || die
 	fi
diff --git a/media-gfx/graphicsmagick/metadata.xml b/media-gfx/graphicsmagick/metadata.xml
index 42c327ea7848..270526b3183b 100644
--- a/media-gfx/graphicsmagick/metadata.xml
+++ b/media-gfx/graphicsmagick/metadata.xml
@@ -22,6 +22,8 @@
     <flag name="fpx">Enable FlashPix support with <pkg>media-libs/libfpx</pkg></flag>
     <flag name="dynamic-loading">Compile graphicsmagick with dynamically
     loadable modules</flag>
+    <flag name="heif">Add HEIF/HEIC image support</flag>
+    <flag name="jpegxl">Enable support for JPEG XL image format</flag>
     <flag name="q16">Set storage quantum size to 16 (~2*memory)</flag>
     <flag name="q32">Set storage quantum size to 32 (~5*memory)</flag>
   </use>