gentoo resync : 22.01.2021

2 files changed, 214 insertions, 0 deletions

diff --git a/media-gfx/gimp/Manifest b/media-gfx/gimp/Manifest
index e18165260bc8..7db9733484e4 100644
--- a/media-gfx/gimp/Manifest
+++ b/media-gfx/gimp/Manifest
@@ -6,6 +6,7 @@ DIST gimp-2.99.2.tar.bz2 32375596 BLAKE2B 3dc5af7935e3503106cf2020798974d68fe86e
 DIST gimp-2.99.4.tar.bz2 30355676 BLAKE2B b982139e36809b7e149c1c055d7cf0506c0c00beda2745904c62f4b56f1f1605378358f29ab427f7df6c68251ce367e00d79a1b9b7b3d0fde22526895eb5ce27 SHA512 1abb6851f4c6af440d75d09c55dcb6bf6485739de1960fb536035935729331221265beef589386da685ad8ffbe83e0f0699cf2db55589953deae4d82aa99154b
 EBUILD gimp-2.10.20-r3.ebuild 5681 BLAKE2B b23d61ef44ec157981c4656bc9a8ee3fc0cbe34e208f27793f9295c952d1df329da2544718c8a1440e7e685339697c7e4110e292a3b2f1222b6ede6c0400c593 SHA512 7469fabcfa82c7fc513fe361ea03514ce142c3252123d5c9905c9d9aeb61099d47dc7dbb833d3fe7b3a2479261d6026121d43e100fdec21ffda8266c6e9153ef
 EBUILD gimp-2.10.22-r1.ebuild 5616 BLAKE2B d470f34e37338e55343ce471e51603c4ef779b04c47bc10fd364c4ff8a8f91d57421707ac87f22f8ac486b595b7a76fd5d7acb760d05542b8f3c3b3668cccc4e SHA512 9ba67887ea7b9fb6af3a382015c3c8cce5ea2cf84f04e52e8e39e3b840792a229cfd4679ab22cb70d12e7e8d4a825c0a2f532d3ae52812554c542325acfd7a8a
+EBUILD gimp-2.10.22-r2.ebuild 5640 BLAKE2B dc9ee64aa55e230e1aaee8f874ed9f2bbcbffdebaf1804831131107212be1f1ca094a6f480dc7f8309d88ed7c0dadb3c6da8ab96753ca229d3c78a1de4cd2926 SHA512 287e5789074d54415a6efafcaee1ef32eefa0decf9dbd10c9429ae1c99a0949b32136b909d63304a3c0a3ba330cd46d2c7678aedfdef087a81758054cebb7e2e
 EBUILD gimp-2.99.2-r100.ebuild 6734 BLAKE2B ec479165a988f22cdcaff9073627c84f9410a3adc557f17c35d9949fc4b15ce4cb862b048118dfdec203e791ecdcd51f2f762c3440d58a9c5dc3fe281c209593 SHA512 ac12d541eb64f5fa31fe8b11f1016fda791842575216073c12cec85e822238dd82712eda2d0a3b36657defab460010b34651d13ca2c3ade565a8ce18e3400d9c
 EBUILD gimp-2.99.2.ebuild 6514 BLAKE2B 413ca26220cf55f1e7c87a4b79a87ed3cbde37a5978683f2d7cbad6e3af0399491dd648b7fe4b9c5f33d45dbf266491e46134d5b7830f75b3ecf224a1c1fb9d1 SHA512 6c1d356d751d641c0dedb7373d62ddfa90679c4b3f90077e4ecfb8a92408e13cab1e58ac03e3deee5918777d71fe38d57d9bc48f708412d97eb114b82711cf54
 EBUILD gimp-2.99.4.ebuild 6555 BLAKE2B d0457e2f35b7d38d273650fbf1cddd7903a3aaf96330cc117ad800c46d85818c2e69b17cb1eaef2e6d7b866e8abe22e735720f08c1e47769ee313ab77108c71b SHA512 fd01d40c7283f154874bf93dde1c303bcf42918c96249786618468c62d214add14db645803c6bbe4e1b9e020903cbd5c09872d858529222e229f351baada6608
