gentoo auto-resync : 24:09:2023 - 11:22:25

2 files changed, 165 insertions, 0 deletions

diff --git a/media-gfx/graphicsmagick/Manifest b/media-gfx/graphicsmagick/Manifest
index 453ac73e0be9..6321d714fa75 100644
--- a/media-gfx/graphicsmagick/Manifest
+++ b/media-gfx/graphicsmagick/Manifest
@@ -9,8 +9,11 @@ DIST GraphicsMagick-1.3.40.tar.xz 5507792 BLAKE2B 2052eb34931f07c902a9c68192ebe4
 DIST GraphicsMagick-1.3.40.tar.xz.asc 228 BLAKE2B 70eaaa0cd30cfe23ac6dc5e8edc026c57eea7b1a608e83da3408f6fa9fc2cceeb8190e4e9015f321ee688f2a32689d244d69bc61764a99ab0f99ada72143a575 SHA512 82c628e4a260a690c7b1941321881a97d54b4c9580dcbfd8ae786a1774dc43c46e8542488ca875346446858e7475847c440cfca572315a5fe123315b187a240a
 DIST GraphicsMagick-1.3.41.tar.xz 5533080 BLAKE2B 878c785b19feb3153cd2ea9cb105938ff7c4e577ce5e563cfdde501ca26b48f4c3ac6e875de240229938fa1b5776564607a35398dcc9adfd0fd801341d87ab63 SHA512 f2b850818f992349e8cb8f74ed8e897af4e1f4b9af9f3622c1ff30f3af5bc8530a60efbb24875fda80ff49e0db0304dfd6a39de87bd2e29b8ce42d653846890e
 DIST GraphicsMagick-1.3.41.tar.xz.asc 228 BLAKE2B 298c1445d7de5114e38e02f4b3c5c91569b70c126849526a822cc5a2fc2623b6bc83b74a4a58cf0e326741a96ace95b60108f9a07bf9c37a3d9ca722485eb8be SHA512 13bb0218a436ab083518f4a32d17b231a941abd960b32b13a05e4fca3d6b57112f2b496bf7fba0996c2c9855c15158f8223003fcbcf4335bd0ba1a1ae7ee8ba9
+DIST GraphicsMagick-1.3.42.tar.xz 5553692 BLAKE2B f8f0d7d420375262b7db8ffcc1c9eb4e372fb20a7c5e55f566d965183bb9a8d3a20a43c249a0b05235caaa0883c58885329d5c8d1967f464c0b757d40d6fc825 SHA512 b512c9c4c06ec60f7d31e140da08f2bc16d492a2dab82778f1b38c074a25340159e59bfbaa30b2997a6fbd10a500ae1bda527e3c3854e4462bcae837e818428a
+DIST GraphicsMagick-1.3.42.tar.xz.asc 228 BLAKE2B 723f8d1ca13bd5b32a12d69bb46f4991df6e7963f0d4c12ddaf60167a9ade4c6fa36819cce1df202437143bc55e17dd6f2cff821412dafceeb3ab5e3dbf3dc7b SHA512 de5d90c748376e7e480a066e9354ac1771f15cb2d8c6e5c9249672fd811b7bbe06f97b3348240538fa8d0d7c11150f57fb5148285214712944f7535afb943bd0
 EBUILD graphicsmagick-1.3.40-r1.ebuild 4040 BLAKE2B 98baf59de8285a54686c0a0bafbe5ab986d72cad923581f6968519d07115655bb4761fb2417c618b96bcf87cec5525b7e8844931f959a2e466bd965a27732bce SHA512 0da0d54081b95d17bf2abbb222a58886614e7e3600dc5b5da1fe1bb797efd3d69d5ce9cc8d5cd23cd785aeea2b268f3481a36eb3f2d4d66b58a2c4a1a7b34f12
 EBUILD graphicsmagick-1.3.40.ebuild 3851 BLAKE2B 5364a3e3f0e5f57089443ad1010a75371507d5a2ed6c4c365b722238518acb26dada10c24ea897507069e0ff23af5f8077908f3b922cc37c686bc23ac075e181 SHA512 fb54d82d2deda4e66b823c33281b382b02e6f14209607f91fd51c60a0d27c2cad59be034b5b9a212a3b42a4dd79cd371ae797a6afce52eb1ca9f63250dcc5b79
 EBUILD graphicsmagick-1.3.41.ebuild 3890 BLAKE2B 8b4ec37c52acdd0d38bf64f29c3ddff022a4a8f494c5f8c5c20665ff78bed432d623de57e05c9030698010c717bf21957e8d0a4c15411e77bef019ac7e7c806a SHA512 bb67ff184d197366dbb021caf7b10e304e0802f5028f78c0ea1b67fbae366b412a5ace96501342381b01a7ea45b6ae80fc7cdd175120a988ac7e5c530e52504f
