gentoo auto-resync : 20:05:2024 - 00:02:15

4 files changed, 173 insertions, 12 deletions

diff --git a/media-gfx/graphicsmagick/Manifest b/media-gfx/graphicsmagick/Manifest
index cc62fb13ab65..0b3b320e3890 100644
--- a/media-gfx/graphicsmagick/Manifest
+++ b/media-gfx/graphicsmagick/Manifest
@@ -7,6 +7,7 @@ DIST GraphicsMagick-1.3.42.tar.xz.asc 228 BLAKE2B 723f8d1ca13bd5b32a12d69bb46f49
 DIST GraphicsMagick-1.3.43.tar.xz 5657460 BLAKE2B caa4fa6546acb4cdaaa421030ccc5cd2b628ae723e07f84700f65e26e1f3e59039cf92fda259ee44ba1e1fa90e9c469844fb5289cc73d50c42bb50fb39358ca2 SHA512 15b4d90119f25fd45f16d50218d51d543841dd3cdaf0c585bce2c18592106bc41573ed1011d7176ff5882fa0cded8f46bfd1e639c26063571109911e22098757
 DIST GraphicsMagick-1.3.43.tar.xz.asc 228 BLAKE2B cb1290af98ea92de948df0421b7de101a713f0b8ce4a07959269d5edd10eb26f088585e1a8272482a9b219ee388ae8f040fc047ca76d5f752f04a7b57987c89c SHA512 3bd62bc64dd1b6f2d7a17f1281d8dc4c67c474860b4d95bfaf5fb4be93d0ee156b54c2a6ef4166687854e5458a6e43e61816a5fd508e4702f693a9d1e43984bf
 EBUILD graphicsmagick-1.3.42.ebuild 3955 BLAKE2B 7fb1f992576d85e80f859d8ae386c0ae6c1a8bce256dc4eac99f7891944d5ece5ff0bf23a1a382fd2ce9d7d8987f78c8ff58bea16fdbef49c2fdc12ff1405b50 SHA512 66784a829ca6496bb386d21507738830839c1c52998fb0520392d833b0eb35f13834bd5c9c936e40b36f9f414e773452e9b9c7ff4ebc2d557954330097d1a619
+EBUILD graphicsmagick-1.3.43-r1.ebuild 3995 BLAKE2B 3a364a3a024e2cd916a5d7c2be15bd89e5b9c94cc1afcfebd47f90992f1875162c2bb6cca948ead3bfe17c5b375240133d2b746f126284d31c202218d428a0bc SHA512 56df172560fcc94566685c9b6753d48698c6b332e0b2415629f9c2279b6e197188759b7471849b5db4463371bfff728fad803abfd7705722d334570e0a44a189
 EBUILD graphicsmagick-1.3.43.ebuild 3948 BLAKE2B bdb1074abfe42fd18e2ba126294b14a08c6651b52bae4463a19464e7076f554cce7d76ac58c5acf2d34aa6ab5a130d5f467af9ab88cbfc4d3227d700557899ee SHA512 055a5ffd475c5c5e8d723b8083f852c8497fb80e36dd380dcd7a1154be952f8f0fc507b5ecf9ff56dc5ba343f64d5d2ed89a346d65fe362cd10a4c947a43fecf
