gentoo resync : 20.03.2022

3 files changed, 189 insertions, 7 deletions

diff --git a/media-gfx/exact-image/Manifest b/media-gfx/exact-image/Manifest
index 7ec9b5343993..efb379ded4a7 100644
--- a/media-gfx/exact-image/Manifest
+++ b/media-gfx/exact-image/Manifest
@@ -3,5 +3,6 @@ AUX exact-image-1.0.2-g++.patch 936 BLAKE2B 6ab787c1393228bb1671c8a2d7b76969fcd1
 AUX exact-image-1.0.2-gcc6.patch 2795 BLAKE2B 17282b91baa020b94654c92d87611001584f82360303a56e70cb8f081caf400394a367982e115bff094dfe11a0798503a606de106f1bf6427b57a9ede1cd6ed5 SHA512 ef42fccab6d0958df2dcf86578f9df1f84254515c2bea611f256e23227b9d6dc917467f2d8f54230f9386e9726152c6bbe4ab4f3d117e0da5a3e99b00e93e348
 AUX exact-image-1.0.2-php.patch 481 BLAKE2B bf9a3935813098c5248bac843c580d61266b60cf7063824c90e5b87df552d2b0fa125648f4ebcba46acc29d72f9bcd0a0c647467ebdc0d433616da5d8c16225f SHA512 b984095cc071558ce8b7d4b7db2915f793ed8d468f38757d2faab0f7ffc9e866a06838a5d0c578f67e9cc3e88f2bd07b0cde00ce95d909cdc07e5fbf24f3e62e
 DIST exact-image-1.0.2.tar.bz2 322174 BLAKE2B 67afefb4c5a52416459cd4ac6198012eb6d7895a73ea8363fae05286c7e7f62aa1a02166985f53b5638c7dc7b23b4dc1fb1c7b2272a9dc595ce329a7083ee1b9 SHA512 8ba5a198a236ddf5fa58f40c80f32ba9d300376c637a13a7acf3d2db7906fced373b33a7ecff9cff4d09d8b21de9ce1fb9f5bfb1f4522557bd01af0e3d6dcc65
-EBUILD exact-image-1.0.2-r2.ebuild 2405 BLAKE2B fdb0b4bb689fb0ae31afaeb51e3e248c08dfbe2753040b12a49bafcb400e7cf34b3915cfe79175776efe6fd9faf06c930fea0ac4056d3e1b98f3d20a40e8fc67 SHA512 5745dd9e8f9fd8f3dbfa91b02028162360632bdb359d3747bce530e1e837bc54230dc7962b6c46441ffd2521bcfd1ee8153f0b0207c3fa4f6efc00a2e4762d91
+EBUILD exact-image-1.0.2-r3.ebuild 2503 BLAKE2B 73421bd5bc02e7ff4dfa1ec67d946395a05b034e9df69325f7db24366ce99de682ccd2ade88a0393362a415b5499794aaafed8ebaf5c6a547b9cf95310038e34 SHA512 764bc63f1682a733c3971bcbfcfd27a69eed2c0f88cfa95a7c8c8fd1b289021ea9433cec84751df976cbc66fc7cf0b98ba3687db74dbbbba577c65506da6d536
+EBUILD exact-image-1.0.2-r4.ebuild 4108 BLAKE2B 867fb014c95adf5f31fd63d8df742d9e477a6547c6135d4736afad04cb00bbb801b7de9305fe5e3b664b92d44a58825af12eacb18e67637aa8148141f48dcce3 SHA512 9b56503e2deb901060252cb7a62afbdb3f5c5abe0b14a2ba1ac6ab6d17d87598a2f5bbabd46323bc220b9f6127d10ee392bb0d4bd7f795efe3dae9a30dd3b0dd
 MISC metadata.xml 330 BLAKE2B 468dfd9c9bc2687f285c5a7496aa989843c32929b4c410253f1d046df2e2416604f6ff8b1cb4622e85e27f13f26cede91825d04b7748cb4f74fdff13478046c1 SHA512 01bc80b3dc7ed3ff2f3402ecd3214793d18267be1e1e4c4b42718b6f6a4982404e243771917fbbae7a1bd6b12a1cd80534d9738149ec9b2a88bbc1ad62fcdf14
