gentoo (valentine's day) resync : 14.02.2021

3 files changed, 179 insertions, 3 deletions

diff --git a/media-gfx/gmic/Manifest b/media-gfx/gmic/Manifest
index 0dc0b392511b..4151a5075253 100644
--- a/media-gfx/gmic/Manifest
+++ b/media-gfx/gmic/Manifest
@@ -1,6 +1,8 @@
 AUX gmic-2.9.2_ipa-sra.patch 665 BLAKE2B b61fa87ac2da5fd5956c89cb4a6c128f266a175dca70cd34ff4bed0483c934241a375131eaddd6ebd5f3afb52e694d4fc6839d20718bc06463c0e263f15b6d5a SHA512 6f04cac4de5914cedd269655fe58ca406199c042bdbab6e706cfea49516d0a7e1234e61c51b6a142341a7984dd96e97c4b8f13c2efbe427627be26539af8653e
 DIST gmic_2.9.2.tar.gz 6639693 BLAKE2B 4b452cc5c82e8ea30a1bd65e51b6187fc12d9c7f8af6d0f8107a8d183c6e87dff11394f103eae7ac17daa00c6c9aa0f47ce78a92156e2da9bc4ee0fcacbf398d SHA512 be8707b5c156b17189548c1f808b976afcb7b7cce20ff54ff4589eda9a76a8cddf81c64b7a53c332254b2c8c29fb8ca0926016cadcb1efb7131a38d857fce796
 DIST gmic_2.9.4.tar.gz 7279628 BLAKE2B ca5fc69a2990a86a340c4305dc406d4e9032ba04afa59819dc2c788b4c181d23bd03d3050380802fe1effa2b6389df60734f8b3523fac7b0ff6bc35b64a368a6 SHA512 76bb4798e91a68e76a985d7fbc488f8677facaa1efc4ab3a0b9c7d966aa3f5763d1ae1de80f572636d58f1831d9bdae1651ea0b6a76d49a18bf5ad6e12756d73
+DIST gmic_2.9.5.tar.gz 7304367 BLAKE2B 5227aced76cc5ff0a0144f940c71daeeb947e282b6f8c28894ecfda6b863803d0c2227bac869362ba0710fa33fcf81a4c77ea582cbea77ab8a670f65eef9826c SHA512 95d0642cad057eeaa8f7bdd4259719adf6f36189e7851e9e09399bb61f3a52722f0f83f0d2d5991c4e44a692fd3afc735fdb93e6fe45ae092d1e51a139560809
 EBUILD gmic-2.9.2-r1.ebuild 4848 BLAKE2B 19cec459abf67e10c99319c9fc1174eba19390e94bfe07595d75c3bcf144cad2235281b1a07eabb56c245aba87ceda414c602f64b51734669010961f652db473 SHA512 1857c8b9c01dbd03f3e2dee257fece0ebb6574ce1eb91db76be86e1b3879b0aed7067ba25857e247e49ec1adfb4cc483f52b41ede31f9156b8650e4f295593c8
-EBUILD gmic-2.9.4.ebuild 4848 BLAKE2B 19cec459abf67e10c99319c9fc1174eba19390e94bfe07595d75c3bcf144cad2235281b1a07eabb56c245aba87ceda414c602f64b51734669010961f652db473 SHA512 1857c8b9c01dbd03f3e2dee257fece0ebb6574ce1eb91db76be86e1b3879b0aed7067ba25857e247e49ec1adfb4cc483f52b41ede31f9156b8650e4f295593c8
+EBUILD gmic-2.9.4.ebuild 4846 BLAKE2B 1b70a21c2004aba565a4e81372930200a373c9985dc47f7a3c23a8cc076bc11c4bc565ebe356384dfcbe94db60c5f568f75c772f4dcb3a885d7b39318309e36b SHA512 bc6dbdb81baef52096e0afe4cec2df0161b227a75a6dac150d07f2b8e37e2d09856b046a9c670db2818eb538b046be21f7eb30512c9b74909c3bdde3d1c09b83
+EBUILD gmic-2.9.5.ebuild 4262 BLAKE2B ea9fdfb207a5a28d1d04136a916d806bab9906e0d4495dd37b29ecae0296a57d5c9f2fdfd6485ac7bfda9b7d5f104b976c4fb9232910839256c3727a115532ad SHA512 2402560d48ea661dabcb9b727d3dcb6669f71fe7270bf3986db57aa5a8f51366133d3950d748e0e631dec77c346ca9057bdd8540aef93c4d5d9bf8a20fd33bbd
 MISC metadata.xml 605 BLAKE2B f1ed3b46614a3e3273e4bdedfd7b45629eca482a0805ff1bda2161e4d785a478b91f8ccdbab399b184ec93d020211e35e4503fbf4205b1e2e1f04c7e547303bd SHA512 8303e0a301edb88bdb7522baf47e29b39e895ccaa729231d64b6a39af73f0eb1626c39439f1ed70d496d982f3abca4ff9586d20fc5a9d08b0e57a19b60bf088d
diff --git a/media-gfx/gmic/gmic-2.9.4.ebuild b/media-gfx/gmic/gmic-2.9.4.ebuild
index 4af6d1c63fa1..0c669de12cc1 100644
--- a/media-gfx/gmic/gmic-2.9.4.ebuild
+++ b/media-gfx/gmic/gmic-2.9.4.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2020 Gentoo Authors
+# Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
@@ -12,7 +12,7 @@ if [[ ${PV} == "9999" ]]; then
 	inherit git-r3
 else
 	SRC_URI="https://gmic.eu/files/source/${PN}_${PV}.tar.gz"
-	KEYWORDS="~amd64 ~arm64 ~x86"
+	KEYWORDS="amd64 ~arm64 x86"
 fi
 
 DESCRIPTION="GREYC's Magic Image Converter"
diff --git a/media-gfx/gmic/gmic-2.9.5.ebuild b/media-gfx/gmic/gmic-2.9.5.ebuild
new file mode 100644
index 000000000000..20cad100504d
--- /dev/null
+++ b/media-gfx/gmic/gmic-2.9.5.ebuild
@@ -0,0 +1,174 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+CMAKE_BUILD_TYPE=Release
+
+inherit cmake bash-completion-r1 toolchain-funcs
+
+if [[ ${PV} == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/dtschump/gmic.git"
+	inherit git-r3
+else
+	SRC_URI="https://gmic.eu/files/source/${PN}_${PV}.tar.gz"
+	KEYWORDS="~amd64 ~arm64 ~x86"
+fi
+
+DESCRIPTION="GREYC's Magic Image Converter"
+HOMEPAGE="https://gmic.eu/ https://github.com/dtschump/gmic"
+
+LICENSE="CeCILL-2 GPL-3"
+SLOT="0"
+IUSE="cli curl ffmpeg fftw gimp graphicsmagick jpeg krita opencv openexr openmp png qt5 static-libs tiff X zlib"
+REQUIRED_USE="
+	gimp? ( png zlib fftw X )
+	krita? ( png zlib fftw X )
+	qt5? ( png zlib fftw X )
+"
+
+MIN_QT_VER="5.2.0"
+QT_DEPEND="
+	>=dev-qt/qtcore-${MIN_QT_VER}:5=
+	>=dev-qt/qtgui-${MIN_QT_VER}:5=
+	>=dev-qt/qtnetwork-${MIN_QT_VER}:5=
+	>=dev-qt/qtwidgets-${MIN_QT_VER}:5=
+"
+COMMON_DEPEND="
+	curl? ( net-misc/curl )
+	fftw? ( sci-libs/fftw:3.0=[threads] )
+	gimp? (
+		media-gfx/gimp:0/2
+		${QT_DEPEND}
+	)
+	graphicsmagick? ( media-gfx/graphicsmagick:0= )
+	jpeg? ( virtual/jpeg:0 )
+	krita? ( ${QT_DEPEND} )
+	opencv? ( >=media-libs/opencv-2.3.1a-r1:0= )
+	openexr? (
+		media-libs/ilmbase:0=
+		media-libs/openexr:0=
+	)
+	png? ( media-libs/libpng:0= )
+	qt5? ( ${QT_DEPEND} )
+	tiff? ( media-libs/tiff:0 )
+	X? (
+		x11-libs/libX11
+		x11-libs/libXext
+	)
+	zlib? ( sys-libs/zlib:0= )"
+RDEPEND="${COMMON_DEPEND}
+	ffmpeg? ( media-video/ffmpeg:0= )
+"
+DEPEND="${COMMON_DEPEND}
+	gimp? ( dev-qt/linguist-tools )
+	krita? ( dev-qt/linguist-tools )
+	qt5? ( dev-qt/linguist-tools )
+"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-2.9.2_ipa-sra.patch
+)
+
+pkg_pretend() {
+	if [[ ${MERGE_TYPE} != binary ]]; then
+		if use openmp; then
+			tc-has-openmp || die "Please switch to an openmp compatible compiler"
+		fi
+	fi
+}
+
+src_prepare() {
+	cmake_src_prepare
+	sed -i '/CMAKE_CXX_FLAGS/s/-g //' CMakeLists.txt || die
+
+	if use gimp || use krita || use qt5; then
+		# respect user flags
+		sed -e '/CMAKE_CXX_FLAGS_RELEASE/d' \
+			-e '/${CMAKE_EXE_LINKER_FLAGS} -s/d' \
+			-i gmic-qt/CMakeLists.txt || die
+		local S="${S}/gmic-qt"
+		# Bug #753377
+		local PATCHES=()
+		cmake_src_prepare
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_LIB=ON
+		-DBUILD_LIB_STATIC=$(usex static-libs)
+		-DBUILD_CLI=$(usex cli)
+		-DBUILD_MAN=$(usex cli)
+		-DBUILD_BASH_COMPLETION=$(usex cli)
+		-DCUSTOM_CFLAGS=ON
+		-DENABLE_CURL=$(usex curl)
+		-DENABLE_X=$(usex X)
+		-DENABLE_FFMPEG=$(usex ffmpeg)
+		-DENABLE_FFTW=$(usex fftw)
+		-DENABLE_GRAPHICSMAGICK=$(usex graphicsmagick)
+		-DENABLE_JPEG=$(usex jpeg)
+		-DENABLE_OPENCV=$(usex opencv)
+		-DENABLE_OPENEXR=$(usex openexr)
+		-DENABLE_OPENMP=$(usex openmp)
+		-DENABLE_PNG=$(usex png)
+		-DENABLE_TIFF=$(usex tiff)
+		-DENABLE_ZLIB=$(usex zlib)
+		-DENABLE_DYNAMIC_LINKING=ON
+	)
+
+	cmake_src_configure
+
+	# configure gmic-qt frontends
+	local CMAKE_USE_DIR="${S}/gmic-qt"
+	mycmakeargs=(
+		-DENABLE_DYNAMIC_LINKING=ON
+		-DENABLE_CURL=$(usex curl)
+		-DGMIC_LIB_PATH="${BUILD_DIR}"
+		-DGMIC_PATH="${S}/src"
+	)
+
+	if use gimp; then
+		mycmakeargs+=( -DGMIC_QT_HOST=gimp )
+		BUILD_DIR="${BUILD_DIR}"/gimp cmake_src_configure
+	fi
+
+	if use krita; then
+		mycmakeargs+=( -DGMIC_QT_HOST=krita )
+		BUILD_DIR="${BUILD_DIR}"/krita cmake_src_configure
+	fi
+
+	if use qt5; then
+		mycmakeargs+=( -DGMIC_QT_HOST=none )
+		BUILD_DIR="${BUILD_DIR}"/qt5 cmake_src_configure
+	fi
+}
+
+src_compile() {
+	cmake_src_compile
+
+	# build gmic-qt frontends
+	local S="${S}/gmic-qt"
+	use gimp && { BUILD_DIR="${BUILD_DIR}"/gimp cmake_src_compile || die "failed building gimp plugin" ; }
+	use krita && { BUILD_DIR="${BUILD_DIR}"/krita cmake_src_compile || die "failed building krita plugin" ; }
+	use qt5 && { BUILD_DIR="${BUILD_DIR}"/qt5 cmake_src_compile || die "failed building qt5 GUI" ; }
+}
+
+src_install() {
+	cmake_src_install
+	dodoc README
+	use cli && newbashcomp "${BUILD_DIR}"/resources/gmic_bashcompletion.sh ${PN}
+
+	local PLUGINDIR="/usr/$(get_libdir)/gimp/2.0/plug-ins"
+	insinto "${PLUGINDIR}"
+	doins resources/gmic_cluts.gmz
+
+	# install gmic-qt frontends
+	if use gimp; then
+		exeinto "${PLUGINDIR}"
+		doexe "${BUILD_DIR}"/gimp/gmic_gimp_qt
+	fi
+	use krita && dobin "${BUILD_DIR}"/krita/gmic_krita_qt
+	use qt5 && dobin "${BUILD_DIR}"/qt5/gmic_qt
+}