-EBUILD graphicsmagick-9999.ebuild 3906 BLAKE2B 2e931311960a26bbf16e3483e7a1f72c102839f7b267f354b19452c892e79490fb1dd2f0553dd3e685c17a16d84b64b0334090d10142cf4c0b712dd19966bcbf SHA512 7a848d5721b37edee2b3a99650aece748e9d27ef92daf57fb07eef1e4a9d21751790a6810719acd69ab68941b4773158cc3f93dc9cdf3ee88127be0710e91dda
-MISC metadata.xml 1230 BLAKE2B 336c8cf97916b4907c95d16791e785336521c865aee9909129771e9d16405ff92471c56e9adae7ffd5354b769804c7e92bb20c1698c06b4994b73148b345bc6e SHA512 cdf719939c41c7aca942d6dec97d2b7496b345c9f9718b758ee08bc03a6a5afc80c989c0e977be021d292c8bf95007a4c42ef2346bb0c460bb48cacc9970560e
+EBUILD graphicsmagick-9999.ebuild 3953 BLAKE2B 2f28cb9079e7262dfff660325136a75f7682aa6a0d6f2ea23f256dddced870eed14f5ba4f522ee90a617af5a17ec11787cbe3ed2f4188e00d2fcfa1166dd274c SHA512 19d5ce53b7bd3689a368f122958f08c696f44dc734f9f51452d95715d02d0c94e418dbe1af709413fa2d4d8326e21761e4b2c148cf7a6af18d5af6825d2cacb3
+MISC metadata.xml 1301 BLAKE2B 1d98e2027f597d0b9c3ae76923adf2dbcb817a439671931076766ec6bc9cb04d053f92fba520a08cc3e629a6802f75d9c4c40058daed25c1555e21516b678997 SHA512 2b1e3cc87a6f9af93fabbc31e142cf4d7206cce3cf2a0e9d70751f93ead7abb9cad7fd58f91264b26e8ea79345973f93cfff2ecd6c9c2c4b176db58c3247b5ff
diff --git a/media-gfx/graphicsmagick/graphicsmagick-1.3.43-r1.ebuild b/media-gfx/graphicsmagick/graphicsmagick-1.3.43-r1.ebuild
new file mode 100644
index 000000000000..74cddef1ebc4
--- /dev/null
+++ b/media-gfx/graphicsmagick/graphicsmagick-1.3.43-r1.ebuild
@@ -0,0 +1,161 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools toolchain-funcs
+
+MY_P=${P/graphicsm/GraphicsM}
+DESCRIPTION="Collection of tools and libraries for many image formats"
+HOMEPAGE="http://www.graphicsmagick.org/ https://foss.heptapod.net/graphicsmagick/graphicsmagick"
+
+if [[ ${PV} == 9999 ]] ; then
+	EHG_REPO_URI="https://foss.heptapod.net/${PN}/${PN}"
+	inherit mercurial
+else
+	VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/bobfriesenhahn.asc
+	inherit verify-sig
+
+	SRC_URI="https://downloads.sourceforge.net/project/${PN}/${PN}-history/$(ver_cut 1-2)/${MY_P}.tar.xz"
+	SRC_URI+=" verify-sig? ( https://downloads.sourceforge.net/project/${PN}/${PN}-history/$(ver_cut 1-2)/${MY_P}.tar.xz.asc )"
+	S="${WORKDIR}/${MY_P}"
+
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
+
+	BDEPEND="verify-sig? ( sec-keys/openpgp-keys-bobfriesenhahn )"
+fi
+
+LICENSE="MIT"
+SLOT="0/${PV%.*}"
+IUSE="bzip2 +cxx debug dynamic-loading fpx heif imagemagick jbig jpeg jpeg2k jpegxl lcms lzma"
+IUSE+=" openmp perl png postscript q16 q32 static-libs tcmalloc tiff truetype"
+IUSE+=" webp wmf X zlib zstd"
+
+RDEPEND="
+	dev-libs/libltdl
+	bzip2? ( app-arch/bzip2 )
+	fpx? ( media-libs/libfpx )
+	heif? ( media-libs/libheif:= )
+	imagemagick? ( !media-gfx/imagemagick )
+	jbig? ( media-libs/jbigkit )
+	jpeg? ( media-libs/libjpeg-turbo:= )
+	jpeg2k? ( media-libs/jasper:= )
+	jpegxl? ( media-libs/libjxl:= )
+	lcms? ( media-libs/lcms:2 )
+	lzma? ( app-arch/xz-utils )
+	perl? ( dev-lang/perl:= )
+	png? ( media-libs/libpng:= )
+	postscript? ( app-text/ghostscript-gpl )
+	tcmalloc? ( dev-util/google-perftools:= )
+	tiff? ( media-libs/tiff:= )
+	truetype? (
+		media-fonts/urw-fonts
+		>=media-libs/freetype-2
+	)
+	webp? ( media-libs/libwebp:= )
+	wmf? ( media-libs/libwmf )
+	X? (
+		x11-libs/libSM
+		x11-libs/libX11
+		x11-libs/libXext
+	)
+	zlib? ( sys-libs/zlib )
+	zstd? ( app-arch/zstd:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND+=" virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.3.41-flags.patch
+	"${FILESDIR}"/${PN}-1.3.41-perl.patch
+	"${FILESDIR}"/${PN}-1.3.43-bashism.patch
+)
+
+pkg_pretend() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+src_prepare() {
+	default
+
+	eautoreconf
+}
+
+src_configure() {
+	local depth=8
+
+	use q16 && depth=16
+	use q32 && depth=32
+
+	local myeconfargs=(
+		--enable-largefile
+		--enable-shared
+		$(use_enable static-libs static)
+		$(use_enable debug prof)
+		$(use_enable debug gcov)
+		$(use_enable imagemagick magick-compat)
+		$(use_enable openmp)
+		--with-threads
+		$(use_with dynamic-loading modules)
+		--with-quantum-depth=${depth}
+		--without-frozenpaths
+		$(use_with cxx magick-plus-plus)
+		$(use_with heif)
+		$(use_with jpegxl jxl)
+		$(use_with perl)
+		--with-perl-options=INSTALLDIRS=vendor
+		$(use_with bzip2 bzlib)
+		$(use_with postscript dps)
+		$(use_with fpx)
+		$(use_with jbig)
+		$(use_with webp)
+		$(use_with jpeg)
+		$(use_with jpeg2k jp2)
+		$(use_with lcms lcms2)
+		$(use_with lzma)
+		$(use_with png)
+		$(use_with tcmalloc)
+		$(use_with tiff)
+		--without-trio
+		$(use_with truetype ttf)
+		$(use_with wmf)
+		--with-fontpath="${EPREFIX}"/usr/share/fonts
+		--with-gs-font-dir="${EPREFIX}"/usr/share/fonts/urw-fonts
+		--with-windows-font-dir="${EPREFIX}"/usr/share/fonts/corefonts
+		$(use_with zlib)
+		$(use_with zstd)
+		$(use_with X x)
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+	default
+
+	use perl && emake perl-build
+}
+
+src_test() {
+	# Some perl tests fail when DISPLAY is set
+	unset DISPLAY
+
+	default
+}
+
+src_install() {
+	default
+
+	if use perl ; then
+		emake -C PerlMagick DESTDIR="${D}" install
+
+		find "${ED}" -type f -name perllocal.pod -exec rm -f {} + || die
+		find "${ED}" -depth -mindepth 1 -type d -empty -exec rm -rf {} + || die
+	fi
+
+	find "${ED}" -name '*.la' -exec sed -i -e "/^dependency_libs/s:=.*:='':" {} + || die
+}
diff --git a/media-gfx/graphicsmagick/graphicsmagick-9999.ebuild b/media-gfx/graphicsmagick/graphicsmagick-9999.ebuild
index de2acbced7ba..fd1d7bcb1476 100644
--- a/media-gfx/graphicsmagick/graphicsmagick-9999.ebuild
+++ b/media-gfx/graphicsmagick/graphicsmagick-9999.ebuild
@@ -7,17 +7,17 @@ inherit autotools toolchain-funcs
 
 MY_P=${P/graphicsm/GraphicsM}
 DESCRIPTION="Collection of tools and libraries for many image formats"
-HOMEPAGE="http://www.graphicsmagick.org/ https://hg.osdn.net/view/graphicsmagick/GM"
+HOMEPAGE="http://www.graphicsmagick.org/ https://foss.heptapod.net/graphicsmagick/graphicsmagick"
 
 if [[ ${PV} == 9999 ]] ; then
-	EHG_REPO_URI="http://hg.code.sf.net/p/${PN}/code"
+	EHG_REPO_URI="https://foss.heptapod.net/${PN}/${PN}"
 	inherit mercurial
 else
 	VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/bobfriesenhahn.asc
 	inherit verify-sig
 
-	SRC_URI="https://downloads.sourceforge.net/${PN}/${MY_P}.tar.xz"
-	SRC_URI+=" verify-sig? ( https://downloads.sourceforge.net/${PN}/${MY_P}.tar.xz.asc )"
+	SRC_URI="https://downloads.sourceforge.net/project/${PN}/${PN}-history/$(ver_cut 1-2)/${MY_P}.tar.xz"
+	SRC_URI+=" verify-sig? ( https://downloads.sourceforge.net/project/${PN}/${PN}-history/$(ver_cut 1-2)/${MY_P}.tar.xz.asc )"
 	S="${WORKDIR}/${MY_P}"
 
 	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
@@ -27,8 +27,8 @@ fi
 
 LICENSE="MIT"
 SLOT="0/${PV%.*}"
-IUSE="bzip2 +cxx debug dynamic-loading fpx heif imagemagick jbig jpeg jpegxl lcms lzma"
-IUSE+=" openmp perl png postscript q16 q32 static-libs svg tcmalloc tiff truetype"
+IUSE="bzip2 +cxx debug dynamic-loading fpx heif imagemagick jbig jpeg jpeg2k jpegxl lcms lzma"
+IUSE+=" openmp perl png postscript q16 q32 static-libs tcmalloc tiff truetype"
 IUSE+=" webp wmf X zlib zstd"
 
 RDEPEND="
@@ -39,13 +39,13 @@ RDEPEND="
 	imagemagick? ( !media-gfx/imagemagick )
 	jbig? ( media-libs/jbigkit )
 	jpeg? ( media-libs/libjpeg-turbo:= )
+	jpeg2k? ( media-libs/jasper:= )
 	jpegxl? ( media-libs/libjxl:= )
 	lcms? ( media-libs/lcms:2 )
 	lzma? ( app-arch/xz-utils )
 	perl? ( dev-lang/perl:= )
 	png? ( media-libs/libpng:= )
 	postscript? ( app-text/ghostscript-gpl )
-	svg? ( dev-libs/libxml2 )
 	tcmalloc? ( dev-util/google-perftools:= )
 	tiff? ( media-libs/tiff:= )
 	truetype? (
@@ -113,8 +113,7 @@ src_configure() {
 		$(use_with jbig)
 		$(use_with webp)
 		$(use_with jpeg)
-		# Needs last-rited/unpackaged jasper
-		--without-jp2
+		$(use_with jpeg2k jp2)
 		$(use_with lcms lcms2)
 		$(use_with lzma)
 		$(use_with png)
@@ -126,7 +125,6 @@ src_configure() {
 		--with-fontpath="${EPREFIX}"/usr/share/fonts
 		--with-gs-font-dir="${EPREFIX}"/usr/share/fonts/urw-fonts
 		--with-windows-font-dir="${EPREFIX}"/usr/share/fonts/corefonts
-		$(use_with svg xml)
 		$(use_with zlib)
 		$(use_with zstd)
 		$(use_with X x)
diff --git a/media-gfx/graphicsmagick/metadata.xml b/media-gfx/graphicsmagick/metadata.xml
index 77c1abede762..99ba429c7cac 100644
--- a/media-gfx/graphicsmagick/metadata.xml
+++ b/media-gfx/graphicsmagick/metadata.xml
@@ -26,5 +26,6 @@
 	</use>
 	<upstream>
 		<remote-id type="sourceforge">graphicsmagick</remote-id>
+		<remote-id type="heptapod">graphicsmagick/graphicsmagick</remote-id>
 	</upstream>
 </pkgmetadata>