diff --git a/media-gfx/exact-image/exact-image-1.0.2-r2.ebuild b/media-gfx/exact-image/exact-image-1.0.2-r3.ebuild
index 32d67a26443a..700070540cde 100644
--- a/media-gfx/exact-image/exact-image-1.0.2-r2.ebuild
+++ b/media-gfx/exact-image/exact-image-1.0.2-r3.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2021 Gentoo Authors
+# Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
@@ -15,7 +15,7 @@ LICENSE="GPL-2"
 SLOT="0"
 KEYWORDS="~amd64 ~x86"
 IUSE="expat jpeg lua openexr php perl png ruby swig tiff truetype X"
-REQUIRED_USE="lua? ( swig )"
+REQUIRED_USE="lua? ( swig ) perl? ( swig ) php? ( swig ) ruby? ( swig )"
 
 RDEPEND="
 	x11-libs/agg[truetype]
@@ -23,7 +23,7 @@ RDEPEND="
 	expat? ( dev-libs/expat )
 	jpeg? ( virtual/jpeg )
 	lua? ( ${LUA_DEPS} )
-	openexr? ( <media-libs/openexr-3.0.0:0= )
+	openexr? ( media-libs/openexr:= )
 	php? ( dev-lang/php:* )
 	perl? ( dev-lang/perl )
 	png? ( >=media-libs/libpng-1.2.43 )
@@ -35,8 +35,7 @@ RDEPEND="
 		x11-libs/libXt
 		x11-libs/libICE
 		x11-libs/libSM
-	)
-"
+	)"
 DEPEND="
 	${RDEPEND}
 	swig? ( dev-lang/swig )