+EBUILD graphicsmagick-1.3.42.ebuild 3890 BLAKE2B 8b4ec37c52acdd0d38bf64f29c3ddff022a4a8f494c5f8c5c20665ff78bed432d623de57e05c9030698010c717bf21957e8d0a4c15411e77bef019ac7e7c806a SHA512 bb67ff184d197366dbb021caf7b10e304e0802f5028f78c0ea1b67fbae366b412a5ace96501342381b01a7ea45b6ae80fc7cdd175120a988ac7e5c530e52504f
 EBUILD graphicsmagick-9999.ebuild 3890 BLAKE2B 8b4ec37c52acdd0d38bf64f29c3ddff022a4a8f494c5f8c5c20665ff78bed432d623de57e05c9030698010c717bf21957e8d0a4c15411e77bef019ac7e7c806a SHA512 bb67ff184d197366dbb021caf7b10e304e0802f5028f78c0ea1b67fbae366b412a5ace96501342381b01a7ea45b6ae80fc7cdd175120a988ac7e5c530e52504f
 MISC metadata.xml 1299 BLAKE2B 8b52e6f32fd37011471723ec75a32611ae53f92a092dd2ef5eba48391b7282f00ffd20131dbeb86c30b77e697634e13a72dcc218f547a005ff828cf7d43bf658 SHA512 a96a6ee1fc8b7c2b3162e356be1536bfde975dceb37894eca59c80fb9623fcce309b2fd0cc233da9f572925aad9821623748c871c7e2e2f61733d1831a1ca368