diff --git a/media-gfx/gimp/gimp-2.10.22-r2.ebuild b/media-gfx/gimp/gimp-2.10.22-r2.ebuild
new file mode 100644
index 000000000000..786ca884d747
--- /dev/null
+++ b/media-gfx/gimp/gimp-2.10.22-r2.ebuild
@@ -0,0 +1,213 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+GNOME2_EAUTORECONF=yes
+WANT_AUTOMAKE=
+
+inherit autotools gnome2 toolchain-funcs virtualx
+
+DESCRIPTION="GNU Image Manipulation Program"
+HOMEPAGE="https://www.gimp.org/"
+SRC_URI="mirror://gimp/v2.10/${P}.tar.bz2"
+LICENSE="GPL-3 LGPL-3"
+SLOT="0/2"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~x86"
+
+IUSE="aalib alsa aqua debug doc gnome heif jpeg2k mng openexr postscript udev unwind vector-icons webp wmf xpm cpu_flags_ppc_altivec cpu_flags_x86_mmx cpu_flags_x86_sse"
+
+RESTRICT="!test? ( test )"
+
+COMMON_DEPEND="
+	>=app-text/poppler-0.50[cairo]
+	>=app-text/poppler-data-0.4.7
+	>=dev-libs/atk-2.2.0
+	>=dev-libs/glib-2.56.2:2
+	>=dev-libs/json-glib-1.2.6
+	dev-libs/libxml2:2
+	dev-libs/libxslt
+	>=gnome-base/librsvg-2.40.6:2
+	>=media-gfx/mypaint-brushes-2.0.2:=
+	>=media-libs/babl-0.1.78
+	>=media-libs/fontconfig-2.12.4
+	>=media-libs/freetype-2.1.7
+	>=media-libs/gegl-0.4.26:0.4[cairo]
+	<media-libs/gegl-0.4.28:0.4
+	>=media-libs/gexiv2-0.10.6
+	>=media-libs/harfbuzz-0.9.19
+	>=media-libs/lcms-2.8:2
+	>=media-libs/libmypaint-1.6.1:=
+	>=media-libs/libpng-1.6.25:0=
+	>=media-libs/tiff-3.5.7:0
+	net-libs/glib-networking[ssl]
+	sys-libs/zlib
+	virtual/jpeg
+	>=x11-libs/cairo-1.12.2
+	>=x11-libs/gdk-pixbuf-2.31:2
+	>=x11-libs/gtk+-2.24.32:2
+	x11-libs/libXcursor
+	>=x11-libs/pango-1.29.4
+	aalib? ( media-libs/aalib )
+	alsa? ( >=media-libs/alsa-lib-1.0.0 )
+	aqua? ( >=x11-libs/gtk-mac-integration-2.0.0 )
+	heif? ( >=media-libs/libheif-1.3.2:= )
+	jpeg2k? ( >=media-libs/openjpeg-2.1.0:2= )
+	mng? ( media-libs/libmng:= )
+	openexr? ( >=media-libs/openexr-1.6.1:= )
+	postscript? ( app-text/ghostscript-gpl )
+	udev? ( dev-libs/libgudev:= )
+	unwind? ( >=sys-libs/libunwind-1.1.0:= )
+	webp? ( >=media-libs/libwebp-0.6.0:= )
+	wmf? ( >=media-libs/libwmf-0.2.8 )
+	xpm? ( x11-libs/libXpm )
+"
+
+RDEPEND="
+	${COMMON_DEPEND}
+	x11-themes/hicolor-icon-theme
+	gnome? ( gnome-base/gvfs )
+"
+
+DEPEND="
+	${COMMON_DEPEND}
+	>=dev-lang/perl-5.10.0
+	dev-libs/appstream-glib
+	dev-util/gtk-update-icon-cache
+	>=dev-util/intltool-0.40.1
+	sys-apps/findutils
+	>=sys-devel/gettext-0.19
+	>=sys-devel/libtool-2.2
+	virtual/pkgconfig
+"
+
+DOCS=( "AUTHORS" "ChangeLog" "HACKING" "NEWS" "README" "README.i18n" )
+
+# Bugs 685210 (and duplicate 691070)
+PATCHES=(
+	"${FILESDIR}/${PN}-2.10_fix_test-appdata.patch"
+	"${FILESDIR}/${PN}-2.99.2_fix_autoconf-2.70.patch"
+)
+
+src_prepare() {
+	sed -i -e 's/mypaint-brushes-1.0/mypaint-brushes-2.0/' configure.ac || die #737794
+
+	sed -i -e 's/== "xquartz"/= "xquartz"/' configure.ac || die #494864
+	sed 's:-DGIMP_DISABLE_DEPRECATED:-DGIMP_protect_DISABLE_DEPRECATED:g' -i configure.ac || die #615144
+
+	gnome2_src_prepare  # calls eautoreconf
+
+	sed 's:-DGIMP_protect_DISABLE_DEPRECATED:-DGIMP_DISABLE_DEPRECATED:g' -i configure || die #615144
+	fgrep -q GIMP_DISABLE_DEPRECATED configure || die #615144, self-test
+
+	export CC_FOR_BUILD="$(tc-getBUILD_CC)"
+}
+
+_adjust_sandbox() {
+	# Bugs #569738 and #591214
+	local nv
+	for nv in /dev/nvidia-uvm /dev/nvidiactl /dev/nvidia{0..9} ; do
+		# We do not check for existence as they may show up later
+		# https://bugs.gentoo.org/show_bug.cgi?id=569738#c21
+		addwrite "${nv}"
+	done
+
+	addwrite /dev/dri/  # bugs #574038 and #684886
+	addwrite /dev/ati/  # bug #589198
+	addwrite /proc/mtrr  # bug #589198
+}
+
+src_configure() {
+	_adjust_sandbox
+
+	local myconf=(
+		GEGL="${EPREFIX}"/usr/bin/gegl-0.4
+		GDBUS_CODEGEN="${EPREFIX}"/bin/false
+
+		--enable-default-binary
+
+		--disable-check-update
+		--disable-python
+		--enable-mp
+		--with-appdata-test
+		--with-bug-report-url=https://bugs.gentoo.org/
+		--with-xmc
+		--without-libbacktrace
+		--without-webkit
+		--without-xvfb-run
+		$(use_enable cpu_flags_ppc_altivec altivec)
+		$(use_enable cpu_flags_x86_mmx mmx)
+		$(use_enable cpu_flags_x86_sse sse)
+		$(use_enable vector-icons)
+		$(use_with aalib aa)
+		$(use_with alsa)
+		$(use_with !aqua x)
+		$(use_with heif libheif)
+		$(use_with jpeg2k jpeg2000)
+		$(use_with mng libmng)
+		$(use_with openexr)
+		$(use_with postscript gs)
+		$(use_with udev gudev)
+		$(use_with unwind libunwind)
+		$(use_with webp)
+		$(use_with wmf)
+		$(use_with xpm libxpm)
+	)
+
+	gnome2_src_configure "${myconf[@]}"
+}
+
+src_compile() {
+	export XDG_DATA_DIRS="${EPREFIX}"/usr/share  # bug 587004
+	gnome2_src_compile
+}
+
+# for https://bugs.gentoo.org/664938
+_rename_plugins() {
+	einfo 'Renaming plug-ins to not collide with pre-2.10.6 file layout (bug #664938)...'
+	local prepend=gimp-org-
+	(
+		cd "${ED}"/usr/$(get_libdir)/gimp/2.0/plug-ins || die
+		for plugin_slash in $(ls -d1 */); do
+		    plugin=${plugin_slash%/}
+		    if [[ -f ${plugin}/${plugin} ]]; then
+			# NOTE: Folder and file name need to match for Gimp to load that plug-in
+			#       so "file-svg/file-svg" becomes "${prepend}file-svg/${prepend}file-svg"
+			mv ${plugin}/{,${prepend}}${plugin} || die
+			mv {,${prepend}}${plugin} || die
+		    fi
+		done
+	)
+}
+
+src_test() {
+	virtx emake check
+}
+
+src_install() {
+	gnome2_src_install
+
+	# Workaround for bug #321111 to give GIMP the least
+	# precedence on PDF documents by default
+	mv "${ED}"/usr/share/applications/{,zzz-}gimp.desktop || die
+
+	find "${D}" -name '*.la' -type f -delete || die
+
+	# Prevent dead symlink gimp-console.1 from downstream man page compression (bug #433527)
+	local gimp_app_version=$(ver_cut 1-2)
+	mv "${ED}"/usr/share/man/man1/gimp-console{-${gimp_app_version},}.1 || die
+
+	# Remove gimp devel-docs html files if user doesn't need it
+	if ! use doc; then
+		rm -r "${ED}"/usr/share/gtk-doc || die
+	fi
+
+	_rename_plugins || die
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+}
+
+pkg_postrm() {
+	gnome2_pkg_postrm
+}