@@ -72,6 +71,11 @@ src_prepare() {
 	sed -i \
 		-e 's/strcpy(\([^,]*\)\(,["a-zA-Z -]*\))/memcpy(\1\2, sizeof(\1))/' \
 		codecs/tga.cc || die
+
+	# openexr vers 3
+	sed -i \
+		-e 's:Int64:uint64_t:g' \
+		codecs/openexr.cc || die
 }
 
 src_configure() {
@@ -97,7 +101,6 @@ src_configure() {
 		--without-bardecode \
 		$(use_with lua) \
 		$(use_with swig) \
-		--without-python \
 		$(use_with perl) \
 		--without-python \
 		$(use_with php) \
diff --git a/media-gfx/exact-image/exact-image-1.0.2-r4.ebuild b/media-gfx/exact-image/exact-image-1.0.2-r4.ebuild
new file mode 100644
index 000000000000..f166ddcf3d83
--- /dev/null
+++ b/media-gfx/exact-image/exact-image-1.0.2-r4.ebuild
@@ -0,0 +1,178 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PHP_EXT_NAME="exactimage"
+USE_PHP="php7-4"
+PHP_EXT_OPTIONAL_USE="php"
+PHP_EXT_SKIP_PATCHES="yes"
+PHP_EXT_SKIP_PHPIZE="yes"
+LUA_COMPAT=( lua5-{1..4} luajit )
+
+inherit php-ext-source-r3 lua-single toolchain-funcs
+
+DESCRIPTION="A fast, modern and generic image processing library"
+HOMEPAGE="https://exactcode.com/opensource/exactimage/"
+SRC_URI="http://dl.exactcode.de/oss/${PN}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="expat jpeg lua openexr php perl png ruby swig tiff truetype X"
+REQUIRED_USE="lua? ( swig ) perl? ( swig ) php? ( swig ) ruby? ( swig )"
+# Tests are broken; 'make check' fails and referenced testsuite dir not found
+RESTRICT="test"
+
+RDEPEND="
+	x11-libs/agg[truetype]
+	sys-libs/zlib
+	expat? ( dev-libs/expat )
+	jpeg? ( virtual/jpeg )
+	lua? ( ${LUA_DEPS} )
+	openexr? ( media-libs/openexr:= )
+	perl? ( dev-lang/perl )
+	png? ( >=media-libs/libpng-1.2.43 )
+	ruby? ( dev-lang/ruby:* )
+	tiff? ( media-libs/tiff )
+	truetype? ( >=media-libs/freetype-2 )
+	X? (
+		x11-libs/libXext
+		x11-libs/libXt
+		x11-libs/libICE
+		x11-libs/libSM
+	)"
+DEPEND="
+	${RDEPEND}
+	swig? ( dev-lang/swig )
+"
+
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-gcc6.patch
+	"${FILESDIR}"/${P}-g++.patch
+	"${FILESDIR}"/${P}-dcraw.patch
+	"${FILESDIR}"/${P}-php.patch
+)
+
+src_prepare() {
+	default
+
+	# Respect user CFLAGS/CXXFLAGS.
+	sed -i \
+		-e '/C\(XX\)\?FLAGS =/s/-O2//' \
+		-e "\$aCFLAGS += ${CFLAGS}\nCXXFLAGS += ${CXXFLAGS}" \
+		Makefile || die
+
+	# Show commands.  Use qualified CC/CXX.
+	sed -i \
+		-e '/^Q =/d' \
+		-e '/^\t@echo /d' \
+		-e "\$aCC:=$(tc-getCC)\nCXX:=$(tc-getCXX)" \
+		build/bottom.make || die
+
+	# The copied string fits exactly.  Use memcpy to reflect that a null
+	# terminator is not needed.
+	sed -i \
+		-e 's/strcpy(\([^,]*\)\(,["a-zA-Z -]*\))/memcpy(\1\2, sizeof(\1))/' \
+		codecs/tga.cc || die
+
+	# openexr vers 3
+	sed -i \
+		-e 's:Int64:uint64_t:g' \
+		codecs/openexr.cc || die
+
+	# When using PHP, the php-config binary should be specified by slot
+	# Cannot be done in a patch as it is live
+	if use php ; then
+		php-ext-source-r3_src_prepare
+		local slot
+		for slot in $(php_get_slots); do
+			php_init_slot_env "${slot}"
+			sed -i "s~php-config~${PHPCONFIG}~" configure || die
+		done
+	fi
+}
+
+src_configure() {
+	# evas -> enlightenment overlay
+	# bardecode -> protected by custom license
+	# libungif -> not supported anymore
+	# python -> allegedly not python3, but python2 only
+
+	./configure \
+		--prefix=/usr \
+		--libdir=/usr/$(get_libdir) \
+		$(use_with X x11) \
+		$(use_with truetype freetype) \
+		--without-evas \
+		$(use_with jpeg libjpeg) \
+		$(use_with tiff libtiff) \
+		$(use_with png libpng) \
+		--without-libgif \
+		--without-jasper \
+		$(use_with openexr) \
+		$(use_with expat) \
+		--without-lcms \
+		--without-bardecode \
+		$(use_with lua) \
+		$(use_with swig) \
+		$(use_with perl) \
+		--without-python \
+		--without-php \
+		$(use_with ruby) || die
+	if use php; then
+		local slot
+		for slot in $(php_get_slots); do
+			php_init_slot_env "${slot}"
+			./configure \
+				--prefix=/usr \
+				--libdir=/usr/$(get_libdir) \
+				--without-x11 \
+				$(use_with truetype freetype) \
+				--without-evas \
+				$(use_with jpeg libjpeg) \
+				$(use_with tiff libtiff) \
+				$(use_with png libpng) \
+				--without-jasper \
+				--without-libgif \
+				$(use_with openexr) \
+				$(use_with expat) \
+				--without-lcms \
+				--without-bardecode \
+				--without-lua \
+				--with-swig \
+				--without-perl \
+				--without-python \
+				--with-php \
+				--without-ruby || die
+		done
+	fi
+}
+
+src_compile() {
+	default
+	if use php ; then
+		local slot
+		for slot in $(php_get_slots); do
+			php_init_slot_env "${slot}"
+			# Copy built objects from default
+			cp -a "${S}/objdir" . || die
+			emake
+		done
+	fi
+}
+
+src_install() {
+	default
+	if use php ; then
+		local slot
+		for slot in $(php_get_slots); do
+			php_init_slot_env "${slot}"
+			exeinto "${EXT_DIR#$EPREFIX}"
+			newexe objdir/api/php/ExactImage.so "${PHP_EXT_NAME}.so"
+		done
+		php-ext-source-r3_createinifiles
+	fi
+}