diff --git a/media-gfx/graphicsmagick/graphicsmagick-1.3.42.ebuild b/media-gfx/graphicsmagick/graphicsmagick-1.3.42.ebuild
new file mode 100644
index 000000000000..e829330a5e8f
--- /dev/null
+++ b/media-gfx/graphicsmagick/graphicsmagick-1.3.42.ebuild
@@ -0,0 +1,162 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools toolchain-funcs
+
+MY_P=${P/graphicsm/GraphicsM}
+DESCRIPTION="Collection of tools and libraries for many image formats"
+HOMEPAGE="http://www.graphicsmagick.org/ https://hg.osdn.net/view/graphicsmagick/GM"
+
+if [[ ${PV} == 9999 ]] ; then
+	EHG_REPO_URI="http://hg.code.sf.net/p/${PN}/code"
+	inherit mercurial
+else
+	VERIFY_SIG_OPENPGP_KEY_PATH="${BROOT}"/usr/share/openpgp-keys/bobfriesenhahn.asc
+	inherit verify-sig
+
+	SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.xz"
+	SRC_URI+=" verify-sig? ( mirror://sourceforge/${PN}/${MY_P}.tar.xz.asc )"
+	S="${WORKDIR}/${MY_P}"
+
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
+
+	BDEPEND="verify-sig? ( sec-keys/openpgp-keys-bobfriesenhahn )"
+fi
+
+LICENSE="MIT"
+SLOT="0/${PV%.*}"
+IUSE="bzip2 +cxx debug dynamic-loading fpx heif imagemagick jbig jpeg jpegxl lcms lzma"
+IUSE+=" openmp perl png postscript q16 q32 static-libs svg tcmalloc tiff truetype"
+IUSE+=" webp wmf X zlib zstd"
+
+RDEPEND="
+	dev-libs/libltdl
+	bzip2? ( app-arch/bzip2 )
+	fpx? ( media-libs/libfpx )
+	heif? ( media-libs/libheif:= )
+	imagemagick? ( !media-gfx/imagemagick )
+	jbig? ( media-libs/jbigkit )
+	jpeg? ( media-libs/libjpeg-turbo:= )
+	jpegxl? ( media-libs/libjxl:= )
+	lcms? ( media-libs/lcms:2 )
+	lzma? ( app-arch/xz-utils )
+	perl? ( dev-lang/perl:= )
+	png? ( media-libs/libpng:= )
+	postscript? ( app-text/ghostscript-gpl )
+	svg? ( dev-libs/libxml2 )
+	tcmalloc? ( dev-util/google-perftools:= )
+	tiff? ( media-libs/tiff:= )
+	truetype? (
+		media-fonts/urw-fonts
+		>=media-libs/freetype-2
+	)
+	webp? ( media-libs/libwebp:= )
+	wmf? ( media-libs/libwmf )
+	X? (
+		x11-libs/libSM
+		x11-libs/libX11
+		x11-libs/libXext
+	)
+	zlib? ( sys-libs/zlib )
+	zstd? ( app-arch/zstd:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND+=" virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.3.41-flags.patch
+	"${FILESDIR}"/${PN}-1.3.41-perl.patch
+)
+
+pkg_pretend() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+src_prepare() {
+	default
+
+	eautoreconf
+}
+
+src_configure() {
+	local depth=8
+
+	use q16 && depth=16
+	use q32 && depth=32
+
+	local myeconfargs=(
+		--enable-largefile
+		--enable-shared
+		$(use_enable static-libs static)
+		$(use_enable debug prof)
+		$(use_enable debug gcov)
+		$(use_enable imagemagick magick-compat)
+		$(use_enable openmp)
+		--with-threads
+		$(use_with dynamic-loading modules)
+		--with-quantum-depth=${depth}
+		--without-frozenpaths
+		$(use_with cxx magick-plus-plus)
+		$(use_with heif)
+		$(use_with jpegxl jxl)
+		$(use_with perl)
+		--with-perl-options=INSTALLDIRS=vendor
+		$(use_with bzip2 bzlib)
+		$(use_with postscript dps)
+		$(use_with fpx)
+		$(use_with jbig)
+		$(use_with webp)
+		$(use_with jpeg)
+		# Needs last-rited/unpackaged jasper
+		--without-jp2
+		$(use_with lcms lcms2)
+		$(use_with lzma)
+		$(use_with png)
+		$(use_with tcmalloc)
+		$(use_with tiff)
+		--without-trio
+		$(use_with truetype ttf)
+		$(use_with wmf)
+		--with-fontpath="${EPREFIX}"/usr/share/fonts
+		--with-gs-font-dir="${EPREFIX}"/usr/share/fonts/urw-fonts
+		--with-windows-font-dir="${EPREFIX}"/usr/share/fonts/corefonts
+		$(use_with svg xml)
+		$(use_with zlib)
+		$(use_with zstd)
+		$(use_with X x)
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+	default
+
+	use perl && emake perl-build
+}
+
+src_test() {
+	# Some perl tests fail when DISPLAY is set
+	unset DISPLAY
+
+	default
+}
+
+src_install() {
+	default
+
+	if use perl ; then
+		emake -C PerlMagick DESTDIR="${D}" install
+
+		find "${ED}" -type f -name perllocal.pod -exec rm -f {} + || die
+		find "${ED}" -depth -mindepth 1 -type d -empty -exec rm -rf {} + || die
+	fi
+
+	find "${ED}" -name '*.la' -exec sed -i -e "/^dependency_libs/s:=.*:='':" {} + || die
+}